How to sum and count cells by color in Excel

In this article, you will learn new effective approaches to summing and counting cells in Excel by color. These solutions work for cells colored manually and with conditional formatting in all versions of Excel 2010 through Excel 365.

Even though Microsoft Excel has a variety of functions for different purposes, none can calculate cells based on their color. Aside from third-party tools, there is only one efficient solution - create your own functions. If you know very little about user-defined functions or have never heard of this term before, don't panic. The functions are already written and tested by us. All you need to do is to insert them in your workbook :)

How to count cells by color in Excel

Below, you can see the codes of two custom functions (technically, these are called user-defined functions or UDF). The first one is purposed for counting cells with a specific fill color and the other - font color. Both are written by Alex, one of our best Excel gurus.

Custom functions to count by color in Excel
Function CountCellsByColor(data_range As Range, cell_color As Range) As Long Dim indRefColor As Long Dim cellCurrent As Range Dim cntRes As Long Application.Volatile cntRes = 0 indRefColor = cell_color.Cells(1, 1).Interior.Color For Each cellCurrent In data_range If indRefColor = cellCurrent.Interior.Color Then cntRes = cntRes + 1 End If Next cellCurrent CountCellsByColor = cntRes End Function Function CountCellsByFontColor(data_range As Range, font_color As Range) As Long Dim indRefColor As Long Dim cellCurrent As Range Dim cntRes As Long Application.Volatile cntRes = 0 indRefColor = font_color.Cells(1, 1).Font.Color For Each cellCurrent In data_range If indRefColor = cellCurrent.Font.Color Then cntRes = cntRes + 1 End If Next cellCurrent CountCellsByFontColor = cntRes End Function

Once the functions are added to your workbook, they will do all work behind the scenes, and you can use them in the usual way, just like any other native Excel function. From the end-user perspective, the functions have the following look.

Count cells by fill color

To count cells with a particular background color, this is the function to use:

CountCellsByColor(data_range, cell_color)

Where:

  • Data_range is a range in which to count cells.
  • Cell_color is a reference to the cell with the target fill color.

