Excel logical operators: equal to, not equal to, greater than, less than

Many tasks you perform in Excel involve comparing data in different cells. For this, Microsoft Excel provides six logical operators, which are also called comparison operators. This tutorial aims to help you understand the insight of Excel logical operators and write the most efficient formulas for your data analysis.

Excel logical operators - overview

A logical operator is used in Excel to compare two values. Logical operators are sometimes called Boolean operators because the result of the comparison in any given case can only be either TRUE or FALSE.

Six logical operators are available in Excel. The following table explains what each of them does and illustrates the theory with formula examples.

Condition Operator Formula Example Description
Equal to = =A1=B1 The formula returns TRUE if a value in cell A1 is equal to the values in cell B1; FALSE otherwise.
Not equal to <> =A1<>B1 The formula returns TRUE if a value in cell A1 is not equal to the value in cell B1; FALSE otherwise.
Greater than > =A1>B1 The formula returns TRUE if a value in cell A1 is greater than a value in cell B1; otherwise it returns FALSE.
Less than < =A1<B1 The formula returns TRUE if a value in cell A1 is less than in cell B1; FALSE otherwise.
Greater than or equal to >= =A1>=B1 The formula returns TRUE if a value in cell A1 is greater than or equal to the values in cell B1; FALSE otherwise.
Less than or equal to <= =A1<=B1 The formula returns TRUE if a value in cell A1 is less than or equal to the values in cell B1; FALSE otherwise.

The screenshot below demonstrates the results returned by Equal to, Not equal to, Greater than and Less than logical operators:
Using Equal to, Not equal to, Greater than and Less than in Excel

It may seem that the above table covers it all and there's nothing more to talk about. But in fact, each logical operator has its own specificities and knowing them can help you harness the real power of Excel formulas.

Using "Equal to" logical operator in Excel

The Equal to logical operator (=) can be used to compare all data types - numbers, dates, text values, Booleans, as well as the results returned by other Excel formulas. For example:

=A1=B1 Returns TRUE if the values in cells A1 and B1 are the same, FALSE otherwise.
=A1="oranges" Returns TRUE if cells A1 contain the word "oranges", FALSE otherwise.
=A1=TRUE Returns TRUE if cells A1 contain the Boolean value TRUE, otherwise it returns FALSE.
=A1=(B1/2) Returns TRUE if a number in cell A1 is equal to the quotient of the division of B1 by 2, FALSE otherwise.

Example 1. Using the "Equal to" operator with dates

You might be surprised to know that the Equal to logical operator cannot compare dates as easily as numbers. For example, if the cells A1 and A2 contain the date "12/1/2014", the formula =A1=A2 will return TRUE exactly as it should.

However, if you try either =A1=12/1/2014 or =A1="12/1/2014" you will get FALSE as the result. A bit unexpected, eh?

The point is that Excel stores dates as numbers beginning with 1-Jan-1900, which is stored as 1. The date 12/1/2014 is stored as 41974. In the above formulas, Microsoft Excel interprets "12/1/2014" as a usual text string, and since "12/1/2014" is not equal to 41974, it returns FALSE.

To get the correct result, you must always wrap a date in the DATEVALUE function, like this =A1=DATEVALUE("12/1/2014")
Using Excel's equal to operator with dates

Note. The DATEVALUE function needs to be used with other logical operator as well, as demonstrated in the examples that follow.

The same approach should be applied when you use Excel's equal to operator in the logical test of the IF function. You can find more info as well as a few formula examples in this tutorial: Using Excel IF function with dates.

Example 2. Using the "Equal to" operator with text values

Using Excel's Equal to operator with text values does not require any extra twists. The only thing you should keep in mind is that the Equal to logical operator in Excel is case-insensitive, meaning that case differences are ignored when comparing text values.

For example, if cell A1 contains the word "oranges" and cell B1 contains "Oranges", the formula =A1=B1 will return TRUE.

If you want to compare text values taking in to account their case differences, you should use the EXACT function instead of the Equal to operator. The syntax of the EXACT function is as simple as:

EXACT(text1, text2)

Where text 1 and text2 are the values you want to compare. If the values are exactly the same, including case, Excel returns TRUE; otherwise, it returns FALSE. You can also use the EXACT function in IF formulas when you need a case-sensitive comparison of text values, as shown in the below screenshot:
Using the EXACT function for case-sensitive comparison of text values

