How to use IF function in Excel: examples for text, numbers, dates, blanks

In this article, you will learn how to build an Excel IF statement for different types of values as well as how to create multiple IF statements.

IF is one of the most popular and useful functions in Excel. Generally, you use an IF statement to test a condition and to return one value if the condition is met, and another value if the condition is not met.

In this tutorial, we are going to learn the syntax and common usages of the Excel IF function, and then take a closer look at formula examples that will hopefully prove helpful to both beginners and experienced users.

IF function in Excel

IF is one of logical functions that evaluates a certain condition and returns one value if the condition is TRUE, and another value if the condition is FALSE.

The syntax of the IF function is as follows:

IF(logical_test, [value_if_true], [value_if_false])

As you see, IF takes a total of 3 arguments, but only the first one is obligatory, the other two are optional.

Logical_test (required) - the condition to test. Can be evaluated as either TRUE or FALSE.

Value_if_true (optional) - the value to return when the logical test evaluates to TRUE, i.e. the condition is met. If omitted, the value_if_false argument must be defined.

Value_if_false (optional) - the value to return when the logical test evaluates to FALSE, i.e. the condition is not met. If omitted, the value_if_true argument must be set.

Basic IF formula in Excel

To create a simple If then statement in Excel, this is what you need to do:

  • For logical_test, write an expression that returns either TRUE or FALSE. For this, you'd normally use one of the logical operators.
  • For value_if_true, specify what to return when the logical test evaluates to TRUE.
  • For value_if_false, specify what to return when the logical test evaluates to FALSE. Though this argument is optional, we recommend always configuring it to avoid unexpected results. For the detailed explanation, please see Excel IF: things to know.

As an example, let's write a very simple IF formula that checks a value in cell A2 and returns "Good" if the value is greater than 80, "Bad" otherwise:

=IF(B2>80, "Good", "Bad")

This formula goes to C2, and then is copied down through C7: Basic IF formula in Excel.

In case you wish to return a value only when the condition is met (or not met), otherwise - nothing, then use an empty string ("") for the "undefined" argument. For example:

=IF(B2>80, "Good", "")

This formula will return "Good" if the value in A2 is greater than 80, a blank cell otherwise: IF formula to return nothing when the condition is not met.

Excel If then formula: things to know

Though the last two parameters of the IF function are optional, your formula may produce unexpected results if you don't know the underlying logic.

If value_if_true is omitted

If the 2nd argument of your Excel IF formula is omitted (i.e. there are two consecutive commas after the logical test), you'll get zero (0) when the condition is met, which makes no sense in most cases. Here is an example of such a formula:

=IF(B2>80, , "Bad")

To return a blank cell instead, supply an empty string ("") for the second parameter, like this:

=IF(B2>80, "", "Bad")

The screenshot below demonstrates the difference: The behavior of the value_if_true argument.

If value_if_false is omitted

Omitting the 3rd parameter of IF will produce the following results when the logical test evaluates to FALSE.

If there is just a closing bracket after value_if_true, the IF function will return the logical value FALSE. Quite unexpected, isn't it? Here is an example of such a formula:

=IF(B2>80, "Good")

Typing a comma after the value_if_true argument will force Excel to return 0, which doesn't make much sense either:

=IF(B2>80, "Good",)

The most reasonable approach is using a zero-length string ("") to get a blank cell when the condition is not met:

=IF(B2>80, "Good", "") The behavior of the value_if_false argument.

Tip. To return a logical value when the specified condition is met or not met, supply TRUE for value_if_true and FALSE for value_if_false. For the results to be Boolean values that other Excel functions can recognize, don't enclose TRUE and FALSE in double quotes as this will turn them into normal text values.

Using IF function in Excel - formula examples

Now that you are familiar with the IF function's syntax, let's look at some formula examples and learn how to use If then statements in real-life scenarios.

Excel IF function with numbers

To build an IF statement for numbers, use logical operators such as:

  • Equal to (=)
  • Not equal to (<>)
  • Greater than (>)
  • Greater than or equal to (>=)
  • Less than (<)
  • Less than or equal to (<=)

Above, you have already seen an example of such a formula that checks if a number is greater than a given number.

And here's a formula that checks if a cell contains a negative number:

=IF(B2<0, "Invalid", "")

For negative numbers (which are less than 0), the formula returns "Invalid"; for zeros and positive numbers - a blank cell. A formula to check if a cell contains a negative number.

Excel IF function with text

Commonly, you write an IF statement for text values using either "equal to" or "not equal to" operator.

