Excel IF statement with multiple conditions

The tutorial shows how to create multiple IF statements in Excel with AND as well as OR logic. Also, you will learn how to use IF together with other Excel functions.

In the first part of our Excel IF tutorial, we looked at how to construct a simple IF statement with one condition for text, numbers, dates, blanks and non-blanks. For powerful data analysis, however, you may often need to evaluate multiple conditions at a time. The below formula examples will show you the most effective ways to do this.

How to use IF function with multiple conditions

In essence, there are two types of the IF formula with multiple criteria based on the AND / OR logic. Consequently, in the logical test of your IF formula, you should use one of these functions:

  • AND function - returns TRUE if all the conditions are met; FALSE otherwise.
  • OR function - returns TRUE if any single condition is met; FALSE otherwise.

To better illustrate the point, let's investigate some real-life formulas examples.

Excel IF statement with multiple conditions (AND logic)

The generic formula of Excel IF with two or more conditions is this:

IF(AND(condition1, condition2, …), value_if_true, value_if_false)

Translated into a human language, the formula says: If condition 1 is true AND condition 2 is true, return value_if_true; else return value_if_false.

Suppose you have a table listing the scores of two tests in columns B and C. To pass the final exam, a student must have both scores greater than 50.

For the logical test, you use the following AND statement: AND(B2>50, C2>50)

If both conditions are true, the formula will return "Pass"; if any condition is false - "Fail".

=IF(AND(B2>50, B2>50), "Pass", "Fail")

Easy, isn't it? The screenshot below proves that our Excel IF /AND formula works right: Excel IF statement with multiple AND conditions

In a similar manner, you can use the Excel IF function with multiple text conditions.

For instance, to output "Good" if both B2 and C2 are greater than 50, "Bad" otherwise, the formula is:

=IF(AND(B2="pass", C2="pass"), "Good!", "Bad") Excel IF function with multiple text conditions

Important note! The AND function checks all the conditions, even if the already tested one(s) evaluated to FALSE. Such behavior is a bit unusual since in most of programming languages, subsequent conditions are not tested if any of the previous tests has returned FALSE.

In practice, a seemingly correct IF statement may result in an error because of this specificity. For example, the below formula would return #DIV/0! ("divide by zero" error) if cell A2 is equal to 0:

=IF(AND(A2<>0, (1/A2)>0.5),"Good", "Bad")

The avoid this, you should use a nested IF function:

=IF(A2<>0, IF((1/A2)>0.5, "Good", "Bad"), "Bad")

For more information, please see IF AND formula in Excel.

Excel IF function with multiple conditions (OR logic)

To do one thing if any condition is met, otherwise do something else, use this combination of the IF and OR functions:

IF(OR(condition1, condition2, …), value_if_true, value_if_false)

The difference from the IF / AND formula discussed above is that Excel returns TRUE if any of the specified conditions is true.

So, if in the previous formula, we use OR instead of AND:

=IF(OR(B2>50, B2>50), "Pass", "Fail")

Then anyone who has more than 50 points in either exam will get "Pass" in column D. With such conditions, our students have a better chance to pass the final exam (Yvette being particularly unlucky failing by just 1 point :) Excel IF function with multiple OR conditions

Tip. In case you are creating a multiple IF statement with text and testing a value in one cell with the OR logic (i.e. a cell can be "this" or "that"), then you can build a more compact formula using an array constant.

For example, to mark a sale as "closed" if cell B2 is either "delivered" or "paid", the formula is:

=IF(OR(B2={"delivered", "paid"}), "Closed", "")

More formula examples can be found in Excel IF OR function.

IF with multiple AND & OR statements

If your task requires evaluating several sets of multiple conditions, you will have to utilize both AND & OR functions at a time.

In our sample table, suppose you have the following criteria for checking the exam results:

  • Condition 1: exam1>50 and exam2>50
  • Condition 2: exam1>40 and exam2>60

If either of the conditions is met, the final exam is deemed passed.

