How to use IF function in Excel: examples for text, numbers, dates, blanks

In this article, you will learn how to build an Excel IF statement for different types of values as well as how to create multiple IF statements.

IF is one of the most popular and useful functions in Excel. Generally, you use an IF statement to test a condition and to return one value if the condition is met, and another value if the condition is not met.

In this tutorial, we are going to learn the syntax and common usages of the Excel IF function, and then take a closer look at formula examples that will hopefully prove helpful to both beginners and experienced users.

IF function in Excel

IF is one of logical functions that evaluates a certain condition and returns one value if the condition is TRUE, and another value if the condition is FALSE.

The syntax of the IF function is as follows:

IF(logical_test, [value_if_true], [value_if_false])

As you see, IF takes a total of 3 arguments, but only the first one is obligatory, the other two are optional.

Logical_test (required) - the condition to test. Can be evaluated as either TRUE or FALSE.

Value_if_true (optional) - the value to return when the logical test evaluates to TRUE, i.e. the condition is met. If omitted, the value_if_false argument must be defined.

Value_if_false (optional) - the value to return when the logical test evaluates to FALSE, i.e. the condition is not met. If omitted, the value_if_true argument must be set.

Basic IF formula in Excel

To create a simple If then statement in Excel, this is what you need to do:

  • For logical_test, write an expression that returns either TRUE or FALSE. For this, you'd normally use one of the logical operators.
  • For value_if_true, specify what to return when the logical test evaluates to TRUE.
  • For value_if_false, specify what to return when the logical test evaluates to FALSE. Though this argument is optional, we recommend always configuring it to avoid unexpected results. For the detailed explanation, please see Excel IF: things to know.

As an example, let's write a very simple IF formula that checks a value in cell A2 and returns "Good" if the value is greater than 80, "Bad" otherwise:

=IF(B2>80, "Good", "Bad")

This formula goes to C2, and then is copied down through C7: Basic IF formula in Excel.

In case you wish to return a value only when the condition is met (or not met), otherwise - nothing, then use an empty string ("") for the "undefined" argument. For example:

=IF(B2>80, "Good", "")

This formula will return "Good" if the value in A2 is greater than 80, a blank cell otherwise: IF formula to return nothing when the condition is not met.

Excel If then formula: things to know

Though the last two parameters of the IF function are optional, your formula may produce unexpected results if you don't know the underlying logic.

If value_if_true is omitted

If the 2nd argument of your Excel IF formula is omitted (i.e. there are two consecutive commas after the logical test), you'll get zero (0) when the condition is met, which makes no sense in most cases. Here is an example of such a formula:

=IF(B2>80, , "Bad")

To return a blank cell instead, supply an empty string ("") for the second parameter, like this:

=IF(B2>80, "", "Bad")

The screenshot below demonstrates the difference: The behavior of the value_if_true argument.

If value_if_false is omitted

Omitting the 3rd parameter of IF will produce the following results when the logical test evaluates to FALSE.

If there is just a closing bracket after value_if_true, the IF function will return the logical value FALSE. Quite unexpected, isn't it? Here is an example of such a formula:

=IF(B2>80, "Good")

Typing a comma after the value_if_true argument will force Excel to return 0, which doesn't make much sense either:

=IF(B2>80, "Good",)

The most reasonable approach is using a zero-length string ("") to get a blank cell when the condition is not met:

=IF(B2>80, "Good", "") The behavior of the value_if_false argument.

Tip. To return a logical value when the specified condition is met or not met, supply TRUE for value_if_true and FALSE for value_if_false. For the results to be Boolean values that other Excel functions can recognize, don't enclose TRUE and FALSE in double quotes as this will turn them into normal text values.

Using IF function in Excel - formula examples

Now that you are familiar with the IF function's syntax, let's look at some formula examples and learn how to use If then statements in real-life scenarios.

Excel IF function with numbers

To build an IF statement for numbers, use logical operators such as:

  • Equal to (=)
  • Not equal to (<>)
  • Greater than (>)
  • Greater than or equal to (>=)
  • Less than (<)
  • Less than or equal to (<=)

Above, you have already seen an example of such a formula that checks if a number is greater than a given number.

And here's a formula that checks if a cell contains a negative number:

=IF(B2<0, "Invalid", "")

For negative numbers (which are less than 0), the formula returns "Invalid"; for zeros and positive numbers - a blank cell. A formula to check if a cell contains a negative number.

Excel IF function with text

Commonly, you write an IF statement for text values using either "equal to" or "not equal to" operator.

For example, the following formula checks the Delivery Status in B2 to determine whether an action is required or not:

=IF(B2="delivered", "No", "Yes")