To count cells of a specific color in a given range, carry out these steps:

  1. Insert the code of the CountCellsByColor function in your workbook.
  2. In a cell where you want the result to appear, start typing the formula: =CountCellsByColor(
  3. For the first argument, enter the range in which you want to count colored cells.
  4. For the second argument, supply the cell with the target color.
  5. Press the Enterkey. Done!

For example, to find out how many cells in range B3:F24 have the same color as H3, the formula is:

=CountCellsByColor(B3:F24, H3)

In our sample dataset, the cells with values less than 150 are colored in yellow, and the cells with values higher than 350 in green. The function gets both counts with ease:
Counting cells by color in Excel

Count cells by font color

In case your cell values have different font colors, you can count them using this function:

CountCellsByFontColor(data_range, font_color)

Where:

  • Data_range is a range in which to count cells.
  • Font_color is a reference to the cell with the sample font color.

For example, to get the number of cells in B3:F24 whose values have the same font color as H3, the formula is:

=CountCellsByFontColor(B3:F24, H3)
Custom function to count cells by font color in Excel

Tip. If you'd like to name the functions differently, feel free to change the names directly in the code.

How to sum by color in Excel

To sum colored values, add the following two functions to your workbook. As with the previous example, the first one handles fill color and the other - font color.

Custom functions to sum by color in Excel
Function SumCellsByColor(data_range As Range, cell_color As Range) Dim indRefColor As Long Dim cellCurrent As Range Dim sumRes Application.Volatile sumRes = 0 indRefColor = cell_color.Cells(1, 1).Interior.Color For Each cellCurrent In data_range If indRefColor = cellCurrent.Interior.Color Then sumRes = WorksheetFunction.Sum(cellCurrent, sumRes) End If Next cellCurrent SumCellsByColor = sumRes End Function Function SumCellsByFontColor(data_range As Range, font_color As Range) Dim indRefColor As Long Dim cellCurrent As Range Dim sumRes Application.Volatile sumRes = 0 indRefColor = font_color.Cells(1, 1).Font.Color For Each cellCurrent In data_range If indRefColor = cellCurrent.Font.Color Then sumRes = WorksheetFunction.Sum(cellCurrent, sumRes) End If Next cellCurrent SumCellsByFontColor = sumRes End Function

Sum values by cell color

To sum by fill color in Excel, this is function to use:

SumCellsByColor(data_range, cell_color)

Where:

  • Data_range is a range in which to sum values.
  • Cell_color is a reference to the cell with the fill color of interest.

For example, to add up the values of all cells in B3:F24 that are shaded with the same color as H3, the formula is:

=SumCellsByColor(B3:F24, H3)
Sum values by fill color in Excel.

Sum values by font color

To sum numeric values with a specific font color, use this function:

SumCellsByFontColor(data_range, font_color)

Where:

  • Data_range is a range in which to sum cells.
  • Font_color is a reference to the cell with the target font color.

For instance, to add up all the values in cells B3:F24 with the same font color as the value in H3, the formula is:

=SumCellsByFontColor(B3:F24, H3)
Sum values by font color in Excel.

Count and sum by color across entire workbook

To count and sum cells of a certain color in all sheets of a given workbook, we created two separate functions, which are named WbkCountByColor and WbkSumByColor, respectively. Here comes the code:

Custom functions to count and sum by color across workbook
Function WbkCountByColor(cell_color As Range) Dim vWbkRes Dim wshCurrent As Worksheet Application.ScreenUpdating = False Application.Calculation = xlCalculationManual vWbkRes = 0 For Each wshCurrent In Worksheets wshCurrent.Activate vWbkRes = vWbkRes + CountCellsByColor(wshCurrent.UsedRange, cell_color) Next Application.ScreenUpdating = True Application.Calculation = xlCalculationAutomatic WbkCountByColor = vWbkRes End Function Function WbkSumByColor(cell_color As Range) Dim vWbkRes Dim wshCurrent As Worksheet Application.ScreenUpdating = False Application.Calculation = xlCalculationManual vWbkRes = 0 For Each wshCurrent In Worksheets wshCurrent.Activate vWbkRes = vWbkRes + SumCellsByColor(wshCurrent.UsedRange, cell_color) Next Application.ScreenUpdating = True Application.Calculation = xlCalculationAutomatic WbkSumByColor = vWbkRes End Function

Note. To make the functions' code more compact, we refer to the two previously discussed functions that count and sum within a specified range. So, for the "workbook functions" to work, be sure to add the code of the CountCellsByColor and SumCellsByColor functions to your Excel too.

How to count colored cells in entire workbook

To find out how many cells of a particular color there are in all sheets of a given workbook, use this function:

WbkCountByColor(cell_color)

The function takes just one argument - a reference to any cell filled with the color of interest. So, a real-life formula may look something like this:

=WbkCountByColor(A1)

Where A1 is the cell with the sample fill color.

How to sum colored cells in whole workbook

To get a total of values in all cells of the current workbook highlighted with a particular color, use this function:

WbkSumByColor(cell_color)

Assuming the target color is in cell B1, the formula takes this form:

=WbkSumByColor(B1)

Count and sum conditionally formatted cells

The custom functions for adding up and counting color-coded cells are really nice, aren't they? The problem is that they do not work for cells colored with conditional formatting, alas :(

To handle conditional formatting, we have written a different code (kudos to Alex again!). It works well with both preset formats and custom formula-based rules. Contrasting with the previous examples, this code is a macro, not a function. The macro counts and sums conditionally formatted cells by fill color. Please insert it in your VBA Editor, and then follow the below instructions.

VBA macro to count and sum conditionally formatted cells.
Sub SumCountByConditionalFormat() Dim indRefColor As Long Dim cellsColorSample As Range Dim cntRes As Long Dim sumRes Dim cntCells As Long Dim indCurCell As Long On Error Resume Next cntRes = 0 sumRes = 0 cntCells = Selection.CountLarge Set cellsColorSample = Application.InputBox( _ "Select sample color:", "Select a cell with sample color", _ Application.Selection.Address, Type:=8) If Not (cellsColorSample Is Nothing) Then indRefColor = cellsColorSample.Cells(1, 1).DisplayFormat.Interior.Color For indCurCell = 1 To (cntCells) If indRefColor = Selection(indCurCell).DisplayFormat.Interior.Color Then cntRes = cntRes + 1 sumRes = WorksheetFunction.Sum(Selection(indCurCell), sumRes) End If Next MsgBox "Count=" & cntRes & vbCrLf & "Sum= " & sumRes & vbCrLf & vbCrLf & _ "Color=" & Left("000000", 6 - Len(Hex(indRefColor))) & _ Hex(indRefColor) & vbCrLf, , "Count & Sum by Conditional Format color" End If End Sub

How to count and sum conditionally formatted cells using VBA macro

With the macro's code inserted in your Excel, this is what you need to do:

  1. Select one or more ranges where you want to count and sum colored cells. Make sure the selected range(s) contains numerical data.
  2. Press Alt + F8, select the SumCountByConditionalFormat macro in the list, and click Run.
  3. A small dialog box will pop asking you to select a cell with the sample color. Do this and click OK.

VBA macro to count and sum conditionally formatted cells

For this example, we used the inbuilt Highlight Cell Rules and got the following results:

  • Count (12) the number of cells in range B2:E22 with the same color as G3.
  • Sum (1512) is the sum of values in cells formatted with Light Red Fill.
  • Color is a hexadecimal color code of the sample cell.

A count and sum of conditional formats

Tip. The sample workbook with the SumCountByConditionalFormat macro is available for download at the end of this post.

How to get cell color in Excel

If you need (or are curious) to know the color of a specific cell (fill or font color), add the following user-defined functions to your Excel. It returns ColorIndex as a decimal number.

Custom functions to get the cell color
Function GetCellColor(cell_ref As Range) Dim indRow, indColumn As Long Dim arResults() Application.Volatile If cell_ref Is Nothing Then Set cell_ref = Application.ThisCell End If If cell_ref.Count > 1 Then ReDim arResults(1 To cell_ref.Rows.Count, 1 To cell_ref.Columns.Count) For indRow = 1 To cell_ref.Rows.Count For indColumn = 1 To cell_ref.Columns.Count arResults(indRow, indColumn) = cell_ref(indRow, indColumn).Interior.Color Next Next GetCellColor = arResults Else GetCellColor = cell_ref.Interior.Color End If End Function Function GetFontColor(cell_ref As Range) Dim indRow, indColumn As Long Dim arResults() Application.Volatile If cell_ref Is Nothing Then Set cell_ref = Application.ThisCell End If If cell_ref.Count > 1 Then ReDim arResults(1 To cell_ref.Rows.Count, 1 To cell_ref.Columns.Count) For indRow = 1 To cell_ref.Rows.Count For indColumn = 1 To cell_ref.Columns.Count arResults(indRow, indColumn) = cell_ref(indRow, indColumn).Font.Color Next Next GetFontColor = arResults Else GetFontColor = cell_ref.Font.Color End If End Function

Note. The functions only work for colors applied manually, and not with conditional formatting.

Get fill color of a cell

To return a decimal code of the color a given cell is highlighted with, make use of this function:

GetCellColor(cell_ref)

For example, to get the color of cell A2, the formula is:

=GetCellColor(A2)

Get font color of a cell

To get a font color of a cell, use an analogous function:

GetFontColor(cell_ref)

For instance, to find the font color of cell E2, the formula is:

=GetFontColor(E2)

Get hexadecimal color code of a cell

To convert a decimal color index returned by our custom functions into a hexadecimal color code, make use of Excel's native DEC2HEX function.

For example:

="#"&DEC2HEX(GetCellColor(A2))

="#"&DEC2HEX(GetFontColor(E2))
Custom functions to get a cell's color in Excel

How to insert VBA code in your workbook

To add the function's or macro's code to your Excel, move on with these 4 steps:

  1. In your workbook, press Alt + F11 to open Visual Basic Editor.
  2. In the left pane, right-click on the workbook name, and then choose Insert > Module from the context menu.
  3. In the Code window, insert the code of the desired function(s):
  4. Save your file as Macro-Enabled Workbook (.xlsm).

If you are not very comfortable with VBA, you can find the detailed step-by-step instructions and a handful of useful tips in this tutorial: How to insert and run VBA code in Excel.

How to get custom functions to update

When summing and counting color-coded cells in Excel, please keep in mind that your formulas won't recalculate automatically after coloring a few more cells or changing existing colors. Please don't be angry with us, this is not a bug in our code :)