At first sight, the formula seems a little tricky, but in fact it is not! You just express each of the above conditions as an AND statement and nest them in the OR function (since it's not necessary to meet both conditions, either will suffice):

OR(AND(B2>50, C2>50), AND(B2>40, C2>60)

Then, use the OR function for the logical test of IF and supply the desired value_if_true and value_if_false values. As the result, you get the following IF formula with multiple AND / OR conditions:

=IF(OR(AND(B2>50, C2>50), AND(B2>40, C2>60), "Pass", "Fail")

The screenshot below indicates that we've done the formula right: IF with multiple AND & OR statements

Naturally, you are not limited to using only two AND/OR functions in your IF formulas. You can use as many of them as your business logic requires, provided that:

  • In Excel 2007 and higher, you have no more than 255 arguments, and the total length of the IF formula does not exceed 8,192 characters.
  • In Excel 2003 and lower, there are no more than 30 arguments, and the total length of your IF formula does not exceed 1,024 characters.

Nested IF statement to check multiple logical tests

If you want to evaluate multiple logical tests within a single formula, then you can nest several functions one into another. Such functions are called nested IF functions. They prove particularly useful when you wish to return different values depending on the logical tests' results.

Here's a typical example: suppose you want to qualify the students' achievements as "Good", "Satisfactory" and "Poor" based on the following scores:

  • Good: 60 or more (>=60)
  • Satisfactory: between 40 and 60 (>40 and <60)
  • Poor: 40 or less (<=40)

Before writing a formula, consider the order of functions you are going to nest. Excel will evaluate the logical tests in the order they appear in the formula. Once a condition evaluates to TRUE, the subsequent conditions are not tested, meaning the formula stops after the first TRUE result.

In our case, the functions are arranged from largest to smallest:

=IF(B2>=60, "Good", IF(B2>40, "Satisfactory", "Poor"))

Naturally, you can nest more functions if needed (up to 64 in modern versions). Nested IF statement in Excel

For more information, please see How to use multiple nested IF statements in Excel.

Excel IF array formula with multiple conditions

Another way to get an Excel IF to test multiple conditions is by using an array formula.

To evaluate conditions with the AND logic, use the asterisk:

IF(condition1) * (condition2) * …, value_if_true, value_if_false)

To test conditions with the OR logic, use the plus sign:

IF(condition1) + (condition2) + …, value_if_true, value_if_false)

To complete an array formula correctly, press the Ctrl + Shift + Enter keys together. In Excel 365 and Excel 2021, this also works as a regular formula due to support for dynamic arrays.

For example, to get "Pass" if both B2 and C2 are greater than 50, the formula is:

=IF((B2>50) * (C2>50), "Pass", "Fail") IF array formula with multiple AND conditions

In my Excel 365, a normal formula works just fine (as you can see in the screenshots above). In Excel 2019 and lower, remember to make it an array formula by using the Ctrl + Shift + Enter shortcut.

To evaluate multiple conditions with the OR logic, the formula is:

=IF((B2>50) + (C2>50), "Pass", "Fail") IF array formula with multiple OR conditions

Using IF together with other functions

This section explains how to use IF in combination with other Excel functions and what benefits this gives to you.

Example 1. If #N/A error in VLOOKUP

When VLOOKUP or other lookup function cannot find something, it returns a #N/A error. To make your tables look nicer, you can return zero, blank, or specific text if #N/A. For this, use this generic formula:

IF(ISNA(VLOOKUP(…)), value_if_na, VLOOKUP(…))

For example:

If #N/A return 0:

If the lookup value in E1 is not found, the formula returns zero.

=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), 0, VLOOKUP(E1, A2:B10, 2, FALSE))

If #N/A return blank:

If the lookup value is not found, the formula returns nothing (an empty string).

=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), "", VLOOKUP(E1, A2:B10, 2, FALSE))

If #N/A return certain text:

If the lookup value is not found, the formula returns specific text.

=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), "Not found", VLOOKUP(E1, A2:B10, 2, FALSE)) If #N/A error in VLOOKUP

For more formula examples, please see VLOOKUP with IF statement in Excel.

Example 2. IF with SUM, AVERAGE, MIN and MAX functions

