by In this tutorial, we will continue exploring the fascinating world of Excel Conditional Formatting. If you do not feel very comfortable in this area, you may want to look through the previous article first to revive the basics - How to use conditional formatting in Excel.
Today are going to dwell on how to use Excel formulas to format individual cells and entire rows based on the values you specify or based on another cell's value. This is often considered advanced aerobatics of Excel conditional formatting and once mastered, it will help you push the formats in your spreadsheets far beyond their common uses.
Excel conditional formatting based on another cell value
Excel's predefined conditional formatting, such as Data Bars, Color Scales and Icon Sets, are mainly purposed to format cells based on their own values. If you want to apply conditional formatting based on another cell or format an entire row based on a single cell's value, then you will need to use formulas.
So, let's see how you can make a rule using a formula and after discuss formula examples for specific tasks.
How to create a conditional formatting rule based on formula
To set up a conditional formatting rule based on a formula in any version of Excel 2010 through Excel 365, carry out these steps:
- Select the cells you want to format. You can select one column, several columns or the entire table if you want to apply your conditional format to rows.
Tip. If you plan to add more data in the future and you want the conditional formatting rule to get applied to new entries automatically, you can either:
- Convert a range of cells to a table (Insert tab > Table). In this case, the conditional formatting will be automatically applied to all new rows.
- Select some empty rows below your data, say 100 blank rows.
- On the Home tab, in the Styles group, click Conditional formatting > New Rule…
- In the New Formatting Rule window, select Use a formula to determine which cells to format.
- Enter the formula in the corresponding box.
- Click the Format… button to choose your custom format.
- Switch between the Font, Border and Fill tabs and play with different options such as font style, pattern color and fill effects to set up the format that works best for you. If the standard palette does not suffice, click More colors… and choose any RGB or HSL color to your liking. When done, click the OK button.
- Make sure the Preview section displays the format you want and if it does, click the OK button to save the rule. If you are not quite happy with the format preview, click the Format… button again and make the edits.
Tip. Whenever you need to edit a conditional formatting formula, press F2 and then move to the needed place within the formula using the arrow keys. If you try arrowing without pressing F2, a range will be inserted into the formula rather than just moving the insertion pointer. To add a certain cell reference to the formula, press F2 a second time and then click that cell.
Excel conditional formatting formula examples
Now that you know how to create and apply Excel conditional formatting based on another cell, let's move on and see how to use various Excel formulas in practice.
Tip. For your Excel conditional formatting formula to work correctly, please always follow these simple rules.
Formulas to compare values (numbers and text)
As you know Microsoft Excel provides a handful of ready-to-use rules to format cells with values greater than, less than or equal to the value you specify (Conditional Formatting >Highlight Cells Rules). However, these rules do not work if you want to conditionally format certain columns or entire rows based on a cell's value in another column. In this case, you use analogous formulas:
| Condition | Formula example |
|---|---|
| Equal to | =$B2=10 |
| Not equal to | =$B2<>10 |
| Greater than | =$B2>10 |
| Greater than or equal to | =$B2>=10 |
| Less than | =$B2<10 |
| Less than or equal to | =$B2<=10 |
| Between | =AND($B2>5, $B2<10) |
The screenshot below shows an example of the Greater than formula that highlights product names in column A if the number of items in stock (column C) is greater than 0. Please pay attention that the formula applies to column A only ($A$2:$A$8). But if you select the whole table (in our case, $A$2:$E$8), this will highlight entire rows based on the value in column C.
In a similar fashion, you can create a conditional formatting rule to compare values of two cells. For example:
=$A2<$B2 - format cells or rows if a value in column A is less than the corresponding value in column B.
=$A2=$B2 - format cells or rows if values in columns A and B are the same.
=$A2<>$B2 - format cells or rows if a value in column A is not the same as in column B.
As you can see in the screenshot below, these formulas work for text values as well as for numbers.
AND and OR formulas
If you want to format your Excel table based on 2 or more conditions, then use either =AND or =OR function:
| Condition | Formula | Description |
|---|---|---|
| If both conditions are met | =AND($B2<$C2, $C2<$D2) |
Formats cells if the value in column B is less than in column C, and if the value in column C is less than in column D. |
| If one of the conditions is met | =OR($B2<$C2, $C2<$D2) |
Formats cells if the value in column B is less than in column C, or if the value in column C is less than in column D. |
In the screenshot below, we use the formula =AND($C2>0, $D2="Worldwide") to change the background color of rows if the number of items in stock (Column C) is greater than 0 and if the product ships worldwide (Column D). Please pay attention that the formula works with text values as well as with numbers.
Naturally, you can use two, three or more conditions in your AND and OR formulas. To see how this works in practice, watch Video: Conditional formatting based on another cell.
These are the basic conditional formatting formulas you use in Excel. Now let's consider a bit more complex but far more interesting examples.
Conditional formatting for empty and non-empty cells
I think everyone knows how to format empty and not empty cells in Excel - you simply create a new rule of the "Format only cells that contain" type and choose either Blanks or No Blanks.
But what if you want to format cells in a certain column if a corresponding cell in another column is empty or not empty? In this case, you will need to utilize Excel formulas again:
Formula for blanks: =$B2="" - format selected cells / rows if a corresponding cell in Column B is blank.
Formula for non-blanks: =$B2<>"" - format selected cells / rows if a corresponding cell in Column B is not blank.
Note. The formulas above will work for cells that are "visually" empty or not empty. If you use some Excel function that returns an empty string, e.g. =if(false,"OK", ""), and you don't want such cells to be treated as blanks, use the following formulas instead =isblank(A1)=true or =isblank(A1)=false to format blank and non-blank cells, respectively.
And here is an example of how you can use the above formulas in practice. Suppose, you have a column (B) which is "Date of Sale" and another column (C) "Delivery". These 2 columns have a value only if a sale has been made and the item delivered. So, you want the entire row to turn orange when you've made a sale; and when an item is delivered, a corresponding row should turn green. To achieve this, you need to create 2 conditional formatting rules with the following formulas:
- Orange rows (a cell in column B is not empty):
=$B2<>"" - Green rows (cells in column B and column C are not empty):
=AND($B2<>"", $C2<>"")
One more thing for you to do is to move the second rule to the top and select the Stop if true check box next to this rule:
In this particular case, the "Stop if true" option is actually superfluous, and the rule will work with or without it. You may want to check this box just as an extra precaution, in case you add a few other rules in the future that may conflict with any of the existing ones.
For more information, please see Excel conditional formatting for blank cells.
Excel formulas to work with text values
If you want to format a certain column(s) when another cell in the same row contains a certain word, you can use a formula discussed in one of the previous examples (like =$D2="Worldwide"). However, this will only work for exact match.
For partial match, you will need to use either SEARCH (case insensitive) or FIND (case sensitive).
For example, to format selected cells or rows if a corresponding cell in column D contains the word "Worldwide", use the below formula. This formula will find all such cells, regardless of where the specified text is located in a cell, including "Ships Worldwide", "Worldwide, except for…", etc:
=SEARCH("Worldwide", $D2)>0
If you'd like to shade selected cells or rows if the cell's content starts with the search text, use this one:
=SEARCH("Worldwide", $D2)>1
Excel formulas to highlight duplicates
If your task is to conditionally format cells with duplicate values, you can go with the pre-defined rule available under Conditional formatting > Highlight Cells Rules > Duplicate Values… The following article provides a detailed guidance on how to use this feature: How to automatically highlight duplicates in Excel.
However, in some cases the data looks better if you color selected columns or entire rows when a duplicate values occurs in another column. In this case, you will need to employ an Excel conditional formatting formula again, and this time we will be using the COUNTIF formula. As you know, this Excel function counts the number of cells within a specified range that meet a single criterion.
Highlight duplicates including 1st occurrences
=COUNTIF($A$2:$A$10,$A2)>1 - this formula finds duplicate values in the specified range in Column A (A2:A10 in our case), including first occurrences.
If you choose to apply the rule to the entire table, the whole rows will get formatted, as you see in the screenshot below. I've decided to change a font color in this rule, just for a change : )
Highlight duplicates without 1st occurrences
To ignore the first occurrence and highlight only subsequent duplicate values, use this formula: =COUNTIF($A$2:$A2,$A2)>1
Highlight consecutive duplicates in Excel
If you'd rather highlight only duplicates on consecutive rows, you can do this in the following way. This method works for any data types: numbers, text values and dates.
- Select the column where you want to highlight duplicates, without the column header.
- Create a conditional formatting rule(s) using these simple formulas:
Rule 1 (blue):=$A1=$A2- highlights the 2nd occurrence and all subsequent occurrences, if any.
Rule 2 (green):=$A2=$A3- highlights the 1st occurrence.
In the above formulas, A is the column you want to check for dupes, $A1 is the column header, $A2 is the first cell with data.
Important! For the formulas to work correctly, it is essential that Rule 1, which highlights the 2nd and all subsequent duplicate occurrences, should be the first rule in the list, especially if you are using two different colors.
Highlight duplicate rows
If you want apply the conditional format when duplicate values occur in two or more columns, you will need to add an extra column to your table in which you concatenate the values from the key columns using a simple formula like this one =A2&B2. After that you apply a rule using either variation of the COUNTIF formula for duplicates (with or without 1st occurrences). Naturally, you can hide an additional column after creating the rule.
Alternatively, you can use the COUNTIFS function that supports multiple criteria in a single formula. In this case, you won't need a helper column.
In this example, to highlight duplicate rows with 1st occurrences, create a rule with the following formula:
=COUNTIFS($A$2:$A$11, $A2, $B$2:$B$11, $B2)>1
To highlight duplicate rows without 1st occurrences, use this formula:
=COUNTIFS($A$2:$A2, $A2, $B$2:$B2, $B2)>1
Compare 2 columns for duplicates
One of the most frequent tasks in Excel is to check 2 columns for duplicate values - i.e. find and highlight values that exist in both columns. To do this, you will need to create an Excel conditional formatting rule for each column with a combination of =ISERROR() and =MATCH() functions:
For Column A: =ISERROR(MATCH(A1,$B$1:$B$10000,0))=FALSE
For Column B: =ISERROR(MATCH(B1,$A$1:$A$10000,0))=FALSE
Note. For such conditional formulas to work correctly, it's very important that you apply the rules to the entire columns, e.g. =$A:$A and =$B:$B.
You can see an example of practical usage in the following screenshot that highlights duplicates in Columns E and F.
As you can see, Excel conditional formatting formulas cope with dupes pretty well. However, for more complex cases, I would recommend using the Duplicate Remover add-in that is especially designed to find, highlight and remove duplicates in Excel, in one sheet or between two spreadsheets.
Formulas to highlight values above or below average
When you work with several sets of numeric data, the AVERAGE() function may come in handy to format cells whose values are below or above the average in a column.
For example, you can use the formula =$E2<AVERAGE($E$2:$E$8) to conditionally format the rows where the sale numbers are below the average, as shown in the screenshot below. If you are looking for the opposite, i.e. to shade the products performing above the average, replace "<" with ">" in the formula: =$E2>AVERAGE($E$2:$E$8).
How to highlight the nearest value in Excel
If I have a set of numbers, is there a way I can use Excel conditional formatting to highlight the number in that set that is closest to zero? This is what one of our blog readers, Jessica, wanted to know. The question is very clear and straightforward, but the answer is a bit too long for the comments sections, that's why you see a solution here :)
Example 1. Find the nearest value, including exact match
In our example, we'll find and highlight the number that is closest to zero. If the data set contains one or more zeroes, all of them will be highlighted. If there is no 0, then the value closest to it, either positive or negative, will be highlighted.
First off, you need to enter the following formula to any empty cell in your worksheet, you will be able to hide that cell later, if needed. The formula finds the number in a given range that is closest to the number you specify and returns the absolute value of that number (absolute value is the number without its sign):
=MIN(ABS(B2:D13-(0)))
In the above formula, B2:D13 is your range of cells and 0 is the number for which you want to find the closest match. For example, if you are looking for a value closest to 5, the formula will change to: =MIN(ABS(B2:D13-(5)))
Note. This is an array formula, so you need to press Ctrl + Shift + Enter instead of a simple Enter stroke to complete it.
And now, you create a conditional formatting rule with the following formula, where B3 is the top-right cell in your range and $C$2 in the cell with the above array formula:
=OR(B3=0-$C$2,B3=0+$C$2)
Please pay attention to the use of absolute references in the address of the cell containing the array formula ($C$2), because this cell is constant. Also, you need to replace 0 with the number for which you want to highlight the closest match. For example, if we wanted to highlight the value nearest to 5, the formula would change to: =OR(B3=5-$C$2,B3=5+$C$2)
Example 2. Highlight a value closest to the given value, but NOT exact match
In case you do not want to highlight the exact match, you need a different array formula that will find the closest value but ignore the exact match.
For example, the following array formula finds the value closest to 0 in the specified range, but ignores zeroes, if any:
=MIN(ABS(B3:C13-(0))+(10^0*(B3:C13=0)))
Please remember to press Ctrl + Shift + Enter after you finished typing your array formula.
The conditional formatting formula is the same as in the above example:
=OR(B3=0-$C$2,B3=0+$C$2)
However, since our array formula in cell C2 ignores the exact match, the conditional formatting rule ignores zeroes too and highlights the value 0.003 that is the closest match.
If you want to find the value nearest to some other number in your Excel sheet, just replace "0" with the number you want both in the array and conditional formatting formulas.
I hope the conditional formatting formulas you have learned in this tutorial will help you make sense of whatever project you are working on. If you need more examples, please check out the following articles:
Why isn't my Excel conditional formatting working correctly?
If your conditional formatting rule is not working as expected, though the formula is apparently correct, do not get upset! Most likely it is not because of some weird bug in Excel conditional formatting, rather due to a tiny mistake, not evident at the first sight. Please try out 6 simple troubleshooting steps below and I'm sure you will get your formula to work:
- Use absolute & relative cell addresses correctly. It's very difficult to deduce a general rule that will work in 100 per cent of cases. But most often you would use an absolute column (with $) and relative row (without $) in your cell references, e.g.
=$A1>1.Please keep in mind that the formulas
=A1=1,=$A$1=1and=A$1=1will produce different results. If you are not sure which one is correct in your case, you can try all : ) For more information, please see Relative and absolute cell references in Excel conditional formatting. - Verify the applied range. Check whether your conditional formatting rule applies to the correct range of cells. A rule of thumb is this - select all the cells / rows you want to format but do not include column headers.
- Write the formula for the top-left cell. In conditional formatting rules, cell references are relative to the top-left most cell in the applied range. So, always write your conditional formatting formula for the 1st row with data.
For example, if your data starts in row 2, you put
=A$2=10to highlight cells with values equal to 10 in all the rows. A common mistake is to always use a reference to the first row (e.g.=A$1=10). Please remember, you reference row 1 in the formula only if your table does not have headers and your data really starts in row 1. The most obvious indication of this case is when the rule is working, but formats values not in the rows it should. - Check the rule you created. Double-check the rule in the Conditional Formatting Rules Manager. Sometimes, for no reason at all, Microsoft Excel distorts the rule you have just created. So, if the rule is not working, go to Conditional Formatting > Manage Rules and check both the formula and the range it applies to. If you have copied the formula from the web or some other external source, make sure the straight quotes are used.
- Adjust cell references when copying the rule. If you copy Excel conditional formatting using Format Painter, don't forget to adjust all cell references in the formula.
- Split complex formulas into simple elements. If you use a complex Excel formula that includes several different functions, split it into simple elements and verify each function individually.
And finally, if you've tried all the steps but your conditional formatting rule is still not working correctly, drop me a line in comments and we will try to fathom it out together :)
In my next article we are going to look into the capabilities of Excel conditional formatting for dates. See you next week and thanks for reading!
1633 comments
Hi
I wondered if you could help me please. I am trying to create a month by month summary of our customer service scores. All i would like to do is to highlight the cell green or red based on whether the score has increased or decreased from the previous month. For exmaple:
Month Overall
Oct-14 -100
Nov-14 18
Dec-14 -50
Jan-15 -8
Feb-15 45
Mar-15 -2
Apr-15 30
May-15 20
So i would like May's score to be highlighted red because it decreased from April. But April to be highlighted green because it increased from march.
Thanks
J M K S
3 2 3 5---------k--?
76 5 75 7---------k--?
4 564 76 53--------j--?
354 34 456 24--------s--?
Hello,
i have a small dilemma and would appreciate if anyone could help out.
So i have the following arrangement
J M K S
3 2 3 5 k ?
76 5 75 7 k ?
4 564 76 53 j ?
354 34 456 24 s ?
Were I would like the letters column to be matched to the letters row, and the question marks replaced by the corresponding value under the letters row.
resulting for example in the following
k 3
k 76
j 4
s 24
does anyone know what equation I need to use to substitute the values instead of the question marks?
Thank you
I have the traffic light icon working in the cell that has the value, however I want the value to be in one cell the the traffic light to be in the next cell. Is that possible?
Hello Caren,
Because it is not possible to use relative references in conditional formatting criteria for icon sets, you cannot apply icons based on another cell's value.
As a workaround, you can copy the values to the next column, say by entering a simple formula like =$A1 in cell B1 and then copying it down to other cells in column B. Then you apply icons to column B and select the "Show Icon Only" option. So, visually you will have values in column A and corresponding icons will display in column B.
Hi svetlana,
Is there a way to colour a cell with two colours depending on a values cells in other work sheet?
ex: sheet 1 cell A1 to be colored with red, if value in sheet 2 cell A1>0 and also sheet 1 cell A1 to be colored with green, if value in sheet 2 cell B1>0
Hi Thushan,
Of course, it's possible. In conditional formatting formulas you can refer to other sheets just as you would normally do. For example, you can create 2 different rules for A1 in sheet 1:
Red: =Sheet2!$A1>0
Green: =Sheet2!$B1>0
Is there a way to conditionally format cells to match the fill color of an original cell with matching text that was manually color filled?
Hi Svetlana.
I have a conditional format running that changes a cell blue if the letters GI are entered or red if the letters AFM are entered, I also need the cell to the left of GI or AFM cell to format blue or red. I have tried many formulas but without any luck
Hi Garry,
Just apply the same rules to two columns instead of one.
Hi Svetlana!
I'm copying exact version of your formula: =AND($B2>5, $B20 but when using "AND" function and trying to make multiple criterias it just keep giving error.
Wbr
Hi Suva,
Please post the entire formula you are using and we will try to figure out the root of the problem.
I have several series of data validation dropdowns, and lets say when E5 = text_value i want G5 to be highlighted
because under specific conditions (depending on what previous choices are made) there needs to be an additional dropdown. i am not concerned with making a conditional data validation (probably not possible anyway) but i was hoping someone could help so that i could just highlight it so it sticks out when additional information is required
nevermind!! i got it! after reading other situations i realized that the rule would be specific to the selected cell and wouldnt necessarily be a general formula for the entire sheet
Hi guys, can someone help me please..
How To use conditional formatting for example... in cell A1 Sheet 1, based on the value from cell A2 in Sheet 2.
So...
If Cell A2 (Sheet2) = "DA"....then Cell A1 (Sheet1) background is RED.
Thank You
Hi Ivan,
Create a rule for cell A1 Sheet 1 with the following formula:
=Sheet2!$A2="DA"
So I have this data on a summary sheet:
#INT1 #INT1 #INT2 #INT2 #INT3 #INT3
$DAT Y $FILB Y $DAT Y
$FIL-B Y $FIL-H Y $FIL-B Y
$FIL-H Y $FIL-POS Y $FIL-H Y
$FIL-POS Y $N/A-FIL YYYYYYNN $FIL-POS Y
$N/A-FIL YYYYYYNN $SEC-M NNNYYNNN $N/A-FIL YYYYYYNN
$ORD-FIL YYYYNNNN BACF NNNYNNNN $ORD-FIL NNNYNNNN
$SEC-M NNNYYNNN BARS YYNYNNNN $SEC-M NNNYYNNN
$SEC-USR NNNYNNNN BATS NNNYNNNN $STATS Y
$STATS Y BBDS YNNYNNNN AONE NNNYNNNN
AONE YYNYNNNN BBIF NNNYNNNN AORD YYYYNNNN
AORD YYYYNNNN BCAT NNNYNNNN ASEC NNNYNNNN
And so on…
I was wondering if there was a way I could check row A and B against all other rows for pairs of data like $DAT and Y would be what to check for so $DAT and Y would be highlighted in A,B and E, F and the whole sheet.
Any help would be greatly appreciated. Thank you. I can send a sample spreadsheet if you need.
Does anyone know how to make a conditional format to create a specific number based on another cells number?
Example:
Cell 1 shows the number 3
I need cell 2 to then show the number 1.
All in increments of 3, if it shows 6 then it will show 2.
9 = 3
12 = 4 etc. Also, If it is between 3 and 5 it will still show a 1, between 6 and 8 it will still show a 2 and so on.
Any help would on this conditional formatting would be appreciated.
Hi Shawn,
I believe a Lookup Formula would be your best option.
If you have your data starting in cell A2, you can add the following formula in cell B2:
=LOOKUP(lookup_value, lookup_vector, [result_vector])
=LOOKUP(A2,{3,6,9,12},{"1","2","3","4"})
You can keep expanding the formula by increments of 3, but make sure you update the lookup_vector and result_vector.
I hope this helps.
Hi
If anyone can suggest a reason for the following problem i'd be grateful.
I am using conditional formatting to colour code times and distances for track and field according to a set of standards.
For example I have formatted columns A, B, C, D so that
2.5 to 3 are red
3.1 to 4.49 are yellow
4.5 and greater are green.
I want to format other columns to use the same colour system but for different parameters as they are to represent different events.
I have tried copy and paste as well as format painter to save time and then edit the rules only, removing the need to select the formatting each time.
However, when I highlight a selection and edit the rule (checking that current selection is correct) it applies the rule change to the entire sheet!!
Why does this happen?
Yours
Matt
I want to count payments: 1 of 30, 2 of 30 by writing 1/30, 2/30 and so on. I want to write two cells and drag to create the rest (as I do with dates or numgers).
Can you suggest a way to do this? Thank you in advance
Hi,
i am working on shift roster excel and i want to highlight only shift person name cell who is today.
e.g.
row A1 has Date
column A2 has shift person name
and B2-z2 has shift name(Day,Night)
formula has to first check today's date then search in that column the shift name(day,night) if match Day the highlight the shift person name which is in column A2.
Hi,
Great forum, hopefully what i'm trying to do is possible. Is it possible to inherit the color from referenced cells. For example, if I had a formula: =concatenate("This is a test ",B2). I need to inherit the existing value and color in cell B2.
Hi there,
I got set of data and I need to color the cell based on value row before it.
Ex.
A B C D
a 2 1 3 4
b 3 0 4 5
c 1 3 5 7
d 8 9 3 3
I need to color the Ab red (>Aa) and Bb green (<Ba). I want to apply the rules to all row and column. Is there anyway i can do it?
Hi,
I have been trying to do cell formatting for following condition:
=$Q3$AS3
I want to highlight the cells of column Q3 if the value doesn't match with values in column AS.
I used above mentioned condition but somehow it's highlighting all the rows and columns from Q until AS. I tried to select following ranges "Q3:Q100" as well as "Q3:AS3, Q100:AS100", but no use.
Please suggest.
Thanks,
Shipra
Hi Shipra,
I have just created a rule for Q3:Q100 with the following formula and it highlighted only cells in column Q that are not equal to values in column AS in the same row:
=$Q3<>$AS3
Please double check the applied range via Conditional Formatting > Manage Rules.
Hey there,
I'm trying to set a conditional format where I want to change the colour of column A if the column width does not equal "10.29".
Would you be able to help out?
Thanks,
Jon
Hey Jon,
I have been trying to attempt the same thing with cell formulas. I have put in =cell("WIDTH") but it does not show the exact amount. Let me know if you have any luck with finding a formula.
Matt
Hi Svetlana,
First of all Congratulations for your blog! I find it 'state of the art' and a precious on-line resource. Of course I will spread the word about it...!
As I wasn't able to find a solution that works among the tutorials and examples you posted above, please allow to present my question:
How to apply conditional formatting to columns F, G, H and I (by instance change font colour to 'red'...) when it met a given criteria (comprised of the word string IMP) in the same line in column A (in Microsoft Excel 2007)...? Or in another way, which formula to use...?
I deeply appreciate your help. Thank you.
Kind regards,
Carlos
Hello Carlos,
Thank you very much for your kind words.
You can select the entire columns $F:$I and create a rule with the following formula:
=$A1="IMP"
The above formula works for the exact match. In case you are looking for a partial match formula, i.e. highlight columns F:I if column A contains values like "IMP 2" or "xIMP", then use the SEARCH function as follows:
=SEARCH("IMP", $A1)>0
Hi Tom,
Assuming that row 2 is your first row with data, select all the cells in column B you want to color beginning with cell B2 and create a rule with the following formula:
=AND($A2="requested",TODAY()-$B2>14)
I'm having a problem with changing a cell colour based on multiple cell values.
Example
Column A has 3 values using a data validation list "requested, booked and delivered"
Column B has the date of request.
I would like the cell in column B to change colour if Column a value is "requested" and if date in column B is over 14 days old.
Any help would be really appreciated
Im doing a data bar formatting for a cell, and I would like the color of the data bar to change relative to the value of another cell.
Hi Luis,
Select the cells where you want data bars to appear, click Conditional formatting > Data bars > More rules. In the "New Formatting Rule" window, select Formula in the "Type" box and enter your formula in the "Value" box. Just keep in mind that relative cell references are not allowed in Data bar formulas.
Hey, guys.
I would like to conditionally format cells which are contained in a formula.
Ex: If A11 equals the Sum of A1:A10, I would like A1 through A10 highlighted a certain color.
This would allow me to quickly see what cells are in the summation without putting the cursor in the formula bar up top.
Thanks.
Hi Ben,
Select cells A1:A10 and create a rule with the following formula:
=$A$11=SUM($A$1:$A$10)
Hi,
I have data's in 1st four column on the excel sheet. In those four columns i have common / similar data in column A and C. Column B and D consists of values which has to be reconcilied by matching the datas of A and C. For example
Example 1
Column A = 1
Column C = 1
Column B = 0.002
Column D = 0.002
The column E should show it is matching.
Exapmle 2
Column A = 1
Column C = 1
Column B = 0.02
Column D = 0.002
The column E should show it is not matching.
The main constraint over here is we can have datas in column A is missing in Column C.on those scenario it should show as NA in column E.
Kindly help me at the earliest.
Thanks is advance.
Jeetesh Jain.
Hi All,
Can any one help me on my request?
Thanks in advance
Best Regards
Jeetesh Jain
Hi,
I received quotation from different supplier and I need to compare the received prices. Can you please advise how to use conditioning function for comparing prices from different supplier. I want to get all best lowest prices in Green and highest price in Red.
Hi Svetlana,
I am trying to fill one cell based on the value of another previously given.
The problem is shwon in the example, number from 01 to 20 will appear in the first 4 columns (C1-C4). I want to take these values and put them into a respective contiguous set of columns (C6-C26). Is it something feasible in excel?
I have this situation:
C01 C02 C03 C04 C05 C06 C07 C08 C09 C10 C11 C12 C13 C14 C15 C16 C17 C18 C19
01 05 09 14 01 05 09 14
02 07 11 12 02 07 11 12
08 09 10 12 08 09 10 12
04 05 13 14 04 05 13 14
and so on
Thanks and Regards,
Ed
I have this table, it show like this:
Given no. USL LSL Measured value Deviation Out of Scope
(GN) + - (MV) (GN - MV) (This I want to get the answer) /
42 42.3 41.7 42.38 .38 .08 (to get this, must choose / which is more nearer, to the
/ Given no. the USL or / LSL
Hello, Chona,
I am sorry, it is not very clear what result you want to get. Please send a small sample workbook with your source data and the expected result to support@ablebits.com.
We’ll look into your task and try to help.
Hi Alexxander , can you please advice me something in comment # 269
I am trying to conditional format formulas that contain an adjustment to the formula. For example We will have A1+A2. I want to identify formulas that have A1+A2+1000 or A1+A2*2 etc. Formulas that have a component of the formula that is not a reference to another cell.
I already can conditional format cells containing formulas ve values. I just can't see formulas that are adjusted and not overwritten completely.
Thank you for the help.
Helllo Chris,
It is an interesting task. You need to add User Defined Function (UDF) to your workbook. Here is the code:
Function GetFormula(rng As range) As String
getFormula = rng.Formula
End Function
For more details how to insert and run VBA code in Excel, please see here:
https://www.ablebits.com/office-addins-blog/add-run-vba-macro-excel/
Then select all the cells with formulas that you want to check, e.g. from F2 till E20, and create a conditional formatting rule using the formula below:
=NOT(ISERR(FIND(RIGHT(GetFormula($B$3),LEN(GetFormula($B$3))-1),GetFormula(F2),1)))
Where $B$3 is the cell with a sample formula that you want to search, e.g. =A1+A2.
If you know for sure what “text” you are looking for, then replace this part of the formula RIGHT(GetFormula($B$3),LEN(GetFormula($B$3))-1) with the “text” you want to search, e. g.:
=NOT(ISERR(FIND("A1+A2",GetFormula(F2),1)))
Hello-- Using Excel 2007---2 questions--
1st --I have a column of cells (column B) containing text and two digit numbers in the same cell. I want the column next to it (column A) to have a conditional format based on whether that 2nd column has a number within a specific range. Meaning if it has a number between 10 and 19 the first column will be green, if between 20 and 29 it will be red, if it has a value between 30 and 40 it is a blue.
2nd--Is it is possible to have is rule skip a number if it is followed by the word "egg" and only read the 2nd number for the conditional formatting rule?
Here are some examples of the text and number in the second column.
3 Split 15 Blast-(Column A Should be Green)
4 Right 16 Blast-(Column A Should be Green)
5 Split 23 Egg 16 Dive-(Column A Should be Green)
6 Split 38 Egg Fly 23 Dive-(Column A Should be Red)
7 Split 22 Dive 37 Egg-(Column A Should be Red)
8 Split 33 Dive 28 Egg-(Column A Should be Blue)
9 Split 33 Egg 28 Around-(Column A Should be Red)
10 Twins R 37 Egg Fly 24 Dive-(Column A Should be Red)
11 Split 23 Egg 30-R Flat-(Column A Should be Blue)
Is this possible
Hello Marty,
Thank you for the detailed description! Yes, it is possible, but you need the UDF function on VBA (to use regular expressions during the search).
I am sorry, we can’t help you with a macro. Please ask for it in specialized sections on http://www.mrexcel or http://www.excelforum.com
I'm using the "between" rule to color code some thickness data, but it is not being inclusive like it should. If the value is exactly the value of one of the bounds, then the cell stays white. I can fix it by having the values range to the value I want plus 0.001, but this is annoying and will take awhile to fix for all twenty tabs of data. Any ideas?
Thanks!
Hi
I have a rule
=IF(OR(DH1=8471702000,DH1=8471609000,DH1=9013901000,DH1=9031499090, DH1=8544422900,DH1=8541409000,DH1=8205400000,DH1=8504401990, DH1=8471703090,DH1=8443321200,DH1=9030311000),AND(BR1="CN", DD1="EXCH NEW"))
If it find these numbers in DH column and same for BR and DD column than it will color a column green,
Now i want to change the rule like color my required column if BR is "CN" and DD is "EXCH NEW" but only where there these no. are not coming in Column DH,
Means same formula just to ignore these no.
I tried in place of = but it does not work. It work if we right as a formula in cell but if i tried to add as a new rule in conditional formatting for color than it does not work.
Can you provide me any help or suggestion on this.
hi
i want to highlight values in a column based on the following condition:-
column to highlight is AC which has % figures in few rows.
CONDITION -if the dates in the cells range(J8:O8>8TH MAY'15)THEN HIGHLIGHT THE %VALUES IN COLUMN AC. rows
kindly suggest solution.
I have a Excel sheet where attendance of various students are marked.Now I would like to highlight the cells in which "present" occurs more than 7 times consecutively (i.e a student is present continuously for 7 days excluding sundays) for each student...?
Hi, I am referencing cells in a data entry worksheet to create coordinating filled cells in a separate sheet. However, when I use Format Painter to copy the conditional formats I created into 6 additional cells, and then edit the cell references to the coordinating cells in the data entry sheet, it changes all the cell references in all the "painted" formats. Is there a way to turn this off, or do I just have to write each conditional format independently?
Thanks for your help!
Hi, I have a question.
I have an excel spreadsheet that I am trying to compare pricing on.
So I have all the information of the vendor, product description, etc. In column L I have the price that the vendor charged us for that product. Each product description has a different contract price. However, the vendor does not always charge us the correct contract price. Is there anyway to apply this type of conditional formatting to a spreadsheet like this? Below is close to what my columns show.
Invoice # Number/SUPC Item Desc Purchase(cs) Vendor Price
5011210 157048861 PIE 2 cases $49.38
So the vendor charged us $49.38 per case, but we should have only been charged $49.11 per case.
Does this make sense as to what I am asking? I am having to go through this manually over 10,000 line items. Every lime item could be different though. I know excel has the tools and technique to help me with this, I am just not sure what formula to use.
Any help or suggestions would be greatly appreciated!
HI,
I just need to get an formula if week cover is higher than 3 how I can block the cell in CTN,so that others cant input anything in that cell.
Dept Article UPC Description Pac WHS CTN IN CTN IN SINGLES STR STK Incl Tst Avg Sale Week Cover
F02 20001578 62886 CRINKLE CUT CHIPS 12 600 50.00 0 31 31 4.15 7.46
F02 20002307 343121 CHUNKY COD FISH FINGERS 12 2076 173.00 0 28 28 5.76 4.87
F02 20002345 323796 STRAIGHT CUT CHIPS 12 1128 94.00 0 8 8 3.03 2.64
kindly covert all this in excel and let me know the fromula
I forgot to mention that the number 34 is the raw value I am using as a divisor. This value can change. For example it can be a 12 or 15 or whatever number.
I have a question.
I have this formula.
(ROUND(MROUND((RAND()*(99-75)+75), (100/34)),0) which correctly returns a random value between 75 and 100. However, I want it to return a value that does not equal 100. I am a bit stuck on this one. So for example, it will return a whole number but it will round the value up to 100 on some trials. That is not good. How can I reconfigure this forumla to react properly? Thanks.
Hi Svetlana,
I have a table with some name positions and values for them in 3 currencyes ($, Euro, GPB)
Have already made a function that whenever I select one of the currency to bring the value just for the respective currency that I have selected. The problem is that it will bring just the value.
Is there any format function that when I select the currency type to format the cell in (either $, E, or GPB - what I selected), so that it will not birng only the value that I need, but to be formated and contain the currency?
Many thanks
Hi Vladimir,
It's difficult to advise anything without seeing your formula. In most cases, you can use the concatenation operator, like this:
=IF(A1="$", B1&"$", "")
or
=IF(A1="$", B1&A1, "")
Dear Svetlana
Looking at all of these posts you certainly do know your stuff!
I need to use duplicate conditional formatting to identify duplicates within a single column, however, I want this to apply to certain cells within the column, so E1-E3, then to start again at E4-E11 etc. I have ~1500 rows of data. The range of cells I want it to perform this on is dependent upon values in another column, which always start at 1 and increase in ones i.e.1,2,3 etc. I want the conditional formatting to start again every time it comes across a 1 for the second time within the other column:
Presentation Chosen box
1 4
2 10
1 4
2 6
3 8
Here, Excel should not highlight the two cells containing '4', as these are within separate ranges (range 1: 1,2; range 2: 1,2,3). I only want it to identify duplicates within the range of cells depending on the values in column 'presentation'.
I am not sure if this can be done. I have searched for a few hours and read various posts but it is looking bleak.
Many thanks in advance, Claire
Hi... I have to perform conditional formatting on a particular column, which should display the numbers entered into it, in 3 decimal format.
My Condition is such that, a cell say example : E5, has some product name "ABCD", based on this text, column of say for example 50cells, has to display the data entered into it in decimal format, for example : 5 decimal places....If the product name differs, the decimal format has to change as per the product.. Product is an electronic product, each product provides output in decimal format of different decimal places(5, 4, 3, 2, etc,.).
Hello,
I am hoping you can help me with a question I have in regards to conditional formatting a cell.
I am try to conditional format cell D3 so that it is green if it is more than 50%>B3*20, red if it is <B3*20, and yellow in between.
Is this possible?
Thanks,
Jackie
Hi Jackie,
Here are the green and red formulas as per your conditions:
Green (if D3 is more than 50% greater than B3*20): =D3-(B3*20)/B3*20>50%
Red (if D3 is less than B3*20): =D3<B3*20
And exactly what "in between" means? :)
Thank you so much! :)
There is no in between.
Hi Svetlana,
First thanks for clear and more useful data u explained me to learn from this site.
Please clear this my problem if you can.
Problem:
In Jan'08 month I spend $2000 for on marketing and I earned $200 each month till jan'2010.
And I continue spending more every month till 2015.
Now I want to highlight the month where my spend reached break even or my budget.
For example: my spend $2000 reached in Aug'09 month.
Please let me know if you understand my problem.
Thanks & Regards
Satish.V
Hello!
I'm working on a sheet. In my G Column I have whether the task is "Resolved" Or not.
The two options are either yes, or no.
Columns A-F is the corresponding information for that task. Each row is a different task.
I can get Column G to go green for yes and red for no, but I can't get the corresponding information in rows A-F go green or red for the corresponding Yes/No in Column G. What is the formula I should be using here?
Thank you for your help!!
Julia
Hi Julia,
You use the same formulas as you used to highlight column G but apply the rule to columns A-F, e.g. A2:F100. Given that row 2 is your first row with data, not including the column headers.
Hello Svetlana,
I am creating a workbook to track and rank various statistics for my office's summer golf league. I am running into a handful of formatting snags.
Some of the stuff that I want to do is a bit more complex than I anticipated but I know it can be done in Excel. My hope is that the workbook can very automated with regards to data input.
Please contact me if you are still available......I see the last post was from almost 1 year ago.
Thank you so much for your time.
Brad Sanok
Oh.....
I must have been looking at the first post :/
Hi Svetlana,
=MATCH(TRIM($Q2),A:A,0)
why does this return the correct cell number where the match is at, as to this
=MATCH(TRIM($Q2),A2:A350,0) or =MATCH(TRIM($Q4),$A$2:$A$350,0)
when using either of the above it makes the cell value off by 1. i.e. the actual cell where value is at: 3 but returns: 2
thanks so much
great stuff!!
BE
I have a list of different items (food menu) to cook, and on monthly basis I want to select from the list. but if I entered a manual item (that is not listed in the list) it should be a different colored text. I cant get result. I don't know how it could be.
Please help
Thanks Svetlana,
Yes, that's exactly what I typed, before it got mangled :)
Originally it applied to the whole column ($E:$E), but I changed it to E2:E1000. This made no difference.
The E column is composed of values obtained by a vlookup() from another sheet. Will this mess things up?
Thanks
Nick
Nick,
In theory, this should make no difference, unless the numbers are formatted as text. Anyway, if you can send me your sample sheet (support@ablebits.com), we will try to figure that thing out. I am curious to know why it does not work on your data :)
Just an afterthought. Did you check the formula after changing the applied range? Excel sometimes changes the references as it thinks is appropriate, so please double check.
Hi,
I'm trying to highlight cells in one column where they differ from the corresponding cell in another column.
So if E2C2, I want it highlighted, similarly if E3C3 etc. I've tried applying a rule to all of column E using the formula "=$E2$C2" (there are headers in row 1), but this produces random results. I've tried changing the fixed portion of the cell reference - E$2, $E$2, etc, but none of them works as expected.
Can I do what I'm trying to do, or am I approaching it the wrong way?
Thanks
Nick
The comments function has swallowed the symbols. Originally this said "if E2 not equals C2" using chevrons, etc.
Hi Nick,
I believe you meant =$E2<>$C2 (formulas often get messed up after posting, sorry for that).
This is a correct formula and I can think of just one reason for it not working - a rule is applied to a wrong range. Please open the Rule Manager and check if it applies to the range beginning with cell E2.