The point is that changing cell color in Excel does not trigger worksheet recalculation. To get the formulas to update, press either F9 to recalculate all open workbooks or Shift + F9 to recalculate only the active sheet. Or just place the cursor into any cell and press F2, and then hit Enter. For more information, please see How to force recalculation in Excel.

Fastest way to calculate colored cells in Excel

If you do not want to waste time tinkering with VBA codes, I'm happy to introduce you to our very simple but powerful Count & Sum by Color tool. Together with 70+ other time-saving add-ins, it is included with Ultimate Suite for Excel.

Once installed, you will find it on the Ablebits Tools tab of your Excel ribbon:
Ablebits Count & Sum by Color tool for Excel

And here is a short summary of what the Count & Sum by Color add-in can do:

  • Count and sum cells by color in all versions of Excel 2016 - Excel 365.
  • Find average, maximum and minimum values in the colored cells.
  • Handle cells colored manually and with conditional formatting.
  • Paste the results anywhere in a worksheet as values or formulas.

Sum and count cells by one color

Selecting the Sum & Count by One Color option will open the following pane in the left part of your worksheet. You specify the source range and sample cell, then then click Calculate.

The result will appear on the pane straight away! No macros, no formulas, no pain :)

Apart from count and sum, the add-in also shows Average, Max and Min for colored numbers. To insert a particular value in the sheet, click the Paste button next to it. Or click Paste All to have all the results inserted at once:
Calculate cells in Excel by selected color.