To sum cell values based on certain criteria, Excel provides the SUMIF and SUMIFS functions.

In some situations, your business logic may require including the SUM function in the logical test of IF. For example, to return different text labels depending on the sum of the values in B2 and C2, the formula is:

=IF(SUM(B2:C2)>130, "Good", IF(SUM(B2:C2)>110, "Satisfactory", "Poor"))

If the sum is greater than 130, the result is "good"; if greater than 110 – "satisfactory', if 110 or lower – "poor". Using the IF function with SUM

In a similar fashion, you can embed the AVERAGE function in the logical test of IF and return different labels based on the average score:

=IF(AVERAGE(B2:C2)>65, "Good", IF(AVERAGE(B2:C2)>55, "Satisfactory", "Poor"))

Assuming the total score is in column D, you can identify the highest and lowest values with the help of the MAX and MIN functions:

=IF(D2=MAX($D$2:$D$10), "Best result", "")

=IF(D2=MAX($D$2:$D$10), "Best result", "")

To have both labels in one column, nest the above functions one into another:

=IF(D2=MAX($D$2:$D$10), "Best result", IF(D2=MIN($D$2:$D$10), "Worst result", "")) Using IF together with the MIN and MAX functions

Likewise, you can use IF together with your custom functions. For example, you can combine it with GetCellColor or GetCellFontColor to return different results based on a cell color.

In addition, Excel provides a number of functions to calculate data based on conditions. For detailed formula examples, please check out the following tutorials:

  • COUNTIF - count cells that meet a condition
  • COUNTIFS - count cells with multiple criteria
  • SUMIF - conditionally sum cells
  • SUMIFS - sum cells with multiple criteria

Example 3. IF with ISNUMBER, ISTEXT and ISBLANK

To identify text, numbers and blank cells, Microsoft Excel provides special functions such as ISTEXT, ISNUMBER and ISBLANK. By placing them in the logical tests of three nested IF statements, you can identify all different data types in one go:

=IF(ISTEXT(A2), "Text", IF(ISNUMBER(A2), "Number", IF(ISBLANK(A2), "Blank", ""))) IF with ISNUMBER, ISTEXT and ISBLANK

Example 4. IF and CONCATENATE

To output the result of IF and some text into one cell, use the CONCATENATE or CONCAT (in Excel 2016 - 365) and IF functions together. For example:

=CONCATENATE("You performed ", IF(B1>100,"fantastic!", IF(B1>50, "well", "poor")))

=CONCAT("You performed ", IF(B1>100,"fantastic!", IF(B1>50, "well", "poor")))

Looking at the screenshot below, you'll hardly need any explanation of what the formula does: Using IF and CONCATENATE

IF ISERROR / ISNA formula in Excel

The modern versions of Excel have special functions to trap errors and replace them with another calculation or predefined value - IFERROR (in Excel 2007 and later) and IFNA (in Excel 2013 and later). In earlier Excel versions, you can use the IF ISERROR and IF ISNA combinations instead.

The difference is that IFERROR and ISERROR handle all possible Excel errors, including #VALUE!, #N/A, #NAME?, #REF!, #NUM!, #DIV/0!, and #NULL!. While IFNA and ISNA specialize solely in #N/A errors.

