*The tutorial explains how to use multiple IF in Excel and provides a couple of nested If formula examples for most common tasks. *

If someone asks you what Excel function you use most often, what would your answer be? In most cases, it's the Excel IF function. A regular If formula that tests a single condition is very straightforward and easy to write. But what if your data requires more elaborate logical tests with multiple conditions? In this case, you can include several IF functions in one formula, and these multiple If statements are called **Excel Nested IF**. The biggest advantage of the nested If statement is that it allows you to check more than one condition and return different values depending on the results of those checks, all in a single formula.

Microsoft Excel has limits to the **levels of nested IFs**. In Excel 2003 and lower, up to 7 levels were allowed. In Excel 2007 and higher, you can nest up to 64 IF functions in one formula.

Further on in this tutorial, you will find a couple of Excel nested If examples along with a detailed explanation of their syntax and logic.

## Example 1. Classic nested IF formula

Here's a typical example of Excel If with multiple conditions. Supposing you have a list of students in column A and their exam scores in column B, and you want to classify the scores with the following conditions:

- Excellent: Over 249
- Good: between 249 and 200, inclusive
- Satisfactory: between 199 and 150, inclusive
- Poor: Under 150

And now, let's write a nested IF function based on the above criteria. It's considered a good practice to begin with the most important condition and keep your functions as simple as possible. Our Excel nested IF formula goes as follows:

`=IF(B2>249, "Excellent", IF(B2>=200, "Good", IF(B2>150, "Satisfactory", "Poor")))`

And works exactly as it should:

### Understanding Excel nested IF logic

I've heard some people say that Excel multiple If is driving them crazy :) Try looking at it at a different angle:

What the formula actually tells Excel to do is to evaluate the *logical_test* of the first IF function and, if the condition is met, return the value supplied in the *value_if_true* argument. If the condition of the 1st If function is not met, then test the 2nd If statement, and so on.

*check if*B2>=249,

*if true - return*"Excellent",

*or else*

IF(

*check if*B2>=200,

*if true - return*"Good",

*or else*

IF(

*check if*B2>150,

*if true - return*"Satisfactory",

*if false -*

return"Poor")))

return

If you need a **nested IF formula with wildcard characters** (partial match), check out this example: If cell contains, then return different values.

## Example 2. Multiple If with arithmetic calculations

Here's another typical task: the unit price varies depending on the specified quantity, and your goal is to write a formula that calculates the total price for any amount of items input in a specific cell. In other words, your formula needs to check multiple conditions and perform different calculations depending on what amount range the specified quantity falls in:

Unit Quantity | Price per unit |

1 to 10 | $20 |

11 to 19 | $18 |

20 to 49 | $16 |

50 to 100 | $13 |

Over 101 | $12 |

This task can also be accomplished by using multiple IF functions. The logic is the same as in the above example, the only difference is that you multiply the specified quantity by the value returned by nested IFs (i.e. the corresponding price per unit).

Assuming the user enters the quantity in cell B8, the formula is as follows:

`=B8*IF(B8>=101, 12, IF(B8>=50, 13, IF(B8>=20, 16, IF( B8>=11, 18, IF(B8>=1, 20, "")))))`

And the result will look something similar to this:

As you understand, this example demonstrates only the general approach, and you can easily customize this nested If function depending on your particular task.

For example, instead of "hard-coding" the prices in the formula, you can reference the cells containing those values (cells B2 to B6). This will enable your users to edit the source data without having to update the formula:

`=B8*IF(B8>=101,B6, IF(B8>=50, B5, IF(B8>=20, B4, IF( B8>=11, B3, IF(B8>=1, B2, "")))))`

Or, you may want to include an additional IF function(s) that fixes an upper, lower or both bounds of the amount range. When the quantity is outside the range, the formula will display an "out of the range" message. For example:

`=IF(OR(B8>200,B8<1), "Qty. out of range", B8*IF(B8>=101,12, IF(B8>=50, 13, IF(B8>=20, 16, IF( B8>=11, 18, IF(B8>=1, 20, ""))))))`

The nested IF formulas described above work in all versions of Excel. In Excel 365 and Excel 2021, you can also use the IFS function for the same purpose.

Advanced Excel users that are familiar with array formulas, can use this formula that basically does the same thing as the nested IF function discussed above. Though the array formula is far more difficult to comprehend, let along to write, it has one indisputable advantage - you specify the range of cells containing your conditions rather than referencing each condition individually. This makes the formula more flexible, and if your users happen to change any of the existing conditions or add a new one, you will only have to update a single range reference in the formula.

## Excel nested IF - tips and tricks

As you have just seen, there is no rocket science in using multiple IF in Excel. The following tips will help you improve your nested IF formulas and prevent common mistakes.

### Nested IF limits

In Excel 2007 - Excel 365, you can nest up to 64 IF functions. In older versions of Excel 2003 and lower, up to 7 nested IF functions can be used. However, the fact that you can nest a lot of IFs in one formula doesn't mean you should. Please keep in mind that each additional level makes your formula more difficult to understand and troubleshoot. If your formula has too many nested levels, you may want to optimize it by using one of these alternatives.

### The order of nested IF functions matters

The Excel nested IF function evaluates the logical tests in the order they appear in the formula, and as soon as one of the conditions evaluates to TRUE, the subsequent conditions are not tested. In other words, the formula stops after the first TRUE result.

Let's see how it works in practice. With B2 equal to 274, the nested IF formula below evaluates the first logical test (B2>249), and returns "Excellent" because this logical test is TRUE:

`=IF(B2>249, "Excellent", IF(B2>=200, "Good", IF(B2>150, "Satisfactory", "Poor")))`

Now, let's reverse the order of IF functions:

`=IF(B2>150, "Satisfactory", IF(B2>200, "Good", IF(B2>249, "Excellent", "Poor")))`

The formula tests the first condition, and because 274 is greater than 150, the result of this logical test is also TRUE. Consequently, the formula returns "Satisfactory" without testing other conditions.

You see, changing the order of IF functions changes the result:

### Evaluate the formula logic

To watch the logical flow of your nested IF formula step-by-step, use the Evaluate Formula feature located on the *Formula* tab, in the *Formula Auditing* group. The underlined expression is the part currently under evaluation, and clicking the **Evaluate** button will show you all the steps in the evaluation process.

For example, the evaluation of the first logical test of the nested IF formula shown in the screenshot below will go as follows: B2>249; 274>249; TRUE; Excellent.

### Balance the parenthesis of nested IF functions

One of the main challenges with nested IFs in Excel is matching parenthesis pairs. If the parentheses do not match, your formula won't work. Luckily, Microsoft Excel provides a couple of features that can help you to balance the parentheses when editing a formula:

- If you have more than one set of parentheses, the parenthesis pairs are shaded in different colors so that the opening parenthesis matches the closing one.
- When you close a parenthesis, Excel briefly highlights the matching pair. The same bolding, or "flickering", effect is produced when you move through the formula by using the arrow keys.

For more information, please see Match parenthesis pairs in Excel formulas.

### Treat text and numbers differently

When building logical tests of your nested IF formulas, remember that text and numbers should be treated differently - always enclose text values in double quotes, but never put quotes around numbers:

Right: **=IF(B2>249, "Excellent",…)**

Wrong: **=IF(B2>"249", "Excellent",…)**

The logical test of the second formula will return FALSE even if the value in B2 is greater than 249. Why? Because 249 is a number and "249" is a numeric string, which are two different things.

### Add spaces or line breaks to make nested IFs easier to read

When building a formula with multiple nested IF levels, you can make the formula's logic clearer by separating different IF functions with spaces or line breaks. Excel doesn't care about extra spacing in a formula, so you may not worry about mangling it.

To move a certain part of the formula to the next line, just click where you want to insert a line break, and press Alt + Enter. Then, expand the formula bar as much as needed and you will see that your nested IF formula has become much easier to understand.

## Alternatives to nested IF in Excel

To get around the limit of seven nested IF functions in Excel 2003 and older versions and to make your formulas more compact and fast, consider using the following alternatives to nested Excel IF functions.

- To test multiple conditions and return different values based on the results of those tests, you can use the CHOOSE function instead of nested IFs.
- Build a reference table and a use VLOOKUP with approximate match as shown in this example: VLOOKUP instead of nested IF in Excel.
- Use IF with logical functions OR / AND, as demonstrated in the these examples.
- Use an array formula like shown in this example.
- Combine multiple IF statements by using the CONCATENATE function or the concatenate operator (&). A formula example can be found here.
- For experienced Excel users, the best alternative to using multiple nested IF functions might be creating a custom worksheet function using VBA.

This is how you use an If formula in Excel with multiple conditions. I thank you for reading and hope to see you on our blog next week.

## Practice workbook for download

Nested If Excel statements (.xlsx file)

## 643 comments

Hey,

I am struggling to finalise a nested if function.

For context, I am trying to calculate point allocation for an online gaming tournament via Excel/Google Sheets.

These are the possible outcomes of the game depending on the end score:

Win = 3 Points

Overtime Win = 2 Points

Overtime Loss = 1 Point

Loss = 0 Points

The way the scores work on the game, I have been able to determine thresholds for scores using ratios (e.g. A score of 7:5 would be a ratio of 1.4). However, when the games haven't been played yet, the score box is empty (meaning the ratio goes to #DIV/0!) and it impacts the sum of points (which is linked to an automated league table).

I have been able to design a Nested IF formula using the ratio thresholds. There are a lot of possible end scores (7:0, 7:1, 7:2, 7:3, 7:4, 7:5, 8:6, 8:7, 7:8, 6:8, 5:7, 4:7, 3:7, 2:7, 1:7 and 0:7) which is why ratios really simplified it. The formula but can only be applied to the played games, otherwise, as said above it messes with the sum of points.

Version that works (Limited) :

