by In this tutorial, we will continue exploring the fascinating world of Excel Conditional Formatting. If you do not feel very comfortable in this area, you may want to look through the previous article first to revive the basics - How to use conditional formatting in Excel.
Today are going to dwell on how to use Excel formulas to format individual cells and entire rows based on the values you specify or based on another cell's value. This is often considered advanced aerobatics of Excel conditional formatting and once mastered, it will help you push the formats in your spreadsheets far beyond their common uses.
Excel conditional formatting based on another cell value
Excel's predefined conditional formatting, such as Data Bars, Color Scales and Icon Sets, are mainly purposed to format cells based on their own values. If you want to apply conditional formatting based on another cell or format an entire row based on a single cell's value, then you will need to use formulas.
So, let's see how you can make a rule using a formula and after discuss formula examples for specific tasks.
How to create a conditional formatting rule based on formula
To set up a conditional formatting rule based on a formula in any version of Excel 2010 through Excel 365, carry out these steps:
- Select the cells you want to format. You can select one column, several columns or the entire table if you want to apply your conditional format to rows.
Tip. If you plan to add more data in the future and you want the conditional formatting rule to get applied to new entries automatically, you can either:
- Convert a range of cells to a table (Insert tab > Table). In this case, the conditional formatting will be automatically applied to all new rows.
- Select some empty rows below your data, say 100 blank rows.
- On the Home tab, in the Styles group, click Conditional formatting > New Rule…
- In the New Formatting Rule window, select Use a formula to determine which cells to format.
- Enter the formula in the corresponding box.
- Click the Format… button to choose your custom format.
- Switch between the Font, Border and Fill tabs and play with different options such as font style, pattern color and fill effects to set up the format that works best for you. If the standard palette does not suffice, click More colors… and choose any RGB or HSL color to your liking. When done, click the OK button.
- Make sure the Preview section displays the format you want and if it does, click the OK button to save the rule. If you are not quite happy with the format preview, click the Format… button again and make the edits.
Tip. Whenever you need to edit a conditional formatting formula, press F2 and then move to the needed place within the formula using the arrow keys. If you try arrowing without pressing F2, a range will be inserted into the formula rather than just moving the insertion pointer. To add a certain cell reference to the formula, press F2 a second time and then click that cell.
Excel conditional formatting formula examples
Now that you know how to create and apply Excel conditional formatting based on another cell, let's move on and see how to use various Excel formulas in practice.
Tip. For your Excel conditional formatting formula to work correctly, please always follow these simple rules.
Formulas to compare values (numbers and text)
As you know Microsoft Excel provides a handful of ready-to-use rules to format cells with values greater than, less than or equal to the value you specify (Conditional Formatting >Highlight Cells Rules). However, these rules do not work if you want to conditionally format certain columns or entire rows based on a cell's value in another column. In this case, you use analogous formulas:
| Condition | Formula example |
|---|---|
| Equal to | =$B2=10 |
| Not equal to | =$B2<>10 |
| Greater than | =$B2>10 |
| Greater than or equal to | =$B2>=10 |
| Less than | =$B2<10 |
| Less than or equal to | =$B2<=10 |
| Between | =AND($B2>5, $B2<10) |
The screenshot below shows an example of the Greater than formula that highlights product names in column A if the number of items in stock (column C) is greater than 0. Please pay attention that the formula applies to column A only ($A$2:$A$8). But if you select the whole table (in our case, $A$2:$E$8), this will highlight entire rows based on the value in column C.
In a similar fashion, you can create a conditional formatting rule to compare values of two cells. For example:
=$A2<$B2 - format cells or rows if a value in column A is less than the corresponding value in column B.
=$A2=$B2 - format cells or rows if values in columns A and B are the same.
=$A2<>$B2 - format cells or rows if a value in column A is not the same as in column B.
As you can see in the screenshot below, these formulas work for text values as well as for numbers.
AND and OR formulas
If you want to format your Excel table based on 2 or more conditions, then use either =AND or =OR function:
| Condition | Formula | Description |
|---|---|---|
| If both conditions are met | =AND($B2<$C2, $C2<$D2) |
Formats cells if the value in column B is less than in column C, and if the value in column C is less than in column D. |
| If one of the conditions is met | =OR($B2<$C2, $C2<$D2) |
Formats cells if the value in column B is less than in column C, or if the value in column C is less than in column D. |
In the screenshot below, we use the formula =AND($C2>0, $D2="Worldwide") to change the background color of rows if the number of items in stock (Column C) is greater than 0 and if the product ships worldwide (Column D). Please pay attention that the formula works with text values as well as with numbers.
Naturally, you can use two, three or more conditions in your AND and OR formulas. To see how this works in practice, watch Video: Conditional formatting based on another cell.
These are the basic conditional formatting formulas you use in Excel. Now let's consider a bit more complex but far more interesting examples.
Conditional formatting for empty and non-empty cells
I think everyone knows how to format empty and not empty cells in Excel - you simply create a new rule of the "Format only cells that contain" type and choose either Blanks or No Blanks.
But what if you want to format cells in a certain column if a corresponding cell in another column is empty or not empty? In this case, you will need to utilize Excel formulas again:
Formula for blanks: =$B2="" - format selected cells / rows if a corresponding cell in Column B is blank.
Formula for non-blanks: =$B2<>"" - format selected cells / rows if a corresponding cell in Column B is not blank.
Note. The formulas above will work for cells that are "visually" empty or not empty. If you use some Excel function that returns an empty string, e.g. =if(false,"OK", ""), and you don't want such cells to be treated as blanks, use the following formulas instead =isblank(A1)=true or =isblank(A1)=false to format blank and non-blank cells, respectively.
And here is an example of how you can use the above formulas in practice. Suppose, you have a column (B) which is "Date of Sale" and another column (C) "Delivery". These 2 columns have a value only if a sale has been made and the item delivered. So, you want the entire row to turn orange when you've made a sale; and when an item is delivered, a corresponding row should turn green. To achieve this, you need to create 2 conditional formatting rules with the following formulas:
- Orange rows (a cell in column B is not empty):
=$B2<>"" - Green rows (cells in column B and column C are not empty):
=AND($B2<>"", $C2<>"")
One more thing for you to do is to move the second rule to the top and select the Stop if true check box next to this rule:
In this particular case, the "Stop if true" option is actually superfluous, and the rule will work with or without it. You may want to check this box just as an extra precaution, in case you add a few other rules in the future that may conflict with any of the existing ones.
For more information, please see Excel conditional formatting for blank cells.
Excel formulas to work with text values
If you want to format a certain column(s) when another cell in the same row contains a certain word, you can use a formula discussed in one of the previous examples (like =$D2="Worldwide"). However, this will only work for exact match.
For partial match, you will need to use either SEARCH (case insensitive) or FIND (case sensitive).
For example, to format selected cells or rows if a corresponding cell in column D contains the word "Worldwide", use the below formula. This formula will find all such cells, regardless of where the specified text is located in a cell, including "Ships Worldwide", "Worldwide, except for…", etc:
=SEARCH("Worldwide", $D2)>0
If you'd like to shade selected cells or rows if the cell's content starts with the search text, use this one:
=SEARCH("Worldwide", $D2)>1
Excel formulas to highlight duplicates
If your task is to conditionally format cells with duplicate values, you can go with the pre-defined rule available under Conditional formatting > Highlight Cells Rules > Duplicate Values… The following article provides a detailed guidance on how to use this feature: How to automatically highlight duplicates in Excel.
However, in some cases the data looks better if you color selected columns or entire rows when a duplicate values occurs in another column. In this case, you will need to employ an Excel conditional formatting formula again, and this time we will be using the COUNTIF formula. As you know, this Excel function counts the number of cells within a specified range that meet a single criterion.
Highlight duplicates including 1st occurrences
=COUNTIF($A$2:$A$10,$A2)>1 - this formula finds duplicate values in the specified range in Column A (A2:A10 in our case), including first occurrences.
If you choose to apply the rule to the entire table, the whole rows will get formatted, as you see in the screenshot below. I've decided to change a font color in this rule, just for a change : )
Highlight duplicates without 1st occurrences
To ignore the first occurrence and highlight only subsequent duplicate values, use this formula: =COUNTIF($A$2:$A2,$A2)>1
Highlight consecutive duplicates in Excel
If you'd rather highlight only duplicates on consecutive rows, you can do this in the following way. This method works for any data types: numbers, text values and dates.
- Select the column where you want to highlight duplicates, without the column header.
- Create a conditional formatting rule(s) using these simple formulas:
Rule 1 (blue):=$A1=$A2- highlights the 2nd occurrence and all subsequent occurrences, if any.
Rule 2 (green):=$A2=$A3- highlights the 1st occurrence.
In the above formulas, A is the column you want to check for dupes, $A1 is the column header, $A2 is the first cell with data.
Important! For the formulas to work correctly, it is essential that Rule 1, which highlights the 2nd and all subsequent duplicate occurrences, should be the first rule in the list, especially if you are using two different colors.
Highlight duplicate rows
If you want apply the conditional format when duplicate values occur in two or more columns, you will need to add an extra column to your table in which you concatenate the values from the key columns using a simple formula like this one =A2&B2. After that you apply a rule using either variation of the COUNTIF formula for duplicates (with or without 1st occurrences). Naturally, you can hide an additional column after creating the rule.
Alternatively, you can use the COUNTIFS function that supports multiple criteria in a single formula. In this case, you won't need a helper column.
In this example, to highlight duplicate rows with 1st occurrences, create a rule with the following formula:
=COUNTIFS($A$2:$A$11, $A2, $B$2:$B$11, $B2)>1
To highlight duplicate rows without 1st occurrences, use this formula:
=COUNTIFS($A$2:$A2, $A2, $B$2:$B2, $B2)>1
Compare 2 columns for duplicates
One of the most frequent tasks in Excel is to check 2 columns for duplicate values - i.e. find and highlight values that exist in both columns. To do this, you will need to create an Excel conditional formatting rule for each column with a combination of =ISERROR() and =MATCH() functions:
For Column A: =ISERROR(MATCH(A1,$B$1:$B$10000,0))=FALSE
For Column B: =ISERROR(MATCH(B1,$A$1:$A$10000,0))=FALSE
Note. For such conditional formulas to work correctly, it's very important that you apply the rules to the entire columns, e.g. =$A:$A and =$B:$B.
You can see an example of practical usage in the following screenshot that highlights duplicates in Columns E and F.
As you can see, Excel conditional formatting formulas cope with dupes pretty well. However, for more complex cases, I would recommend using the Duplicate Remover add-in that is especially designed to find, highlight and remove duplicates in Excel, in one sheet or between two spreadsheets.
Formulas to highlight values above or below average
When you work with several sets of numeric data, the AVERAGE() function may come in handy to format cells whose values are below or above the average in a column.
For example, you can use the formula =$E2<AVERAGE($E$2:$E$8) to conditionally format the rows where the sale numbers are below the average, as shown in the screenshot below. If you are looking for the opposite, i.e. to shade the products performing above the average, replace "<" with ">" in the formula: =$E2>AVERAGE($E$2:$E$8).
How to highlight the nearest value in Excel
If I have a set of numbers, is there a way I can use Excel conditional formatting to highlight the number in that set that is closest to zero? This is what one of our blog readers, Jessica, wanted to know. The question is very clear and straightforward, but the answer is a bit too long for the comments sections, that's why you see a solution here :)
Example 1. Find the nearest value, including exact match
In our example, we'll find and highlight the number that is closest to zero. If the data set contains one or more zeroes, all of them will be highlighted. If there is no 0, then the value closest to it, either positive or negative, will be highlighted.
First off, you need to enter the following formula to any empty cell in your worksheet, you will be able to hide that cell later, if needed. The formula finds the number in a given range that is closest to the number you specify and returns the absolute value of that number (absolute value is the number without its sign):
=MIN(ABS(B2:D13-(0)))
In the above formula, B2:D13 is your range of cells and 0 is the number for which you want to find the closest match. For example, if you are looking for a value closest to 5, the formula will change to: =MIN(ABS(B2:D13-(5)))
Note. This is an array formula, so you need to press Ctrl + Shift + Enter instead of a simple Enter stroke to complete it.
And now, you create a conditional formatting rule with the following formula, where B3 is the top-right cell in your range and $C$2 in the cell with the above array formula:
=OR(B3=0-$C$2,B3=0+$C$2)
Please pay attention to the use of absolute references in the address of the cell containing the array formula ($C$2), because this cell is constant. Also, you need to replace 0 with the number for which you want to highlight the closest match. For example, if we wanted to highlight the value nearest to 5, the formula would change to: =OR(B3=5-$C$2,B3=5+$C$2)
Example 2. Highlight a value closest to the given value, but NOT exact match
In case you do not want to highlight the exact match, you need a different array formula that will find the closest value but ignore the exact match.
For example, the following array formula finds the value closest to 0 in the specified range, but ignores zeroes, if any:
=MIN(ABS(B3:C13-(0))+(10^0*(B3:C13=0)))
Please remember to press Ctrl + Shift + Enter after you finished typing your array formula.
The conditional formatting formula is the same as in the above example:
=OR(B3=0-$C$2,B3=0+$C$2)
However, since our array formula in cell C2 ignores the exact match, the conditional formatting rule ignores zeroes too and highlights the value 0.003 that is the closest match.
If you want to find the value nearest to some other number in your Excel sheet, just replace "0" with the number you want both in the array and conditional formatting formulas.
I hope the conditional formatting formulas you have learned in this tutorial will help you make sense of whatever project you are working on. If you need more examples, please check out the following articles:
Why isn't my Excel conditional formatting working correctly?
If your conditional formatting rule is not working as expected, though the formula is apparently correct, do not get upset! Most likely it is not because of some weird bug in Excel conditional formatting, rather due to a tiny mistake, not evident at the first sight. Please try out 6 simple troubleshooting steps below and I'm sure you will get your formula to work:
- Use absolute & relative cell addresses correctly. It's very difficult to deduce a general rule that will work in 100 per cent of cases. But most often you would use an absolute column (with $) and relative row (without $) in your cell references, e.g.
=$A1>1.Please keep in mind that the formulas
=A1=1,=$A$1=1and=A$1=1will produce different results. If you are not sure which one is correct in your case, you can try all : ) For more information, please see Relative and absolute cell references in Excel conditional formatting. - Verify the applied range. Check whether your conditional formatting rule applies to the correct range of cells. A rule of thumb is this - select all the cells / rows you want to format but do not include column headers.
- Write the formula for the top-left cell. In conditional formatting rules, cell references are relative to the top-left most cell in the applied range. So, always write your conditional formatting formula for the 1st row with data.
For example, if your data starts in row 2, you put
=A$2=10to highlight cells with values equal to 10 in all the rows. A common mistake is to always use a reference to the first row (e.g.=A$1=10). Please remember, you reference row 1 in the formula only if your table does not have headers and your data really starts in row 1. The most obvious indication of this case is when the rule is working, but formats values not in the rows it should. - Check the rule you created. Double-check the rule in the Conditional Formatting Rules Manager. Sometimes, for no reason at all, Microsoft Excel distorts the rule you have just created. So, if the rule is not working, go to Conditional Formatting > Manage Rules and check both the formula and the range it applies to. If you have copied the formula from the web or some other external source, make sure the straight quotes are used.
- Adjust cell references when copying the rule. If you copy Excel conditional formatting using Format Painter, don't forget to adjust all cell references in the formula.
- Split complex formulas into simple elements. If you use a complex Excel formula that includes several different functions, split it into simple elements and verify each function individually.
And finally, if you've tried all the steps but your conditional formatting rule is still not working correctly, drop me a line in comments and we will try to fathom it out together :)
In my next article we are going to look into the capabilities of Excel conditional formatting for dates. See you next week and thanks for reading!
1709 comments
There is a way for a cell to take the format of another, for example:
If a cell has a red background, condition another cell to have the same color.
Hi! You cannot use Excel formulas and functions to determine the background color of a cell. You need to use a custom user-defined function to do this. For an example of such a function, see this article: How to sum and count cells by color in Excel.
Fill cell K1 with the color you want to use in the formatting condition (red background). For example, create a conditional formatting rule with a formula for the range B1:B20.
Here is an example of such a formula:
=CountCellsByColor(A1,$K$1)=1
As a result, if a cell in column A has a red background, the corresponding cell in column B will be highlighted.
Thank you Alexander for this tutorial, it's really great information. I'm not sure if I might've missed this info, but what I'm trying to do is format one cell (B14) if any of the cells in a certain range contain "No" (P19:P23). I tried this: =$P$19:$P$23="No" applied to B14, but it only gives results when P19 is "No", not when P20, P21, P22, or P23 are "No". Is there a way to achieve my goal in a single formula?
Hello Andrea!
Apply the conditional formatting formula to the range P19:P23
=P19="No"
For the detailed instructions, please see: How to change background color in Excel based on cell value
I am using this formula in cell I3 =IF((W3=""),"",IF(X3>=W3,"Y","N"))
It does give me a blank in I3 when there is no data in W3 and gives me a Y or N when data is entered into W3 and X3 but the problem I now have created is that I have a formula in W3 and therefore it is giving me a Y in I3 when no data has been entered but I want to maintain the blank condition of I3 when there is no data in W3. I am also using Conditional Formatting in I3, so that when a Y is auto entered into I3, the cell will fill with Green colour and when there is an N the cell will fill with Red colour and when it is blank it will be clear. This formula will be loaded into I3 to I40. I have also disabled zero fill for this project as this is only part of a 27 column x 41 row spreadsheet. In closing I thankyou for what ever help you can give me.
Hello Peter!
If there is a formula in cell W3, then there will always be data in that cell. Unfortunately, you did not specify what type of value the formula in cell W3 returns. I can assume that it is a number. Try using 0 in the nested IF formula.
=IF((W3=0),"",IF(X3>=W3,"Y","N"))
If that's not what you need, give more info.
Hello!
I have created a vacation file with conditional formatting. One of these formattings colors certain cells in the date worksheet green as soon as a date is entered in the "Inputs" worksheet. Now, however, I would like to enter a formatting that, once a certain number of cells are colored green, other cells are colored red so that a certain number of vacationers is not exceeded.
Hello Klaus!
You cannot use an Excel formula to count cells that are colored green using conditional formatting.
You can count the number of cells that meet the condition by which you colored them green. You can count the number of cells by this condition using the COUNTIFS function or using the SUMPRODUCT formula.
Since I don't know this condition, I can't give you more precise advice.
Hello! How to highlight cell with date and 7 cells bottom with text value, if cell with date is equal to TODAY()? I try =D9=TODAY() when I select range D9:D16 but not work for cells D10:D16. How can I include this range in the same rule?
Thank you in advance and all the best!
THis app is fun
I'm trying to format the entire row if two conditions are true. I've gotten it to format the first cell of the row. Here is my formula- =AND(M13>=30, O13>=55) and it I have it applying to this selection- =$B$13:$O$13 (I'm working on one row for starters to make sure I get it right before I apply it to the entire table).
What am I doing wrong? How do I get this to format the entire row?
Hello Emily!
You can find the answer to your question in this article: Change the row color based on cell value. Use this conditional formatting formula:
=AND($M13>=30, $O13>=55)
Hello,
Is it possible to create new conditional formatting role with icons?
Thanks in advance.
Hi! If I understand your task correctly, this article may be helpful: Excel Icon Sets conditional formatting: inbuilt and custom.
I have 5 columns, 2 rows.
I would like to highlight the first cell (col 1-5) in row 1 that is >= the corresponding cell in row 2.
once that condition is met (it could be col 3 for example), do not continue and check the rest of the columns (4-5).
I tried the formalu =A$1>=A$2 applied to A$1:E$2
thanks
Hello Sharon!
If I understand your task correctly, you can apply this conditional formatting rule to the range A1:E2. Read more: How to use conditional formatting in Excel.
If this is not what you wanted, please describe the problem in more detail.
Hello :)!
I have calendar (6 rows x 7 columns) and a list with assignments and dates. How can highlight day in calendar correspond to assignment date from list? I use =VLOOKUP(F6;$Q$7:$Q$37;1;FALSE)=F6 where F6 is day of calendar (6 rows x 7 columns) and range $Q$7:$Q$37 is monthly dates from assignments. Formula work and highlight all days in calendar (6 rows x 7 columns) bt not all days from assignments list have assignments. How I can add range $S$7:$S$37 where are assignments like criteria, something like =if($S7 "",VLOOKUP(F6;$Q$7:$Q$37;1;FALSE)=F6 in conditional formatting?
Thank you in advance and have a great day!
Hi! If I understand your task correctly, to do conditional formatting on two conditions, use the SUMPRODUCT formula.
Based on this information, the formula could be as follows:
=SUMPRODUCT(($Q$7:$Q$37=F6)*($S$7:$S$37<>""))
You can find the examples and detailed instructions here: Excel SUMPRODUCT function with multiple criteria.
WOW! YOU ARE GREAT!
Formula work like a charm!
THANK YOU SOOOOO MUCH!
I'm attempting to highlight cells based on whether a different column contains a word.
So, C1:C355 if it contains "overtime" I want G1:G355 AND C1:C355 in that row to turn orange
Please help!
Hi! To determine whether text in a cell contains a particular word, you can use these instructions: How to find substring in Excel. For example:
=ISNUMBER(SEARCH("overtime",C1))
To create conditional formatting, use the guidelines from the article above.
Hi,
If C3 cell is having "R" means, i need "R" to appear automatically in J3 cell.
Hi! You can find useful information in this article: How to find substring in Excel. Using the IF function, insert a value into cell J3:
=IF(ISNUMBER(SEARCH("R",C3)),"R","")
If letter case is important, use the FIND function:
=IF(ISNUMBER(FIND("R",C3)),"R","")
Can you show me how conditional formatting yellow highlight for cells that have less than 2 units difference in value. Like 3,7,10, 9?
Hi! Calculate the absolute difference of the values in the cells using the ABS function. Use 2 conditional formatting rules. Here is an example of conditional formatting formulas:
For the range A1:A20:
=ABS(A2-A1)<=2
For the range A2:A20:
=ABS(A2-A1)<=2
Hello!
I'm very new to writing out excel formulas and I currently have the rule set at
"Format only cells that contain: Specific Text: Ending with: 9" to make them a specific color
How can I create a similar formula to carry that color all the way across A-E instead of just column A?
The value of Column A needs to determine what color the entire row is.
Thank you so much!
Hello Holland!
The answer to your question can be found in this article: How to change the row color based on a cell value in Excel. Select a range of cells for conditional formatting and use this formula:
=RIGHT($A1,1)="9"
Hi! Great article but i´m having some trouble when I try to apply conditional formatting between 2 different values. Whenever I apply the AND formula you use, a pop up appears saying that there´s a problem with the formula and doesn't do anything. Do you know why this might be and how to solve it? Thanks!
Hi! I will try to find the cause of the problem if you describe the problem in detail and write what formula you used.
Hi! Thank you for answering. The formula I used was: =AND($Q22>2, $Q22<5) but whenever I try to use it, it tells me theres a problem with it. I have to use it as a new rule because it has to be applied to another cell.
Hi! I have no problem with this formula. Check what character you are using as a delimiter. It might be “;” instead of “,”. Separate function arguments with a proper character. Read more: Excel formulas not working.
Hi, I'm wanting to highlight cells that have value smaller than the cell to its left. I selected the row and created the rule =c3<b3.
This is my sample values I've been testing with:
b3=70.6, c3=64.33, d3=64.3, e3=68.9, f3=74.3
It's not highlighting c3 and d3. It's highlighting b3, c3 and f3 instead.
Does it not work for decimal numbers or cells with percentage format? Do you have a solution for this?
Hi! For the range $B$3:$F$3, use the conditional formatting formula =B3Cell references in Excel conditional formatting.
Not sure what I'm doing wrong..still not getting the right results
Hi there!
I'm trying to use this for a schedule, where, when I type the abbreviation of a subject, say "mt" it formats the cell, including writing in the text "Maths". I've gotten as far as formatting the cells and that it fills in text but it always keeps the initial abbreviation that i used, so it gives me the formatted cell but the text is "mt Maths". this is due to the format code, where in the 'Number' field, i select custom (it tells you to start from a previously existing code) and i chose "@" and then my text in between the "" (so i type @"Maths"). I understand that the '@' copies and takes the text i wrote in the cell, but when i removed the @ sign from the code, it won't recognize the text written after, only when I add the @ sign. Can you help me with this? I'm trying to keep this as a formatting rule so I don't need a formatting rule AND a formula. Thank you!
Hi! Your question is not entirely clear to me. What formula do you use for conditional formatting? Give an example of your data and specify which ones should be formatted by condition.
UPDATE!!!
I found out, you have to put ;;;"desired text". Thanks anyways!!!
Your article and comments are super helpful!
I am trying to use conditional format when a name changes. The goal is to easily see when a name does change. ie. i have a column of names, sorted alphabetically. Many are listed more than once. I want to say if then turn blue. And clearly i am missing something!
Hello Kena!
Based on your description, it is hard to completely understand your task. However, I’ll try to guess that you want to highlight in color the cells in which name first appears. Try this conditional formatting formula:
=COUNTIF($A$1:A1,A1)=1
For the detailed instructions, please see: How to highlight duplicate cells and rows in Excel.
I've just wasted 2 hours trying to get your examples to work - the problem is the way you have written the AND formula which looks like a space has been added in your table - and Excel is not having it! Only when I saw the image of the actual formula entered, without a space did it work. If you're going to provide help, please stop making it more frustrating than it already is by giving the incorrect syntax!
The spacing you have used in the table makes it look like there is a space after the Function AND, when there is not.
Hello Marc!
You can see that there is no space after AND if you copy the AND formula from the article and paste it into an Excel cell.
hi alex. formula to display cells with the results of a specified number
Hi! Please clarify your specific problem or provide additional details to highlight exactly what you need.