For example, the following formula checks the Delivery Status in B2 to determine whether an action is required or not:

=IF(B2="delivered", "No", "Yes")

Translated into plain English, the formula says: return "No" if B2 is equal to "delivered", "Yes" otherwise. Using the IF function with text.

Another way to achieve the same result is to use the "not equal to" operator and swap the value_if_true and value_if_false values:

=IF(C2<>"delivered", "Yes", "No")

Notes:

  • When using text values for IF's parameters, remember to always enclose them in double quotes.
  • Like most other Excel functions, IF is case-insensitive by default. In the above example, it does not differentiate between "delivered", "Delivered", and "DELIVERED".

Case-sensitive IF statement for text values

To treat uppercase and lowercase letters as different characters, use IF in combination with the case-sensitive EXACT function.

For example, to return "No" only when B2 contains "DELIVERED" (the uppercase), you'd use this formula:

=IF(EXACT(B2,"DELIVERED"), "No", "Yes") Case-sensitive IF statement for text values.

If cell contains partial text

In situation when you want to base the condition on partial match rather than exact match, an immediate solution that comes to mind is using wildcards in the logical test. However, this simple and obvious approach won't work. Many functions accept wildcards, but regrettably IF is not one of them.

A working solution is to use IF in combination with ISNUMBER and SEARCH (case-insensitive) or FIND (case-sensitive).

For example, in case "No" action is required both for "Delivered" and "Out for delivery" items, the following formula will work a treat:

=IF(ISNUMBER(SEARCH("deliv", B2)), "No", "Yes") IF cell contains partial text.

For more information, please see:

Excel IF statement with dates

At first sight, it may seem that IF formulas for dates are akin to IF statements for numeric and text values. Regrettably, it is not so. Unlike many other functions, IF does recognize dates in logical tests and interprets them as mere text strings. In other words, you cannot supply a date in the form of "1/1/2020" or ">1/1/2020". To make the IF function recognize a date, you need to wrap it in the DATEVALUE function.

For example, here's how you can check if a given date is greater than another date:

=IF(B2>DATEVALUE("7/18/2022"), "Coming soon", "Completed")

This formula evaluates the dates in column B and returns "Coming soon" if a game is scheduled for 18-Jul-2022 or later, "Completed" for a prior date. Excel IF statement with dates.

Of course, there is nothing that would prevent you from entering the target date in a predefined cell (say E2) and referring to that cell. Just remember to lock the cell address with the $ sign to make it an absolute reference. For instance:

=IF(B2>$E$2, "Coming soon", "Completed")

To compare a date with the current date, use the TODAY() function. For example:

=IF(B2>TODAY(), "Coming soon", "Completed")

Excel IF statement for blanks and non-blanks

If you are looking to somehow mark your data based on a certain cell(s) being empty or not empty, you can either:

  • Use the IF function together with ISBLANK, or
  • Use the logical expressions ="" (equal to blank) or <>"" (not equal to blank).

The table below explains the difference between these two approaches with formula examples.

  Logical test Description Formula Example
Blank cells =""

Evaluates to TRUE if a cell is visually empty, even if it contains a zero-length string.

Otherwise, evaluates to FALSE.

 =IF(A1="", 0, 1)

Returns 0 if A1 is visually blank. Otherwise returns 1.

If A1 contains an empty string (""), the formula returns 0.
ISBLANK()

Evaluates to TRUE is a cell contains absolutely nothing - no formula, no spaces, no empty strings.

Otherwise, evaluates to FALSE.

 =IF(ISBLANK(A1), 0, 1)

Returns 0 if A1 is absolutely empty, 1 otherwise.

If A1 contains an empty string (""), the formula returns 1.
Non-blank cells <>"" Evaluates to TRUE if a cell contains some data. Otherwise, evaluates to FALSE.

Cells with zero-length strings are considered blank.

 =IF(A1<>"", 1, 0)

Returns 1 if A1 is non-blank; 0 otherwise.

If A1 contains an empty string, the formula returns 0.
ISBLANK()=FALSE Evaluates to TRUE if a cell is not empty. Otherwise, evaluates to FALSE.

Cells with zero-length strings are considered non-blank.

 =IF(ISBLANK(A1)=FALSE, 0, 1)

Works the same as the above formula, but returns 1 if A1 contains an empty string.

And now, let's see blank and non-blank IF statements in action. Suppose you have a date in column B only if a game has already been played. To label the completed games, use one of these formulas:

=IF(B2="", "", "Completed")