Note. If you want to compare the length of two text values, you can use the LEN function instead, for example =LEN(A2)=LEN(B2) or =LEN(A2)>=LEN(B2).

Example 3. Comparing Boolean values and numbers

There is a widespread opinion that in Microsoft Excel the Boolean value of TRUE always equates to 1 and FALSE to 0. However, this is only partially true, and the key word here is "always" or more precisely "not always" : )

When writing an 'equal to' logical expression that compares a Boolean value and a number, you need to specifically point out for Excel that a non-numeric Boolean value should be treated as a number. You can do this by adding the double minus sign in front of a Boolean value or a cell reference, e. g. =A2=--TRUE or =A2=--B2.

The 1st minus sign, which is technically called the unary operator, coerces TRUE/FALSE to -1/0, respectively, and the second unary negates the values turning them into +1 and 0. This will probably be easier to understand looking at the following screenshot:
Comparing Boolean values and numbers

Note. You should add the double unary operator before a Boolean when using other logical operators such as not equal to, greater than or less than to correctly compare a numeric and Boolean values.

When using logical operators in complex formulas, you might also need to add the double unary before each logical expression that returns TRUE or FALSE as the result. Here's an example of such a formula: SUMPRODUCT and SUMIFS in Excel.

Using "Not equal to" logical operator in Excel

You use Excel's Not equal to operator (<>) when you want to make sure that a cell's value is not equal to a specified value. The use of the Not equal to operator is very similar to the use of Equal to that we discussed a moment ago.

The results returned by the Not equal to operator are analogous to the results produced by the Excel NOT function that reverses the value of its argument. The following table provides a few formula examples.

Not equal to operator NOT function Description
=A1<>B1 =NOT(A1=B1) Returns TRUE if the values in cells A1 and B1 are not the same, FALSE otherwise.
=A1<>"oranges" =NOT(A1="oranges") Returns TRUE if cell A1 contains any value other than "oranges", FALSE if it contains "oranges" or "ORANGES" or "Oranges", etc.
=A1<>TRUE =NOT(A1=TRUE) Returns TRUE if cell A1 contains any value other than TRUE, FALSE otherwise.
=A1<>(B1/2) =NOT(A1=B1/2) Returns TRUE if a number in cell A1 is not equal to the quotient of the division of B1 by 2, FALSE otherwise.
=A1<>DATEVALUE("12/1/2014") =NOT(A1=DATEVALUE("12/1/2014")) Returns TRUE if A1 contains any value other than the date of 1-Dec-2014, regardless of the date format, FALSE otherwise.

Greater than, less than, greater than or equal to, less than or equal to

You use these logical operators in Excel to check how one number compares to another. Microsoft Excel provides 4 comparison operates whose names are self-explanatory:

  • Greater than (>)
  • Greater than or equal to (>=)
  • Less than (<)
  • Less than or equal to (<=)

Most often, Excel comparison operators are used with numbers, date and time values. For example:

=A1>20 Returns TRUE if a number in cell A1 is greater than 20, FALSE otherwise.
=A1>=(B1/2) Returns TRUE if a number in cell A1 is greater than or equal to the quotient of the division of B1 by 2, FALSE otherwise.
=A1<DATEVALUE("12/1/2014") Returns TRUE if a date in cell A1 is less than 1-Dec-2014, FALSE otherwise.
=A1<=SUM(B1:D1) Returns TRUE if a number in cell A1 is less than or equal to the sum of values in cells B1:D1, FALSE otherwise.

Using Excel comparison operators with text values

In theory, you can also use the greater than, greater than or equal to operators as well as their less than counterparts with text values. For example, if cell A1 contains "apples" and B1 contains "bananas", guess what the formula =A1>B1 will return? Congratulations to those who've staked on FALSE : )

When comparing text values, Microsoft Excel ignores their case and compares the values symbol by symbol, "a" being considered the lowest text value and "z" - the highest text value.

So, when comparing the values of "apples" (A1) and "bananas" (B1), Excel starts with their first letters "a" and "b", respectively, and since "b" is greater than "a", the formula =A1>B1 returns FALSE.

