How to use IF function in Excel: examples for text, numbers, dates, blanks

In this article, you will learn how to build an Excel IF statement for different types of values as well as how to create multiple IF statements.

IF is one of the most popular and useful functions in Excel. Generally, you use an IF statement to test a condition and to return one value if the condition is met, and another value if the condition is not met.

In this tutorial, we are going to learn the syntax and common usages of the Excel IF function, and then take a closer look at formula examples that will hopefully prove helpful to both beginners and experienced users.

IF function in Excel

IF is one of logical functions that evaluates a certain condition and returns one value if the condition is TRUE, and another value if the condition is FALSE.

The syntax of the IF function is as follows:

IF(logical_test, [value_if_true], [value_if_false])

As you see, IF takes a total of 3 arguments, but only the first one is obligatory, the other two are optional.

Logical_test (required) - the condition to test. Can be evaluated as either TRUE or FALSE.

Value_if_true (optional) - the value to return when the logical test evaluates to TRUE, i.e. the condition is met. If omitted, the value_if_false argument must be defined.

Value_if_false (optional) - the value to return when the logical test evaluates to FALSE, i.e. the condition is not met. If omitted, the value_if_true argument must be set.

Basic IF formula in Excel

To create a simple If then statement in Excel, this is what you need to do:

  • For logical_test, write an expression that returns either TRUE or FALSE. For this, you'd normally use one of the logical operators.
  • For value_if_true, specify what to return when the logical test evaluates to TRUE.
  • For value_if_false, specify what to return when the logical test evaluates to FALSE. Though this argument is optional, we recommend always configuring it to avoid unexpected results. For the detailed explanation, please see Excel IF: things to know.

As an example, let's write a very simple IF formula that checks a value in cell A2 and returns "Good" if the value is greater than 80, "Bad" otherwise:

=IF(B2>80, "Good", "Bad")

This formula goes to C2, and then is copied down through C7: Basic IF formula in Excel.

In case you wish to return a value only when the condition is met (or not met), otherwise - nothing, then use an empty string ("") for the "undefined" argument. For example:

=IF(B2>80, "Good", "")

This formula will return "Good" if the value in A2 is greater than 80, a blank cell otherwise: IF formula to return nothing when the condition is not met.

Excel If then formula: things to know

Though the last two parameters of the IF function are optional, your formula may produce unexpected results if you don't know the underlying logic.

If value_if_true is omitted

If the 2nd argument of your Excel IF formula is omitted (i.e. there are two consecutive commas after the logical test), you'll get zero (0) when the condition is met, which makes no sense in most cases. Here is an example of such a formula:

=IF(B2>80, , "Bad")

To return a blank cell instead, supply an empty string ("") for the second parameter, like this:

=IF(B2>80, "", "Bad")

The screenshot below demonstrates the difference: The behavior of the value_if_true argument.

If value_if_false is omitted

Omitting the 3rd parameter of IF will produce the following results when the logical test evaluates to FALSE.

If there is just a closing bracket after value_if_true, the IF function will return the logical value FALSE. Quite unexpected, isn't it? Here is an example of such a formula:

=IF(B2>80, "Good")

Typing a comma after the value_if_true argument will force Excel to return 0, which doesn't make much sense either:

=IF(B2>80, "Good",)

The most reasonable approach is using a zero-length string ("") to get a blank cell when the condition is not met:

=IF(B2>80, "Good", "") The behavior of the value_if_false argument.

Tip. To return a logical value when the specified condition is met or not met, supply TRUE for value_if_true and FALSE for value_if_false. For the results to be Boolean values that other Excel functions can recognize, don't enclose TRUE and FALSE in double quotes as this will turn them into normal text values.

Using IF function in Excel - formula examples

Now that you are familiar with the IF function's syntax, let's look at some formula examples and learn how to use If then statements in real-life scenarios.

Excel IF function with numbers

To build an IF statement for numbers, use logical operators such as:

  • Equal to (=)
  • Not equal to (<>)
  • Greater than (>)
  • Greater than or equal to (>=)
  • Less than (<)
  • Less than or equal to (<=)

Above, you have already seen an example of such a formula that checks if a number is greater than a given number.

And here's a formula that checks if a cell contains a negative number:

=IF(B2<0, "Invalid", "")

For negative numbers (which are less than 0), the formula returns "Invalid"; for zeros and positive numbers - a blank cell. A formula to check if a cell contains a negative number.

Excel IF function with text

Commonly, you write an IF statement for text values using either "equal to" or "not equal to" operator.

For example, the following formula checks the Delivery Status in B2 to determine whether an action is required or not:

=IF(B2="delivered", "No", "Yes")

Translated into plain English, the formula says: return "No" if B2 is equal to "delivered", "Yes" otherwise. Using the IF function with text.

Another way to achieve the same result is to use the "not equal to" operator and swap the value_if_true and value_if_false values:

=IF(C2<>"delivered", "Yes", "No")