For example, to replace the "divide by zero" error (#DIV/0!) with your custom text, you can use the following formula:

=IF(ISERROR(A2/B2), "N/A", A2/B2) Using IF together with ISERROR

And that's all I have to say about using the IF function in Excel. I thank you for reading and hope to see you on our blog next week!

Practice workbook for download

Excel IF multiple criteria - examples (.xlsx file)

2536 comments

  1. Hi!

    IFS CONDITION is not working in my excel. Tried putting multiple condition no luck either. Can you please help me?

    Situation:

    If E3 is =JPA-1608 (cell C1), JPA-1619(cell D1), LGSA-1420(cell E1), TRSA-1204(cell F1), and TRSA-1427(cell G1), write "NEW", but if not, vlookup

    some of the formulas i tried:
    1. =IF(AND(E3="JPA-1608", E3="JPA-1619","NEW",VLOOKUP(R3,LEGEND!D:E,2,FALSE)))
    2. =IF(E3=C1,"NEW",VLOOKUP(R3,LEGEND!D:E,2,FALSE), IF(E3=D1,"NEW",VLOOKUP(R3,LEGEND!D:E,2,FALSE))) and so on...
    3. =IF(E3=C1:G1,"NEW",VLOOKUP(R3,LEGEND!D:E,2,FALSE))

    =IF(E3=C1,"NEW",VLOOKUP(R3,LEGEND!D:E,2,FALSE) is working but when i try to add the other condition (E3=C1:G1) it doesn't accepted.

    1. Hello Liliane!
      To correct first formula, read the article above carefully. The second formula is not possible because it contains two conditions that cannot be fulfilled simultaneously. In third formula, you cannot compare a single value with an array of values. This can be done using SUMPRODUCT function. For example:

      =IF(SUMPRODUCT(--(E3=C1:G1)),"NEW",VLOOKUP(R3,LEGEND!D:E,2,FALSE))

  2. i have a cell containing data -100. i want to set conditional formatting that if data is equal to -100 then its color should be grey. =if(R5=-100, 0), but this is not working

  3. Help...

    I want to write a formula that says if cell A1 contains "+" character in a code (ie ABC123+:1), in B1 write "PLUS", or if cell A1 contains "-" (ie ABC123-:1, in B1 write "MINUS" and if cell A1 contains neither of those write "BASIC"

    TIA

    1. Hi! To find a specific character in a text string, use these instructions: Excel FIND and SEARCH functions with formula examples. Use ISNUMBER function to use the result of the search in an IF formula. For example:

      =IF(ISNUMBER(SEARCH("+",A1)),"Plus", IF(ISNUMBER(SEARCH("-",A1)),"Minus","Basic"))

      Here is the article that may be helpful to you: Nested IF in Excel – formula with multiple conditions.
      For multiple conditions, you can also use the IFS function. Read more: Excel IFS function instead of multiple IF.

  4. I want to create a points table where points are awarded as under:

    if cell E2 is same as I2, 2
    if cell E2 is NR, 1
    if cell E2 is anything else, 0

    What would be the formula?

  5. How can I use IF function, the results to be in column
    If Column Result;

    The result in between then ;

    Condtions Results

    9-10 1
    18-20 2
    27-30 3
    36-40 4
    45-50 5
    55-60 6
    65-70 7

    Please provide the guideline

    Regards.

  6. i want to see if you can create a formula for below:

    if colmun F has any option from list 1 i want column G to display no and column H to display £0, but if column F has any option from list 2 i want colum g to display Yes and column H to show 1% of column E. however but then also if column F is blank i want Columns G-I to display nothing.

    1. Hi! I think you know that an Excel formula can only change the value in the cell in which it is written.
      Use a nested IF statement in cell G1. Look for the value in list 1 and list 2 using the MATCH function.
      For the detailed instructions, please see: Excel if match formula: check if two or more cells are equal.
      Based on the information given, the formula could be as follows:

      =IF(ISNUMBER(MATCH(F1,N9:N11,0)),"no",IF(ISNUMBER(MATCH(F1,P9:P17,0)),"Yes",""))

    2. list one is column n9-n11
      list two is column p9-p17

  7. if cell I16=B then cell O16=1,
    if cell I16=C then cell P16=1,
    if cell I16=UR then cell Q16=1

    1. Hi! An Excel formula cannot change a value in three cells at once. Create an IF formula in each of the cells. For example cell O16:

      =IF(I16="B",1,"")

  8. I need your help and thankful to you,
    I need to multiply the value with the criteria
    if a1>4 then multiply by 1
    if a1>5 less than 8 multiply be 2
    if a1> 9 than multiply by 3
    I need a single formula.

      1. Thanks a lot Sir for your response,
        I try the article but not succeeded kindly help me..

  9. PRICE INSURANCE
    550000
    664000
    766000
    1090000

    600000<=0.5%, 800000<=1%, 1000000<=2%
    Please solve this
    THANKS IN ADVANCE

  10. I am trying to pull data from one cell that has a lot of data.

    I want to do is easily pull out the specific number in one cell. Here is an actual example of some of the data that could be in ONE cell (the data is not always in this order):
    Cell A1 : 営業2G 張 JIES JP-S0502-00100BS-N0EPB-551-0000×4台 JIES-24-J01
    Cell A2 : 営業2G 張 JIEI-24-J0132/蘭盛-三門巨力 JP-S2002-00300BS-N0CCB-5

    The specific number I want to pull out :
    Number 100 before letter BS in Cell A1
    Number 300 before letter BS in Cell A2

    Kindly help me using excel formula for this

  11. I fill B2 with fixed date, B2 = 10/12/2024
    I use B3 as input date, and result must be appeared in B4.
    In B4, I write this formula, =IF(B3="x",0,IF(B3="","",IF(B3>B2,1,IF(B3<=B2,2,"")))).
    My problem is, if I insert alphabet other than x, the result is 1.
    I just want the result in B4 is 0 when I fill with x only.
    How to write correct formula / function?

    1. Hi! If I understand your task correctly, the following formula should work for you:

      =IF(B3="x",0,IF(ISNUMBER(B3),IF(B3>B2,1,IF(B3<=B2,2,"")),""))

      ISNUMBER function returns FALSE if any text character is written in cell B3 or if B3 is empty.

  12. Hello,

    I am trying to get a separate cell to populate an additional 7 days entered from another cell if another cell is a Yes answer. If H23 is Yes (from a dropdown selection) I want H23 to add 7 (days) to the date entered in Cell H21. If Cell H23 is a No or Blank, then no additional data will be needed.
    Example: If H21 has 12/24/24 entered and H23 has a Yes, then H24 should then show 12/31/24

  13. Hi Sir, I have trying to "if formula with Full Columns but not apply. and also i use formula for = search under the mention the formula
    =If(search("filter",a1),"spare",if(Search("oill",a1),"lubricant","non OEM"))
    A column
    filters
    oil
    spray
    oil
    filter

  14. Hi

    I am trying to get a cell to show a result of a formula, if someone is above a certain age.
    I currently have =IF(G2>20,"(=SUM(AB2-AE2)*AF2)", "0.00")

    It's returning a result, but it's just displaying the actual formula (=SUM(AB2-AE2)*AF2) - in the cell, rather than the numerical value I require.

    Any help on what I am doing wrong would be appreciated!

  15. Hi Alexander,
    I am trying to set a Nested IF ISBLANK formula and am hoping you can help! The sum carried out is based on the population of several cells, I have this at the moment - =IF(ISBLANK(EQ4),EJ4-EC4,EQ4-EC4,IF(ISBLANK(EJ4),EC4-DS4,EJ4-EC4)). The first part *=IF(ISBLANK(EQ4),EJ4-EC4,EQ4-EC4)* works fine, but when I add the second possibility it is returning an error. Basically, if the last cell (EJ4) is blank, then it needs to subtract the previous two (EJ4-EC4), if the last two cells are blank it needs to subtract the third from the fourth cell (EC4-DS4). Is it possible to set a formula with these conditions?
    Thank you.

    1. Hi Nic!
      Unfortunately I could not understand the description of your problem. What does “last two cells are blank” mean?
      However, I’ll try to guess and offer you the following formula:

      =IF(ISBLANK(EQ4),IF(ISBLANK(EJ4),EC4-DS4,EJ4-EC4),EQ4-EC4)

      If this is not what you wanted, please describe the problem in more detail.
      Maybe this article will help: Nested IF in Excel – formula with multiple conditions.

  16. I have an Excel spreadsheet I am trying to write a formula to find specific supplier on a date and add the total amount from that supplier into a column to use in a graph. Having issues getting the formula to work, not sure what formula to use as it need to perform multiple functions at the same time. I can provide a generic example to explain better

    Need to search by date in column D, then find all client in column A and sum the count in column C for that day. Need to do this over multiple days.

    Client Carrier Quantity (Skid count) Scheduled arrival Date
    Client 1 Carrier 1 9 Tuesday, July 2, 2024
    Client 2 Carrier 2 7 Tuesday, July 2, 2024
    Client 2 Carrier 3 34 Tuesday, July 2, 2024
    Client 3 Carrier 4 4 Tuesday, July 2, 2024
    Client 4 carrier 5 17 Tuesday, July 2, 2024
    Client 2 Carrier 2 11 Tuesday, July 2, 2024
    Client 5 Carrier 1 1 Wednesday, July 3, 2024
    Client 4 carrier 6 2 Wednesday, July 3, 2024
    Client 6 Carrier 7 27 Wednesday, July 3, 2024
    Client 6 Carrier 8 15 Thursday, July 4, 2024
    Client 2 Carrier 2 18 Thursday, July 4, 2024
    Client 1 Carrier 9 27 Thursday, July 4, 2024
    Client 5 Carrier 4 31 Thursday, July 4, 2024

    1. Hello Randy!
      You can find the sum of values over several conditions using SUMIFS function. You can find the examples and detailed instructions here: How to use Excel SUMIFS and SUMIF with multiple criteria.
      More information about the calculation of the amount for a specific date or date range is available here: How to use Excel SUMIF with dates.
      I hope it’ll be helpful. If something is still unclear, please feel free to ask.

  17. Hi,
    Thank you for this first introduction to the "If" formula. I tried to apply it to my file but without success until now.
    in this list of the Payement Term (B001, B005,...), i've added a quantity per year (e.g. the PT B001 has been used the last time in 2013 for 26.508 tons.
    I would to have a formula that write in a cell the last year of use (the last year where i find a value >0)
    Thank you very much !
    Geoffroy

    Payment Terms Year 2012 2013 2014 2015 2016
    B001 8.648 11.297 26.508 0 0 0 2013*
    B005 0 11.063 20.201 25.944 975 0
    B006 0 0 0 0 525 0

  18. Dear sir ,
    I need support from your end , I need prepare shift schedule every month ,

    for example : In sheet -1 listed out 20 operators shift schedule like General shift -G , First shift - A, Second shift -B, Night shift -c . like that i prepared shift schedule every month .

    what is my requirement : when ever i entered G shift in sheet -1 , G- shift time will be required in second sheet .

    Example : In sheet -1 I entered Ramesh -G , Ramesh - A , Ramesh- B , Ramesh -C and Ramesh - W
    In sheet -2 I required Ramesh - 9 to 18 , Ramesh- 6 to 14 , Ramesh- 14 to 22 , Ramesh-22 to 6 and Ramesh - w.off

    1. Hi! Create an additional table of two columns. In the first column write down the shifts, in the second column write down the working hours corresponding to each shift.
      Then, using the VLOOKUP formula or the INDEX MATCH formula, extract from this table the times that correspond to shift G, A, B, and so on.
      You can find the examples and detailed instructions here: Excel VLOOKUP function tutorial with formula examples and INDEX & MATCH in Excel - better alternative to VLOOKUP.
      We have a tool that can solve your task in a couple of clicks - VLOOKUP Wizard. It is a easy way to build complex VLOOKUP formulas. The tool is included in the Ultimate Suite for Excel and can be used in a free trial to see how it works.

  19. Trying to Grab more than one Row of info at once if one column is true and another column is true give me a value if false =0
    this works
    =IF((Supplies2024!B5="Wolf")*(Supplies2024!D5="Housewares"),Supplies2024!J5,0)
    but when I try to get more than one row, I can't find the formula to make this work
    =IF((Supplies2024!B2:B5="Grizzly")*(Supplies2024!D2:D5="Housewares"),Supplies2024!J2:J5,0)

  20. Why the following formula doesn't work:

    =IF(AC2>0,"AC2*20%+7500",IF(AC2<0,"(AC2+30,000)15%+3000"))

Post a comment



Thanks for your comment! Please note that all comments are pre-moderated, and off-topic ones may be deleted.
For faster help, please keep your question clear and concise. While we can't guarantee a reply to every question, we'll do our best to respond :)