=IF(ISBLANK(B2), "", "Completed")

=IF($B2<>"", "Completed", "")

=IF(ISBLANK($B2)=FALSE, "Completed", "")

In case the tested cells have no zero-length strings, all the formulas will return exactly the same results: IF statement for blank and non-blank cells.

Check if two cells are the same

To create a formula that checks if two cells match, compare the cells by using the equals sign (=) in the logical test of IF. For example:

=IF(B2=C2, "Same score", "") Check if two cells contain the same values.

To check if the two cells contain same text including the letter case, make your IF formula case-sensitive with the help of the EXACT function.

For instance, to compare the passwords in A2 and B2, and returns "Match" if the two strings are exactly the same, "Do not match" otherwise, the formula is:

=IF(EXACT(A2, B2), "Match", "Don't match") Case-sensitive IF formula to check if two cells match.

IF then formula to run another formula

In all of the previous examples, an Excel IF statement returned values. But it can also perform a certain calculation or execute another formula when a specific condition is met or not met. For this, embed another function or arithmetic expression in the value_if_true and/or value_if_false arguments.

For example, if B2 is greater than 80, we'll have it multiplied by 7%, otherwise by 3%:

=IF(B2>80, B2*7%, B2*3%) IF formula that runs another formula.

Multiple IF statements in Excel

In essence, there are two ways to write multiple IF statements in Excel:

  • Nesting several IF functions one into another
  • Using the AND or OR function in the logical test

Nested IF statement

Nested IF functions let you place multiple IF statements in the same cell, i.e. test multiple conditions within one formula and return different values depending on the results of those tests.

Assume your goal is to assign different bonuses based on the score:

  • Over 90 - 10%
  • 90 to 81 - 7%
  • 80 to 70 - 5%
  • Less than 70 - 3%

To accomplish the task, you write 3 separate IF functions and nest them one into another like this:

=IF(B2>90, 10%, IF(B2>=81, 7%, IF(B2>=70, 5%, 3%))) Nested IF statement.

For more formula examples, please see:

Excel IF statement with multiple conditions

To evaluate several conditions with the AND or OR logic, embed the corresponding function in the logical test:

For example, to return "Pass" if both scores in B2 and C2 are higher than 80, the formula is:

=IF(AND(B2>80, C2>80), "Pass", "Fail")

To get "Pass" if either score is higher than 80, the formula is:

=IF(OR(B2>80, C2>80), "Pass", "Fail") Excel IF statement with multiple conditions.

For full details, please visit:

If error in Excel

Starting from Excel 2007, we have a special function, named IFERROR, to check formulas for errors. In Excel 2013 and higher, there is also the IFNA function to handle #N/A errors.

And still, there may be some circumstances when using the IF function together with ISERROR or ISNA is a better solution. Basically, IF ISERROR is the formula to use when you want to return something if error and something else if no error. The IFERROR function is unable to do that as it always returns the result of the main formula if it isn't an error.

For example, to compare each score in column B against the top 3 scores in E2:E4, and return "Yes" if a match is found, "No" otherwise, you enter this formula in C2, and then copy it down through C7:

=IF(ISERROR(MATCH(B2, $E$2:$E$4, 0)), "No", "Yes" ) If error formula in Excel.

For more information, please see IF ISERROR formula in Excel.

Hopefully, our examples have helped you get a grasp of the Excel IF basics. I thank you for reading and hope to see you on our blog next week!

Practice workbook

Excel IF statement - formula examples (.xlsx file)

Table of contents