Translated into plain English, the formula says: return "No" if B2 is equal to "delivered", "Yes" otherwise. Using the IF function with text.

Another way to achieve the same result is to use the "not equal to" operator and swap the value_if_true and value_if_false values:

=IF(C2<>"delivered", "Yes", "No")

Notes:

  • When using text values for IF's parameters, remember to always enclose them in double quotes.
  • Like most other Excel functions, IF is case-insensitive by default. In the above example, it does not differentiate between "delivered", "Delivered", and "DELIVERED".

Case-sensitive IF statement for text values

To treat uppercase and lowercase letters as different characters, use IF in combination with the case-sensitive EXACT function.

For example, to return "No" only when B2 contains "DELIVERED" (the uppercase), you'd use this formula:

=IF(EXACT(B2,"DELIVERED"), "No", "Yes") Case-sensitive IF statement for text values.

If cell contains partial text

In situation when you want to base the condition on partial match rather than exact match, an immediate solution that comes to mind is using wildcards in the logical test. However, this simple and obvious approach won't work. Many functions accept wildcards, but regrettably IF is not one of them.

A working solution is to use IF in combination with ISNUMBER and SEARCH (case-insensitive) or FIND (case-sensitive).

For example, in case "No" action is required both for "Delivered" and "Out for delivery" items, the following formula will work a treat:

=IF(ISNUMBER(SEARCH("deliv", B2)), "No", "Yes") IF cell contains partial text.

For more information, please see:

Excel IF statement with dates

At first sight, it may seem that IF formulas for dates are akin to IF statements for numeric and text values. Regrettably, it is not so. Unlike many other functions, IF does recognize dates in logical tests and interprets them as mere text strings. In other words, you cannot supply a date in the form of "1/1/2020" or ">1/1/2020". To make the IF function recognize a date, you need to wrap it in the DATEVALUE function.

For example, here's how you can check if a given date is greater than another date:

=IF(B2>DATEVALUE("7/18/2022"), "Coming soon", "Completed")

This formula evaluates the dates in column B and returns "Coming soon" if a game is scheduled for 18-Jul-2022 or later, "Completed" for a prior date. Excel IF statement with dates.

Of course, there is nothing that would prevent you from entering the target date in a predefined cell (say E2) and referring to that cell. Just remember to lock the cell address with the $ sign to make it an absolute reference. For instance:

=IF(B2>$E$2, "Coming soon", "Completed")

To compare a date with the current date, use the TODAY() function. For example:

=IF(B2>TODAY(), "Coming soon", "Completed")

Excel IF statement for blanks and non-blanks

If you are looking to somehow mark your data based on a certain cell(s) being empty or not empty, you can either:

  • Use the IF function together with ISBLANK, or
  • Use the logical expressions ="" (equal to blank) or <>"" (not equal to blank).

The table below explains the difference between these two approaches with formula examples.

  Logical test Description Formula Example
Blank cells =""

Evaluates to TRUE if a cell is visually empty, even if it contains a zero-length string.

Otherwise, evaluates to FALSE.

 =IF(A1="", 0, 1)

Returns 0 if A1 is visually blank. Otherwise returns 1.

If A1 contains an empty string (""), the formula returns 0.
ISBLANK()

Evaluates to TRUE is a cell contains absolutely nothing - no formula, no spaces, no empty strings.

Otherwise, evaluates to FALSE.

 =IF(ISBLANK(A1), 0, 1)

Returns 0 if A1 is absolutely empty, 1 otherwise.

If A1 contains an empty string (""), the formula returns 1.
Non-blank cells <>"" Evaluates to TRUE if a cell contains some data. Otherwise, evaluates to FALSE.

Cells with zero-length strings are considered blank.

 =IF(A1<>"", 1, 0)

Returns 1 if A1 is non-blank; 0 otherwise.

If A1 contains an empty string, the formula returns 0.
ISBLANK()=FALSE Evaluates to TRUE if a cell is not empty. Otherwise, evaluates to FALSE.

Cells with zero-length strings are considered non-blank.

 =IF(ISBLANK(A1)=FALSE, 0, 1)

Works the same as the above formula, but returns 1 if A1 contains an empty string.

And now, let's see blank and non-blank IF statements in action. Suppose you have a date in column B only if a game has already been played. To label the completed games, use one of these formulas:

=IF(B2="", "", "Completed")

=IF(ISBLANK(B2), "", "Completed")

=IF($B2<>"", "Completed", "")

=IF(ISBLANK($B2)=FALSE, "Completed", "")

In case the tested cells have no zero-length strings, all the formulas will return exactly the same results: IF statement for blank and non-blank cells.