Notes:

  • When using text values for IF's parameters, remember to always enclose them in double quotes.
  • Like most other Excel functions, IF is case-insensitive by default. In the above example, it does not differentiate between "delivered", "Delivered", and "DELIVERED".

Case-sensitive IF statement for text values

To treat uppercase and lowercase letters as different characters, use IF in combination with the case-sensitive EXACT function.

For example, to return "No" only when B2 contains "DELIVERED" (the uppercase), you'd use this formula:

=IF(EXACT(B2,"DELIVERED"), "No", "Yes") Case-sensitive IF statement for text values.

If cell contains partial text

In situation when you want to base the condition on partial match rather than exact match, an immediate solution that comes to mind is using wildcards in the logical test. However, this simple and obvious approach won't work. Many functions accept wildcards, but regrettably IF is not one of them.

A working solution is to use IF in combination with ISNUMBER and SEARCH (case-insensitive) or FIND (case-sensitive).

For example, in case "No" action is required both for "Delivered" and "Out for delivery" items, the following formula will work a treat:

=IF(ISNUMBER(SEARCH("deliv", B2)), "No", "Yes") IF cell contains partial text.

For more information, please see:

Excel IF statement with dates

At first sight, it may seem that IF formulas for dates are akin to IF statements for numeric and text values. Regrettably, it is not so. Unlike many other functions, IF does recognize dates in logical tests and interprets them as mere text strings. In other words, you cannot supply a date in the form of "1/1/2020" or ">1/1/2020". To make the IF function recognize a date, you need to wrap it in the DATEVALUE function.

For example, here's how you can check if a given date is greater than another date:

=IF(B2>DATEVALUE("7/18/2022"), "Coming soon", "Completed")

This formula evaluates the dates in column B and returns "Coming soon" if a game is scheduled for 18-Jul-2022 or later, "Completed" for a prior date. Excel IF statement with dates.

Of course, there is nothing that would prevent you from entering the target date in a predefined cell (say E2) and referring to that cell. Just remember to lock the cell address with the $ sign to make it an absolute reference. For instance:

=IF(B2>$E$2, "Coming soon", "Completed")

To compare a date with the current date, use the TODAY() function. For example:

=IF(B2>TODAY(), "Coming soon", "Completed")

Excel IF statement for blanks and non-blanks

If you are looking to somehow mark your data based on a certain cell(s) being empty or not empty, you can either:

  • Use the IF function together with ISBLANK, or
  • Use the logical expressions ="" (equal to blank) or <>"" (not equal to blank).

The table below explains the difference between these two approaches with formula examples.

  Logical test Description Formula Example
Blank cells =""

Evaluates to TRUE if a cell is visually empty, even if it contains a zero-length string.

Otherwise, evaluates to FALSE.

 =IF(A1="", 0, 1)

Returns 0 if A1 is visually blank. Otherwise returns 1.

If A1 contains an empty string (""), the formula returns 0.
ISBLANK()

Evaluates to TRUE is a cell contains absolutely nothing - no formula, no spaces, no empty strings.

Otherwise, evaluates to FALSE.

 =IF(ISBLANK(A1), 0, 1)

Returns 0 if A1 is absolutely empty, 1 otherwise.

If A1 contains an empty string (""), the formula returns 1.
Non-blank cells <>"" Evaluates to TRUE if a cell contains some data. Otherwise, evaluates to FALSE.

Cells with zero-length strings are considered blank.

 =IF(A1<>"", 1, 0)

Returns 1 if A1 is non-blank; 0 otherwise.

If A1 contains an empty string, the formula returns 0.
ISBLANK()=FALSE Evaluates to TRUE if a cell is not empty. Otherwise, evaluates to FALSE.

Cells with zero-length strings are considered non-blank.

 =IF(ISBLANK(A1)=FALSE, 0, 1)

Works the same as the above formula, but returns 1 if A1 contains an empty string.

And now, let's see blank and non-blank IF statements in action. Suppose you have a date in column B only if a game has already been played. To label the completed games, use one of these formulas:

=IF(B2="", "", "Completed")

=IF(ISBLANK(B2), "", "Completed")

=IF($B2<>"", "Completed", "")

=IF(ISBLANK($B2)=FALSE, "Completed", "")

In case the tested cells have no zero-length strings, all the formulas will return exactly the same results: IF statement for blank and non-blank cells.

Check if two cells are the same

To create a formula that checks if two cells match, compare the cells by using the equals sign (=) in the logical test of IF. For example:

=IF(B2=C2, "Same score", "") Check if two cells contain the same values.

To check if the two cells contain same text including the letter case, make your IF formula case-sensitive with the help of the EXACT function.

For instance, to compare the passwords in A2 and B2, and returns "Match" if the two strings are exactly the same, "Do not match" otherwise, the formula is:

=IF(EXACT(A2, B2), "Match", "Don't match") Case-sensitive IF formula to check if two cells match.

IF then formula to run another formula

In all of the previous examples, an Excel IF statement returned values. But it can also perform a certain calculation or execute another formula when a specific condition is met or not met. For this, embed another function or arithmetic expression in the value_if_true and/or value_if_false arguments.

