by If you are a regular visitor of this blog, you've probably noticed a few articles covering different aspects of Excel conditional formatting. And now we will leverage this knowledge and create spreadsheets that differentiate between weekdays and weekends, highlight public holidays and display a coming deadline or delay. In other words, we are going to apply Excel conditional formatting to dates.
If you have some basic knowledge of Excel formulas, then you are most likely familiar with some of date and time functions such as NOW, TODAY, DATE, WEEKDAY, etc. In this tutorial, we are going to take this functionality a step further to conditionally format Excel dates in the way you want.
Excel conditional formatting for dates (built-in rules)
Microsoft Excel provides 10 options to format selected cells based on the current date.
- To apply the formatting, you simply go to the Home tab > Conditional Formatting > Highlight Cell Rules and select A Date Occurring.
- Select one of the date options from the drop-down list in the left-hand part of the window, ranging from last month to next month.
- Finally, choose one of the pre-defined formats or set up your custom format by choosing different options on the Font, Border and Fill tabs. If the Excel standard palette does not suffice, you can always click the More colors… button.
- Click OK and enjoy the result! : )
However, this fast and straightforward way has two significant limitations - 1) it works for selected cells only and 2) the conditional format is always applied based on the current date.
Excel conditional formatting formulas for dates
If you want to highlight cells or entire rows based on a date in another cell, or create rules for greater time intervals (i.e. more than a month from the current date), you will have to create your own conditional formatting rule based on a formula. Below you will find a few examples of my favorite Excel conditional formats for dates.
How to highlight weekends in Excel
Regrettably, Microsoft Excel does not have a built-in calendar similar to Outlook's. Well, let's see how you can create your own automated calendar with quite little effort.
When designing your Excel calendar, you can use the =DATE(year,month,date) function to display the days of the week. Simply enter the year and the month's number somewhere in your spreadsheet and reference those cells in the formula. Of course, you could type the numbers directly in the formula, but this is not a very efficient approach because you would have to adjust the formula for each month.
The screenshot below demonstrates the DATE function in action. I used the formula =DATE($B$2,$B$1,B$4) which is copied across row 5.
Tip. If you want to display only the days of the week like you see in the image above, select the cells with the formula (row 5 in our case), right-click and choose Format Cells…> Number > Custom. From the drop-down list under Type, select either dddd or ddd to show full day names or abbreviated names, respectively.
Your Excel calendar is almost done, and you only need to change the color of weekends. Naturally, you are not going to color the cells manually. We'll have Excel format the weekends automatically by creating a conditional formatting rule based on the WEEKDAY formula.
- You start by selecting your Excel calendar where you want to shade the weekends. In our case, it is the range $B$4:$AE$10. Be sure to start the selection with the 1st date column - Colum B in this example.
- On the Home tab, click Conditional Formatting menu > New Rule.
- Create a new conditional formatting rule based on a formula as explained in the above linked guide.
- In the "Format values where this formula is true" box, enter the following WEEKDAY formula that will determine which cells are Saturdays and Sundays:
=WEEKDAY(B$5,2)>5 - Click the Format… button and set up your custom format by switching between the Font, Border and Fill tabs and playing with different formatting options. When done, click the OK button to preview the rule.
Now, let me briefly explain the WEEKDAY(serial_number,[return_type]) formula so that you can quickly adjust it for your own spreadsheets.
- The
serial_numberparameter represents the date you are trying to find. You enter a reference to your first cell with a date, B$5 in our case. - The
[return_type]parameter determines the week type (square brackets imply it is optional). You enter 2 as the return type for a week starting from Monday (1) through Sunday (7). You can find the full list of available return types here. - Finally, you write >5 to highlight only Saturdays (6) and Sundays (7).
The screenshot below demonstrates the result in Excel 2013 - the weekends are highlighted in the reddish colour.
Tips:
- If you have non-standard weekends in your company, e.g. Fridays and Saturdays, then you would need to tweak the formula so that it starts counting from Sunday (1) and highlight days 6 (Friday) and 7 (Saturday) -
WEEKDAY(B$5,1)>5. - If you are creating a horizontal (landscape) calendar, use a relative column (without $) and absolute row (with $) in a cell reference because you should lock the reference of the row - in the above example it is row 5, so we entered B$5. But if you are designing a calendar in vertical orientation, you should do the opposite, i.e. use an absolute column and relative row, e.g. $B5 as you can see in the screenshot below:
How to highlight holidays in Excel
To improve your Excel calendar further, you can shade public holidays as well. To do that, you will need to list the holidays you want to highlight in the same or some other spreadsheet.
For example, I've added the following holidays in column A ($A$14:$A$17). Of course, not all of them are real public holidays, but they will do for demonstration purposes : )
Again, you open Conditional Formatting > New Rule. In the case of holidays, you are going to use either MATCH or COUNTIF function:
=COUNTIF($A$14:$A$17,B$5)>0=MATCH(B$5,$A$14:$A$17,0)
Note. If you have chosen a different color for holidays, you need to move the public holiday rule to the top of the rules list via Conditional Formatting > Manage Rules…
The following image shows the result in Excel 2013:
Conditionally format a cell when a value is changed to a date
It's not a big problem to conditionally format a cell when a date is added to that cell or any other cell in the same row as long as no other value type is allowed. In this case, you could simply use a formula to highlight non-blanks, as described in Excel conditional formulas for blanks and non-blanks. But what if those cells already have some values, e.g. text, and you want to change the background color when text is changed to a date?
The task may sound a bit intricate, but the solution is very simple.
- First off, you need to determine the format code of your date. Here are just a few examples:
- D1: dd-mmm-yy or d-mmm-yy
- D2: dd-mmm or d-mmm
- D3: mmm-yy
- D4: mm/dd/yy or m/d/yy or m/d/yy h:mm
You can find the complete list of date codes in this article.
- Select a column where you want to change the color of cells or the entire table in case you want to highlight rows.
- And now create a conditional formatting rule using a formula similar to this one:
=CELL("format",$A2)="D1". In the formula, A is the column with dates and D1 is the date format.If your table contains dates in 2 or more formats, then use the OR operator, e.g.
=OR(cell("format", $A2)="D1", cell("format",$A2)="D2", cell("format", $A2)="D3")The screenshot below demonstrates the result of such conditional formatting rule for dates.
How to highlight rows based on a certain date in a certain column
Suppose, you have a large Excel spreadsheet that contains two date columns (B and C). You want to highlight every row that has a certain date, say 13-May-14, in column C.
To apply Excel conditional formatting to a certain date, you need to find its numerical value first. As you probably know, Microsoft Excel stores dates as sequential serial numbers, starting from January 1, 1900. So, 1-Jan-1900 is stored as 1, 2-Jan-1900 is stored as 2… and 13-May-14 as 41772.
To find the date's number, right-click the cell, select Format Cells > Number and choose the General format. Write down the number you see and click Cancel because you do not really want to change the date's format.
That was actually the major part of the work and now you only need to create a conditional formatting rule for the entire table with this very simple formula: =$C2=41772. The formula implies that your table has headers and row 2 is your first row with data.
An alternative way is to use the DATEVALUE formula that converts the date to the number format is which it is stored, e.g. =$C2=DATEVALUE("5/13/2014")
Whichever formula you use, it will have the same effect:
Conditionally format dates in Excel based on the current date
As you probably know Microsoft Excel provides the TODAY() functions for various calculations based on the current date. Here are just a few examples of how you can use it to conditionally format dates in Excel.
Example 1. Highlight dates equal to, greater than or less than today
To conditionally format cells or entire rows based on today's date, you use the TODAY function as follows:
Equal to today: =$B2=TODAY()
Greater than today: =$B2>TODAY()
Less than today: =$B2<TODAY()
The screenshot below demonstrates the above rules in action. Please note, at the moment of writing TODAY was 12-Jun-2014.
Example 2. Conditionally format dates in Excel based on several conditions
In a similar fashion, you can use the TODAY function in combination with other Excel functions to handle more complex scenarios. For example, you may want your Excel conditional formatting date formula to color the Invoice column when the Delivery Date is equal to or greater than today BUT you want the formatting to disappear when you enter the invoice number.
For this task, you would need an additional column with the following formula (where E is your Delivery column and F the Invoice column):
=IF(E2>=TODAY(),IF(F2="", 1, 0), 0)
If the delivery date is greater than or equal to the current date and there is no number in the Invoice column, the formula returns 1, otherwise it's 0.
After that you create a simple conditional formatting rule for the Invoice column with the formula =$G2=1 where G is your additional column. Of course, you will be able to hide this column later.
Example 3. Highlight upcoming dates and delays
Suppose you have a project schedule in Excel that lists tasks, their start dates and durations. What you want is to have the end date for each task calculated automatically. An additional challenge is that the formula should also consider the weekends. For example, if the starting date is 13-Jun-2014 and the number of days of work (Duration) is 2, the ending date should come as 17-Jun-2014, because 14-Jun and 15-Jun are Saturday and Sunday.
To do this, we will use the WORKDAY.INTL(start_date,days,[weekend],[holidays]) function, more precisely =WORKDAY.INTL(B2,C2,1).
In the formula, we enter 1 as the 3rd parameter since it indicates Saturday and Sunday as holidays. You can use another value if your weekends are different, say, Fri and Sat. The full list of the weekend values is available here. Optionally, you can also use the 4th parameter [holidays], which is a set of dates (range of cells) that should be excluded from the working day calendar.
And finally, you may want to highlight rows depending on how far away the deadline is. For example, the conditional formatting rules based on the following 2 formulas highlight upcoming and recent end dates, respectively:
=AND($D2-TODAY()>=0,$D2-TODAY()<=7)- highlight all rows where the End Date (column D) is within the next 7 days. This formula is really handy when it comes to tracking upcoming expiration dates or payments.=AND(TODAY()-$D2>=0,TODAY()-$D2<=7)- highlight all rows where the End Date (column D) is within the last 7 days. You can use this formula to track the latest overdue payments and other delays.
Here are a few more formula examples that can be applied to the table above:
=$D2<TODAY() - highlights all passed dates (i.e. dates less than the current date). Can be used to format expired subscriptions, overdue payments etc.
=$D2>TODAY() - highlights all future dates (i.e. dates greater than the current date). You can use it to highlight upcoming events.
Of course, there can be infinite variations of the above formulas, depending on your particular task. For instance:
=$D2-TODAY()>=6 - highlights dates that occur in 6 or more days.
=$D2=TODAY()-14 - highlights dates occurring exactly 2 weeks ago.
How to highlight dates within a date range
If you have a long list of dates in your worksheet, you may also want to highlight the cells or rows that fall within a certain date range, i.e. highlight all dates that are between two given dates.
You can fulfil this task using the TODAY() function again. You will just have to construct a little bit more elaborate formulas as demonstrated in the examples below.
Formulas to highlight past dates
- More than 30 days ago:
=TODAY()-$A2>30 - From 30 to 15 days ago, inclusive:
=AND(TODAY()-$A2>=15, TODAY()-$A2<=30) - Less than 15 days ago:
=AND(TODAY()-$A2>=1, TODAY()-$A2<15)
The current date and any future dates are not colored.
Formulas to highlight future dates
- Will occur in more than 30 days from now:
=$A2-TODAY()>30 - In 30 to 15 days, inclusive:
=AND($A2-TODAY()>=15, $A2-TODAY()<=30) - In less than 15 days:
=AND($A2-TODAY()>=1, $A2-TODAY()<15)
The current date and any past dates are not colored.
How to shade gaps and time intervals
In this last example, we are going to utilize yet another Excel date function - DATEDIF(start_date, end_date, interval). This function calculates the difference between two dates based on the specified interval. It differs from all other functions we've discussed in this tutorial in the way that it lets you ignore months or years and calculate the difference only between days or months, whichever you choose.
Don't see how this could work for you? Think about it in another way… Suppose you have a list of birthdays of your family members and friends. Would you like to know how many days there are until their next birthday? Moreover, how many days exactly are left until your wedding anniversary and other events you wouldn't want to miss? Easily!
The formula you need is this (where A is your Date column):
=DATEDIF(TODAY(), DATE((YEAR(TODAY())+1), MONTH($A2), DAY($A2)), "yd")
The "yd" interval type at the end of the formula is used to ignore years and calculate the difference between the days only. For the full list of available interval types, look here.
Tip. If you happen to forget or misplace that complex formula, you can use this simple one instead: =365-DATEDIF($A2,TODAY(),"yd"). It produces exactly the same results, just remember to replace 365 with 366 in leap years : )
And now let's create an Excel conditional formatting rule to shade different gaps in different colors. In this case, it makes more sense to utilize Excel Color Scales rather than create a separate rule for each period.
The screenshot below demonstrates the result in Excel - a gradient 3-color scale with tints from green to red through yellow.
"Days Until Next Birthday" Excel Web App
We have created this Excel Web App to show you the above formula in action. Just enter your events in 1st column and change the corresponding dates in the 2nd column to experiment with the result.
If you are curious to know how to create such interactive Excel spreadsheets, check out this article on how to make web-based Excel spreadsheets.
Hopefully, at least one of the Excel conditional formats for dates discussed in this article has proven useful to you. If you are looking for a solution to some different task, you are most welcome to post a comment. Thank you for reading!
1256 comments
Hi, i have a sheet where we enter a planned process completion date and the next column is actual completion date. Some times the work is delayed and the complttion date might be 3 or 4days later than the planned date. When this happens i want the delayed date to be highlighted . For example planned date in p3 is 25th march and actual completion date is 28th march that is entered in q3. How do we automatically highlight the delayed date
Hi! All the necessary information is in the article above. For a range of cells, e.g. Q3:Q100, this can be done using the conditional formatting formula:
=Q3>P3
You can also find useful information in this article: Excel conditional formatting formulas based on another cell.
Thank you. That was so straight and simple...it worked...🙏
Thanks for the Employee Absence Tracker!
I wonder if it's possible to change the year e.g., our vacation year is December to November. Is there a way of changing this to run December 1st to November 30th every year?
Hello Kay!
You can create any date using the DATE function. You can also automatically subtract month from date using the EDATE function. For example, subtract one month from date:
=EDATE(A1,-1)
I can't give more specific advice as I don't know what you want to do.
I want to highlight a date 2 months in the past. Love the "a date occurring" options, this gives me last month, but I need 2 months ago. Is that possible?
Hello Stacey!
Use the EOMONTH function to set the start and end dates of the interval last 2 months before the current date. Here is an example of a conditional formatting formula for dates in column D.
=AND(D1>EOMONTH(TODAY(),-3),D1<EOMONTH(TODAY(),-1))
I want to conditional format a cell based on a date cell + a number of days. Example: =IF(H34+10<I34, TRUE, FALSE) I have +15 and +20. I then do that for J34, K34, L34, and M34 all off the cell to the left. The formatting works. What I need is that I need to do this for 10+ lines of excel but all need to be independent. e.g. H35, H36, H37 and so on.
When I try to copy and paste, or apply to a range, it keeps the H34 even though it is not formatted $H$34. Is there a way I can cascade my formulas so I don't have to input them each by hand. That is a lot of coding.
Hi! Maybe this guide will be helpful: How to copy Excel conditional formatting.
Hi - In Excel I have a cell which records an altered dollar amount. The date on which this happens is manually written into a cell nearby. It is not a daily event, therefore the date may not change for days or even weeks. I would like to automate the cell carrying the date, so that when the dollar amount changes in one cell, the date changes as well, and stays fixed until the next time the dollar amount changes.
Thanks,
Roger
Hello Roger!
If I understand your task correctly, to prevent your date from automatically changing, you can use several methods:
1. Use Shortcuts to insert the current date and time
2. Use the recommendations How to insert today date & current time as unchangeable time stamp in our blog.
3. Replace the date and time returned by the TODAY function with their values. Copy the date (CTRL + C), then paste only the values using Paste Special or Shortcut CTRL + ALT + V.
4. Use VBA to write the current date and time to the cell.
Good Day All
I want Excel to insert the date in Colum "A" if I insert date in Colum "B"
Many Thanks
Hello Marius!
If you want to show the current date in column B by condition, use the IF formula and TODAY function.
=IF(B1<>"",TODAY(),"")
Set the date format you want in the formula cell as described here: How to change Excel date format and create custom formatting.
If this date should not change, try these instructions: Formula to insert today date & current time as unchangeable time stamp. Or use a VBA macro to insert a date automatically.
Hello,
Can someone help me out with below query in excel how to resolved with functions and formulas
i want to change the date as per status change in one cell by following the various status which are change within 1/2 days
For example: Today i done a booking for part load so i change the status as "booking received" The very next day i am change the status as "Booking Done" and last day means after 3/4 day i change the status as "delivery completed" so every status change i want to record the current date and as status change date should be followed by status change effective date, also if possible i want to check the History of the Cell on which date the status is change Link Google edit history
Hello!
If I understand your task correctly, to insert and prevent date from automatically changing, you can use several methods:
1. Use Shortcuts to insert the current date and time
2. Use the recommendations How to insert today date & current time as unchangeable time stamp in our blog.
3. Replace the date and time returned by the TODAY function with their values. Copy the date (CTRL + C), then paste only the values using Paste Special or Shortcut CTRL + ALT + V.
4. Use VBA to write the current time to the cell.
Helpful, but I still cannot get the sheet to conditional format the way I want to. I want to track dates that become "expired".
I'm tracking dates of course completions, yet they have to take them again every year. I think I need 4 different formulas for the same sheet:
1) If I have not taken the class and no date is entered, I want it highlighted white or no fill.
2) I completed a class on a date it would show highlighted in green.
3) However, if this date is between 180 and 365 days later, I want to have it automatically highlight as orange indicating the re-certification is coming due.
4) If this dates is past 365 days later I want it to be highlighted in red as the recertification is past due.
Hi! Please re-check the article above since it covers your case. Pay attention to the following paragraph of the article above: How to highlight dates within a date range. For example:
=AND(TODAY()-$A1>=180, TODAY()-$A1<=365)
=TODAY()-$A1>=365
Hi! I found this post and it goes in a similar direction like the problem i would like to solve.
I'm creating kind of a calendar for a whole year - see screenshot here:
https://drive.google.com/file/d/1O4HaEpp2VS85fsPvQDcqNBmprAMtqVDC/view?usp=sharing
In the screenshot i annotated 2 areas - in the calendar itself (blue) and in a list below the month (red). Both are formatted as dates.
What i would like to do is to highlight a date in the calendar (change it's font color), if there is one or more entries in the list below with the same date.
Is that even possible?
Glad for every direction or help with the formula
Thanks + best regards!
Achim
Hi! Use the DAY function to get the day from the date. Use the SUMPRODUCT function to determine if the day is the same as the numbers on the calendar (blue). Use conditional formatting as recommended in this article: Relative and absolute cell references in Excel conditional formatting.
=SUMPRODUCT(--(D$2=DAY($A$3:$A$16)))>0
Thank you for this!!! No one else had the date based on a list of holidays. Thank you!!
Hello, thanks for your work!
We have a problem with expiration dates, expiration dates after product openning. We ar using this formula to calculate expiration date after openning if product expires after 10 days: =IF(J3="";"";J3+10) J - openning day.
Ecample: Product X general expiration date is 2024-09-10, after openning, product expires after 10 days. We openned product on 2024-09-05, with formula we're using date we get is 2024-09-15, but, product expired on 2024-09-10.
Is there some formula that makes cell red, if expiration date after openning is greater than general expiration date?
Hello! The following tutorial should help: Excel conditional formatting formulas based on another cell.
For example, if the general expiration date is written in D3 and the formula to calculate expiration date is written in E3, the conditional formatting formula might look like this:
=E3 > D3
Or you can try this formula:
=(J3+10) > D3
Thank you for quick responce!
Can we apply formula for whole column? For example: H column - expiration date, J - openning day, L - expiration date after openning. But H2 may be different from H3 and so on. =E3 > D3 is valid for one cell. We need, if possible, formula for section $L$1:$L$400.
Hi! Select the range $L$1:$L$400. Then create a conditional formatting rule =E1>D1 for this range.
For more information, please visit: Excel Conditional Formatting tutorial with examples.
Great tips on formatting dates.
How do I format the cells based on dates comparing 1 column cell with another column cell for the whole column
i.e column B2 vs column C2 and the whole column if B2 is > C2
Hi! If you want to apply a conditional formatting rule to an entire column, select entire column and create a conditional formatting rule as follows
=B1 > C1
Read more: How to create a new conditional formatting rule.
Note that in large tables, formulas and conditional formatting for an entire column can slow down calculations.
Hi Alexander,
Thanks so much for taking the time to reply to comments and provide such a comprehensive article.
I am trying to use formulas to highlight past dates
More than 10 days ago: =TODAY()-$A2>10
From 4 to 9 days ago, inclusive: =AND(TODAY()-$A2>=4, TODAY()-$A2=0, TODAY()-$A2<3)
These are all just altered based on the examples in the article, however I need them to apply to all the cells in column J (excluding title column)
I have tried a few different things but none of them seem to work.
Can you please help me?
Sorry! Typo above ^^
This is what I meant to do:
red - More than 10 days ago: =TODAY()-$A2>10
yellow - From 4 to 9 days ago, inclusive: =AND(TODAY()-$A2>=4, TODAY()-$A2=0, TODAY()-$A2<3)
Need to apply these formulas to column J, any help greatly appreciated!
Hello Lauren!
Here is the article that may be helpful to you: Excel conditional formatting formulas based on another cell.
Select the range J2:J100 (cells for the conditional formatting) and apply your conditional formatting formula to this range.
Formula from 4 to 9 days ago - =AND(TODAY()-$A2>=4, TODAY()-$A2<=9)
From 4 to 9 days ago, inclusive: =AND(TODAY()-$A2>=4, TODAY()-$A2=1, TODAY()-$A2<3)
Sorry this keeps changing my comment.
Hi, can you please help me?
I need to format a column in excel. I have dates in columns B and C. I need that if the date in column B is smaller than in column C, the given cell (in column C) will be colored green. Otherwise, there will be no discoloration. I need to apply this to all rows from column C.
for ex.:
B C
10.7.2024 12.7.2024 (12.7.2024 will be green)
20.7.2024 12.7.2024 (12.7.2024 will be normal)
thank you
Hi Alena!
All the necessary information is in the article above.
Conditional formatting rule for C column might look like this:
=B1<C1
You can also find useful information in this article: Excel conditional formatting formulas based on another cell.
Thank you very much :), Excel automatickly put "$" between the cell number and it didnt work, but now with only B1 and C1 it does!
Could anyone have an idea how to create Weekly Summary Manhours Report based on the DIR/IND from the listed Daily Manhours.
Please clarify your specific problem or provide additional details to highlight exactly what you need. As it's currently written, it's hard to tell exactly what you're asking.
I want to know, if we make a database of employees number of expereince, how can the data is updated with each passing year i.e. how can the number of expereince can be increased with each passing year?
Hi! I can't know how your data will change. If you have a specific question about the operation of a function or formula, I will try to answer it.
Hi..
I need to know how can I extract the date of a value if it changed. (Ex: if I fill in A2:A10 some values in 10-6-2024, in A2=55, after 7 days I changed to 66 but I keep the other values without any changes. I need a formula to know only the cells that have changed after the above dat.
Thanks
Hi! Maybe this article will be helpful: How to track changes in Excel.
Hi,
Sorry I have a second part of my question.
I've created a Visual Basic Module, that sends an email reminder to me 1 week before check-in date (A1).
When I 'run' the module from Visual Basic, it works (i.e. sends me an email) - but how/where/what do I insert (formula wise) and where, to tell the spreadsheet to run the module when it gets to 7 days out from the check-in date?
Hi! You cannot run a macro at a specific time using an Excel formula.You can do this with another macro that will check the cell value and run your macro.
Hi,
I'm trying to do conditional formating using a check-in date (A1) and check-out date (A2)?
I'd like 3 conditions:
Before check in (both A1 & A2 are yellow)
Once Check in date is today or past, (both A1 & A2 are green) - to indicate a guest has checked in
once the check out date has passed (both A1 & A2 are red) - to indicate a guest has checked out
Thank you
Hi! Please re-check the article above since it covers your task. Create a separate rule for each color. Yellow - A1>TODAY() Green - A1<=TODAY()
Note also these guidelines: Apply multiple rules to same cells.
Hi, can you help me to solve this. im working on this problem for a couple of days and yet i just cant resolve this. please guide
on conditional formatting
if sheet1.a1 date is equal to sheet2.a1 date and sheet2.b1 text = "conflict" then sheet1.a1 row change its color
Hi! If I understand your task correctly, this article may be helpful: Excel conditional formatting formulas based on another cell. To correctly do a reference to another worksheet, use these guidelines: Excel reference to another sheet or workbook (external reference). Based on the information given, the conditional formatting formula could be as follows:
=AND(Sheet1!A1=Sheet1!A1, Sheet2!B1="conflict")
thanks a lot, do you also have a solution on this problem.
two different set of dates to determine whether there's a conflict on set schedules
example:
set 1, from june 1, 2024 - june 5, 2024 - meeting with the board
set 2, from june 4, 2024 - june 7, 2024 - meeting with higher ups
do you know how to calculate that june 4 & 5 have a conflict on set 2 schedule.
thanks in advance, i still in float on this problem
Hi! Excel can't compare dates written as text. Also, it's best to use special programs to work with schedules, not Excel, which isn't designed for this purpose.