4719 comments

  1. I have an excel sheet I am working on and can't figure out the formula to use.
    So I have column G "Procedure Type" (Example: XXX, YYY, ZZZ) and column L Start date. If Coumn G is XXX, I need it to calculate how many cells in column L has a date (not counting the blank cells).

  2. Hi!
    Thanks for your article. I have some work to do more. Is there any way to put “else condition” into another column?

    Thank You.

  3. hi, I tried to write a formula about if a certain column appear a certain key word "gas", then the column of CoC equal the column contractor, or appear "na"
    =IF([@[Facility
    Owner]]="gas",[@COC]=[@[Contractor
    /Excavator]],"na")

    it appear" na" correctly if the value is not "gas", but when the context is gas, the value appear 0, I don't know how to fix this problem. can you help?

    • Hi! I can't check your formula because I don't have your data. When the context is "gas" then the expression [@COC]=[@[Contractor/Excavator]] is fulfilled and returned FALSE or zero.

  4. Seeking help on how to assign formula if you have a range of variables

    For example

    If the cell contains 0, then the result should be 0
    If the cell contains Nos 1 - 5, then the result should be A
    If the cell contains Nos 6 - 10, then the result should be B
    If the cell contains Nos 11 - 15, then the result should be C
    ....

  5. I work in a Coffee plantations where our estates are coded in the following format:
    "EAPCPK51" - The first three letters denote the estate name, "EAP", the second three letters denote the division name, "CPK" and finally the number denotes the block number. How do I decode these codes into three columns namely, estate, division and block number. Is there a formula for this?

  6. I'm building an attendance tracker where several conditions must be met.
    Cell B4 - Duration >4.00 or <4.00
    Cell C4 - Reason = Illness/Injury, Family Emergency, Other
    Cell D4 - Excused/Unexcused = Unexcused
    Cell E4 - IF B4 is greater than 4.00 and all other conditions are met, result is be 1.00; IF B4 is less than 4.00 and all other conditions are met, result is 0.50; IF D4=Excused (regardless of other conditions), result is 0.00

      • A little more direction is needed. Are you able to show me the formula?

        • =IF(AND(B4>=4.00, c4="Illness/Injury""Family Emergency","Other") D4="Unexcused"), "1.00", IF(AND(B4<4.00, c4="Illness/Injury""Family Emergency""Other"), D4="Unexcused"), "0.50")

      • Correction...here is the formula I used... Still getting tripped up somewhere.
        =IF(AND(B4>=4.00), (c4="Illness/Injury","Family Emergency","Other"), (D4="Unexcused"), "1.00", IF(AND(B4<4.00), (c4="Illness/Injury","Family Emergency","Other"), (D4="Unexcused"), "0.50")))

        • Hi!If one of several conditions is true, I recommend using IF OR statement. For example

          =IF(AND(B4>=4,OR(C4="Illness/Injury",C4="Family Emergency",C4="Other"),D4="Unexcused"), "1.00", IF(AND(B4<4,OR(C4="Illness/Injury",C4="Family Emergency",C4="Other"),D4="Unexcused"),"0.50"))

  7. Basically, what I need is:

    If H2 is "A" then enter 234 in K2, OR if H2 is "AB" then enter 456 in K2, etc...etc...

    Note. This sequence has four letter to number combinations.

    Thank you

  8. Hello, I have columns that has "Yes, No, Yes" as an answer. If I have all 3 as "Yes, No, Yes", my formula should reflect "Yes". And if one of the 3 has a different answer, (i.e "No, No, Yes"), my formula should reflect as a "No". How can I do this?

    i.e Column H = Yes, Column J= No, and Column K=Yes and result in Column N should be Yes.
    if Column H answer is No then Column N Should reflect as NO

    • Hi!
      If I understand your task correctly, the following formula should work for you:

      =IF((H1="Yes")+(J1="Yes")+(K1="Yes")>1,"Yes","No")

      • Thank you for your help Alexander. Unfortunately, it did not work.
        (H1=Yes)+(J1=No)+(K1=Yes) should give me a result of "Yes"
        And all other combinations should result as "No"

        I tried and modified the above given formula but it does not work as I want it to be.

        • Hi! The formula I sent to you was created based on the description you provided in your first request. However, as far as I can see from your second comment, your task is now different from the original one.
          Use IF AND statements:

          =IF(AND((H1="Yes"),(J1="No"),(K1="Yes")),"Yes","No")

          • Hi! Sorry if I was not clear on my first message. The new formula worked! Thank you

  9. I am trying to write a nested formula. In cells A25:C25, the value is either "Paid" or "Unpaid". I would like to write a formula in a single cell (G30) such that the IF statement evaluates the entire range (A23:C25) ... if the value of a cell = "Paid", do nothing and move to next cell in the range, ... but ... if the value of the cell = "Unpaid", I want the value of another cell to be added together (Cell G30 should return either 0 or a SUM (of all cells in this range =Unpaid)).

    For example, if A25="Paid", do nothing and move to B25. If B25= "Unpaid", go to B23 and capture that value (5), then go to C25. If C25="Unpaid", go to C23 and capture that value (10). Now add B23 + C23 (but not A23). If this can work, the return value on G30 would be "15" (because two of the cells in the range =Unpaid, so their associated values (in Row 23) were added together.

    I tried IF with AND and with OR, but I could not get the "calculate across the range" to work; I keep getting errors or the value of only one cell (like B23). I cannot get the SUM calculation to work properly.

  10. Hello,

    I have a column with different values "RN, OT, PCC, " I am trying to ask if J2 = RN, match H2 cell to these values, if the value matches return 4 or 5, and so on if cell J3 matches RN, Ot, Pcc, and give them all different values to match?

    =IFERROR(J2="RN",IF(AND(H2>=1.48,H2=1.47,H2=1.63,0,0))))*IF(J2="PT",AND(H2=1.19,H2>=1.33,4,IF(H2=1.34,0,0))))

  11. I'm trying to do a long list of variable consequences. The line I am trying to do is, in simple terms, IF cell=A, 1,m if cell =B, 2 etc. But I am getting an error that it is not complete.

    • Never mind, I found my error. Thank you.

  12. I have sheet as: rows has days like: sunday, monday etc for a whole month and column has present or absent. now i want to make formula which will give me count of how many days someone absent on friday and saturday on that month

  13. Create a formula in cell I4 that displays the word Yes if the value in cell H4 is less than the discontinue threshold in cell B21, otherwise the word No is displayed. Your formula must use an appropriate reference to cell B21 so that it will copy correctly. Make sure to use structured references when referencing cells in the table.

  14. I need help with a formula that will look at Column A and compare it to Column B in sheet 1. If there is a number in column B in sheet 1 display the contents of column A in sheet 2, if it is blank display "Need" where the number would go in sheet 2.

  15. Hello,
    I have a formula that will pull registered number of attendees over expected when there is a value. However, there can be duplicated rows of registered attendee numbers. I inserted another formula into the J column to flag this and it inputs the text "duplicate".
    Is there a way to add to the formula below to input 0 into I2 when the "duplicate" text exists"?
    =IF(I2="",G2,I2)
    Thank you,
    Lisa

  16. I am trying to have a column that states if a specific cell has a number greater than or equal to 30 than show "overdue" otherwise blank. I am using this formula [=IF($J5>= 30, "OVERDUE", "")]

    however it also will mark overdue for the J column cells that have the formula [=IF(G4>1, TODAY()-G4, "")] in their cell even if the cell is technically blank. How do I exclude the formula and only look for cells that have a number value greater than or equal to 30

    • Hi!
      Based on your description, it is hard to completely understand your task. However, I’ll try to guess and recommend using ISFORMULA function to check whether a cell contains a value or a formula.
      If this is not what you wanted, please describe the problem in more detail.

      • I have column J contains the formula =IF(G4>1, TODAY()-G4, "") and I want to use the formula =IF($J5>= 30, "OVERDUE", "") in column K so that it showcases whether a specific entry has been over 30 days. The formula for K works except that it also puts a value in column K for rows that column J is technically empty but still contains the formula text string. I am looking to find a way where the column k formula will only place "overdue" when connected to a number value >=30 and exclude those cells with the formula text string. Hope that makes sense.

  17. I have a list of names in one column with a column of one of 9 possible values associated with it. e.g A1 = Alan, B1 = Apple, and Apple & Alan are associated.

    I want to visually show by variable the names associated with that variable, ideally in a 9 box chart. E.g under the variable Apple would be all the names associated with Apple. Under Banana would be all the names associated with Banana, is there a way with a nested IF statement to print those names automatically? The list will change periodically so want to avoid manual intervention is possible.

    Thanks!

  18. I'm trying to do a combination of an If then statement and a textjoin function.

    Common language of what I'm trying to say if A26:A167="SB", then TEXTJOIN C26:C167 together into one cell for the ones that match "SB"

    I'm at: =IF(A26:A167="SB",(TEXTJOIN("",TRUE,C26:C167)))

    This will dump all the email addresses into one field that are marked SB.

    I am getting a #SPILL! error.

    • I think I figured it out...not sure if it is the most efficient or best formula, but it seems to work.

      =TEXTJOIN("; ",TRUE,IF(A26:A167="SB",C26:C167,""))

  19. =IF(G3>H3,H3,G3)
    am using this calculation to identify if G3 greater than H3, but I also need the reverse if H3 <G3, needs to be value G3, unsure how to add this into formula
    Need excel to distinguish greater value over both columns
    Hope this makes sense!

  20. Hello,

    I want to highlight column A one color depending on specific name in column G of the same line.

  21. Hi, I am trying to write an if-formula where, if the value is true, the outcome should but 0, but if the outcome is false, a formula should calculate a value. So far this is what I have got: "=IF(F4="Yes",0,(G4+J4)-(E4+H4+I4))". However, this does not work. Is this idea possible or should I implement this in a different way?

    • I got it! The answer was "=IF(F4="Yes";0;(G4+J4)-(E4+H4+I4))"

  22. Hello, good day!
    I need a formula for my sheet that automatically updates my cell as "Updated Recently" if the date I entered is within this week, if not it should be automatically update with just a blank.

    For example:
    [Cell1] Last Sale: March 10 (within a week) = [Cell2] Status: Updated Recently
    [Cell1] Last Sale: Feb 27 (Last week/last month) = [Cell2] Status:

  23. What shall I write in logic test,value true and value false while doing my ecxel program

  24. **Correction to my previous question: need help with this formula- If the date in cell W2 > date in cell Q2, then return the number that is in cell AB2, if not then return number in cell T2

  25. need help with this formula- If the date in cell W2 > date in cell Q2, then return the number that is in column T2

    • Hi!
      All the necessary information is in the article above. Since the dates in Excel are numbers, you can compare them as numbers.

  26. I want help writing a formula where on an expenditure sheet there are two 'company names' which amounts spent ge assigned to. The formula I require is to automatically take the amounts from the other sheet and list the amount assigned to either company on diiferent cells under the heading of the company name.

  27. Hi. I need a formula to populate the name of the counselor assigned to a student based on a students last name. I have a list of student's last names on column G and I have the the counselors names on a different sheet within the same workbook. Please help. I got it to work if I place the counselors names on the same sheet where the student information is located but if I delete a student, it will mess with the formula.

  28. Hi, Im trying to find a formula to search from column D2 to D10 for an exact name if there is to print yes if not to print no.

    First name Last name
    1 John Smith
    2 Mike Hunt
    3 Sam Isaco

    So basically what I want to do is if the certain name and last name are found in these columns to print yes

    Is this possible?

    Thank you

    • Hello!
      If I understand your task correctly, you can define a partial match of a word and a text string with the combination ISNUMBER + SEARCH functions.

      =ISNUMBER(SEARCH("Smith",A1:A20))

      I hope it’ll be helpful. If this is not what you wanted, please describe the problem in more detail.

  29. Hi, Can you please help me, in Excel if column A2 value= Column B value, then only compare column C value with column D value and provide result in column E.
    Example:

    1234 END 1234 CERIAL END
    1234 FORNT 1234 BACK FRONT
    1234 ARIAL 1234 GAME9 N/A
    1234 GAME 1234 GAME2 GAME2
    1234 GAME 6 1234 GAME8 N/A
    1234 GAME9 1234 GAME7 GAME9
    1234 GAME2 1234 FRONT N/A
    1234 GAME3 1234 CHANG N/A
    1234 GAME1 1234 END N/A

  30. Hi,

    I'm not sure if anyone can help with what I think should be a relative simple formula that I'm stuck on. I need to create and IF or an AND formula that will look at two arguments that both need to be be True, one argument is checking that a Date is =>2023,1,1 and another cell contains an exact text "Vacancy".

    I have managed to get the Date check to work, however I have no idea how to add the AND argument to check the text in the other cell, I currently have the following formula:

    =IF(A2>=DATE(2023,1,1),"Yes","No")

    The person should only be entitled to the payment if the Date is >=2023,1,1 and that the Role (text) in cell B2 is "Vacancy".

    Thank you for your help.

      • Brilliant! Thank you so much for your help, this has worked perfectly. I could not work out where the AND should go. Thank you.

  31. How can i categorize the cell content based on the starting letter. (Example:- Different grade of fruits has code like a123, b123 etc., i want to categorize the fruits as "A grade" for the code that starts with "a".

      • Thank for your prompt response Mr. Alexander

        i have list of materials in row A which has two types of material codes one type starts with alphabet like "S123, S234 and so on" which is semi finished and another code was only numeric it was finished goods. In row D i need the codes which starts with alphabetic should name as "Semifinished" and numeric code as "Finished goods". i believe that i gave you the clarity to derive the formula.

        • Hello!
          This formula returns TRUE if the first character is a letter.

          =ISERROR(--LEFT(A1,1))

          I hope this will help, otherwise don't hesitate to ask.

          • Yes, it's working but it will be convenient if the formula returns to any name instead of TRUE or FALSE.

    • I have 3 options in source column instead of two so how should I do
      For example
      If IND2522 - it should reflect in colour as India
      If BNG2522 - it should be reflect as Bangladesh
      If PAK2522 - it should be reflect as Pakistan

      • Hi! Please clarify your specific problem or provide additional details to highlight exactly what you need. As it's currently written, it's hard to tell exactly what you're asking.

  32. Logical Text in A1 Cell ,TRUE Value in A2 and FALSE Value in A3
    i write IF Function in A4 = IF(A1,A2,A3)
    but it doesn't work properly. it will prompt Error Massage (#Value!)
    so can i put LOGICAL TEXT in cell.

  33. Hello. Please help provide the formula for a cell L23 to either show "N" if less than a certain date such as 02/15/2023 and "N" if passed that date in A23, thank you!

    • Hi!
      Pay attention to the following paragraph of the article above: Excel IF statement with dates.
      It covers your case completely.

  34. Hey Friends,

    Donno if this Forum works now:

    I am trying to figure out a formula for the following:
    I have 3 Columns : viz : A1,D1, L1 with text contents. And output expected in M1

    So if All of the 3 cells A,D,L are Blank, Then out put should be "Spare",
    If any of the 3 cells mentions : "In Stock", Output should be "In Stock",
    If any of the 3 cells mentions : "Faulty", Output should be "Faulty",
    Else if any columns has any text it should show " Mapped"

    • Hi!
      Combine cell values and search for the desired text using the SEARCH function. Use a nested IF function to display values based on conditions.
      Try this formula:

      =IF(ISNUMBER(SEARCH("In Stock",A1&D1&L1)),"In Stock", IF(ISNUMBER(SEARCH("Faulty",A1&D1&L1)),"Faulty", IF(A1&D1&L1="","Spare","Mapped")))

  35. i need to calculate the hours of the roster of the month of each staff (M=6.5, E=6.5 , N=8, O=0) please help

  36. Hi!
    I am trying to get my IF statement to take a current number, and if it is over 40, bring it down to 40. If it is under 40 I want to leave it at 40.

    I have attempted the formula =IF(E10>40, 40, E10) I just don't know what to put in the false statement, to keep it at the current value it was at if under 40.

    Thanks for the help!

  37. Hi,

    =IF(B1=5 and C1=3, "Good combination", how i can use this formula

    Kindly confirm.

  38. I'm trying to create a formula to help build a table for a student outcome report.
    A B C D
    1 Comm 1010 Comm 2010 Comm 3000
    2 Communication 2 4
    3 Critical/Creative Thinking 5
    4 Community Awareness 3 4

    If any text in Column A=Communication and any text in Row 1= Comm 1010, then show the number for that combination. In this example, 2 would be displayed.

    If any text in Column A=Critical* and any text in Row 1=Comm 2010*, then show the number for that combination. In this example, 5 would be displayed. I need to be able to use a wildcard for both text options.

    If there is no number in the cell, then leave it blank.

    The numbers will be sent to a different sheet. Right now, I have to sort both sheets so everything lines up. I am hoping there is a formula that will pull over the numbers and I don't have to sort anything.

  39. Can you help? What is the correct IF formula for - Should Grunar continue to make the part or buy it from the supplier? #2 question below.

    Complete the schedule to support the decision of whether to make or buy the part.

    Relevant Costs to Make Relevant Cost to Buy
    Direct materials $2.80
    Direct labor 1.70
    Variable manufacturing overhead 0.50
    Fixed manufacturing overhead 0.40
    Total cost $5.40 $6.25

    #2. Should Grunar continue to make the part or buy it from the supplier?

    Grunar should
    ** Function: IF; Cell reference.
    Input the IF function with cell references to this work with output of "make the part." and "buy the part." for the decision.

  40. Hello, good day,
    I want to extract in sheet 1 from sheet 2 the value(text) and is if there is not text to writre no text, or if is blank to write no text, sample.
    Sheet 2 FM "NAME", copy in sheet 1 that name, and if there is not name to write "No Name", i try many ways and always i have error, i try with
    =if(Sheet2!C15="","","No mane") but don't copy the name if is there!!! as well =TEXT(Claudio!C15,IF(ISBLANK(Claudio!C15),"NO FM"))
    please can you help me,

    • Hi!
      All the necessary information is in the article above.
      If I understand your task correctly, try the following formula:

      =IF(Sheet2!C15="","No mane",Sheet2!C15)

  41. 0 points if the employee age is less than 27.
    5 points if the employee age is between 27 and 30.
    10 points if the employee age is between 30 and 33.
    15 points if the employee age is between 33 and 35.
    SDP:
    0 points if the employee is not an SP.
    15 points if the employee is an Sp
    GPA:
    5 points if the employee GPA is between 2 and 2.3.
    10 points if the employee GPA is between 2.3 and 2.5.
    15 points if the employee GPA is between 2.5 and 2.7.
    20 points if the employee GPA is between 2.7 and 2.9.
    25 points if the employee GPA is greater than 2.9.

  42. hi i want to create a formula =if(colum A:A=name of a product = colum B:B) is it posible?

    • Hi!
      Please clarify your problem and provide additional details to highlight exactly what you need. As it's currently written, it's hard to tell exactly what you're asking.

  43. I have an xlookup (in 'Bill 1-9-23'!E2) is used to find a three letter code (AIHP or UCH) in col E of 'Client Roster', that works :
    =XLOOKUP('Bill 1-9-23'!A2,'Client Roster'!A:A,'Client Roster'!E:E,"")

    Then in 'Bill 1-9-23'!G2 I want to use an IF to determine if I found AIHP or UCH and make different results, so:
    =IF(E2="AIHP",500,350)

    It always returns 350 (FAILED), even when E2 is displaying AIHP.
    If I enter a number in Client Roster'!E2 and logically test against that, then it works.

    Thank you for yourhelp, in advance.
    LH

  44. I'm trying to work on a formula; say
    I type in the value 5857 in D12
    Then, if the value i typed has it's first three values matching the first three values of any cell in the range A2:A35 counting from the left, pick the corresponding value on the right

    So if the one I entered has its first three values counting from the left matching that of A14... Both values are matching 587, it will pick the corresponding value on B14 then add it to the cell C8

    i did something like this
    =IF(AND(LEFT(A18:A213,3)=LEFT(A2,3),RIGHT(A2,1)="0"),B18:B213+C8, IF(AND(LEFT(A18:A213,3)=LEFT(A2,3),RIGHT(A2,1)="1"),B18:B213+C8))

    and I'm getting
    #VALUE

    • Hi!
      Your formula does not match the question. Therefore, your problem is difficult to understand. Note, however, that LEFT(A18:A213,3)=LEFT(A2,3) returns not a single value, but an array of 195 values.

  45. hi.........I have 1 problem
    cell 1 cell 2
    we have text in 1 cell, bellow that cell we want some respective numbers with that text. ex1. A 1
    B 2
    C 3
    AND WE CREATED FOR CELL 1 DROPDOWN LIST SO PLEASE HELP ME....AS SOON AS POSSIBLE
    THANKS

  46. Hi Alex,
    I am trying to build an IF function that will select beneficiaries based on set of criteria. Below is the Formula I have used =IF(T35,IF(BD3="Yes",IF(BE3<=2,"Selected""Not Selected")))))))))))

    Kindly advise as the result of the function keeps coming out as "FALSE"

  47. Hi Alexander,
    I am attempting to streamline repetitive data entry by using Sheet 1 as a 'controlled data' sheet, where data can be identified and automatically transferred across to new worksheets/cells when data is being entered. I'd like the active cells to recognise various text codes such as EDT01, EDT02, EDT03,etc, and transfer selected information from various cells across to the same cell location in the new work sheet.

    In essence, when entering data for EDT01 into the new worksheet, columns C2, D2 and E2 will have the same specific size dimensions, therefore rather than continually typing in these dimensions for multiple entries, it would be beneficial to have the code EDT01 identified when typed and the size dimensions automatically filled into these specific columns.

    I'm struggling to explain this in any great detail but hope you get the gist of my problem.

    Thanks you in advance.

    Les McA-B

  48. Good work

  49. I'm trying to work on a formula to say if B22 is equal to 12 multiply the number in D22 by 2, and if B23 is equal 12 then multiply the number in D23 by 2. So on until B30. But if the numbers in B22 to B30 don't contain 12 leave the cell blank. I have the following formula which returns the result FALSE instead of blank.

    =IF((IF($B$22=12,$D$22*2,0)+IF($B$23=12,$D$23*2,0)+IF($B$24=12,$D$24*2,0)+IF($B$25=12,$D$25*2,0)+IF($B$26=12,$D$26*2,0)+IF($B$27=12,$D$27*2,0)+IF($B$28=12,$D$28*2,0)+IF($B$29=12,$D$29*2,0)+IF($B$30=12,$D$30*2,0)),"")

    Can you help on this?

  50. I need formula for condition
    if condition in J15 column is "returned" Than F15=0
    otherwise, it should remain same please make formula for this situation

Post a comment



Thank you for your comment!
When posting a question, please be very clear and concise. This will help us provide a quick and relevant solution to
your query. We cannot guarantee that we will answer every question, but we'll do our best :)