For example, if B2 is greater than 80, we'll have it multiplied by 7%, otherwise by 3%:

=IF(B2>80, B2*7%, B2*3%) IF formula that runs another formula.

Multiple IF statements in Excel

In essence, there are two ways to write multiple IF statements in Excel:

  • Nesting several IF functions one into another
  • Using the AND or OR function in the logical test

Nested IF statement

Nested IF functions let you place multiple IF statements in the same cell, i.e. test multiple conditions within one formula and return different values depending on the results of those tests.

Assume your goal is to assign different bonuses based on the score:

  • Over 90 - 10%
  • 90 to 81 - 7%
  • 80 to 70 - 5%
  • Less than 70 - 3%

To accomplish the task, you write 3 separate IF functions and nest them one into another like this:

=IF(B2>90, 10%, IF(B2>=81, 7%, IF(B2>=70, 5%, 3%))) Nested IF statement.

For more formula examples, please see:

Excel IF statement with multiple conditions

To evaluate several conditions with the AND or OR logic, embed the corresponding function in the logical test:

For example, to return "Pass" if both scores in B2 and C2 are higher than 80, the formula is:

=IF(AND(B2>80, C2>80), "Pass", "Fail")

To get "Pass" if either score is higher than 80, the formula is:

=IF(OR(B2>80, C2>80), "Pass", "Fail") Excel IF statement with multiple conditions.

For full details, please visit:

If error in Excel

Starting from Excel 2007, we have a special function, named IFERROR, to check formulas for errors. In Excel 2013 and higher, there is also the IFNA function to handle #N/A errors.

And still, there may be some circumstances when using the IF function together with ISERROR or ISNA is a better solution. Basically, IF ISERROR is the formula to use when you want to return something if error and something else if no error. The IFERROR function is unable to do that as it always returns the result of the main formula if it isn't an error.

For example, to compare each score in column B against the top 3 scores in E2:E4, and return "Yes" if a match is found, "No" otherwise, you enter this formula in C2, and then copy it down through C7:

=IF(ISERROR(MATCH(B2, $E$2:$E$4, 0)), "No", "Yes" ) If error formula in Excel.

For more information, please see IF ISERROR formula in Excel.

Hopefully, our examples have helped you get a grasp of the Excel IF basics. I thank you for reading and hope to see you on our blog next week!

Practice workbook

Excel IF statement - formula examples (.xlsx file)

Table of contents