If the first letters are the same, then the 2nd letters are compared, if they happen to be identical too, then Excel gets to the 3rd, 4th letters and so on. For example, if A1 contained "apples" and B1 contained "agave", the formula =A1>B1 would return TRUE because "p" is greater than "g".
Using Excel comparison operators with text values

At first sight, the use of comparison operators with text values seems to have very little practical sense, but you never know what you might need in the future, so probably this knowledge will prove helpful to someone.

Common uses of logical operators in Excel

In real work, Excel logical operators are rarely used on their own. Agree, the Boolean values TRUE and FALSE they return, though very true (excuse the pun), are not very meaningful. To get more sensible results, you can use logical operators as part of Excel functions or conditional formatting rules, as demonstrated in the below examples.

1. Using logical operators in arguments of Excel functions

When it comes to logical operators, Excel is very permissive and allows using them in parameters of many functions. One of the most common uses is found in Excel IF function where the comparison operators can help to construct a logical test, and the IF formula will return an appropriate result depending on whether the test evaluates to TRUE or FALSE. For example:

=IF(A1>=B1, "OK", "Not OK")

This simple IF formula returns OK if a value in cell A1 is greater than or equal to a value in cell B1, "Not OK" otherwise.

And here's another example:

=IF(A1<>B1, SUM(A1:C1), "")

The formula compares the values in cells A1 and B1, and if A1 is not equal to B1, the sum of values in cells A1:C1 is returned, an empty string otherwise.

Excel logical operators are also widely used in special IF functions such as SUMIF, COUNTIF, AVERAGEIF and their plural counterparts that return a result based on a certain condition or multiple conditions.

You can find a wealth of formula examples in the following tutorials:

2. Using Excel logical operators in mathematical calculations

Of course, Excel functions are very powerful, but you don't always have to use them to achieve the desired result. For example, the results returned by the following two formulas are identical:

IF function: =IF(B2>C2, B2*10, B2*5)

Formula with logical operators: =(B2>C2)*(B2*10)+(B2<=C2)*(B2*5)
Using Excel logical operators in mathematical calculations

I guess the IF formula is easier to interpret, right? It tells Excel to multiply a value in cell B2 by 10 if B2 is greater than C2, otherwise the value in B1 is multiplied by 5.

Now, let's analyze what the 2nd formula with the greater than and less than or equal to logical operators does. It helps to know that in mathematical calculations Excel does equate the Boolean value TRUE to 1, and FALSE to 0. Keeping this in mind, let's see what each of the logical expressions actually returns.

If a value in cell B2 is greater than a value in C2, then the expression B2>C2 is TRUE, and consequently equal to 1. On the other hand, B2<=C2 is FALSE and equal to 0. So, given that B2>C2, our formula undergoes the following transformation:
Formula with logical operators

Since any number multiplied by zero gives zero, we can cast away the second part of the formula after the plus sign. And because any number multiplied by 1 is that number, our complex formula turns into a simple =B2*10 that returns the product of multiplying B2 by 10, which is exactly what the above IF formula does : )

Obviously, if a value in cell B2 is less than in C2, then the expression B2>C2 evaluates to FALSE (0) and B2<=C2 to TRUE (1), meaning that the reverse of the described above will occur.

3. Logical operators in Excel conditional formatting

Another common use of logical operators is found in Excel Conditional Formatting that lets you quickly highlight the most important information in a spreadsheet.

For example, the following simple rules highlight selected cells or entire rows in your worksheet depending on a value in column A:

Less than (orange): =A1<5

Greater than (green): =A1>20
Using logical operator in Excel conditional formatting

For the detailed-step-by-step instructions and rule examples, please see the following articles:

As you see, the use of logical operators in Excel is intuitive and easy. In the next article, we are going to learn the nuts and bolts of Excel logical functions that allow performing more than one comparison in a formula. Please stay tuned and thank you for reading!