Check if two cells are the same

To create a formula that checks if two cells match, compare the cells by using the equals sign (=) in the logical test of IF. For example:

=IF(B2=C2, "Same score", "") Check if two cells contain the same values.

To check if the two cells contain same text including the letter case, make your IF formula case-sensitive with the help of the EXACT function.

For instance, to compare the passwords in A2 and B2, and returns "Match" if the two strings are exactly the same, "Do not match" otherwise, the formula is:

=IF(EXACT(A2, B2), "Match", "Don't match") Case-sensitive IF formula to check if two cells match.

IF then formula to run another formula

In all of the previous examples, an Excel IF statement returned values. But it can also perform a certain calculation or execute another formula when a specific condition is met or not met. For this, embed another function or arithmetic expression in the value_if_true and/or value_if_false arguments.

For example, if B2 is greater than 80, we'll have it multiplied by 7%, otherwise by 3%:

=IF(B2>80, B2*7%, B2*3%) IF formula that runs another formula.

Multiple IF statements in Excel

In essence, there are two ways to write multiple IF statements in Excel:

  • Nesting several IF functions one into another
  • Using the AND or OR function in the logical test

Nested IF statement

Nested IF functions let you place multiple IF statements in the same cell, i.e. test multiple conditions within one formula and return different values depending on the results of those tests.

Assume your goal is to assign different bonuses based on the score:

  • Over 90 - 10%
  • 90 to 81 - 7%
  • 80 to 70 - 5%
  • Less than 70 - 3%

To accomplish the task, you write 3 separate IF functions and nest them one into another like this:

=IF(B2>90, 10%, IF(B2>=81, 7%, IF(B2>=70, 5%, 3%))) Nested IF statement.

For more formula examples, please see:

Excel IF statement with multiple conditions

To evaluate several conditions with the AND or OR logic, embed the corresponding function in the logical test:

For example, to return "Pass" if both scores in B2 and C2 are higher than 80, the formula is:

=IF(AND(B2>80, C2>80), "Pass", "Fail")

To get "Pass" if either score is higher than 80, the formula is:

=IF(OR(B2>80, C2>80), "Pass", "Fail") Excel IF statement with multiple conditions.

For full details, please visit:

If error in Excel

Starting from Excel 2007, we have a special function, named IFERROR, to check formulas for errors. In Excel 2013 and higher, there is also the IFNA function to handle #N/A errors.

And still, there may be some circumstances when using the IF function together with ISERROR or ISNA is a better solution. Basically, IF ISERROR is the formula to use when you want to return something if error and something else if no error. The IFERROR function is unable to do that as it always returns the result of the main formula if it isn't an error.

For example, to compare each score in column B against the top 3 scores in E2:E4, and return "Yes" if a match is found, "No" otherwise, you enter this formula in C2, and then copy it down through C7:

=IF(ISERROR(MATCH(B2, $E$2:$E$4, 0)), "No", "Yes" ) If error formula in Excel.

For more information, please see IF ISERROR formula in Excel.

Hopefully, our examples have helped you get a grasp of the Excel IF basics. I thank you for reading and hope to see you on our blog next week!

Practice workbook

Excel IF statement - formula examples (.xlsx file)

Table of contents