Count and sum all colored cells at once

To handle all colored cells at a time, choose the Sum & Count by All Color option. Basically, it works in the same way, except that instead of color, you choose the function to calculate.
Calculate all colored cells at once.

Tip. To have the results inserted in the worksheet as formulas (custom functions), check the corresponding box at the bottom of the pane.

Well, calculating colored cells in Excel is pretty easy, isn't it? Of course, if you have that little gem that makes the magic happen :) Curious to see how our add-in will cope with your colored cells? The download link is right below.

Available downloads

Sum and count by color in Excel - examples (.xlsm file)
Ultimate Suite 14-day fully-functional version (.exe file)

Table of contents

829 comments

  1. How to have a dynamic formula for the count of coloured cells? After applying 3 cells in a row colour and applying formula I get 3 but if I remove colour from one cell it not becomes 2 automatically. Regards Jay

    1. Hi! In VBA (Visual Basic for Applications), the Application.Volatile function is used to make a User Defined Function (UDF) volatile. A volatile function is recalculated every time any cells in the worksheet are recalculated, whether its input data has been changed or not.
      If you change the color of a cell using the Fill Color menu, Excel does not recognize this as changing the cell value and does not recalculate the formulas. If you change the color of a cell by using the Format Painter tool, Excel recalculates all of the formulas and user-defined functions on the worksheet.

      1. Thanks a lot for the valuable comments. Regards Jay

  2. Thank you for your effort, but this tricks are not working.
    The formula gives the error #NAME

    1. Hi! My guess is that you do not have the VBA code installed, or that you did it incorrectly. That is why you get the error message. You can see other causes of the #NAME error at this link.

  3. Using the count by conditional formatting colour, how can i input the result of this into a cell? Is there a formula so i can return this figure in a cell within my table? I have a large amount of data in a table and at the end of each row i would like to have an overall RAG rating based on the coloured cells with the row.

  4. I have used the sumcolouredcells formula, but it just gives me 0

    1. Hi! I can assume that you have incorrectly specified the color sample to sum the values. Without seeing your formula and your data, I can't help you. You can use the sample file linked at the end of the article.

  5. Thank you very much! This helped a lot.
    It would have been better if you included instructions on how to add the new formulas in Excel.

    1. Hello Phil!
      If you have a specific question about a function or formula, feel free to ask, and we will do our best to assist you.

  6. Hi. I'm looking for a way to count coloured formatted cells. The VBA macro above works well but it only gives me the answer in a box, I want to be able to show that value in a cell and copy the formula down so it counts colours in various rows. Is this possible? Many thanks

    1. Hello Jeanette!
      A VBA macro is the only way to specify the color of a cell that is colored by conditional formatting. You cannot do this using a user-defined function. As a result, it is not possible to use a formula to count cells that are highlighted with conditional formatting.
      You can calculate colored cells using Count & Sum by Color tool. You can then automatically insert the results into any cells of your choice. It is available as a part of our Ultimate Suite for Excel that you can install in a trial mode and check how it works for free.

  7. Good morning, the formula gives me the error #NAME?, it had already happened to me with another case, but I really don't remember how they told me to solve it, it even happens to me in the example file,
    Can you help me please

  8. Hi ! I managed to get the function working. However it also count blank cells (which are not formated) any idea why ?

    1. Hello Vincent!
      I have no idea because I couldn't reproduce your problem. The CountCellsByColor function works correctly.

  9. Hi, the color sum works perfectly, but I need to calculate the sum total with decimal points. Is there any solution to do so? thank you.

    1. Hi! The user-defined function SumCellsByColor counts with decimals. Change the number format of the cell containing the formula to your preferred format. You can find the examples and detailed instructions here: Custom Excel number format.

  10. The colour count works perfectly, but would there be a way to edit it so it counts a specific name against the colour. So if I had Agent 1 appear in a yellow cell 5, a red cell 4 times and a blue cell 8 times it would return that number to me without counting any other names or coloured boxes. I have tried multiple different ways of count/countif/countifs to include both but they don't seem to work. Thanks in advance.

    1. Hello Phillip!
      This can be done, however we do not do VBA code creation or customization on request.
      However, you can use the custom GetCellColor function to get the cell color code. Read the detailed description in the articles above.
      Use the SUMPRODUCT function to count the number of values for multiple conditions.
      The formula might look as follows:

      =SUMPRODUCT((GetCellColor(A2:A15)=49407) * (A2:A15="Agent 1"))

  11. Just what I need, great job!

    However, I'm wanting to count cells that have been Conditionally Formatted. I see there is a Macro for this and it brings up a Message Box giving the count and details.

    Is there a way to have the count info on the sheet instead of a Message Box, similar to the first CountCellsByColor Function?

    Thanks

  12. Hi,
    I had this working but now it has stopped I also downloaded the example file and it is not working on my computer I get the #NAME error (even in the example file) Is there some option I need to change?
    Thanks
    Vicki

      1. Hi,
        I got the example file working (Macro was being blocked) but still can't get mine working even with cutting and pasting everything
        Vicki

  13. Hi! I've been using the sum by color function for years. All of the sudden it has slowed down my workbook dramatically and I can't figure out how to fix it.

  14. I was looking for something to count cells colored with conditional formatting. and found SumCountByConditionalFormat. And it worked perfectly. Thanks

  15. Can you tell me something...
    How to count names in rows and don't count if they are in red color.
    In case I have a table with planner
    There are names in hours for work. If someone is missing marks field with red.
    and i want to have column with total visits.. without missings

  16. Useful thank you. However when using CountCellsByColor I get an error that says "Value!" the only thing I see is excel automatically changes the function to COUNTCellsByColor. Otherwise straightforward but doesn't work. :(

    1. Hi! Excel takes the name of the custom function from the code you set up in your workbook. I am not able to verify how you did this. Follow the instructions carefully. You can also use the sample file linked at the end of this article.

  17. Hello!
    I followed the steps for count cells by conditional formatting and it worked great! Thank you very much for that.
    I had a follow up question:
    I get the count in a dialogue box. Is there anyway to get that in a cell instead?

    Thank you.

    1. Hi! To do this, you need to modify the macro code and specify in it the cell to which you want to write the resulting value. You can change the address of the cell only if you change the code of the macro. You can try to do this on your own.

  18. Hi!
    Is anyone finding that when you change the color (but not the data) the calculation does not automatically update? I have Calculations Options as Automatic, but it won't update unless I hit Calculate Now.

  19. CountCellsByColor and CountCellsByFontColor are just what I needed.

    Had to add this code as in 6,000 rows with many irregular fill colours applied, I couldn't easily find the cells in one column that were "" or blank, but had a colour (I'm in the UK) fill or text format applied. The below addition would have saved hours trying to find the subtotal errors for various filling colours:

    For Each cell current In data_range
    If cellCurrent = "" Then 'if typed content is blank
    GoTo Skip
    End If

    If indRefColor = cellCurrent.Interior.Color Then
    cntRes = cntRes + 1
    End If

    Skip:

    Next cellCurrent

  20. how do you adjust the "Count and sum conditionally formatted cells" coding so that it can applied for an individual row or column?

    1. Hi! Your problem is not very clear. When using a function SumCellsByColor, you have to specify the cells, row, or column in the formula. When using a macro, you have to select the desired range, row, or column with the mouse. Please read the above article carefully.

Post a comment



Thank you for your comment!
When posting a question, please be very clear and concise. This will help us provide a quick and relevant solution to
your query. We cannot guarantee that we will answer every question, but we'll do our best :)