4731 comments

  1. My formula is used to do education tracking for work:

    {=MAX(IF('Raw Data'!$A$2:$A$19997=$C$31,(IF('Raw Data'!$I$2:$I$19997='Course Names'!E47,'Raw Data'!$L$2:$L$19997))))}

    It worked great when there was only one course per requirement. Now there are 4+ course names per requirement. I was wondering if it is possible to modify the 'Course Names'!E47 part of the formula to have multiple courses to draw the most current date from.

    I tried 'Course Names'!E47:E53 But it keeps giving me a #N/A error now. Unless I drop it down to one course. I suppose I could list every single course but that could get quite large and I try to keep the readout to one page for ease of use for the manager.

    I am using Excel 2016.

    ANy help would be greatly appreciated.

    • Hi!
      It is very difficult to understand a formula that contains unique references to your workbook worksheets. If I understand your task correctly, this article can help you: MAX IF in Excel to get highest value with conditions.

      Instead of $I$2:$I$19997=E47 use OR($I$2:$I$19997=E47,$I$2:$I$19997=E48,$I$2:$I$19997=E49,$I$2:$I$19997=E50 ......)
      If this is not what you wanted, please describe the problem in more detail.

      • Hi Alexander,
        I was able to modify my formula using part of the article listed. Thank you for your help the formula works great now with multiple search parameters.
        Peter

  2. Hi,
    i need to highlight the entire row if A2 has text value containing an even number at the end of it (basically it's alphanumeric). eg.. if A2 has "hrr-102" where 2 at the end is even, then it should highlight the entire row. thanks experts for your ansers.

  3. hi,

    my data: =MAX((IF(H15=H15,I15,"")),(IF(K15=K15,L15,"")),(IF(N15=N15,O15,"")),(IF(Q15=Q15,R15,"")))
    they show zero*
    i want the max number and show the alphabet rather than the number.

    DATA:
    22-001(H15) A(I15)
    22-008(K15) UR(L15)
    22-010(N15) NA(O15)
    22-032(Q15) AC(R15)

  4. Hello check this formula out and guide with the right one
    =IF(A3="printing",=500,IF(A3="photocopying",=200,IF(A3="scanning",=1000)))

    • Hi!
      Pay attention to the first paragraph of the article above. Take a close look at the syntax of the IF function.

      =IF(A3="printing",500,IF(A3="photocopying",200,IF(A3="scanning",1000,"")))

  5. excel if h7<j7<K7 it will show h7 or j7 or k7 value

  6. hi
    how do i create a command that

    it will update my latest

    example
    latest; 22-030
    day1 22-001
    day2 22-015
    day3 22-023
    day4 22-030
    day5
    day6

  7. Hi

    I want help in writing an advanced function which gives the output in week number when the existing inventory specified in the data will run out. The column header specify product title, existing inventory quantity, Sales projections from WK 1 to WK 52. The rows have the product name, and the corresponding values to the headers. Please refer to the below data for reference:

    Product A, Qty 52, WK 1 - 10 units, WK 2 - 10 units, WK 3 - 10 units, WK 4 - 12 units, WK 5 - 10 units
    Product B, Qty 65, WK 1 - 5 units, WK 2 - 10 units, WK 3 - 10 units, WK 4 - 10 units, WK 5 - 10 units, WK 6 - 10 units, WK 7 - 10 units

    I want a the output as a column in which it specifies the WK num in which the existing qty is running out.
    The answer should be like WK 5 for Product A and WK 7 for product B.

    Is this possible?

    Regards
    Bhavya Naidu

  8. Hi There,
    I need your help to fix this formula. if a colleague works more than 365 days but less than 1800 days that the number of days should multiply by 0.02. but if the colleague works more than 1095 days and less than 1800 days, then that number of days should multiply by 0.04. Above 1825 days then must multiply by 0.06
    if he works more than 2190 days then should multiply by 0.08.

    Highly appreciate your guidance
    Thanks
    Nuwan

  9. Hello!

    Im trying to place multiple functions in single formula, however, I have a roadblock which hopefully we can clear,

    My current formula is:
    =IF(I2=G2,"Completed Same Day Plotted",IF(I2G2,"Didn't Complete On Time")))

    Legend:
    I2 - Date Completed (this data is extracted and vlooked up from another report)
    G2 - Plotted Date

    The problem Im encountering is, in the source file of the Date Completed, if it appears blank, it will automatically place 0/01/1900 which will trigger the Completed Before Plotted Date.

    I'm trying to add a formula that would generate a result stating if date is 0/01/1900, it means the person is currently finishing the course or it can be reflecting as "In Progress".

    How do I do that?

    • Hello!
      Date 0/01/1900 is 0 in date format. Therefore, add another condition to your formula to check if the value is 0.

      =IF(I2=G2,”Completed Same Day Plotted”,IF(I2 > G2,”Didn’t Complete On Time”,IF(I2=0,”In Progress”))))

  10. What is the formula if I want a cell to input the following:
    If cell is
    001 input COGON
    002 input DICAYAS
    003 input DIWAN
    004 input GALAS
    005 input GULAYON
    006 input LUGDUNGAN
    007 input MINAOG
    008 input OLINGAN
    009 input ESTACA_(POB.)
    010 input BIASONG_(POB.)
    011 input BARRA_(POB.)
    012 input CENTRAL_(POB.)
    013 input MIPUTAK_(POB.)
    014 input PUNTA
    015 input SAN_JOSE
    016 input SANGKOL
    017 input SANTA_FILOMENA
    018 input SICAYAB
    019 input SINAMAN
    020 input TURNO
    021 input SANTA_ISABEL

  11. Hi I am trying to do the following with dates and it seems the if(or) does not recognise the dates as a value

    =If(or(j4="",N2<J4),G4,K4)

    J4=date
    N2=date
    G4=£
    K4=£

    I am basically trying to say if J4 date is blank then use selling price G4, If month date N2 is less than the date J4 then use new selling price K4

    any help would be appreciated

    Lorna

  12. This was awesome. I wanted to track the status of an inventory of items that move from one status to another status as they are delivered, used, and readied for removal. This will assist in visualizing the lifespan of an object by using nested if statements and using the cell value as the final "if not true" statement to keep the value present when if has a calculation change but only on the date that the change takes place. This is interesting. my formula does require the file to be opened each day, so that the date change will trigger the status calculation in the field. I am using conditional statements to color code the cells based on the values 1,2 or 3 which is assigned to the cell of the date on that line of the object based on its status which is chosen off criteria as I alter the cell information of the objects as they change status by entering the date of the change of that status, and using a null cell to keep unused rows from calculation.

    Works great.

  13. A1 is “Full”, B1 is “Not Full”, C1 returns “Full”
    A2 is “Full”, B2 is “Full”, C2 returns “Full”
    A3 is “Half Full”, B3 is “Full”, C3 returns “Half Full”
    A4 is “Not Full”, B4 is “Half Full”, C4 returns “Half Full”
    A5 is “Not Full”, B5 is “Not Full”, C5 returns “Not Full”

    As long as there is Half Full in either col A or col B, col C will return “Half full”

    Can anyone help? I can’t find a formula to return 3 end results (full/not full/half full)

    • Hello!
      If there are too many conditions, then it is better to use the CHOOSE function instead of the IF function:

      =CHOOSE(MATCH(N1,{"Not Full","Half Full","Full"},0) + MATCH(O1,{"Not Full","Half Full","Full"},0)*2, "Not Full","Full","","Half Full","","","Half Full","Full")

      I hope it’ll be helpful.

  14. I want to link a cell instead of text in value -if -true in nested if formulas. what to do

  15. Hi i have 4 letter words. In which any word starting with letter DL should show as LCC otherwise GCC . i am getting the result with following formula

    =IF(ISNUMBER(SEARCH("DL",B55)), "LCC", "GCC")

    but problem is that, if DL is third or fourth letter even though i m getting the result as LCC which i dont want

    Kindly help

      • Thank you Alexander for your promp reply and yes you solution has worked perfect

        Regards/Irfan

  16. Hi,
    my very simple formula, continues not to work;
    =if(cell ref= Yes,""", "follow up")
    for example
    =if(e5=yes, "", "follow up")

    Help :)
    Thanks Julian

  17. Hello, can someone help me please? I need to do an IF function but where true i need it to equal another cells contents, is this possible? every time i do it like this =IF(E2>0,"A2","") it keeps pulling back the words A2 and not the actual contents of A2... I may be being dumb...

    • try: =IF(E2>0,A2," ")

      you don't need quotes when referencing a cell

  18. I want to use an IF function to calculate taxes of 1% on an income more than 6250 per month.

  19. Hi! I Have the next if statement:
    =IF(C4=F4, "[] ", (IF(C4=F5, "[] ", (IF(C4=F6, "[]", "Error, please choose a correct platform")))))

    Between "[]" I want to put a cell value like this [&D5] but excel is printing the string "[&D5]".
    How can I insert the value of a cell inside a string of an if statement?

    Thank your for the post, was so usefully!

    • Hello!
      If I understand your task correctly, try the following formula:

      =IF(C4=F4,"["&D5&"] ",(IF(C4=F5,"["&D5&"] ",(IF(C4=F6,"["&D5&"] ","Error, please choose a correct platform")))))

      To learn how to concatenate a cell and symbols using the & operator, read this article.

  20. Hello. I have a query. I want to use a simple IF function and print a true or false result.

    =IF(E22>=J22,"Person A won INR ","Person B won INR ")

    In the above formula, in the statement "Person A won INR " after INR I want to print the value of the result (E22-J22)

    For example, if E22 is 200 and J22 is 100, It should print "Person A won INR 100"

      • Firstly, thanks for the reply.

        I am using the below formula but still it is complaining of invalid name error.

        =IF(E22>=J22,”Person A WON INR“& " " &G38,”Person B WON INR“& " " &G39)

        G38 has value for E22-J22
        G39 has value for J22-E22.

        Could you please help to point out what is the mistake in the above formula.

      • Please ignore my last reply. It is resolved now. Thanks a lot for the quick response Alexander :)

  21. Need a formula for
    if C3 = number then D# = a name

    I can change or make a master of names to pull from

    • Hello!
      You can use the VLOOKUP function to extract the name by number. See this article for examples and instructions.
      I hope it’ll be helpful. If something is still unclear, please feel free to ask.

  22. Sir, let me apologize ahead of time for the incoherent attempt to describe the problem...

    I am attempting to have two columns that contain specific text (drop down selection) yield a result based on the multiple combination of options. I am trying to get develop a formula that uses the specific text with multiple variations results in generating new text based on the two cells. Looking below you can see there are multiple combinations that will results in RAC 1, RAC 2, RAC 3, and RAC 4.

    In short the goal is to select the probability and Severity rating then the RAC Code will auto-populate based on the available combinations.

    Probability Severity RAC Code
    I Catastrophic (A) Frequent RAC 1
    I Catastrophic (B) Likely RAC 1
    (II) Critical (A) Frequent RAC 1
    (I) Catastrophic (C) Occasional RAC 2
    (I) Catastrophic (D) Seldom RAC 2
    (II) Critical (B) Likely RAC 2
    (II) Critical (C) Occasional RAC 2
    (III) Moderate (A) Frequent RAC 2
    (III) Moderate (B) Likely RAC 2
    (III) Moderate (C) Occasional RAC 2
    I Catastrophic (E) Unlikely RAC 3
    (II) Critical (D) Seldom RAC 3
    (IV) Negligible (A) Frequent RAC 3
    (II) Critical (E) Unlikely RAC 4
    (III) Moderate (D) Seldom RAC 4
    (III) Moderate (E) Unlikely RAC 4
    (IV) Negligible (B) Likely RAC 4
    (IV) Negligible (C) Occasional RAC 4
    (IV) Negligible (D) Seldom RAC 4
    (IV) Negligible (E) Unlikely RAC 4

    This was my attempt however it populates the RAC without both cells populated.
    =IFS(AND(AND(H2="(I) Catastrophic",I2="(B) Likely"),AND(H2="(I) Catastrophic",I2="(A) Frequent"),OR(H2="(II) Critical",I2="(A) Frequent")),"RAC 1",(OR(AND(H2="(I) Catastrophic",I2="(C) Occasional"),AND(H2="(I) Catastrophic",I2="(D) Seldom"),AND(H2="(II) Critical",I2="(B) Likely"),AND(H2="(II) Critical",I2="(C) Occasional"),AND(H2="(III) Moderate",I2="(A) Frequent"),AND(H2="(III) Moderate",I2="(B) Likely"),OR(H2="(III) Moderate",I2="(C) Occasional"))),"RAC 2",(OR(AND(H2="(I) Catastrophic ",I2="(E) Unlikely"),AND(H2="(II) Critical",I2="(D) Seldom"),OR(H2="(IV) Negligible",I2="(A) Frequent "))),"RAC 3",(OR(AND(H2="(II) Critical",I2="(E) Unlikely"),AND(H2="(III) Moderate",I2="(D) Seldom"),AND(H2="(III) Moderate",I2="(E) Unlikely"), AND(H2="(IV) Negligible",I2="(B) Likely"),AND(H2="(IV) Negligible",I2="(C) Occasional"),AND(H2="(IV) Negligible",I2="(D) Seldom"),OR(H2="(IV) Negligible",I2="(E) Unlikely "))),"RAC 4")

  23. What function I will be using to perform a nested if condition between 2 excel CHAR function.

  24. Hi Albeit Team,

    Thanks for a great article. I have a range of data showing a merchant's transactions performed through a platform that we'll call FastExpress broken down in a sample below (the original data has over 10,000 entries):

    PAID_LOCAL STATUS CURRENCY AMOUNT COUNTRY_CODE CARD COMPANY
    01/04/2019 success USD 1,956.00 US Mastercard
    02/04/2019 failed USD 2,390.57 GH Mastercard
    02/04/2019 success USD 1,201.06 GB AmEx
    02/04/2019 success USD 5,201.06 GB AmEx

    The Card company takes it fees, FastEx takes theirs and then pays the merchant
    The Card company & FastEx has the below fees:

    Mastercard = 1% for local transactions (done in US) and 1.5% for foreign transactions if fees are below $200 then 2% and 2.5% respectively for fees equal to or above $200

    AmEx = 1.2% for local transactions (done in US) and 1.7% for foreign transactions if fees are below $200 then 2.2% and 2.7% respectively for fees equal to or above $200

    FastEx = 0.8% for local transactions (done in US) and 1.3% for foreign transactions if fees are below $200 then 1.8% and 2.3% respectively for fees equal to or above $200

    Please note that fees are capped at $180 maximum for local transactions

    and would like calculate how much is due to pay the Card Company, how much for FastEx and the net payment to the merchant
    Not sure if the IF function would best suit this computation as every attempt kept getting confusing and complex.

    Hoping to hear from you.
    Thanks!

  25. Hi.
    I am trying to create a formula with this information:

    If Date A - Date B (check-in and check-out date for guests) are lower than 20.6.2022 or higher than 31.8.2022 the statement is true, value should be "low" if they are between those dates (so higher than 20.6 and lower than 31.8) then "high".

    I tried:
    =IF(AND(B4=DATEVALUE("31.8.2022"), D4=DATEVALUE("31.8.2022")), "low", "high")
    But it doesn't really work. Help would be apreciated.
    Thanks in advance.

      • Hi, me again :)
        Your solution worked. Thank you.

        But what if I want to make it even more complicated.
        Instead of 2 "seasons" I want to use 3.

        So for example.
        1.4. - 20.5.2022 = low
        21.5 - 30.6.2022 = mid
        1.7 - 31.8.2022 = high
        1.9 - 30.9 = mid
        1.10 - 31.10 = low again

        I tried with IFS but it gets complicated because it has to check 2 times or maybe I'm just useless when it comes to this.
        Or maybe it can't be done.
        I would appreciate the help.
        Thanks in advance.

        • Hi!
          Use the AND and OR operators in your IF function. I recommend this guide: Excel IF statement with multiple AND/OR conditions.

          =IF(OR(AND(B4>=DATE(2022,4,1),D4<=DATE(2022,5,20)), AND(B4>=DATE(2022,10,1),D4<=DATE(2022,10,31))),"low", IF(OR(AND(B4>=DATE(2022,5,21),D4<=DATE(2022,6,20)), AND(B4>=DATE(2022,9,1),D4<=DATE(2022,9,30))),"mid", IF(AND(B4>=DATE(2022,7,1),D4<=DATE(2022,8,31)),"High","")))

          I hope this will help.

  26. Hi! Do you have any propositions for a formula that would both work for extracting the name and surname from these rows in a singe cell

    21-Feb-2022 requested by Suvarna, Rashmita21-Feb-2022 completed by dbgURL provided just too long with the coding to accept
    17-Feb-2022 Requested by Chacko, Alphonsa21-Feb-2022 Completed by SPVersion Update Request
    21-FEB-2022: Request by Alonso Nunez, Marta21-FEB-2022: Completed by BOT

    For instance, should extract Suvarna, Rashmita as a result from the first row

  27. if the amount is 350000 than bonus 100 and than amount is 351000 per thousand 1 plus 350000=100 and 351000= 101, 353000= 103

  28. I need the formula Like ( Block code B-218 in sheet 3 times and amount 100 x 3 = 300 ) now another cell have different block code and values i need if block code B-218 has no payment or not found then give Outstanding if the all data is there then calculate all amount sum 300 however these value and block code in different cell.

  29. Please I would like to know how I can set an automated text on one excel sheet if a value is found in another sheet. If a value is found in sheet one, then I should get a text as ''done'' on the other sheet where that value is.

  30. PLEASE HELP ME ON BELOW MENTIONED FORMULA:-
    A B C D E F G
    1 NO. NAME PAN TEL NO. PERSON ADRESS PROOF EMAIL ID
    2 1 BALDEV ABCDE12345F 99999 AMIT DDEGE12345C BALDEV@G.COM
    3 2 SURESH CDEFG12345A 88888 RAKESH CCCCC12345C SURESH@G.COM
    4 3 AMIT DDEGE12345C 77777 SURESH CDEFG12345A AMIT@G.COM
    5 4 DEEPAK AAAAA12345A 66666 MAHESH BBBBB12345B DEEPAK@G.COM
    6 5 MAHESH BBBBB12345B 55555 DEEPAK AAAAA12345A MAHESH@G.COM
    7 6 RAKESH CCCCC12345C 44444 BALDEV ABCDE12345F RAKESH@G.COM

    Formula Answer
    =VLOOKUP(C2,$C$2:$G$7,4,FALSE) DDEGE12345C

    NOTE:- I Neen Answer as BALDEV@G.COM [EMIAL ID]

    • Hi!
      I don't understand what formula helps you want. The value DDEGE12345C is in columns 2 and 5 of your range. Is this the problem?

  31. I am trying to apply a formula to the cell if a specific cell contains specific text like D8 contains the total amount of project order and E8 contains the status of order ether it is completed canceled or under revision. In F8, I want to use IF Formula in such a way that if E8=completed then it will apply the formula to get the value of 80% of the D8 Our Actual Profit, rest 20% is our cost of work) but if the text is not equal to completed then the value should be 0. How can it be possible? I am trying this formula but getting error (=IF(E8=Completed,"(D8/100)*80", "0")).

    Thanks.

    • Put the string to compare in "". Like =IF(E8="Completed",D8*0.8,)
      Try this.

  32. Is it possible to use IF Function (or what other function) on my case?
    If value is less than or equal 0 type "True" but if greater than it will just show the number as is? Thanks

  33. Hello sir,

    Project status of Open and closed using conditional format was done. Now i want to conclude all these in a overall project status like if all closed it shows closed, if any one open , it shows Open...Like that,,,pls help me

  34. I am trying to set up an IF where it check a cell to see if an ‘X’ is there. I can set up for it to check for numbers, but if I put =IF(A1=‘X’,1,0) it gives me an error code.

  35. Hi,

    it is possible to write a formula for this task.

    In A1 I have text "v:part1:neg:vn:undef:neutr|būti=nebūtina" and so on everytime with ending "=text". I want that formula would type that "text" into B1. Text in all the lines is different.

    Thank you.

    • Hi!
      I am not sure I fully understand what you mean. If you want to split a text into cells, read this guide. If I didn't guess, please describe in detail the result you want to get.

      • Hi,

        I read that guide but don't have "split text" option.
        I need to split the text into cells after equal sign. So if I have a text in cell A1 "v:part1:neg:vn:undef:neutr|būti=nebūtina", I need the word after equal sign to appear in cell B1 "nebūtina".

  36. Hi.

    I need to do a formula.

    I have the following columns:

    Status, Date offer accepted, actual start date, Client driven hold, requisition cancel date.

    In the status column, we have the following on a dropdown list (all different colours)
    Filled Not Yet Started
    Closed
    Did Not Fill
    Partially Filled
    On Hold
    Cancelled

    I need to do a formula where it will automatically choose one of the options on the dropdown (above) by inputting a date in the column and change to that colour on the status column.

  37. Hi Sir,

    I am facing a challenge to come to find a formula for the below issue. I hope if you can help me sort it out.

    I have lot of data in word format (its the syllabus for children) and I want to convert the same in Excel format to make it attractive to children. I used Left, MID, Right formulas, but the last word some times come incompletes in the sentence, do you know what can be done to skip the incomplete word in the end of the sentence and to get that in the next line.

    I know it doesn't looks straight forward, but whenever you have a solution, it would be appreciated if you would share it with me. Thanks in advance.

    • Hi!
      The information you provided is not enough to understand your case and give you any advice. For me to be able to help you better, please specify which formula you mean and describe the problem in more detail.

  38. Good evening,

    I am in grad school and we had a test that asked if the following formula was wrong. =IF($A1="Yes","1","0")

    I put this in excel and gave it a set of data under column A and went from row 1-10 using yes and no. The formula worked correctly, however, I am told I was wrong and the formula wouldn't work because you are not allowed to put quotation marks on numbers in an IF statement.

    Is not using quotations on numbers in an IF statement his opinion or is it a fact? If it is fact, then why does the formula still work with the given data set?

    • Hello!
      The quotes mean that the number is written as text. Your formula will return the number as text. The numbers in quotes follow the syntax of the IF function and are not an error in using it. However, keep in mind that with these numbers you will not be able to perform mathematical calculations, since they are already text. However, there is no prohibition in Excel to use quotes with numbers.

      • Thank you for your time on the reply. I now understand why I gave the wrong answer.

  39. why
    =IF(A1;"text";"") - returns "text" if a1 has any data and blank if a1 is blank

    but

    =IF(AND(A1;DAY(A1)1);"text";"") - returns "text" if a1 is blank or has data, and blank only if day(a1) is 1

    =IF(AND(A1"";DAY(A1)1);"text";"") - works as intended

    what am i missing?

  40. 1 6
    2 8
    3 12
    4 12
    5 15
    6 18
    I want If formula 1st Row Data
    2nd Row Formula Requierd kinldy Share IF formula

  41. Hai Sir,

    i need a formula for Marks to percentage,

    if the percentage is below 1% mark is 5

    if the percentage is 1% to 3% mark is 10

    if the percentage above 3% to 5% mark is 15

    if the percentage above 5% mark is 20....

  42. I'm trying to come up with a formula that will input words, so if a number is below 30 it will say "within 30 days then if it's between 30-365 it will say "within 12 months and anything over 365 will be blank. so far I can do the first part but I'm not sure how to add another condition.

    =IF(E6<30, "within 30 days")

  43. I want to make a formula that goes something like this

    =if(value>blank(G3:L3 add 80 to M3)

    Sorry I'm a real novice in excel. :-(

    Hope somebody can help me out.

    \Lars

    • Hello!
      Please use the following formula:

      =IF(SUM(--(G3:L3<>""))=0,M3+80,0)
      or
      =IF(SUM(--(G3:L3=""))=6,M3+80,0)

      Hope this is what you need.

  44. hi, i am trying to do a formula where the following occurs

    if the balance is greater than 37500 (say 50,000) then the excess 12500 needs to be multiplied by 40% and the original 37500 needs to be multiplied by 20%

    if its less than 37500 then only that balance needs to be multiplied by 20%

    i have tried a few IF formulas but they only do part of the task

  45. How do i return a result to be good or bad from a list of numbers

  46. HI,
    can anyone help me to set a formula with data validate I have three conditions in my data validation list Present Absent and Paid Leave which is denoted With P, A, and PL, what I want when my leave balance is equal to zero and then I select PL then popup message appeared no leave balance

  47. A B C D
    TOTAY

    346 INV-0354 30/06/2021 18901.52 =+IF(TODAY-B346>90<180,D346,0)
    347 INV-0355 30/06/2021 1330.20
    348 INV-0356 30/06/2021 2861.50

    Please Help On This Function and suggest me correct formula

  48. I am Trying to Use the Value(Text) in Cell E to determine the the condition in cell I to read (Pass, Fail) based on the Value(numerical) in field G. Example. IF E = Gram, Eight, Quarter, Half and G Numerical Value fits a given field then I = Pass or Fail. The Value in E will Determine if the Value in G is True. The True/Pass parameters for G will be Gram >=1.08 ,=3.7, =7.27, =14.16, <=14.4. As long as Cell G Falls Between these ranges for the appropriate value in Cell E then Cell I should show Pass. IF outside these then Fail.

    • Hi!
      I’m sorry but your description doesn’t give me a complete understanding of your task.
      But conditions >=1.08 ,=3.7, =7.27, =14.16, <=14.4 cannot be met at the same time. I recommend leaving two conditions: >=1.08, <=14.4

  49. I want to write an if formula that if the cell has a number >0 to return a certain value, if the cell has text to return it as zero.

    Example I have a time card Monday = 8 , Tuesday= FO, Wednesday = 8, Thursday =8, Friday = 8. I am trying to say everyday the person works they get an extra 2 minutes of pay. currently I have multiple if functions stating =if cell >0, 2,0 but the cell with the FO text is getting the true statement.

  50. Hello,

    i need a formula, that says: IF =H3-J3>0, and iF =H3-J3<0,121 (then it is ok),
    but: IF =H3-J30,121 (then rise or lower the G3 cell so it can be in the parameters from 0 to 0,121).

    If this is possible.

    • Something is wrong. So i will send the question in 2 parts.

      1. part

      i need a formula, that says: IF =H3-J3>0, and iF =H3-J3<0,121 (then it is ok).

      • 2. part

        but: IF =H3-J30,121 (then rise or lower the G3 cell so it can be in the parameters from 0 to 0,121).

        • again it is not good...grrr

Post a comment



Thank you for your comment!
When posting a question, please be very clear and concise. This will help us provide a quick and relevant solution to
your query. We cannot guarantee that we will answer every question, but we'll do our best :)