How to use Excel COUNTIFS and COUNTIF with multiple criteria

The tutorial explains how to use COUNTIFS and COUNTIF formulas with multiple criteria in Excel based on AND as well as OR logic. You will find a number of examples for different data types - numbers, dates, text, wildcard characters, non-blank cells and more.

Of all Excel functions, COUNTIFS and COUNTIF are probably most often mixed up because they look very much alike and both are purposed for counting cells based on the specified criteria.

The difference is that COUNTIF is designed for counting cells with a single condition in one range, whereas COUNTIFS can evaluate different criteria in the same or in different ranges. The aim of this tutorial is to demonstrate different approaches and help you choose the most efficient formula for each particular task.

Excel COUNTIFS function - syntax and usage

The Excel COUNTIFS function counts cells across multiple ranges based on one or several conditions. The function is available in Excel 365, 2021, 2019, 2016, 2013, Excel 2010, and Excel 2007, so you can use the below examples in any Excel version.

COUNTIFS syntax

The syntax of the COUNTIFS function is as follows:

COUNTIFS(criteria_range1, criteria1, [criteria_range2, criteria2]…)
  • criteria_range1 (required) - defines the first range to which the first condition (criteria1) shall be applied.
  • criteria1 (required) - sets the condition in the form of a number, cell reference, text string, expression or another Excel function. The criteria defines which cells shall be counted and can be expressed as 10, "<=32", A6, "sweets".
  • [criteria_range2, criteria2]… (optional) - these are additional ranges and their associated criteria. You can specify up to 127 range/criteria pairs in your formulas.

In fact, you don't have to remember the syntax of the COUNTIF function by heart. Microsoft Excel will display the function's arguments as soon as you start typing; the argument you are entering at the moment is highlighted in bold. The syntax of the Excel COUNTIFS function

Excel COUNTIFS - things to remember!

  1. You can use the COUNTIFS function in Excel to count cells in a single range with a single condition as well as in multiple ranges with multiple conditions. If the latter, only those cells that meet all of the specified conditions are counted.
  2. Each additional range must have the same number of rows and columns as the first range (criteria_range1 argument).
  3. Both contiguous and non-contiguous ranges are allowed.
  4. If the criteria is a reference to an empty cell, the COUNTIFS function treats it as a zero value (0).
  5. You can use the wildcard characters in criteria - asterisk (*) and question mark (?). See this example for full details.

How to use COUNTIFS and COUNTIF with multiple criteria in Excel

Below you will find a number of formula examples that demonstrate how to use the COUNTIFS and COUNTIF functions in Excel to evaluate multiple conditions.

How to count cells with multiple criteria (AND logic)

This scenario is the easiest one, since the COUNTIFS function in Excel is designed to count only those cells for which all of the specified conditions are TRUE. We call it the AND logic, because Excel's AND function works this way.

Formula 1. COUNTIFS formula with multiple criteria

Suppose you have a product list like shown in the screenshot below. You want to get a count of items that are in stock (value in column B is greater than 0) but have not been sold yet (value is column C is equal to 0).

The task can be accomplished by using this formula:

=COUNTIFS(B2:B7,">0", C2:C7,"=0")

And the count is 2 ("Cherries" and "Lemons"): Counting cells with multiple criteria based on AND logic

Formula 2. COUNTIFS formula with two criteria

When you want to count items with identical criteria, you still need to supply each criteria_range / criteria pair individually.

For example, here's the right formula to count items that have 0 both in column B and column C:

=COUNTIFS($B$2:$B$7,"=0", $C$2:$C$7,"=0")

This COUNTIFS formula returns 1 because only "Grapes" have "0" value in both columns. COUNTIFS formula with identical criteria

Using a simpler formula with a single criteria_range like COUNTIFS(B2:C7,"=0") would yield a different result - the total count of cells in the range B2:C7 containing a zero (which is 4 in this example).

How to count cells with multiple criteria (OR logic)

As you have seen in the above examples, counting cells that meet all of the specified criteria is easy because the COUNTIFS function is designed to work this way.

But what if you want to count cells for which at least one of the specified conditions is TRUE, i.e. based on the OR logic? Overall, there are two ways to do this - by adding up several COUNTIF formulas or using a SUM COUNTIFS formula with an array constant.

Formula 1. Add up two or more COUNTIF or COUNITFS formulas

In the table below, supposing you want to count orders with the "Cancelled" and "Pending" status. To have it doen, you can simply write 2 regular Countif formulas and add up the results:

=COUNTIF($C$2:$C$11,"Cancelled") + COUNTIF($C$2:$C$11,"Pending") Counting cells that meet any of the specified criteria

In case each of the functions is supposed to evaluate more than one condition, use COUNTIFS instead of COUNTIF. For example, to get the count of "Cancelled" and "Pending" orders for "Apples" use this formula:

=COUNTIFS($A$2:$A$11, "Apples", $C$2:$C$11,"Cancelled") + COUNTIFS($A$2:$A$11, "Apples", $C$2:$C$11,"Pending") Another formula to count cells with multiple criteria and OR logic

Formula 2. SUM COUNTIFS with an array constant

In situations when you have to evaluate a lot of criteria, the above approach is not the best way to go because your formula would grow too big in size. To perform the same calculations in a more compact formula, list all of your criteria in an array constant, and supply that array to the criteria argument of the COUNTIFS function. To get the total count, embed COUNTIFS inside the SUM function, like this:

SUM(COUNTIFS(range,{"criteria1","criteria2","criteria3",…}))

In our sample table, to count orders with the status "Cancelled" or "Pending" or "In transit", the formula would go as follows:

=SUM(COUNTIFS($C$2:$C$11, {"cancelled", "pending", "in transit"})) A more compact formula to count cells with multiple criteria and OR logic

In a similar manner, you can count cells based on two or more criteria_range / criteria pairs. For instance, to get the number of "Apples" orders that are "Cancelled" or "Pending" or "In transit", use this formula:

=SUM(COUNTIFS($A$2:$A$11,"apples",$C$2:$C$11,{"cancelled","pending","in transit"})) Counting cells with multiple criteria_range / criteria pairs and OR logic

You can find a few more ways to count cells with OR logic in this tutorial: Excel COUNTIF and COUNTIFS with OR conditions.

How to count numbers between 2 specified numbers

By and large, COUNTIFS formulas for numbers fall into 2 categories - based on several conditions (explained in the above examples) and between the two values you specify. The latter can be accomplished in two ways - by using the COUNTIFS function or by subtracting one COUNTIF from another.

Formula 1. COUNTIFS to count cells between two numbers

To find out how many numbers between 5 and 10 (not including 5 and 10) are contained in cells C2 through C10, use this formula:

=COUNTIFS(C2:C10,">5", C2:C10,"<10") A COUNTIFS formula to count numbers between X and Y

To include 5 and 10 in the count, use the "greater than or equal to" and "less than or equal to" operators:

=COUNTIFS(B2:B10,">=5", B2:B10,"<=10")

Formula 2. COUNTIF formulas to count numbers between X and Y

The same result can be achieved by subtracting one Countif formula from another. The first one counts how many numbers are greater than the lower bound value (5 in this example). The second formula returns the count of numbers that are greater than the upper bound value (10 in this case). The difference between the first and second number is the result you are looking for.

  • =COUNTIF(C2:C10,">5")-COUNTIF(C2:C10,">=10") - counts how many numbers greater than 5 and less than 10 are in the range C2:C10. This formula will return the same count as shown in the screenshot above.
  • =COUNTIF(C2:C10, ">=5")-COUNTIF(C2:C10, ">10") - the formula counts how many numbers between 5 and 10 are in the range C2:C10, including 5 and 10.

How to use cell references in COUNTIFS formulas

When using logical operators such as ">", "<", "<=" or ">=" together with cell references in your Excel COUNTIFS formulas, remember to enclose the operator in "double quotes" and
add an ampersand (&) before a cell reference to construct a text string.

In a sample dataset below, let's count "Apples" orders with amount greater than $200. With criteria_range1 in cells A2:A11 and criteria_range2 in B2:B11, you can use this formula:

=COUNTIFS($A$2:$A$11, "Apples", $B$2:$B$11, ">200")

Or, you can input your criteria values in certain cells, say F1 and F2, and reference those cells in your formula:

=COUNTIFS($A$2:$A$11, $F$1, $B$2:$B$11, ">"&$F$2)

Please notice the use of absolute cell references both in the criteria and criteria_range arguments, which prevents the formula from being broken when copied to other cells. Using cell references in COUNTIFS formulas

For more information about the use of an ampersand in COUNTIF and COUNTIFS formulas, please see Excel COUNTIF - frequently asked questions.

How to use COUNTIFS with wildcard characters

In Excel COUNTIFS formulas, you can use the following wildcard characters:

  • Question mark (?) - matches any single character, use it to count cells starting and/or ending with certain characters.
  • Asterisk (*) - matches any sequence of characters, you use it to count cells containing a specified word or a character(s) as part of the cell's contents.