1248 comments

  1. -Svetlana,
    Great site- thanks for such a great resource!
    I'm trying to create formula to show when a cell/number/Sum is higher than 42.5, then show that number in decimals. Can you help please?

    • Hi Fred,

      Thank you for your kind words. I am not sure I fully understand your goal. Do you want to display no decimal places for numbers less than 42.5 and a certain number of decimal places, say 2, for numbers greater than 42.5? If so, you can use a formula similar to this:

      =IF(A1<=42.5, ROUND(A1,0), ROUND(A1,2))

      Instead of ROUND you can use any other Rounding function as your business logic requires.

      If you are looking for something different, please clarify.

  2. Hi Svetlana,
    Please help me.. my requirement are:
    condition=> =if(and(z9>=j10,z9 z10=i10
    or else=> z10="v"

    my current formula is =if(and(z9>=j10,z9<=k10),"wd","v"))

    where it is fine, but I want to reconstruct that "wd" or cell value appear to z10 is dependent to cell value of i10 (where I can enter either "wd" or "wn" from cell i10 but will appear to z10 once satisfy the condition if.

    Please note z9,j10,k10 are date format; and z10,i10 are text format.

    Many thanks!
    Marlone

    • Hi Svetlana,
      Good day!
      I figured it out the correct syntax that I needed. I inspired with this blog and reviewed old comments until I got an idea and executed it, then it works...Good luck and thanks, you have a very helpful blog!

      Thanks and Regards!

  3. Hi Svetlana,
    i need when:
    h2>8 and i2>123900 then k2give (good)
    h2=8 and i2=123900 then k2 give(ok)
    h2<8 and i2<123900 then k2 give (0)
    many thanks

    • Hi Majed,

      Here's the formula for K2:

      =IF(AND(H2>8, I2>123900),"good", IF(AND(H2=8,I2=123900), "OK", IF(AND(H2<8,I2<123900), 0, "")))

  4. how to add farmula
    if B3>12 then + 500 ???
    how ???????
    kindly make farmula

    • Hi Benson,

      You can use a formula similar to this:

      =IF(B3>12, B3+500, "")

  5. Hi Svetlana,

    The values of column Q are 100, 99.71, 99.21, 94.99, 80.00 & in some places it is <70.
    I want the result in column R like, IF Q=100, R = 2, IF Q is b/w 99.99 to 99.50, R = 1.6. If Q is b/w 99.49 to 95.00, R = 1.2. IF Q is b/w 94.99 to 90.00, R = 0.8. If Q is <70 then R = 0.

    Please help me with the formula to capture the required value.

    • Hello Shashikumar,

      You can use the following nested If functions:

      =IF(Q1>=100,2, IF(Q1>=99.5, 1.6, IF(Q1>=95,1.2, IF(Q1>=90, 0.8, IF(Q1 >=70,0.6,0)))))

      You didn't not specify R for Q b/w 70 to 89.99, and I added 0.6. Just replace it with the right value in the last IF statement.

  6. Hi Sveltana,
    I am trying to match with an if function the foloowing:
    if (item1=y,"y","n")
    But then I'm getting error Name?

    Thanks,

    Item 1 Item 2
    Y
    Y
    Y
    Y
    Y
    Y
    Y

    • Hi Mona,

      Try the following formula:

      =IF(A2="y", "y", "n")

      Where A2 is the first cell of the Item 1 column.

  7. l need help on if the value greater than 50 subtract 30 and is less than 50 add 10

  8. My comments are getting broken just as yours were. I'l try again.
    For Category 1 (Greater or equal to 12500) use:
    =SUMPRODUCT(--(A:A>12499),A:A)
    For Category 2 (Greater or equal to 7500, but less than 12500) use:
    =SUMPRODUCT(--(A:A>7499),--(A:A2999),--(A:A<7500),A:A)
    These formulas will add all the data as well. The "--" identifies a function as Boolean (True or False), so that if it doesn't meet this criteria, it multiples the other values by 0, which in turn makes the total 0. Hope that makes sense and helps. I'm hoping you are familiar with the Sumproduct formula.

  9. sorry that last post did not come out right it should have said -

    11=1
    7= 2
    3=3
    <4 =4

  10. HI - WOuld really appreciate help with this pleae x
    =IF(J611,1,IF(J67,2,IF(J63,3,IF(J6<4,4))))
    What I am trying to do is if J6 is
    11 put 1 in the cell with the formula
    7 Put 2 in the cell with the formula
    3 put 3 in the cell with the formula
    <4 put 4 in the cell with the formula
    Can anyone help ?

    JO

  11. I need help with a formula for a commission grid for my sales team.

    I'm trying to get the following answer from the formula.

    IF cell G34 is less than 29939.99 = blank
    IF cell G34 is greater than 4500 - blank
    IF cell G34 is greater than 3000 but less than 4499.99, multiply G34 x D37

    Thanks in advance for your help...

    • Hi Charles,

      Try the following formula:

      =IF(AND(G34>=3000, G34<=4500), G34*D37, "")

  12. A 14
    B 23
    C 83
    D 74
    E 38

    hi, i want least 3 value with name. please help......

  13. Hi if I want a cell to display zero or - if the value is equal to or less than lets say 150, how do I do that?

  14. If the numerical value of G4 is between 0-30,then in cell I4,it should show the value of D4,or 0.How to put the formula in I4.
    Thanks

  15. Hi i have the follwoing excel exercise and i need assistance;

    1.Number Student passes B5=40,B6=25,B7=32,B8=48
    2.Life guards allocations are as follows;

    Student pass ranges: 0-30 = 2 life guards, 31-60= 4 life guards,61-90= 6 life guards,150+ = 12 life guards

    Assume the Number of Lifeguards needed in a day depends on the number of Student passes for that day as given above. Use an appropriate formula to determine the expected number of lifeguards for each day to go into a separate column called Number of lifeguards. Hint: Vlookup formula.

    Please provide the Vlookup formula or some formula i can use in my excel.Thanks a lot in advance.

  16. ----------------------- | Student |No of life|
    |Number of | Guards| |pass range| guards |
    |student passes| | ----------------------
    -----------------------| | 0-30 | 2 |
    | 40 | ? | | 31-60 | 4 |
    | 25 | ? | | 91-120 | 6 |
    | 32 | ? | | 150+ | 8 |
    | 98 | ? | | | |
    Table 2:
    Hi please assist;

    i have the following question pertaining to the above;

    Assume the Number of Lifeguards needed in a day depends on the number of Student passes for that day as given in Table 2 above. Use an appropriate formula to determine the expected number of lifeguards for each day to go into Column G. Hint: Vlookup formula.
    Please provide the Vlookup formula i can use in my excel.Thanks a lot in advance.

  17. I have 6 columns in Excel (A, B, C, D, E, F). In column A and B containing source of number. And in column C,D,E,F i want formula that comparing column A and B that is containing smaller number,Can you help me please?

    A B C D E F
    "Permissible
    10% payable "Permissible
    5% payable
    1963 -651.291 0 0 98.15 553.141
    1963 -449.040 0 0 98.15 350.89
    1963 -336.882 0 0 98.15 238.732
    1963 144.131 144.131 0 0 0
    1963 467.218 196.300 270.92 0 0
    1963 888.713 196.300 692.41 0 0
    1963 830.873 196.300 634.57 0 0
    1963 824.150 196.300 627.85 0 0
    1963 762.288 196.300 565.99 0 0
    1963 698.961 196.300 502.66 0 0
    a*10%(Positive) (B-C) prositive a*5%(Negitive) (B-E) Negitive

  18. Hi,

    I have 3 columns in Excel (A, B and C). In column A and B containing number. And in column C i want formula that comparing column A and B that is containing smaller number and then stating in what column that smaller number. Can you help me please?

    A | B | C
    ------------
    3 | 2 | .....

  19. Good afternoon!

    I have two columns (M & N) containing dollars. I need to compare the two columns and highlight at least one of them when the difference between the two columns is greater than 25%. Can you please help with a formula for this?
    Thanks!

  20. Hello I have a condition where SLA will b written as Meet o Not Meet

    And i wan a formula where i can get 95% automatically if that cell contains Meet and 0% if Not meet...

    Do we have any way to make e happen?

  21. Hi,

    If a cell is having some text & some country name then how can i get only country names in a second cell. I know the exact spell of the country name.

    • Hello Vaibhav,

      The formula depends on your data pattern. For example, i.e. all cells contain some text, followed by a single space, followed by a country name (like text USA, then you can use the following formula:
      =RIGHT(A1,LEN(A1)-LEN(LEFT(A1,FIND(" ",A1))))

      If your data has some other pattern, please provide a few examples, and we will try to work out a proper formula.

      • Hi Svetlana;

        i have the following excel exercise and i need your assistance;

        1.Number Student passes B5=40,B6=25,B7=32,B8=48
        2.Life guards allocations are as follows;

        Student pass ranges: 0-30 = 2 life guards, 31-60= 4 life guards,61-90= 6 life guards,150+ = 12 life guards

        Assume the Number of Lifeguards needed in a day depends on the number of Student passes for that day as given above. Use an appropriate formula to determine the expected number of lifeguards for each day to go into a separate column called Number of lifeguards. Hint: Vlookup formula.

        Please provide the Vlookup formula or some formula i can use in my excel.Thanks a lot in advance.

  22. Hi, comparision of more than 2 value, with shows lowest value as L1, 2nd lowest as L2 & as so on. e.g.
    A B C D
    25000 35000 24000 38000

    A L1 24000
    B L2 25000
    C L3 35000
    D L4 38000

  23. Hi. Is it possible for the value of cell a2 to equal 1 if the value of cell a1 is greater than zero but less than or equal to 50 and the same cell (a2) to equal 2 if the value of cell a1 is greater than 50 but less than or equal to 250, and so on? Thanks

  24. I need help on comparing two dates and giving a value. I am currently using =IF(AND(N2>=$B2,N2<=$C2),"1H","1E") where N2(a date) has to be greater that equal to and less than equal to dates B2 and C2.

    Please help!

  25. If Cells have a number >0 i want to equal today's date...is that possible?

  26. For example:-
    Apr May Jun Jul short / Excess
    100 0 100 100 -120

    If manual are doing then come the below value
    Apr May Jun Jul
    100 0 80 0

    I have above sheet in excel i want to use the formula in another column

    can you please provide the correct formula for using in that sheet

    also i have 12/13 column for the same, so please help and resolve

  27. Hi All,

    I had a question about whether it is possible to create an If-Then formula if the value has a "<" sign in it? What I would like is any value with a "<" to be be rid of the "<" and divided in half. For example, if the cell has "<0.05", I would like it to be "0.025". I'm dealing with values below detection limits and have a lot of them and would like to be able to do this for all 2000 cells! Any advice would be great. Thanks!

  28. can you create a formula in order to find the difference between 2 cells with only subtracting whatever is above a certain limit for once cell?

    Ex: cell 1 is 4500. Cell 2 is 1320. I want to subtract anything above 1000 (in this case it would be 320). is this possible to make a standard formula to subtract any limit that goes over 1000?

    Thanks!

  29. I need help, I have a formula that I need to figure is out - it goes like this:
    If cell B7 is 90%-94.99% then B11 should be multiplied by .25%, if cell B7 is 95%-99.99% then B11 should be multiplied by .5%, or if B7 is 100% or greater then B11 should be multiplied by .75%
    How do I write this formula?

  30. How can I make a cell blank if the succeeding date would be of the next month on an auto-compute date cell?

    Example: Last cell id February 29, 2016, the next row cell would contain March 1, 2016, and I would like to automatically make the cell for march 1 blank? What would be the formula for the March 1 cell?

    Thank you.

  31. I've been working on this problem for two days now, and I can't seem to be able to solve this problem; enter a formula in B8 to return a value of 15% if the cell B6 is greater or equal to 20,000 or 3% if it is not. What formula can I use to solve this?

  32. Dear Svetlana,

    I am trying to check the task type and if it is Admin, I want to calculate and return the rate as the number of hours multiplied by 5 and if it is not (for other tasks) I want to multiply the number of hours by 6 and return it as the rate. I wrote the following formula, by excel calls it an error:

    =if(C12=''General_Admin'', E12*5, E12*6)

    Could you please let me know what is the mistake I have made?

    Thank You in anticipation!

  33. I wrote this formula =IF(OR(F2>=3,F2<=17),H34*E34,0) I am trying to get H34*E34 to calculate if F2 is between 3 and 17 and if not to put 0 in the cell. What did I do wrong?

  34. I want to get a value greater than or equal to certain CELL VALUE from a column in form of a numeric value as added already in that cell of a column.
    Ex:
    A B C
    1 456 250 Want a only 1st value greater than 250 from A in no ?
    2 789
    3 121
    4 89

  35. Hi,
    I am trying to use the IF function to validate a number in a cell which is a calculated field. Example:

    Function within G2 field: =E2-F2
    If function: =IF(G2=0,"VALID","INVALID").

    For some reason this IF function is returning VALID no matter what the calculated value in cell G2 is.

    Additionally, the E2 and F2 fields are calculated (but working correctly), one is a VLOOKUP function returning a number, and the other returns a number based on a mathematical calculation.

    Can you please help?

  36. Hi Svetlana,

    Can you please help in creating a formula as below:

    suppose 154 days, a formula to classify 0-60, 61-120, 121-180, 181-360.

    I'm unable to create the formula =If(154>60,61120,121180,181360,"<60","61-120","121-180","181-360")

    it should be 154days 121-180

    Thanks

  37. Hello,
    I have rows of numbers, some negative some positive. I need a formula to count the value of only the negative cells and sum them up at the end of the row. Please help -thank you

  38. Have the >= and =0.93,"A",=90,"A-",=87,"B+",= 83, "B",=80,"B-",=77,"C+",=73,"C",=72, "C-", <70,"YOU FAILED")

    It's for a grade calculator, in which E24 is the grade as calculated by points earned divided by possible points. Anyone see my error? Psyched about this new SWITCH function.

    • Okay, that didn't post right...What I meant is have the = functions been incorporated into the SWITCH function yet? That formula is NOT what I had. It was a lot more complicated than that and had a lot of operators in it. Oh, well! Cest la Vie!

  39. I want to return a True or False answer if Week 4 team selection has already been selected in another Week.

    Week 1 Week 2 Week 3 Week 4 Week 5
    Liverpool Arsenal Arsenal Liverpool

  40. hello
    I need help with a formula please:
    I use a formula to calculate how much I pay for an item, that is: =(91.2/2)*2*b12*4.3. Depending on what the figure in b12 is the sum can be very high and I want to cap the result at a dollar figure of 1200. What can I use to show a result of 1200 if the sum of the formula exceeds 1200?

  41. How to find the text greater than 40 char.
    Like:-
    Shop No 01 Shree Shankar Sadan Chawdi Naka, Samelpada, Nallasopara (w) Mumbai

    I want to split it into two cells first 40 char in one cell and greater than 40 in another cell.

  42. what is the formula for "condition if F4 IS EQUAL TO OR MORE THAN 100 USE 70 OTHERWISE USE THE SAME VALUE IN F4

  43. what is the formula for "condition if Column A is more than Column B, use Column A-Column B*0.40"

  44. a1,50

  45. Tyre code Tyre desc C1 C2 C3 C4 C5 Total STK 01-02-2016 02-02-2016 03-02-2016 04-02-2016
    3IND5050810810 5.00 - 8 IT 30 8 PR TT TVS 40 20 60 80 200 22 0 0 15 35
    3IND5650810810 5.00 - 8 8PR TT MARANGONI 55 65 75 195 10
    3IND5050821010 5.00 - 8 IT 45 10 PR TT TVS 60 32 42 134 30

  46. what is the formula for "condition if Column A is more than Column B, use Column B"

    • Hi Charlie,

      You can use a formula similar to this:

      =IF(A1>B1, B1, "")

  47. HELP!!
    I am trying to find what formula I should use.

    IE:
    A B
    1 john Paris
    2 smith London
    3 rose Milan

  48. Hello friends,

    I am struggling with a formula. please help me out.

    If a cell value is greater and less then a given value then "OK" and "Not ok"

    for Example. IF cell A2 is greater then 12 but less then 22.8 . If cell A2 meet this criteria then "Ok" otherwise "Not Ok".

    Thanks

    • Hi Sumit,

      You can use the following formula:

      =IF(AND(A2>12, A2<22.8), "OK", "Not OK")

  49. HELP!!
    I am trying to find what formula I should use.

    IE:

    1-9 multiply by .07
    10-19 multiply by .08
    20-29 multiply .10
    30-39 multiply .12
    40 or greater multiply .14

  50. IF cell A=Apples and cell B10 but 20 but <30, then return cell C=500.
    IF cell A=Grapes and cell B10 but 20 but <30, then return cell C=300.

Post a comment



Thank you for your comment!
When posting a question, please be very clear and concise. This will help us provide a quick and relevant solution to
your query. We cannot guarantee that we will answer every question, but we'll do our best :)