by The tutorial shows how to use the VLOOKUP function to copy data from another worksheet or workbook, Vlookup in multiple sheets, and look up dynamically to return values from different sheets into different cells.
When looking up some information in Excel, it's a rare case when all the data is on the same sheet. More often, you will have to search across multiple sheets or even different workbooks. The good news is that Microsoft Excel provides more than one way to do this, and the bad news is that all the ways are a bit more complicated than a standard VLOOKUP formula. But with just a little patience, we will figure them out :)
How to VLOOKUP between two sheets
For starters, let's investigate a simplest case - using VLOOKUP to copy data from another worksheet. It's very similar to a regular VLOOKUP formula that searches on the same worksheet. The difference is that you include the sheet name in the table_array argument to tell your formula in which worksheet the lookup range is located.
The generic formula to VLOOKUP from another sheet is as follows:
As an example, let's pull the sales figures from Jan report to Summary sheet. For this, we define the following arguments:
- Lookup_values are in column A on the Summary sheet, and we refer to the first data cell, which is A2.
- Table_array is the range A2:B6 on the Jan sheet. To refer to it, prefix the range reference with the sheet name followed by the exclamation point: Jan!$A$2:$B$6.
Please pay attention that we lock the range with absolute cell references to prevent it from changing when copying the formula to other cells.
Col_index_num is 2 because we want to copy a value from column B, which is the 2nd column in the table array. - Range_lookup is set to FALSE to look up an exact match.
Putting the arguments together, we get this formula:
=VLOOKUP(A2, Jan!$A$2:$B$6, 2, FALSE)
Drag the formula down the column and you will get this result:
In a similar manner, you can Vlookup data from the Feb and Mar sheets:
=VLOOKUP(A2, Feb!$A$2:$B$6, 2, FALSE)
=VLOOKUP(A2, Mar!$A$2:$B$6, 2, FALSE)
Tips and notes:
- If the sheet name contains spaces or non-alphabetical characters, it must be enclosed in single quotation marks, like 'Jan Sales'!$A$2:$B$6. For more info, please see How to reference another sheet in Excel.
- Instead of typing a sheet name directly in a formula, you can switch to the lookup worksheet and select the range there. Excel will insert a reference with the correct syntax automatically, sparing you the trouble to check the name and troubleshoot.
Vlookup from a different workbook
To VLOOKUP between two workbooks, include the file name in square brackets, followed by the sheet name and the exclamation point.
For example, to search for A2 value in the range A2:B6 on Jan sheet in the Sales_reports.xlsx workbook, use this formula:
=VLOOKUP(A2, [Sales_reports.xlsx]Jan!$A$2:$B$6, 2, FALSE)
For full details, please see VLOOKUP from another workbook in Excel.
Vlookup across multiple sheets with IFERROR
When you need to look up between more than two sheets, the easiest solution is to use VLOOKUP in combination with IFERROR. The idea is to nest several IFERROR functions to check multiple worksheets one by one: if the first VLOOKUP does not find a match on the first sheet, search in the next sheet, and so on.
To see how this approach works on real-life data, let's consider the following example. Below is the Summary table that we want to populate with the item names and amounts by looking up the order number in West and East sheets:
First, we are going to pull the items. For this, we instruct the VLOOKUP formula to search for the order number in A2 on the East sheet and return the value from column B (2nd column in table_array A2:C6). If an exact match is not found, then search in the West sheet. If both Vlookups fail, return "Not found".
=IFERROR(VLOOKUP(A2, East!$A$2:$C$6, 2, FALSE), IFERROR(VLOOKUP(A2, West!$A$2:$C$6, 2, FALSE), "Not found"))
To return the amount, simply change the column index number to 3:
=IFERROR(VLOOKUP(A2, East!$A$2:$C$6, 3, FALSE), IFERROR(VLOOKUP(A2, West!$A$2:$C$6, 3, FALSE), "Not found"))
Tip. If needed, you can specify different table arrays for different VLOOKUP functions. In this example, both lookup sheets have the same number of rows (A2:C6), but your worksheets may be different in size.
Vlookup in multiple workbooks
To Vlookup between two or more workbooks, enclose the workbook name in square brackets and put it before the sheet name. For example, here's how you can Vlookup in two different files (Book1 and Book2) with a single formula:
=IFERROR(VLOOKUP(A2, [Book1.xlsx]East!$A$2:$C$6, 2, FALSE), IFERROR(VLOOKUP(A2, [Book2.xlsx]West!$A$2:$C$6, 2, FALSE),"Not found"))
Make column index number dynamic to Vlookup multiple columns
In situation when you need to return data from several columns, making col_index_num dynamic could save you some time. There are a couple of adjustments to be made:
- For the col_index_num argument, use the COLUMNS function that returns the number of columns in a specified array: COLUMNS($A$1:B$1). (The row coordinate does not really matter, it can be just any row.)
- In the lookup_value argument, lock the column reference with the $ sign ($A2), so it remains fixed when copying the formula to other columns.
As the result, you get a kind of dynamic formula that extracts matching values from different columns, depending on which column the formula is copied to:
=IFERROR(VLOOKUP($A2, East!$A$2:$C$6, COLUMNS($A$1:B$1), FALSE), IFERROR(VLOOKUP($A2, West!$A$2:$C$6, COLUMNS($A$1:B$1), FALSE), "Not found"))
When entered in column B, COLUMNS($A$1:B$1) evaluates to 2 telling VLOOKUP to return a value from the 2nd column in the table array.
When copied to column C (i.e. you've dragged the formula from B2 to C2), B$1 changes to C$1 because the column reference is relative. Consequently, COLUMNS($A$1:C$1) evaluates to 3 forcing VLOOKUP to return a value from the 3rd column.
This formula works great for 2 - 3 lookup sheets. If you have more, repetitive IFERRORs become too cumbersome. The next example demonstrates a bit more complicated but a lot more elegant approach.
Vlookup multiple sheets with INDIRECT
One more way to Vlookup between multiple sheets in Excel is to use a combination of VLOOKUP and INDIRECT functions. This method requires a little preparation, but in the end, you will have a more compact formula to Vlookup in any number of spreadsheets.
A generic formula to Vlookup across sheets is as follows:
Where:
- Lookup_sheets - a named range consisting of the lookup sheet names.
- Lookup_value - the value to search for.
- Lookup_range - the column range in the lookup sheets where to search for the lookup value.
- Table_array - the data range in the lookup sheets.
- Col_index_num - the number of the column in the table array from which to return a value.
For the formula to work correctly, please bear in mind the following caveats:
- It's an array formula, which must be completed by pressing Ctrl + Shift + Enter keys together.
- All the sheets must have the same order of columns.
- As we use one table array for all lookup sheets, specify the largest range if your sheets have different numbers of rows.
How to use the formula to Vlookup across sheets
To Vlookup multiple sheets at a time, carry out these steps:
- Write down all the lookup sheet names somewhere in your workbook and name that range (Lookup_sheets in our case).
- Adjust the generic formula for your data. In this example, we'll be:
- searching for A2 value (lookup_value)
- in the range A2:A6 (lookup_range) in four worksheets (East, North, South and West), and
- pull matching values from column B, which is column 2 (col_index_num) in the data range A2:C6 (table_array).
With the above arguments, the formula takes this shape:
=VLOOKUP($A2, INDIRECT("'"&INDEX(Lookup_sheets, MATCH(1, --(COUNTIF(INDIRECT("'"& Lookup_sheets&"'!$A$2:$A$6"), $A2)>0), 0)) &"'!$A$2:$C$6"), 2, FALSE)Please notice that we lock both ranges ($A$2:$A$6 and $A$2:$C$6) with absolute cell references.
- Enter the formula in the topmost cell (B2 in this example) and press Ctrl + Shift + Enter to complete it.
- Double click or drag the fill handle to copy the formula down the column.
As the result, we've got the formula to look up the order number in 4 sheets and retrieve the corresponding item. If a specific order number is not found, a #N/A error is displayed like in row 14:
To return the amount, simply replace 2 with 3 in the col_index_num argument as amounts are in the 3rd column of the table array:
=VLOOKUP($A2, INDIRECT("'"&INDEX(Lookup_sheets, MATCH(1, --(COUNTIF(INDIRECT("'" & Lookup_sheets & "'!$A$2:$A$6"), $A2)>0), 0)) & "'!$A$2:$C$6"), 3, FALSE)
If you'd like to replace the standard #N/A error notation with your own text, wrap the formula into the IFNA function:
=IFNA(VLOOKUP($A2, INDIRECT("'"&INDEX(Lookup_sheets, MATCH(1, --(COUNTIF(INDIRECT("'" & Lookup_sheets & "'!$A$2:$A$6"), $A2)>0), 0)) & "'!$A$2:$C$6"), 3, FALSE), "Not found")
Vlookup multiple sheets between workbooks
This generic formula (or its any variation) can also be used to Vlookup multiple sheets in a different workbook. For this, concatenate the workbook name inside INDIRECT like shown in the below formula:
=IFNA(VLOOKUP($A2, INDIRECT("'[Book1.xlsx]" & INDEX(Lookup_sheets, MATCH(1, --(COUNTIF(INDIRECT("'[Book1.xlsx]" & Lookup_sheets & "'!$A$2:$A$6"), $A2)>0), 0)) & "'!$A$2:$C$6"), 2, FALSE), "Not found")
Vlookup between sheets and return multiple columns
If you want to pull data from several columns, a multi-cell array formula can do that in one go. To create such a formula, supply an array constant for the col_index_num argument.
In this example, we wish to return the item names (column B) and amounts (column C), which are the 2nd and 3rd columns in the table array, respectively. So, the required array is {2,3}.
=VLOOKUP($A2, INDIRECT("'"&INDEX(Lookup_sheets, MATCH(1, --(COUNTIF(INDIRECT("'"& Lookup_sheets &"'!$A$2:$C$6"), $A2)>0), 0)) &"'!$A$2:$C$6"), {2,3}, FALSE)
To correctly enter the formula in multiple cells, this is what you need to do:
- In the first row, select all the cells to be populated (B2:C2 in our example).
- Type the formula and press Ctrl + Shift + Enter. This enters the same formula in the selected cells, which will return a different value in each column.
- Drag down the formula to the remaining rows.
How this formula works
To better understand the logic, let's break down this basic formula to the individual functions:
=VLOOKUP($A2, INDIRECT("'"&INDEX(Lookup_sheets, MATCH(1, --(COUNTIF(INDIRECT("'"& Lookup_sheets&"'!$A$2:$A$6"), $A2)>0), 0)) &"'!$A$2:$C$6"), 2, FALSE)
Working from the inside out, here's what the formula does:
COUNTIF and INDIRECT
In a nutshell, INDIRECT builds the references for all lookup sheets, and COUNTIF counts the occurrences of the lookup value (A2) in each sheet:
--(COUNTIF( INDIRECT("'"&Lookup_sheets&"'!$A$2:$A$6"), $A2)>0)
In more detail:
First, you concatenate the range name (Lookup_sheets) and the range reference ($A$2:$A$6), adding apostrophes and the exclamation point in the right places to make an external reference, and feed the resulting text string to the INDIRECT function to dynamically refer to the lookup sheets:
INDIRECT({"'East'!$A$2:$A$6"; "'South'!$A$2:$A$6"; "'North'!$A$2:$A$6"; "'West'!$A$2:$A$6"})
COUNTIF checks each cell in the range A2:A6 on each lookup sheet against the value in A2 on the main sheet and returns the count of matches for each sheet. In our dataset, the order number in A2 (101) is found in the West sheet, which is 4th in the named range, so COUNTIF returns this array:
{0;0;0;1}
Next, you compare each element of the above array with 0:
--({0; 0; 0; 1}>0)
This yields an array of TRUE (greater than 0) and FALSE (equal to 0) values, which you coerce to 1's and 0's by using a double unary (--), and get the following array as the result:
{0; 0; 0; 1}
This operation is an extra precaution to handle a situation when a lookup sheet contains several occurrences of the lookup value, in which case COUNTIF would return a count greater than 1, while we want only 1's and 0's in the final array (in a moment, you will understand why).
After all these transformations, our formula looks as follows:
VLOOKUP($A2, INDIRECT("'"&INDEX(Lookup_sheets, MATCH(1, {0;0;0;1}, 0)) &"'!$A$2:$C$6"), 2, FALSE)
INDEX and MATCH
At this point, a classic INDEX MATCH combination steps in:
INDEX(Lookup_sheets, MATCH(1, {0;0;0;1}, 0))
The MATCH function configured for exact match (0 in the last argument) looks for the value 1 in the array {0;0;0;1} and returns its position, which is 4:
INDEX(Lookup_sheets, 4)
The INDEX function uses the number returned by MATCH as the row number argument (row_num), and returns the 4th value in the named range Lookup_sheets, which is West.
So, the formula further reduces to:
VLOOKUP($A2, INDIRECT("'"&"West"&"'!$A$2:$C$6"), 2, FALSE)
VLOOKUP and INDIRECT
The INDIRECT function processes the text string inside it:
INDIRECT("'"&"West"&"'!$A$2:$C$6")
And converts it into a reference that goes to the table_array argument of VLOOKUP:
VLOOKUP($A2, 'West'!$A$2:$C$6, 2, FALSE)
Finally, this very standard VLOOKUP formula searches for the A2 value in the first column of the range A2:C6 on the West sheet and returns a match from the 2nd column. That's it!
Dynamic VLOOKUP to return data from multiple sheets into different cells
First off, let's define what exactly the word "dynamic" means in this context and how this formula is going to be different from the previous ones.
In case you have large chunks of data in the same format that are split over multiple spreadsheets, you may want to extract information from different sheets into different cells. The image below illustrates the concept:
Unlike the previous formulas that retrieved a value from a specific sheet based on a unique identifier, this time we are looking to extract values from several sheets at a time.
There are two different solutions for this task. In both cases, you need to do a little preparatory work and create named ranges for data cells in each lookup sheet. For this example, we defined the following ranges:
- East_Sales - A2:B6 on the East sheet
- North_Sales - A2:B6 on the North sheet
- South_Sales - A2:B6 on the South sheet
- West_Sales - A2:B6 on the West sheet
And now, let's build a couple of formulas to get the desired result.
VLOOKUP and nested IFs
If you have a reasonable number of sheets to look up, you can use nested IF functions to select the sheet based on the keywords in the predefined cells (cells B1 through D1 in our case).
With the lookup value in A2, the formula is follows:
=VLOOKUP($A2, IF(B$1="east", East_Sales, IF(B$1="north", North_Sales, IF(B$1="south", South_Sales, IF(B$1="west", West_Sales)))), 2, FALSE)
Translated into English, the IF part reads:
If B1 is East, look in the range named East_Sales; if B1 is North, look in the range named North_Sales; if B1 is South, look in the range named South_Sales; and if B1 is West, look in the range named West_Sales.
The range returned by IF goes to table_array of VLOOKUP, which pulls a matching value from the 2nd column on the corresponding sheet.
The clever use of mixed references for the lookup value ($A2 - absolute column and relative row) and the logical test of IF (B$1 - relative column and absolute row) allows copying the formula to other cells without any changes - Excel adjusts the references automatically based on the relative position of a row and column.
So, we enter the formula in B2, copy it right and down to as many columns and rows as needed, and get the following result:
INDIRECT VLOOKUP
When working with many sheets, multiple nested levels could make the formula too lengthy and difficult to read. A far better way is to create a dynamic vlookup range with the help of INDIRECT:
=VLOOKUP($A2, INDIRECT(B$1&"_Sales"), 2, FALSE)
Here, we concatenate the reference to the column header that contains a unique part of the named range (B$1) and the common part (_Sales). This produces a text string like "East_Sales", which INDIRECT converts to the range name understandable by Excel.
When copied to C2, a relative column reference (B$1) changes to (C$1). As the result, the function INDIRECT(C$1&"_Sales") returns the range named North_Sales and passes that range to VLOOKUP.
As the result, you get a compact formula that works beautifully on any number of named ranges in different sheets:
That's how to Vlookup between sheets and files in Excel. I thank you for reading and hope to see you on our blog next week!
Practice workbook for download
Vlookup multiple sheets examples (.xlsx file)
Latest comments
in your example: =vlookup($a13, Indirect(B$11&"_sales"), 2, false) I don't see where "sales" is anywhere in the example spreadsheet. Where is it pull _sales from?
Hi Sarah,
"Sales" is just a text string that we supply to the INDIRECT function to get an appropriate range name for a specific column. We have the source data in the range A2:B6 in 4 different sheets, each corresponding to a particular region. The ranges of data are named East_Sales, North_Sales, South_Sales and West_Sales. Please see an image with the source data in the beginning of the "Dynamic VLOOKUP to return data from multiple sheets into different cells" section.
Now, back to the formula. The formula in B2 (see below) takes "East" from B1 and concatenates it with "_Sales". As the result, we get the range name East_Sales. This range name is used for the table_array argument of VLOOKUP forcing it to search for the matching value exactly in that range.
=VLOOKUP($A2, INDIRECT(B$1&"_Sales"), 2, FALSE)
When copied to C2, a relative column reference (B$1) in the formula changes to C$1. As the result, the function INDIRECT(C$1&"_Sales") returns the range named North_Sales and passes that range to VLOOKUP.
Hope this helps.
Hello Sarah!
INDIRECT(B$1&“_Sales”) function creates a reference to a named range, for example, named “East_Sales”. For this example, this could be the name of the range of cells A2:B6. You can read more about named ranges here: Excel names and named ranges: how to define and use in formulas and INDIRECT with named ranges.
Hi
I have entered the following formula and getting error message. "Formula is missing an opening or closing parenthesis"
=IF([@[Profit Center]]="300","ABC",IF([@[Profit Center]]="400","DEF",IF([@[Profit Center]]="410","GHI",IF([@[Profit Center]]="420","XYZ","").
could you please advise this error. Thank you
Hi! To write down the formula correctly, study these instructions carefully: Structured reference in Excel tables.
Your formulas are missing the name of the Excel table.
Hello
I hope you can help me.
In sheet A, column L, I have a Narrative from timesheets e.g. CRM Is 964016 - Project x - TS14nnnnn
In sheet B, column A, I have a list of the CRM IDs that relate to that project ID
I want Excel to look up sheet B, column A to see if sheet A column L has the same number in amongst the text and put either the number or n/a in sheet A, column S.
Can this be done?
Hello! If I understand you correctly, you want to determine the partial match between the text in column A and the text in column L. Based on the information given, the formula could be as follows:
=INDEX(B!$A$1:$A$10,MATCH(TRUE,ISNUMBER(SEARCH(" "&B!$A$1:$A$10&" ",A!L1)),0))
For more information, please read: How to find substring in Excel
Use INDEX MATCH to get the value that matches the partial match found.
Alexander, thank you so much, I've been working on this for weeks. I just had to tweek the actual names of the tabs and voila!
Hi,
I have 2 sheets within a single workbook. My first sheet has students' ID numbers, students' test scores, teachers, etc. My second sheet has students' ID numbers, students' teachers and the class periods that students have the teachers. I am trying to pull the class periods from sheet 2 and return it to sheet one (where student test scores are located) using the students' ID numbers that are in both. The formula that I am using is =VLOOKUP(B2,'Class Rosters'!A:E,3,false). I am getting #N/A error message. What am I doing wrong?
Hi! I can't check a formula that contains unique references to your data, which I don't have.
Here is the article that may be helpful to you: Fixing #N/A error in VLOOKUP.
This is driving me nuts, so hopefully you can help. I have a spreadsheet with seven worksheets. The first sheet has my data to lookup, the other six sheets have data about some of the values I need to lookup. What I want to do is look for the data in Sheet1 A2 and return the sheet name it finds the lookup value in first. In other words, if sheet1 A2 is "test", I want to look for test in the other sheets, and if the first place it finds test is in Sheet4, I need to return the name of that tab (Sheet4). I have a formula to return the name of the tab in column C of each sheet ( =RIGHT(CELL("filename",A2),LEN(CELL("filename",A2))-FIND("]",CELL("filename",A2),1)) ) which works great if I'm only looking for the name of one sheet. When I copy that formula to each sheet's column C, it gives me the name of the sheet the formula was last run on across all of the sheets, which I thought was kind of weird. I tried the "VLOOKUP across multiple sheets with IFERROR" formula to pull this sheet name from column C, which is how I discovered that it returns the name of the sheet the formula was last run on. Any idea how I can do this?
Hi! To return the name of the worksheet on which the value from cell A2 is found in column A, try this formula:
=IFNA(INDEX(Lookup_sheets,MATCH(1,--(COUNTIF(INDIRECT("'"&Lookup_sheets&"'!$A$2:$A$20"),$A2)>0),0)),"Not found")
Lookup_sheets - named range with the names of all worksheets
I want to extract two columns from first sheet to 2nd sheet.
Data range is D4:I50
Columns: Control # Party Name Start Date End Date Status Category
-------------------------------------------------------------------------------------------------------------------------
Date: Active Commercial
Required rows are on the basis of last two columns value "Active" and "Commercial".
Please guide.
Hello! You can use the FILTER function to extract part of the data from the range based on the criterion. You can find the examples and detailed instructions here: Excel FILTER function - dynamic filtering with formulas. Hope this is what you need.
Hello Alex,
In an excel workbook , I have 45 worksheets/ tabs. The master data resides in the first sheet with all the item data while the other sheets represent each item category. The data structure is the same across the 44 sheets and is an extract of the data from the master sheet. I keep adding additional columns in the master sheet as and when I receive data from the source; I add these columns on each of the 44 sheets too. My question is how do I add these new columns together with the values across the 44 sheets in one go!! Item Code is the common reference value between the master sheet and the other 44 sheets.
Hello! You can only add data to a master sheet and extract the desired data for each item from the master sheet using the pivot table or the FILTER function. I hope it’ll be helpful. If something is still unclear, please feel free to ask.
Hello,
I have this data in one sheet. Need to Order: 10 30 20 (in one rows, cell number D40, E40, F40).
I want to insert this data in another sheet called 'Product List' in 'Order' column (in columns, cell number E3, E4, E5).
Can you please help me.
Hi! Here is the article that may be helpful to you: Excel reference to another sheet or workbook (external reference).
I am trying to fetch data from each sheet of a different workbook (ABC.xlsx). Sheet names are changing as per Date. Example:
05-24-2023
05-25-2023
05-26-2023
Currently I am using formula:
=VLOOKUP(B2,[ABC.xlsx]05-24-2023!$E$2:$F$7,2,FALSE)
Please let me know how I can make the sheet name dynamic (vary as per date. As per above example).
Hi! Try to use the recommendations described in this article: INDIRECT formula to dynamically refer to another worksheet. I hope my advice will help you solve your task.
Hi,
I have created a spreadsheet for an event to record results.
I have a names tab which collates rider and horse and concatenates it to create a unique combo. I then have an event tab which hyperlinks to individual tab for each event and records 1st, 2nd, 3rd placing which is then converted to points ie. 1st = 5 points, 2nd = 3 points in a second column. Ihave each results tab set up identical so it is consistent across the board.
I now need to set up a summary sheet to calculate all points per rider and horse combination. I have used a vlookup to this effect - =vlookup(a2,tab1 a:f, 6,false)+vlookup(a2,tab2 a:f,6,false)+……
The first vlookup works, but as soon as I add the second (or more) it fails. Because I may have only calculated points in the first event and not the second. So I get an #refs error.
Is this the best way to total the points? Or is there a better formula?
Any suggestions would be appreciated.
Hi! Maybe this article will be helpful: VLOOKUP across multiple sheets in Excel with examples. I hope it’ll be helpful. If this is not what you wanted, please describe the problem in more detail.
I'm trying to make a testing workbook where in Im trying to auto populate my summary of failed cases with data from 4 different sheets. I want to get entire rows where the test cases failed including, date, account number, employee number, and a validation based (Passed, Failed).
Hello!
You can get the data from each worksheet into a separate table using the FILTER function. Use this guide: Excel FILTER function - dynamic filtering with formulas.
If you want to get data from 4 worksheets in one table, you first need to merge these 4 worksheets into one. We have a special tutorial about this: Merge multiple sheets into one. Then extract the data from this sheet using the FILTER function.
I recommend that you pay attention to Copy Sheets tool. You can create a single table with data from several sheets in a couple of clicks.
It is available as a part of our Ultimate Suite for Excel that you can install in a trial mode and check how it works for free.
Hi, I am having two sheets in 1 sheet I have multiple dates entry with repeated same date as well and I want this multiple dates entry as a single date in another sheet same as pivot table works.
Hello!
Maybe this article will be helpful: How to remove duplicates in Excel. I recommend paying attention to Duplicate Remover - fast and efficient way to locate duplicates in Excel. It is available as a part of our Ultimate Suite for Excel that you can install in a trial mode and check how it works for free.
I am using Excel Sheets with Dates and I want to use vlookup() with dates formulas like this VLOOKUP(C7,'02-Jan-23'!$C:$H,6,0)+VLOOKUP(C7,'02-Jan-23'!$C:$K,9,0)-VLOOKUP(C7,'02-Jan-23'!$C:$I,7,0) in next dates sheets to get last dates' closing amounts in new sheets opening and I want to have these sheets names to be changed automatically. Like VLOOKUP(C7,'02-Jan-23-1'!$C:$H,6,0)+VLOOKUP(C7,'02-Jan-23-1'!$C:$K,9,0)-VLOOKUP(C7,'02-Jan-23-1'!$C:$I,7,0).
Please help me in this situation that how can I get it as in this way I am getting an error.
Hello!
To dynamically change the name of a worksheet, use the INDIRECT function. See detailed instructions and examples here: Creating an Excel dynamic reference to another sheet. I hope my advice will help you solve your task.
Thanks for this helpful article - I used the method with the below formula across multiple worksheets:
=VLOOKUP(X2, INDIRECT("'"&INDEX(Lookup_Sheets, MATCH(1, --(COUNTIF(INDIRECT("'" & Lookup_Sheets & "'!R$4:R$27"), X2)>0), 0)) & "'!R$4:AJ$27"), 16, FALSE)
The problem i am having is that where X2 (which is a comment/string of text) is long, the formula returns the error "VALUE"
When i reduce the characters in X2, it returns the correct lookup entry.
I have also tried changing to TRUE and also tried adding X2&"*" but none of these work either.
For further context, X2 is a sheet of data pull from a software system, each row is allocated to a specific team (separate sheets) where X2 is replicated in R4:R27. On each team sheet, a name is filled out in a colum to the right of this data. I need those people's names to "match" and populate on the original data pull sheet for summary. Not sure if the error lies within the original data sheet or the separate sheets they are being duplicated on.
Is there any way around this please?
Hello!
VLOOKUP cannot search for values with more than 255 characters. Read about it in more detail here: #VALUE! error in VLOOKUP formulas.
In this case, you can use the INDEX+MATCH function to look up values.
I hope this will help.
HI
Under your title Vlookup multiple sheets with INDIRECT
you havent defined what is "Sheet_list"
Kind Regards
Maurice
Hi Maurice,
My bad. Actually, there is no "Sheet_list" in the formula. It's just another name for the Lookup_sheets named range. Initially, I named it "Sheet_list", then changed the name to "Lookup_sheets", but failed to replace one instance in the generic formula. Sorry for that.
Anyway, the formula is fixed now. Thank you for pointing our that mistake!
Hi Milosz
Have two spreadsheets with multiple rows. Each row has a unique ID, pay component code and amount. I am try to do a v-lookup between the spreads to check the the amounts against each pay component match.
Please can you tell if any of the above would work in this scenario or do I need todo something completely different?
Thanks
Becky
Hello!
To search between two tables you can use this tutorial for VLOOKUP function: Excel VLOOKUP function tutorial with formula examples.
I hope it’ll be helpful. If something is still unclear, please feel free to ask.
Hi,
I am trying to use the formula under 'Lookup multiple sheets between workbooks'
The spreadsheet I am using will be opened by multiple colleagues across the business but the workbook it is linking to will not be open. Therefore using the COUNTIF function is returning #N/A:
=(VLOOKUP($AH8, INDIRECT("'[Book1.xlsx]"&INDEX(Sheet_list, MATCH(1, --(COUNTIF(INDIRECT("'[Book1.xlsx]"&Sheet_list&"'!$B$17:$B$32"), $AH8)>0), 0))&"'!$B$17:$K$32"), 4, FALSE))
Is there a way to fix this so that it works when Book1 is not open?
Thanks
Hi!
A VBA macro or Power Query can work with a workbook that is not open. Regular Excel formulas require special references. Read more - External reference to a closed workbook.
Hi, great tutorial on Vlookup. First time user of Vlookup. My first formula worked fine; =VLOOKUP(D4,CREWS2!A1:E55,2). The second formula; =VLOOKUP(C8,CREWS2!$A$1:$E$55,1)is producing an odd result. Both formulas use the same data table;
A B C D
GRF Groundperson 6 Months - ST $60.72 ST
GRG Groundperson 6 Months - PT $88.05 PT
JTA Journeyman Tree Trimmer - ST $95.68 ST
JTB Journeyman Tree Trimmer - PT $138.74 PT
the first formula finds column A when the name in column B is entered. my second formula is to find column B when the name in column A is entered. When i run second formula I am getting GRG when i enter Journeyman Tree Trimmer - ST, instead of JTA.
Does the direction column B to column A matter? Does the name structure matter; Journeyman Tree Trimmer - ST?
Thank you for any assistance
Hello!
The VLOOKUP function always searches in the leftmost column of the table and returns a value from a column to the right. To get the value to the left of the lookup column, use the INDEX + MATCH combination.
I hope I answered your question. If something is still unclear, please feel free to ask.
Trying to make the vlookup indirect function work for my data and can't quite get my head around it.
What I have based on your examples above is:
=IFNA(VLOOKUP($B2, INDIRECT("'"&INDEX(Lookup_sheets, MATCH(1, --(COUNTIF(INDIRECT("'" & Lookup_sheets & "'!$C$2:$C$20"), $B2)>0), 0)) & "'!$A$2:$R$20"), 18, FALSE), "Not found")
B2 = lookup value
C2:C20 across the multiple sheets is range the lookup value will be in
A2:R20 is my table/data
Column 18 or R is where i want to return the value from that matches the C2 result.
The only thing being returned no matter what i enter in B2 is "Not found""/NA. Any help is much appreciated.
Hello!
I cannot verify your formula as I do not have your data. Use the instructions carefully. Check the named range Lookup_sheets. In it, you need to write down the names of the worksheets.
I'm trying to search for a customer number (B2) that returns text/notes from column R/18 across multiple worksheets and the text is not the same across each occurrence. Is this possible?
Multiple sheets linked to one sheet, sample if i have 4 sheets of my inventories and i want to monitor all damages in fifth sheets.
Hello!
Use external references in formulas. All other recommendations can be found in this article.