Tip. If you want to count cells with an actual question mark or asterisk, type a tilde (~) before an asterisk or question mark.

Now let's see how you can use a wildcard char in real-life COUNTIFS formulas in Excel. Suppose, you have a list of projects in column A. You wish to know how many projects are already assigned to someone, i.e. have any name in column B. And because we are learning how to use the COUNTIFS function with multiple criteria, let's add a second condition - the End Date in column D should also be set.

Here is the formula that works a treat:

=COUNTIFS(B2:B10,"*",D2:D10,"<>"&""))

Please note, you cannot use a wildcard character in the 2nd criteria because you have dates rather that text values in column D. That is why, you use the criteria that finds non-blank cells: "<>"&"" The COUNTIFS formula to count entries containing any text in one column and non-blank cells in another column.

COUNTIFS and COUNTIF with multiple criteria for dates

The COUNTIFS and COUNTIF formulas you use for dates are very much similar to the above formulas for numbers.

Example 1. Count dates in a specific date range

To count the dates that fall in a certain date range, you can also use either a COUNTIFS formula with two criteria or a combination of two COUNTIF functions.

For example, the following formulas count the number of dates in cells C2 through C10 that fall between 1-Jun-2014 and 7-Jun-2014, inclusive:

=COUNTIFS(C2:C9, ">=6/1/2014", C2:C9, "<=6/7/2014")

=COUNTIF(C2:C9, ">=6/1/2014") - COUNTIF(C2:C9, ">6/7/2014") The COUNTIF formula with 2 conditions to count dates in a specific date range

Example 2. Count dates with multiple conditions

In the same manner, you can use a COUNTIFS formula to count the number of dates in different columns that meet 2 or more conditions. For instance, the below formula will find out how many products were purchased after the 20th of May and delivered after the 1st of June:

=COUNTIFS(C2:C9, ">5/1/2014", D2:D9, ">6/7/2014") The COUNTIF formula to count dates with multiple conditions

Example 3. Count dates with multiple conditions based on the current date

You can use Excel's TODAY() function in combination with COUNTIF to count dates based on the current date.

For example, the following COUNTIF formula with two ranges and two criteria will tell you how many products have already been purchased but not delivered yet.

=COUNTIFS(C2:C9, "<"&TODAY(), D2:D9, ">"&TODAY()) The COUNTIF formula to count dates with multiple conditions based on the current date

This formula allows for many possible variations. For instance, you can tweak it to count how many products were purchased more than a week ago and are not delivered yet:

=COUNTIFS(C2:C9, "<="&TODAY()-7, D2:D9, ">"&TODAY())

This is how you count cells with multiple criteria in Excel. I hope you will find these examples helpful. Anyway, I thank you for reading and hope to see you on our blog next week!

Table of contents