4780 comments

  1. Hi! Is this possible to use if function in this situation?

    Like overtime hours is:
    1:19 how can I get a result to this 1.25 hours in decimal?

    And what is the formula to get night differential in morning time in like this:
    time in is 3:00am how can get 3hours of night differential?

    Thank you

  2. Hi all,

    I need to use an if formula that need to have in the return value if true and value if false, both a phrase and a value from a cell (better if the format of the number is showing as accounting).

    Ex.:=IF('page1'!O39>0,"Please see attached. Increased day over day by 'page1'!O39 ,Please see attached. Decreased day over day by 'page1'!O39")

  3. Hi all I need help
    No is 0 to 1000, I need 3 results,
    1 if the calculated no is less than 350 then use it , if more use 350.
    2 if the calculated no is more than 350 but less than 500, use it, less the 350, if more use 500
    3 if the calculated no is more than 500, use that no , less the 500
    Tks

  4. Hi,
    the apostrophe in true/false options has solved many of my problems
    thanks and regards

  5. Hello, I am trying to populate a cell with another cell value only if the cell is more than $0, but I can't find a formula to do this. I do not need it colored, or yes,no, or true,false. I need the value of the cell only if it's positive. Can someone help me?

    • Hi! You cannot replace a value in a cell with another value using an Excel formula. You can do it manually or by using VBA. You can get the value you want in another cell using the recommendations in the article above.

      • Alexander I tried the formulas above, but I do not need a true or false. I was thinking a formula with the IF function, like =IF(A2>0,"A2") but that does not work. It doesn't populate the value of the cell, it populates whatever I put inside the "", so in this case A2. Technically I could use =A2 but I need it to only populate if the value is over $0 because if the value is negative is going to affect the other calculations.

  6. Im trying to maka a table that has this conditions
    percentage A B C
    100% 200 180 150
    95-99% 170 150 120
    90-94% 150 120 90
    85-89% 120 90 60
    80-84% 50 20 0
    79% and below 0 0 0

    How can easily get results from this table when i encode class and percentage
    class percentage result
    Person 1 A 93% _______

    Result shoudl be 150

  7. Hi everybody, I have a question. Suppose if in an office the cut-off time is 9:00 am. If a staff entered office at 9:00 AM he will be marked "on time" in attendance sheet. but he entered at 9:05 AM, he will be marked "LATE". But if some one is on leave, how to formulate this in the attendance sheet with the two conditions mentioned before?

  8. Hi, i have a problem in excel formula.
    If, -528 less -590 / -590 = 62
    i want the result in percentage with positive sign instead of negative.

    Thanks.

  9. I am trying to create an if formula. I have 10 questions on column A. Column B I have yes and no for each of the 10 questions. On column C, I need to create a formula that if all the questions are "yes", 40%, if there is a no, it should be 0. Can you help me?

  10. if formula if(a =>12,48,50),of(b=>12,42,45) how to resolve the query

  11. Hi.. for logical_test, can it be in formula?

  12. Hello. I need formula to check if the item in the this tab, can be find in the other tab. Result will be yes or no

  13. I need a formula in cell H4 that divides H14 by H24 but if the value is greater than 100 enter 100 but if less than 100 then enter the true value of H14/H14.

    Thank you

  14. Hi,
    I have 2 questions.

    1. I have employees that will be resigning effective June 20, 2024. They are currently tagged as "Active". I want excel to tag them as "Separated" come June 20. What do I do?
    2. I have employees that are still active, did not resign yet. Since there are no resignation date in the column, I want to tag them still as "Active" What do I do?

    Thank you.

  15. I need help with a formula that where the value in B4 is multiplied by either rates in (C2,D2,E2) if it is greater than a range of specific cells (C1, D1, E1). Example if B4=45, total will be 225.00 (C1*C2). Thank you.

    C1:45
    C2:5.00
    D1:100
    D2:4.00
    E1:300
    E2:2.00

    B4: 45

    B8: total

    • Sorry total will be 225.00 (B4*C2) not C1.

      • Thank you for your reply but it isn't calculating the way I would like it to. The formula provided is adding the cells with 5.25 and 5.00 then multiplying cell B4 which isn't correct. The output i'm looking for is that B4 would be multiplied 5.00 since it is greater than 100. Hopefully this is much clearer, thank you.

        45 100 300 500 1000
        5.25 5.00 4.95 4.90 4.80

        B4: 105

        B5: TOTAL

        • Hi! The formula I sent to you was created based on the description you provided in your first request. However, as far as I can see from your second comment, your task is now different from the original one.
          If I understand correctly, find the maximum number that is less than B4 using the MAX function and MATCH function. Then extract the corresponding value from the range C2:E2 using INDEX MATCH.

          =INDEX(C2:E2,MATCH(MAX((C1:E1

          • I apologize for not explaining it clearly. I used the formula but it says I'm missing a parenthesis. Also, where would I enter B4 in the formula?

            • Please disregard as I don't think it can be done.

  16. Hi. Can you please help for IF/THEN.

    IF A1=X1, then show what is in cell Z1.

    • Disregard.. I figured it out.

      • Sir, Good evening!

        Sir i have one question, may be you can solve this.

        Sir,
        According in if function,

        If cell is blank then we can use - this cell number ="" ( that's ok)
        If cell will be number format /test format =?? ( how we show ?)

  17. in excel I want to enter a value (1 and above in one cell), and it should display 1 (value) in another cell. It should display 0 if the supplied value is 0.

  18. this is great god job thank you for sharing.

  19. Hi, I have values in two coloums i.e. in row 1, the value is in Col A and from row 2 to 10, the value is in Col B. Which formula can be used to call the required values from both Col A and B and return the value in Col C. Thanks.

    • Hi! It is impossible to guess how you want to call required values. You can use the VLOOKUP formula to search multiple columns as described in this article. You can also combine multiple columns into a single column using the VSTACK function. There may be other solutions depending on what you want to do.

      • Thank you for your prompt response

      • Hello, Alex! I have two lists; an authorized user list and a transaction list. On the transaction list, it gives the name of who authorized the transaction. I already completed a VLOOKUP to have the authorized user's name next to the user who authorized the transaction. Now, I need to filter the data to show unauthorized transactions. I was thinking an easy IF statement would be the answer, but the wall I am hitting is stumping me. The names on the authorized user list have a couple names of who has authorization.
        Example: (A3)Authorized: Hayes, (B3)Authorizer: Hayes/Lopez.
        As you can see, Hayes is on the authorized list so he should be fine. My If statement is =IF(A3=B3,"Authorized","Unauthorized"). It seems the = is only giving me an EXACT match. Is there a way I can make the IF statement work?

        • Hi! If I understand the question correctly, you want to determine if the text strings in cells A3 and B3 are partial matched. Based on the information provided, the formula could look like this:

          =IF(ISNUMBER(SEARCH(A3,B3)),"Authorized","Unauthorized")

          For more information, please read: How to find substring in Excel

  20. Good Day,

    I have prepared a salary sheet with dates in a row and name of employee in the column, I want to get the total sum of salary Only of Today() (everyday in the same cell)
    =IF(T10="P", ((G10*1)+(U10*(G10/9))), "0") then sum of all the employees but this works only on one day.

    how may I automate it, please.

  21. I have a table for vacation for employee
    I would like to enter the day that start with month and year than it will automatically add the week date (which will start Sunday)
    Also in the table when a cell is selected it will subtract from the total of weeks each person have.

    Please help

  22. Hi
    Newbie question sorry....I have a column containing a number of text names equating to project status. As follows: onboarding, offboarding, leaving etc... (With a different designated numerical value to each)

    I.e Onboarding 5, Offboarding 3, Leaving 1 etc

    I would like to create an IF statement as a form of lookup to check the text name in the column against the list/values and display said value in a new column. I am wondering if this is the best way to do this? have started with the following..... =IF(E2="onboarding","5") .... but am wondering how to add the other names and values... and if this is actually possible?

    Again, a new user so scrabbling about without a lot of time to study the options...

    Any suggestions welcome.

  23. i need an if stmt to perform:

    IF cell E4 > 120
    then cell E36 = (E4-120)/8)
    ELSE
    cell E36 = 0

  24. Hi, i need to separate a mix column similar to this one. into 3 columns, (name, date, yes/no).
    Column is
    first, last
    11/27/2023
    Unapproved
    11/28/2023
    Unapproved
    Unapproved
    Unapproved
    12/6/2023
    Unapproved

    b, d
    12/1/2023
    Unapproved
    Unapproved
    12/2/2023
    Unapproved
    Unapproved

    needs to look something like this
    first, last 11/27/2023 unapproved
    first, last 11/28/2023 unapproved
    first last 11/28/2023 unapproved
    first last 11/28/2023 unapproved
    first last 12/6/2023 unapproved
    b, d 12/1/2023 Unapproved
    b, d 12/1/2023 Unapproved
    b, d 12/2/2023 Unapproved
    b, d 12/2/2023 Unapproved

      • Could you write three individual loops/statement in three different columns and the final condition is blank for the rows for the name and the date but in the row for the unapproved/approve in it. that row will place the name-date-condition??

        I have stated trying to solve this: =IF(A10="Unapproved", "Unapproved", "")

        • Hi! Your question is not entirely clear to me. Please clarify your specific problem or provide additional details to highlight exactly what you need.

  25. Hi, i need to use the IF function for a total score of more than 45 but less than 55 and a total score of more than 55 but less than 60

  26. I have 5 sell prices for each item in excel and I need to write an IF statement to see if they all match. Can you help?

  27. Hi, I need to write an IF statement for a column in which I already have some values which need to remain unchanged if the corresponding cell in the C column reads 'TRUE'. However, if the coresponding cell in the C column reads 'FALSE', then the cell must return 'NULL'. e.g C2 contains 'FALSE', therefore D2 will write 'NULL'. However, C4 contains 'TRUE', therefore the existing number in D4 '0.29' should remain unchanged. I can't find any logic which allows me to do this? The examples given use "" which returns a blank cell.

    • Hi! An Excel formula can only return a value to the cell in which it is written, and it cannot return a value to another cell. A previously written value in a cell cannot be changed by an Excel formula. This can be done with VBA. For example, you can use a formula in the E column to either set the value to NULL or to get the value from the C column. For example:

      =IF(C2=FALSE,"NULL",D2)

Post a comment



Thank you for your comment!
When posting a question, please be very clear and concise. This will help us provide a quick and relevant solution to
your query. We cannot guarantee that we will answer every question, but we'll do our best :)