=IF(A5>1.39, $D$72, IF(A5>1.10, $D$73, IF(A5>0.74, $D$74, IF(A51.39, $D$72, IF(A5>1.10, $D$73, IF(A5>0.74, $D$74, IF(A5<0.72, $D$75)))))

Legend:

A5 - Row where the ratios are (A)

I5 - Point difference column (I)

J5 - Points column (J) (where the formula is input)

$D$72 - 3 (Points)

$D$73 - 2 (Points)

$D$74 - 1 (Points)

$D$75 - 0 (Points)

$D$80 - 0 (Default point difference when game hasn't been played)

I appreciate there is a lot going on here. Any help/advice would be appreciated. I can send a screenshot on request to make it clearer but do not want to spam the blog with a link to the spreadsheet.

Hello!

Instead of a nested IF function with many conditions, you can use an approximate search with the VLOOKUP function. Here are detailed instructions and an example.

I hope this will help.

There seems to have been an error when posting the comment, this is the formula I have used that partially works :

=SI(A5>1.39, $D$72, SI(A5>1.1, $D$73, SI(A5>0.74, $D$74, SI(A5<0.72, $D$75))))

Thank you Alexander, I will have a look !

Hello,

I did it for 5 conditional, and get the feedback "You've entered too many arguments for this function". So my question is "Is there any other way for 4 and more conditions?".

Thank you in advance,

Lachin.

Hi!

How can I guess what formula you're talking about?

can i ask, I have two seperate of IF function i want to add together

=IF(E10=$K$6,"90.1",IF(E10=$K$4,"51.6",IF(E10=$K$5,"80.5")))

=IF(F11=$K$20,"85",IF(F11=$K$19,"61.3",IF(F11=$K$18,"61.3")))

how can i add these two IF together in one cell, is it possible?

Hi!

I don't think this is possible. What value should be returned if the conditions are met simultaneously - E10=$K$6 and F11=$K$20 ?

I feel like what I am attempting is not that difficult, but I have searched and searched and can't find the answer.

I will tell one of the easier scenarios and can probably get the gist of how to write it and use that on the more difficult ones.

We have a sales quota at my bank of a total of 45 items but in order to be paid a bonus some of these have to be particular things. Like you can't just open 45 savings accounts and get a bonus.

Of the 45 items you must have 11 things specific things and then after that they can be anything as long as there are 45 or more. I have already done all the calculation of the sales $ amounts separately (as if they met all rules) and have it stated in the cell above where I want to put this calculation that I will need to actually pay out.

So I just need this calculation to tell me whether to give a 0 if all are not attained or if all are attained to give the number in the cell above. Sounds simple but so far cannot figure it out.

I thought I would use an If And statement but can't get it to work correctly. It seems like I could say =IF(AND(# of checking accounts cell =3, # of savings accounts =2, # of credit cards sold =2....

I would just go down the list of required things and say- If 'this rule' AND 'this next rule AND 'this last rule' are all true then copy the cell above to down here and if it's not all true put a 0 here.

See sounds simple but I can't find an example anywhere.

Hello!

To count the number of values that match certain criteria, use the COUNTIF or COUNTIFS functions.

I hope I answered your question. If something is still unclear, please feel free to ask.

Hi Alexander,

I would like to multiply cell A3 by cell B3 to return a result in C3, however if there is no number in A3 I would like instead it to multiply A1 by B3 to return a result in C3. If both A3 and A1 are empty, I would like C3 to return no result. Can you please help me with this?

Kind regards

Hi!

I hope you have studied the recommendations in the tutorial above. It contains answers to your question.

The formula below will do the trick for you:

=IF(AND(A3="",A1=""),"", IF(AND(A3="",ISNUMBER(A1)), A1*B3,A3*B3) )

How do I achieve the all of following to get the result in cell A3?

IF (A1="Yes") and (B1=1) then A3=C1/B1

IF (A1="Yes") and (B1=2) then A3=C2/B1

IF (A1="Yes") and (B1=3) then A3=C3/B1

IF (A1 does not = "Yes") then A3=0

Hello!

Please reread the article above since it covers your case.

Use the formula below:

=IF(A1="Yes",IF(B1=1,C1/B1,IF(B1=2,C2/B1, IF(B1=3, C3/B1,0))))

Why does this not work:

IF((F7=5),SUM(E6/F7),if(F7=4),sum(E5/F7),E2)

Ignore this one it's not what I am trying to do. Thanks

Hi!

I don't know what result you want to get, but try this formula -

=IF(F7=5,E6/F7,IF(F7=4,E5/F7,E2))

Hello,

I converted a text file into an excel and some cells are split into 2 cells. For example, cell B1 now shows up as B1 and in B2.

the sheet looks something like this:

A1: Na B1: Ly

A2: B2: dia

A3: B3:

A4: City B4: Toro

A5: B5: nto

A6: B6:

A7: Day B7: Monday

A8:Day B8:Tuesday

A9: Car B9: Audi

A10: B10: xxi

A11: B11:

what I would like to do, is have cells B1 & B2 show up in 1 cell in C1 based on the condition:

=IF((AND(B1>0,B2>0,B3=0,A2=0)),B1&B2,B1)

I also tried using the concatenate(B1,B2) instead of ,B1&B2, but got the same results:

LY

I wanted to get LYDIA.

Not sure why I am not getting the right results.

As well, is it possible in the results that cell B2 not populate again underneath so the end result will look like this:

A1: Name B1: Ly C1: Lydia

A2: B2:dia C2:

A3: B3: C3:

A4: City B4: Toro C4: Toronto

A5: B5:nto C5:

A6: B6: C6:

A7: Day B7: Monday C7:Monday

A8:Day B8:Tuesday B8: Tuesday

A9: Car B9: Audi B9: Audi xxi

A10: B10: xxi B10:

A11: B11: B11:

Thank you,

Lydia

Hello!

In the cells that look empty, some text character is written (space, line break, apostrophe). Therefore, your formula does not work. Check these cells and try this formula

=IF((AND(B1 < > "",B2 < > "",B3="",A2="")),B1&B2,B1)

I hope my advice will help you solve your task.

Sir, I have made a formula for the below calculation & its not working.

Employees will get his end of benefits based on the service tenure.

Conditions to eligible for the end of benefits based on the service years are as follows

IF service less than 1 year = 0

if >1 3 5 = salary /30* 21

If - those have long service 05 years & more, then the calculation should be - for up to 05 years (Salary/30*21) above 05 years (salary/30*30)

Hi!

Read carefully the first paragraph of this article. There is an answer to your question and an example formula.

Hello,

Thank you for the informational tutorials!

I am trying my hardest to create an excel sheet to quickly sum up points based on a score.

For example, if you finish 1st, you receive 40 pts, 2nd = 39, etc..

I have a column for "Place": 1, 2, 3...40

I have a column for "Points."

Could you please provide me with some direction on HOW to get 1st Place = 40 pts, 2nd Place = 39, etc?

I thought this would be an IF formula but I'm not getting the output I would like, just VALUE!

I would GREATLY appreciate it!

Hello!

In the "Points" column, you can use the formula

=41-A1

=IF($A$4=$P$4,($B$4=Q4)+(IF($D$4=$P$4,($E$4=Q4)+(IF($G$4=$P$4,($H$4=Q4)+(IF($J$4=$P$4,($K$4=Q4)+(IF($M$4=$P$4,($N$4=Q4),"")))))))))

Hi, can you please help me with my formula on how I can return multiple true values because for only 1 false value the rest are not showing.

Hi!

Sorry, it's not quite clear what you are trying to achieve. Please provide me with an example of the source data and the expected result.

I am trying to create a reservation log calendar that will shade corresponding dates, the condition will be - it should only shade if room number matches.

That formula works when entered in conditional formatting, only it errors if there is a single room number differ and it will not shade the rest of the dates with matching room numbers.

What function I can use to return multiple true values even if there are false values as well, I tried index and match even vlookup, but just can't figure it out.

Total 38 rooms

5 different reservation dates (with diff room numbers)

Apologies, this is the formula I have:

=IF($A$4=$P$4,($B$4=Q4)+(IF($D$4=$P$4,($E$4=Q4)+(IF($G$4=$P$4,($H$4=Q4)+(IF($J$4=$P$4,($K$4=Q4)+(IF($M$4=$P$4,($N$4=Q4),"")))))))))

I wish to share a screenshot but not possible when tried.

Thanks a lot.

Hello!

The information you provided is not enough to understand your case.

Write what data is written in the cells that your formula refers to and what result you wanted to get.

P4 -23 (this is the room number to match from the below reservations dates)

P4-41 (38 Rooms)

A4 - 23 Room number

B4 - Jan 5

C4 - Jan 10

D4 - 23 Room number

E4 - Jan 13

F4 - Jan 18

G4 - 5 Room number

H4 - May 1

I4 - May 20

J4 - 23 Room number

K4 - Jun 2

L4 - Jun 15

M4 - 23 Room number

N4 - 12 Dec

O4 - 20 Dec

And I have a one year calendar: Q4:NQ4

What I want to achieve, if any of the room number matches to (P4), dates to automatically highlight in the calendar.

Hello!

If I understand your task correctly, the following conditional formatting formula should work for you:

=($A$4=$P$4)*($B$4=Q4)+ ($A$4=$P$4)*($C$4=Q4)+ ($D$4=$P$4)*($E$4=Q4)+ ($D$4=$P$4)*($F$4=Q4)+ ($G$4=$P$4)*($H$4=Q4)+ ($G$4=$P$4)*($I$4=Q4)+ ($J$4=$P$4)*($K$4=Q4)+($L$4=Q4)+ ($M$4=$P$4)*($N$4=Q4)+ ($M$4=$P$4)*($O$4=Q4)

I hope my advice will help you solve your task.

I like to have different formulate based on the previous cell conditions eg, =if(c2="Male",2+1,if(C2="Female",2-1)) but I get error

Hi!

What error are you getting?

You need an "else" option.

If there are only Male and Female in your list with no blanks then:

=if(c2="Male",2+1,2-1)

OR, instead of making a formula, just state the value for each:

=if(c2="Male",3,1)

If there are blanks:

=if(c2="Male",3,if(c2="Female",1,2))

I'm a fan of binary myself:

=if(c2="Male",1,if(c2="Female",0,""))

This counts all the males, provides a 0 for females, and a blank for anyone missing that information. This allows you to sort by that column and fill in the missing information if desired but the Else could also be something like "U" for unknown.

Hope this helps.

UPI/103312588735/CR/NOBLE AUTO CARE K/CIU/Payment (Ref# S52276500)

TRTR/776802210414/02-02-2 02121:04:14/BNA (Ref# S52704553)

UPI/103418091878/CR/RAJAV EL/KKB/tyre (Ref# S55846936)

UPI/103418535311/CR/BALAM URUGAN RENU/UTI/UPI (Ref# S56044583)

UPI/103420379551/CR/Mr S VIJAY RAGHAV/IDI/Tyrep (Ref# S56421977)

BY CASH JAYAMOORTHY (Ref# IB82474)

i am trying to bifurcate the transactions in seperate catagory like - Cash, UPI, TRTR - how to plot multiple conditions in if statement

I am trying below formula it is not working

=IF(FIND("TRTR",F2,1),"TRTR",IF(FIND("ATM",F2,1),"ATM",0))

Please help on this

Hi!

What exactly is not working in your formula? Perhaps you need to add all the conditions. For instance,

=IF(FIND(“TRTR”,F2,1),”TRTR”,IF(FIND(“ATM”,F2,1),”ATM”,0),IF(FIND(“UPI”,F2,1),”UPI”,0))

Hello,

I've been working on an excel sheet for nearly a month and cannot figure out how to get the result that I want using IF Statements. I was able to get 2 of my statements to work the way I need them to but the third seems to require a few more IF, AND, OR statements to work but I cannot for the life of me get the result I want. My example is as follows:

=IF(A2<=1,C31/1.7,0) This statement is in cell C32 and works as I intend it to with the correct result populating in C32. C33 and C34 populate as 0 which is what is needed.

=IF(A3<=1,C31/1.3,0) This statement is in cell C33 and also works as I intend it to with the correct result populating in C33. C32 and C34 populate as 0 which is also what is needed.

=IF(AND(A2=0,A3=0),C31/1.9,0) This statement is in cell C34 calculates the correct result in C34 however, C32 and C33 also calculate their respective correct results when I need them to return a result of 0.

The actual cell data I am using is as follows:

A1 $1,321.00

A2 $567.00

A3 $1,919.00

A4 $50.00

$3,857.00

$308.56

$4,165.56

$1,000.00

$700.00

$700.00

$0.00

$0.00

$0.00

$0.00

$6,565.56

$2,500.00

$0.00

$9,065.56

$453.28

$9,518.84

$0.00

$0.00

$0.00

$0.00

$0.00

$0.00

A31 $9,518.84

A32 $0.00

A33 $0.00

A34 $0.00

Any help or insight would be greatly appreciated! Thank you!

Hello!

Try adding one more condition to your IF function.

=IF(AND(A2< = 1, A2 < > 0, A3 < > 0),C31/1.7,0) I hope it’ll be helpful.

Thank you for the insight! I will play with adding an additional condition and see where that gets me.

Just a follow up...

Your suggestions did end up working! Thank you so much! After playing around with adding an additional condition, everything is working as I need it to, and I was even able to expand on that to encompass much more data. Thank you for the insight Alexander!

Hello,

I am seeing if anyone can help me write a nested formula with multiple arguments, or what is the best way to do what I'm trying to do? the result, based on what's was rcvd. yes, if yes result would be n/a, if not rcvd, the result would be yes, if n/a, result will be n/a

RCVD NEEDED

DOC 1 YES DOC 1 N/A

DOC 2 NO DOC 2 YES

DOC 3 N/A DOC 3 N/A

=IF(X7="YES","N/A",IF(X7="NO","YES","YES",IF(X7="N/A","N/A","N/A")))

Hello!

Please check the formula below, it should work for you:

=IF(X7="YES","N/A",IF(X7="NO","YES",IF(X7="N/A","N/A","N/A")))

I need to write a formula like IF the company Name = List and Product name = List and Product category = List then The Price = List

Hello!

Please check out the following article on our blog, it’ll be sure to help you with your task: How to Vlookup multiple criteria in Excel.

I hope this will help, otherwise please do not hesitate to contact me anytime.

Wonder if anyone can help me to solve this

Column B5: GOV or PRI

Column B39: Total value example 2,500

IF B5 = GOV, and B39 range 1 to 1,000 = 0, 1,001 to 2000 = 100, 2001 to 3000 = 200 etc

IF B5 = PRI, and B39 range 1 to 1,000 = 0, 1,001 to 2000 = 50, 2001 to 3000 = 100 etc

Hello!

If I understand your task correctly, the following formula should work for you:

=IF(B39 < 1001,0, IF(B39 < 2001,100, IF(B39 < 3001,200, )))*(IF(B5="GOV",1, IF(B5="PRI",0.5,)))

Basically i want that based on the value on B column, C column should be filled.

below is giving me value 10 for all values of B column. Kindly help

=IF(OR(B2>=0,B2=49,B2<=108),12))

Hello!

I don't know what values you have in column B. There is no value 10 in your formula. The second condition does not make sense, because if B2=49 then always B2<=108

Hi! How do you write 17<=C13<=28 in a formula? Please help me. Thank you.

Hi!

Read Example 1 in this article carefully. There is an answer to your question.

How to compute in a 3 situation to the column 1 to column 2 in 1 formula

Situation 1, Column 1 equal to column 2 the answer is column 2

Sample:

2 & 2 = 2

-1 & -1 = -1

Situation 2, Column 1 is greater than or less than column 2 but both positive or both negative the answer is whichever is higher

Sample:

2 & 3 = 3

4 & 1 = 4

-2 & -3 = -3

-4 & -1 = -4

Situation 3, Column 1 is greater than or less than column 2 but in different (Column 1 is positive and Column 2 is negative or vice versa) the answer should be in sum

Sample:

2 & -3 = -1

-2 & 3 = 1

-4 & 1 = -3

4 & -1 = 3

Anyone can solve this situation?

Hi!

If you read these instructions carefully, you can easily write the formulas you need. All the instructions you need are found above in this article.

Hi!

Please re-read the article above, it covers your case completely.

Can you share with me the right formula? Article is very broad, no exact formula base on the situation.

hi

any idea way the ONLINE NOT show

=IF(H2&J2="APPROVD","APPROVd",IF(AND(H2&J2="NOTAPPROVD","NOTAPPROVD"),"ONTIME","DEILY"))

Hi!

What do you want to calculate exactly? Your question is not entirely clear, please specify.

Write a programme to input an alphabet and then check the alphabet vowel or consonant

Hello!

I am trying to create and If/Then formula for generations. What I am looking for is if a birthdate (1/1/1954) falls into a range of dates (1/1/1946 to 12/31/2964) then it would be labelled a Baby Boomer. I have 5 generations that I need to include. Thank you!

Great information shared here!! Thanks for sharing.

I need help with the following formula.

Column I is a title

Column J is a dollar

if column I is X title and column J is less than X dollars increase by Y not to exceed Z but if column J is more than X dollars do not increase.

I need to count the value (will be a whole number) in Column "I" IF Column B word is "New" AND Column C word is "Shirt". How would I set this up?

Thank you!

Hello!

You can find the examples and detailed instructions here: Excel COUNTIFS and COUNTIF with multiple AND / OR criteria.

Hello,

Trying to create a formula with no success so far. The range of cells, in this case D:32:D35, are assigned either "yes" or "no". If 1-2 of these cells are marked "yes" then L:31 should be assigned value of .5. However, if 3-4 of the range of cells are marked "yes", then L:31 should be assigned value of 1.

Any advice greatly appreciated.

Thanks!

Hi!

I have already answered you. Why are you asking the second time?

Attenace Incentive allowance

No Of Day Full OT Incentive Amount Per Day

26 4 40

26.5 4 60

27 3 60

27.5 3 60

28 60

29 60

30 60

31 60

Can someone please help me with a basic formula. I have 5 product codes each with a $ value, and I have 200 rows of information, each time I enter a product code in 1 cell then I would like the value shown in the next cell without having to do a manual calculation each time. Is this possible and what would the formula be please. Thank you for any assistance you can offer in this regard.

Hi!

The information you provided is not enough to understand your case and give you any advice.

What value do you want to display in the next cell? Please describe your problem in more detail.

How do I send you the spreadsheet and you can see how Im trying to work it.

Hi!

Please describe your task in more detail and send us a small sample workbook with the source data and expected result to support@ablebits.com. Please shorten your tables to 10-20 rows/columns and include the link to your blog comment.

We'll look into your task and try to help.

I am looking for a formula that will give me a percentage if a certain number falls within a range of numbers.

Range:

$200-$299 I get 1%

$300-$399 I get 2%

$400-$1000 I get 3%

Scenario--My total sales are $39,308 and I worked 147 hours this would put me at $267.40 per hour, by the example below I would get 1% of the 39,308 totaling $393.08 commission

Hello!

The answer to such questions has already been given. I recommend looking here and here.

This should solve your task.

I think, it is more simple you face multiple range data, just make a reference table, sort by value asc, then use VLOOKUP (value, table, col_index, [range_lookup]), with [range_lookup]=1.

Hi how can I make this formula shorter? It seems like it doesn't work because its too long but its all the data i need to input. thank you!!

=IF(H21>2.8,6.60,IF(H21>2.7,7.20,IF(H21>2.6,7.80,IF(H21>2.5,8.40,IF(H21>2.4,9.00, IF(H21>2.3,9.60,IF(H21>2.2,10.20,IF(H21>2.1,10.80,IF(H21>2.0,11.40,IF(H21>1.9,12.00,IF(H21>1.8,12.60,IF(H21>1.7,13.20,IF(H21>1.6,13.80,IF(H21>1.5,14.40,IF(H21>1.4,15.00,IF(H21>1.3,15.60,IF(H21>1.2,16.20,IF(H21>1.1,16.80,IF(H21>1.0,17.40,IF(H21>0.1,18.00))))))))))))))))))))

Hi,

Describe your source data and conditions for the IF formula. Then I will try to help you.

Kindly,remove the commas from the digits

Thank you - this post of yours helped me to learn something new today.

Here is the IF(AND formula that returns the first answer: =IF(AND(C8="PL",D8="1/4",K8="S304L"),11.16). The problem is I cannot connect that in the same cell with: =IF(AND(C9="PL",D9="1/4",K9="A36"),10.21).

I need to check 3 cells and return an answer, then check the same 3 cells with new conditions and return a new answer. This is a spreadsheet for steel estimates. It needs to see "PL" (plate), "1/4" (thickness), and "S304L" (Stainless Steel) and return a weight per Square Foot. It also needs the see "L" (angle), 2x2x1/4 (size), and "A529-50" (Carbon Steel) and return a weight per Linear Foot. It also needs to see a lot of different shapes, sizes, and grades and return a correct weight per unit. Automating this function would save a lot of time looking through steel books!

Happy Friday!

Clark

Hello!

I’m sorry but your task is not entirely clear to me. Could you please describe it in more detail? What result do you want to get? Give an example of the source data and the expected result.

I am trying to write a formula such as this:

=IF((M10="FORD")*AND(M23="F750")*OR(M23="F550"),1,0)

Basically i want to return a value of 1 if M10 is equal to FORD and M23 is equal to either F550 or F750.

This formula returns a value of 1 every time even if i have M23 equal to F250

Hello!

Please check the formula below, it should work for you:

=IF(AND(M10="FORD",OR(M23="F750",M23="F550")),1,0)

Please have a look at this article — Using logical functions in Excel: AND, OR

hi could you help me? im having trouble with my formula.

here are the conditions;

if 17<=X<=28, then the answer would be 0.85

but if 28<X=55, the answer should be 0.65

thank you

X is in cell C4.

i hope i could reach some help :((

Hi,

I hope you have studied the recommendations in the tutorial above. It contains answers to your question.

Try the following formula:

=IF(AND(A1>=17,A1<=28),0.85,IF(AND(A1>28,A1<=55),0.65,""))

HI,

I need to calculate the IF statement between two numbers having multiple criteria:

ex: Criteria

from 20-30 =200

from 31-40=300

from 41-50=500

B2 = 18

B3= 25

B4= 39

B5=41

With only one criteria I can calculated: =IF(AND( B2>=31,B2<=40),"300","0"), but when it comes to more I am not sure how to do it.

Thank you.

Hello!

The formula below will do the trick for you:

=IFERROR(INDEX(B1:B4,MATCH(D1,A1:A4,1)),0)

A B

20 200

31 300

41 500

50 500

D1 --- 18, 25,39 or 41

I hope my advice will help you solve your task.

Can you please help me. I have been struggling with this nested formula.

Cell Values:

C12 - 85, C13 - 87, C14 - 90, C15 - 95

D12 - 200, D13 - 300, D14 - 500, D15 - 1000

E3 - 90, E4 - 86, E5 - 98, E6 - 85

I need to find the corresponding value for E cells from D cells if the number is greater than or equal to numbers in C cells. [how can I come up with a formula for this? - Cell F should be "500" since E3 => C14]

Formula in Cell F:

=IF(E3>=C12,D12,IF(E3>=C13,D13,IF(E3>=C14,D14,IF(E3>=C15,D15,"0"))))

Hi,

I’m sorry but your task is not entirely clear to me. Could you please describe it in more detail? What result do you want to get?

What does "Cell F should be “500” since E3 => C14"??

Give an example of the expected result.

Good day Sir

Can you please help me. I have been struggling with this nested formula.

I just need someone to please explain it to me cause I just can't grasp this.

I need a formula which helps me with the following:

1) If Column B & C has no date populated the Cell E should reflect a " "

2) IF column B has a date populated and no date populated for Column C then Column E must read "Open"

3) IF column B & C have a date populated then Column E must read "Finalized"

I need to have these conditions nested in one in Column E

Here's the formula I'm using, I think I'm on the right track ;

=IF(AND(ColumnB>1,ColumC>1),"Finalised", "Open")

Somewhere in this formula I need amend it to display " " in fields where no Date is captured in Column B

Column A Column B Column C Column E

Policy number: Task Start: Task End:

1234567890 22/02/2021 16:11 22/02/2021 16:14:07

Please help kind Sir

Hello!

Please use the following formula

=IF(B1&C1="","",IF(AND(B1 < > "",C1=""),"Open","Finalized"))

After that you can copy this formula down along the column.

I am working with data across multiple sheets. I have a dropdown list in one sheet. I need a formula that will take the data from multiple sheets and return it to cells on the first sheet of the book based on data chosen in the drop down menu. All data is text I have tried if statements but can't seem to make it work. Any help in this matter would be greatly appreciated.

Hello!

Here is the article that may be helpful to you: How to VLOOKUP across multiple sheets in Excel and How to VLOOKUP multiple values in Excel with one or more criteria

I hope this will help, otherwise please do not hesitate to contact me anytime.

Greetings,

=IF(L16>=1,B16,IF(L15>=1,B15,IF(L14>=1,B14,"""")))

This is the general idea of the formula I need but the data spans thousands of rows. In column L is numbers, column B is dates in descending order. The purpose is to display the date from the same row as cell value in Column L =>1. This formula works but I obviously cannot type out that many conditions. Any help will be greatly appreciated.

V/R

Erik

Hello!

If I understand your task correctly, you need to return multiple results conditionally. Please check out the following article on our blog, it’ll be sure to help you with your task: How to VLOOKUP multiple values in Excel with one or more criteria.

If you have any other questions please don’t hesitate to ask.

A B C D E F G H I J K L

1 1-May-20 FS 1.0 1.0

2 3-Jun-21 BS 1.0

3 5-Jul-19 FS 5.0 1.0

4 3-Nov-21 BS 1.0

5 2-Feb-21 BS 1.0

6 3-Feb-21 1.0

7 4-Feb-21 .7

I apologize I don't know how to show the gridlines on here but essentially I need to scan column J for the most recent entry greater than 1 & display the date from column A of the same row. The formula would yield, based on the numbers above, 3 Feb 21 as the most recent date column J was >=1. So one result based on multiple conditions I guess. I just don't know how to get it to scan thousands of rows in a column without doing individual IF formulas in descending order. Thank you for the help.

I have looked into the Vlookup option. This function will not work due to the fact that multiple cells may have the same data & it is not in descending order. I need to scan for values >=1.0 & display the date in the same row that is closest to today. So if Cell L14=1.5 the date in B14 would be displayed unless cell L36=1.0 in which case the date in B36 should be displayed. Again, if further down L45=1.0 I want the date in B45 displayed. Thank you again!

Hello!

To find the last match of a value in a column, use the formula

=LOOKUP(2,1/(D2:D8>=1),B2:B8)

D2:D8 - column in which we are looking for the condition

B2:B8 - the column from which we show the value

Been working at this for 3 days and my Brain is starting to hurt. I have these formulas and need to get it into 1 line formula. Each single line works but I can't get them to play nice together.

Appreciate the help to make this work

=if(and(A3="D",E3>2000),E3*0.25,"500")

or

=if(and(A3="U",E3>1200),E3*0.25,"300")

or

=if(and(A3="N",E3>800),E3*0.25,"200")

Hello!

Your formulas contradict each other. For example, if A3 = "" and E3 = 0, then the conditions of all formulas will return FALSE. What value do you want to write in the cell - 500, 300 or 200? Therefore, you cannot combine your formulas. Change the conditions.

Hi Guys,

Am trying to create an if formula but keep getting errors.

I am looking at four years data and want to compare individual or collective year results to a rating

Year 1 = 33%

Year = 60%

Year 3 =20%

Year 5 = 1%

I want to create a formula which says that if the average of year1 to Year 4 is >=60% but =60%,=60%,<=90%),"meet requirements", "not met requirements").

Any suggestion is appreciated.

Thanks

Should say if Year 1 to 4 is >=60% but <=90%

Hello!

Describe the background and conditions more precisely. Which means -

Year = 60% ??

average of year1 to Year 4 is >=60% but =60%,=60%,<=90%),"meet requirements", "not met requirements") -??

Can anyone guess why my formula below get error

=IF(J2>=750000, I2+(J2/2), IF(J2>=250000, I2+(J2/3), IF(J2>=100000, I2+(J2/4), IF(J2>=50000), I2+(J2/5))))

Thanks Guys

Hello!

Please try the following formula:

=IF(J2>=750000,I2+(J2/2),IF(J2>=250000,I2+(J2/3), IF(J2>=100000,I2+(J2/4),IF(J2>=50000,I2+(J2/5),""))))

I hope it’ll be helpful.

Got formula parse error.. Can i send you Mr Alexander, my screenshot excel, so you can help me analyze it.. thanks a lot mr. alex

Hello!

This formula

=IF(J2>=750000,I2+(J2/2),IF(J2>=250000,I2+(J2/3), IF(J2>=100000,I2+(J2/4),IF(J2>=50000,I2+(J2/5),""))))

works for me. J2 and I2 must have numbers.

What error are you getting?

yes, my J2 and I2 already numbers but also get #ERROR! sir.. can you help me review my excel?

thanks mr.alex

Hello!

Send us a small sample workbook with the source data and expected result to support@ablebits.com. Please include the link to your blog comment.

We'll look into your task and try to help.

I do hope that you guys/gals are all ok in this time of stress.

I am trying to use IF, And, and also Or in the same formula.

=IF(AND('Project Information'!H12="EST",B8>0),LOOKUP(B8,EST),"")

=IF(AND('Project Information'!H12="system sensor",B8>0),LOOKUP(B8,SS),"")

I know both the above formulas work but I want to be able to use them both in one formula so if the 1st one doesn't work it will go on to the 2nd one and if neither one work it will show a blank cell.

Is this possible.

Thank You Very Much

Walter Culpepper

Good

=IF(F7=1,((100-H7)*E7)/88),IF(F7=2,((100-H7)*G7)/88)

2 worksheets A and B

B pulls from A

A has 4 columns that are used to calculate monthly median in B.

Formula: =IFERROR(MEDIAN(IF('[FY2020 Volumes.xlsx]Transplants'!$E:$E="Adult", IF('[FY2020 Volumes.xlsx]Transplants'!$K:$K="Kidney", IF('[FY2020 Volumes.xlsx]Transplants'!$U:$U>=DATE(2019,10,1), IF('[FY2020 Volumes.xlsx]Transplants'!$U:$U<=DATE(2019,10,31), '[FY2020 Volumes.xlsx]Transplants'!$Y:$Y))))), "N/A")

This pull from Oct 2019 to Sept 2020 calculates the monthly median just fine.

When i change the dates to 2020,10,1 and 2020,10,31 all i get is zero from Oct 2020 onwards.

Any help is appreciated.

thanks

Forgot to mention, that column Y is the numbers from whihc the monthly median is calculated.

I am trying to use the following IF formula to return a date and time in D3 when I scan a value into C3:

=IF(C3"",IF(D3"",D3,NOW()),""). However, it is not a static date/time, it is dynamic, so every time I scan in column C it replaces the last value in column D with the current value as well. I hope this makes sense.

hi i have printing press and 3 machines GTO, SOLNA, HELDELBERG each machine has different capacity of handling paper GTO printing size is 12-18 inches, Solna Size is 18-25 and Heidelberg is 19-40 inches paper handling capacity

=IF(AND(J17<=12,K1718,K1718,K17<=40),"HEIDELBERG",IF(AND(K17<=12,J1718,J1718,J17<=40),"HEIDELBERG"))))))

this formula is working to some extant but not working 100% let me know how can i solve my problem

Hello!

Sorry, it's not quite clear what you are trying to achieve. What result do you want to get? What problem or error occurred? Please describe your problem in more detail. It’ll help me understand it better and find a solution for you.

I have columns "A" and "B". "A" is defined as Currency and "B" is a date and "C" contains "=today()". I am trying to populate "B" with todays date when "A" is entered and only when "A" is entered. I have tried:

=IF(A1>0,$C$1,"") - which populates 'B1" when the sheet is opened if A1>0...I lose the date A1 was entered

=IF(AND(A1>0,B1=""),$C$1,"") - which didn't work at all...evaluate said circular reference "if 0 > 0"

I have tried multiple other attempts, but these seemed the most likely. Not sure what I'm doing wrong. Any help/suggestions would be appreciated.

Hello!

Sorry, I do not fully understand the task. Formula =IF(A1>0,$C$1,””) is correct. What does "I lose the date A1 was entered"? Explain your problem in more detail.

Thank you for your response.

I enter a currency amount ($20.00) in A1 on June 1, 2020. The currency amount appears in A1 and 06/01/2020 appears in B1 (populated by the formula). On June 5, 2020 I open the spreadsheet and A1 contains $20.00, B1 contains 06/05/2020.... I lose the date the currency amount was entered. I would like to capture the date the currency amount is entered, and once captured, do not update it again. My second example where if A1 > 0 and B1 Is blank ("") was my attempt to leave B1 alone if it has already been populated, but I couldn't get that to work.

Hello!

Please check out the following article on our blog, it’ll be sure to help you with your task: Formula to insert today date & current time as unchangeable time stamp .

I hope my advice will help you solve your task.

Thank you very much. It works well. I should have searched for "time stamp". I guess it just shows that "all you have to know is what you are doing". Again, thank you.