2050 comments

  1. Hi, i have tried this formula and it works for 1 criteria at the front, when i add another 2 criteria at the back of formula, it doesn't work. can you advice this,
    =COUNTIFS(actual!$C:$C,Export!$A37,actual!$H:$H,">="&Export!C$35,actual!$H:$H,"<="&EDATE(Export!C$35,1))

    i would like to add criteria, "mobilized" and "On-Leave". i add these 2 criteria at the front and i tried at the back of formula as well, but it doesnt work.

    thank you

  2. I have a list of 3000 different names and I need to highlight all names that appear fewer than 8 times.

  3. I am trying to calculate the number of occurrences in that text appears in column 'F' using the year from column I2 as a criterion to search column 'B'. I have tried using SUMPRODUCT, COUNTIFS, and INDEX/Match but keep getting no results. Here are a couple of examples I have tried:

    COUNTIFS($F$2:$F$27,"Not-Started", YEAR($B$2:$B$27),"="&$I$2)

    SUMPRODUCT(1*(YEAR(B2:B27)=I2),INDEX(B2:B27,,MATCH("Not-Started",F2:F27)))

    SUMIFS(F2:F27,B2:B27,YEAR(dates_kit)=I2,F2:F27,"Not-Started")

    Here is a sample of my spread sheet:
    A B C D E F I
    1 Job Number Kit Date Test Date Final TestDate Days Status YEAR
    2 895965 8/15/2024 9/26/2024 9/16/2024 42 On-Time 2024
    3 835958 (16") 2/28/2024 4/10/2024 4/9/2024 42 On-Time
    4 835958 (20") 4/25/2024 6/6/2024 5/20/2024 42 On-Time
    5 835958 (28") 4/12/2024 5/24/2024 Not-Started
    6 867183 8/16/2024 9/27/2024 11/1/2024 77 Late

    2. I just figured out the solution:

      =SUM(COUNTIFS(B2:B27,">"&DATE(1900,1,1),B2:B27,"<="&DATE(I2,12,31),F2:F27,"Not-Started"))

  4. Hi Sir,
    Good day to you. I am trying to track stock price movements relative to its moving average ‘MA’, basically how many days it had stayed above the MA (before ‘going below’) and vice versa.
    My column A2:A300 contains the dates (with A300 the most recent), B2:B300 the ‘closing price (for that day)’, and C2:C300 a ‘MA’. An example to illustrate what I wish to have please.
    P > MA ‘dates’
    Price B300 is 100, MA C300 is 98 Y today
    B299 is 95 C299 is 91 Y day-before
    B298 is 60 C298 is 70 N 2 day before
    B297 is 85 C297 is 72 Y and so on

    I would like to have a formula output like “XaMAby2D” (which is cross above MA for past 2 days) for above instance (and if converse is true, “XbMAby2D”). I am unsure if I should post here as I think COUNTIF is regardless of the order it appears as long as it is within a ‘date range’ but here I need to ‘count backwards’ the number of days from today it stays above / below the MA (that is start from cell 300 followed by 299 and so on). Ignore Price=MA please.

    Could kindly advise please?
    Much obliged. Wishing you and loved ones health and bliss.
    Sincerely,

    1. Hi! If I understand your task correctly, write this formula in cell C3 and then copy it down along the column:

      =IF(B3>C3,COUNT($B$2:B3) - IFERROR(XMATCH(B3>C3,$B$2:B2<$C$2:C2,0,-1),0),0)

      XMATCH function searches a column to find the nearest value that does not satisfy the IF condition.
      I hope my advice will help you solve your task.

  5. How do I countifs if 2 columns have a name?

    I.E.
    A | B | C | D | E
    Name | Item | Status | Partial Item Name | NameOnPaper

    Bens | Shoe | Delivered | Sho* | Joes |
    Joes | Boxs | Missing | Bo* | Bens |
    Saul | Shrt | Delivered | Shr* | |
    Sams | Shoe | Delivered | pan* | |
    Bens | Short | Delivered | | |

    =COUNTIFS(B:B, D2, C:C, "Found", C:C, "Missing")

    This works, but I want to add it saying Don't count if Name doesn't exist under NameOnPaper in any row. It counts the item only if partial name is found in the item name, but doesn't count if the status isn't delivered. I want it to do all that but then I don't want Sams to be counted because NameOnPaper doesn't have his name listed in any row. It counts how many times "sho*" appears in the Item list, which is three times, but I am trying to get it to only count it twice because Bens Name is not under NameOnPaper. It should count Sho twice because it is delivered and matches shoe and Short and Bens name in NameOnPaper exists.

    1. Hello Ben!
      From your description, it is difficult to have a full understanding of your task. However, I’ll try to guess and offer you the following formula:

      =SUMPRODUCT(COUNTIF($E$1:$E$5,A1:A5) * ($C$1:$C$5="Delivered") * (IFERROR(SEARCH(SUBSTITUTE(D1,"*",""),$B$1:$B$5),0)))

      COUNTIF function checks if there are partial matches in columns. SEARCH function is used to determine if there are any partial matches in a row.
      SUMPRODUCT function counts the number of rows whose values match conditions.

  6. Hello
    I have a spreadsheet where on a separate tab I need excel to add up the figures in column M if the month in column D is October, then again the figures in column M if the month in column D is November so that on the separate tab I send up with:

    October £***
    November £***
    December £*** etc - all based on the information on the first spreadsheet.

    Does that make sense? Can someone help??

    1. Hello!
      You can calculate the sum of the condition by using the SUMIF function. For example:

      =SUMIF(D2:D100,"October",M2:M100)

      If column D contains dates rather than the name of the month, use the SUMIFS function. You can find the examples and detailed instructions here: Excel SUMIFS and SUMIF with multiple criteria – formula examples.

      =SUMIFS(M2:M100,D2:D100,">="&DATE(2024,10,1),D2:D100,"<="&DATE(2024,10,31))

      Instead of using the DATE function in a formula, you can use a reference to a cell with a date.
      You can also use the SUMPRODUCT function as described in these instructions: Excel SUMPRODUCT function with multiple criteria. To get the month number, use the MONTH function. For example:

      =SUMPRODUCT(M2:M100*(MONTH(D2:D100)=10))

      1. That is SO helpful - thank you!

        How do I get that information from one sheet to another? My data is on one tab - and I need the totals to be on a separate tab.

        Sorry - I feel I should know that!!

  7. I have a student who created a spreadsheet based on a questionaire. She wants to count all the 5s in each cell when there are multiple numbers in that cell. Is there a way to do that? Does she have to redo the spreadsheet so only one number is i each cell?

    So there is a range of cells B2:B8
    B2 might have this data 1,2,5,6
    B3 contains 3,5,7,9
    B4 contains 1,3,6,7
    B5 contains 1,2,6,7
    B6 contains 1,3,5,7
    B7 contains 2,4,5,7
    B8 contains 3,6,7

    1. Hello Irene!
      If you want to find the sum of numbers within a single cell in Excel, you can use a combination of SUMPRODUCT and TEXTSPLIT functions.

      =SUMPRODUCT(--TEXTSPLIT(B2,,","))

      You can also extract all characters sequentially from the text using MID function. Using a mathematical operation and IFERROR function, determine all numbers and sum them with SUMPRODUCT.

      =SUMPRODUCT(IFERROR(MID(B2,ROW(INDIRECT("1:"&LEN(B2))),1)*1,0))

      If TEXTSPLIT isn't available, also you can use this approach:
      Split the values manually:
      Use Text to Columns feature found under the Data tab and split by comma delimiter.
      Sum the values: Use the SUM function.

  8. I have the following formula set- IF(COUNTIFS(N4,"EXP",P4,"EXP",R4,"EXP"),"EXP","") and want to add a second option e.g. IF(COUNTIFS(N4,"EXP",P4,"EXP",R4,"EXP"),"EXP",""),countifs(N4,"GDS",P4,"GDS",R4,"GDS"),"GDS")). I need it to return based on the criteria being met in all three columns. I've managed to achieve this with the one (first formula) using a couple of different types of formula but cannot get it to work with the second part. Can anyone help?

    1. Hello Nic!
      If I understand your task correctly, you want to check values in three cells.
      The formula might look like this:

      =IF(COUNTIFS(N4,"EXP",P4,"EXP",R4,"EXP"),"EXP", IF(COUNTIFS(N4,"GDS",P4,"GDS",R4,"GDS"),"GDS",""))

      In such cases, it is a common practice to use the nested IF formula as it is described in this guide: Nested IF in Excel – formula with multiple conditions. For example:

      =IF(AND(N4="EXP",P4="EXP",R4="EXP"),"EXP", IF(AND(N4="GDS",P4="GDS",R4="GDS"),"GDS",""))

      Hope this is what you need.

      1. Hi Alexander, that is exactly what I needed! Thank you very much, I've been going round in circles!

  9. I have countcellsbycolor formula set up. Is there a way I can use this in combination with COUNTIFS?
    For example, count if a range of cells is a particular color AND if a range of cells has a specific letter entered into it.

    something like =COUNTIFS(F10:F9999,"Y",=countcellsbycolor(K10:K10057,K1))

  10. can I use countifs to count multiple occurrences of the same string in a single cell.
    For instance

    cell a1 contains "loan loan"
    cell a2 contains "loan"
    cell a3 contains "loan loan loan"

    I want to see a count of 6.

  11. Hi, thank you for explanation for the use of countif and countifs for range of dates using ">5/1/2014" for example.
    But can you give explanation about how to use this if i need to use the date entered in another cell, not in the formula it self.
    For example : I have entered "1/1/2024" in one cell and "31/1/2024" in another one (3 months range). How to use both cell to in the countif/countifs formula?
    It will ease the effort to mess with the formula again. Thank you.

    1. Hello Edward!
      You can use logical operators such as ">", "<", "<=" or ">=" together with cell references in your Excel COUNTIFS formulas. Remember to enclose the operator in "double quotes" and add concatenation operator (&) before a cell reference.
      Cells may contain dates or numbers. For example:

      =COUNTIFS(C2:C9,">="&A1,C2:C9,"<="&"B1")

      1. Very helpful answer! It already solved my problem. Thank you very much.

  12. Hi sir, please help to solve the below formula:
    =Countifs(S4:S545,"0")

  13. Hello! Thank you so much for this information! It has proved to be so helpful.
    I am trying to calculate how many items in a A3:A51 list have "true" marked in either F3:F51 OR G3:G51. Can I do this through a formula?

    1. Hi! Please read the following paragraph in the article above very carefully: How to count cells with multiple criteria (OR logic). It covers your case completely.

  14. In trying to calculate prorated salary based from 2 other columns "daily rate" x "# of days" between 2 date ranges, but only want them to be calculated if the Status = In Progress, On Hold or Not Started.

    I am trying to calculate using =SUM([@[daily Rate calculation ]]*[@['# of days]],(COUNTIFS([Status],{"In Progress","On Hold","Not Started"}))), however it is picking up all other statuses also.

  15. Hi!!
    I have a problem. How can I use countifs when I have to count- for example sales target achieved between 1% to 51% how many times by a particular manager from list of different managers.

    1. Hi! Pay attention to the following paragraph of the article above: How to count numbers between 2 specified numbers. Add another condition to the proposed formula: the manager's name. For example:

      =COUNTIFS(B2:B10,"Name",C2:C10,">1%", C2:C10,"<51%")

  16. Hi, im currently counting rows tagged with "a" and "b". tags ranges from a - r. how to do itt? thank you!

  17. Hi

    I am trying to countifs between hours and minutes (00:00:00) but my formula is not bringing back all results when checked manually. I'm not sure where it is going wrong.
    1st count between dates, 2nd count matching data in a colum, 3rd count counting between hours and minutes. It's bringing back some of the data but not all.

    =COUNTIFS(Sheet1!$M:$M,">="&DATE(2024, 5, 1),Sheet1!$M:$M,"=00:00:00", Sheet3!$R:$R, "="&DATE(2024, 5, 1),Sheet1!$M:$M,"=00:15:00", Sheet3!$R:$R, "<=00:29:59")

    1st row brings back all results(12), 2nd row brings back 0 results. When checked manually there should be 10 results.

    Thanks

    Craig

    1. Hello Craig!
      To extract the time from the date, use the MINUTE function. Read more about it here: How to calculate time in Excel. Но вы не можете использовать это в формуле COUNTIFS. Therefore, to calculate values by condition, I recommend using the SUMPRODUCT formula with multiple criteria. For example:

      =SUMPRODUCT((Sheet1!$M:$M>=DATE(2024,5,1)) * (MINUTE(Sheet1!$M:$M)=0)*(Sheet3!$R:$R=DATE(2024,5,1)) * (MINUTE(Sheet1!$M:$M)=15) * (MINUTE(Sheet3!$R:$R)<30))

    2. Seems like line of formula hasn't shown up properly.

      =COUNTIFS(Sheet1!$M:$M,">="&DATE(2024, 5, 1),Sheet1!$M:$M,"=00:15:00", Sheet3!$R:$R, "<00:29:59")

      This same line is used to count 0 - 15mins, 15 - 30mins, 30 - 45mins, 45 - 60mins, etc

      Thanks,

  18. shift department
    Angulo, Ingrid N F2 Pick
    Anon, Kobon Jean Francois S2 Pack
    Badey, Spenser R F2 Pick
    Baez, Jasmarie L S2 Pick
    Bah, Houleymatou W2 Pick

    Hi there!
    Im trying to do the countif to return a value with how many people with specific shift are in certain department. For example, how many people with F2 shift are in pick department.

    1. Hi! I hope you have studied the recommendations in the tutorial above. It contains answers to your question. Use the COUNTIFS function to calculate the number of records that meet the two conditions.

  19. Really it was soo help ful.
    May almighty God bless you all

  20. I've been scratching my head at this for awhile now. I'm using the SUMIFS formula to add data based on 3 criteria; start date, end date, and a name. I have the formula working but im searching multiple columns for the name resulting in adding 15 identical SUMIFS formulas just to check different columns.

    Example:

    =COUNTIFS(Table1[[Date]:[Date]],">="&$F$2,Table1[[Date]:[Date]],"="&$F$2,Table1[[Date]:[Date]],"="&$F$2,Table1[[Date]:[Date]],"="&$F$2,Table1[[Date]:
    [Date]],"="&$C$3,Table1[[Date]:[Date]],"<="&$D$3, Table1[[SL]:[SD]],$B6)

    I have a similar issue for another cell which is identical with the SUMIFS function. Another challenge is that I have to stay in base excel formulas and can't go into MBA due to job security.

    I've never posted on a forum before so you know I'm on my last leg trying to figure this out.

Post a comment



Thank you for your comment!
When posting a question, please be very clear and concise. This will help us provide a quick and relevant solution to
your query. We cannot guarantee that we will answer every question, but we'll do our best :)