Many tasks you perform in Excel involve comparing data in different cells. For this, Microsoft Excel provides six logical operators, which are also called comparison operators. This tutorial aims to help you understand the insight of Excel logical operators and write the most efficient formulas for your data analysis.

## Excel logical operators - overview

A logical operator is used in Excel to compare two values. Logical operators are sometimes called Boolean operators because the result of the comparison in any given case can only be either TRUE or FALSE.

Six logical operators are available in Excel. The following table explains what each of them does and illustrates the theory with formula examples.

Condition | Operator | Formula Example | Description |

Equal to | = | =A1=B1 | The formula returns TRUE if a value in cell A1 is equal to the values in cell B1; FALSE otherwise. |

Not equal to | <> | =A1<>B1 | The formula returns TRUE if a value in cell A1 is not equal to the value in cell B1; FALSE otherwise. |

Greater than | > | =A1>B1 | The formula returns TRUE if a value in cell A1 is greater than a value in cell B1; otherwise it returns FALSE. |

Less than | < | =A1<B1 | The formula returns TRUE if a value in cell A1 is less than in cell B1; FALSE otherwise. |

Greater than or equal to | >= | =A1>=B1 | The formula returns TRUE if a value in cell A1 is greater than or equal to the values in cell B1; FALSE otherwise. |

Less than or equal to | <= | =A1<=B1 | The formula returns TRUE if a value in cell A1 is less than or equal to the values in cell B1; FALSE otherwise. |

The screenshot below demonstrates the results returned by *Equal to*, *Not equal to*, *Greater than* and *Less than* logical operators:

It may seem that the above table covers it all and there's nothing more to talk about. But in fact, each logical operator has its own specificities and knowing them can help you harness the real power of Excel formulas.

### Using "Equal to" logical operator in Excel

The *Equal to* logical operator (=) can be used to compare all data types - numbers, dates, text values, Booleans, as well as the results returned by other Excel formulas. For example:

=A1=B1 | Returns TRUE if the values in cells A1 and B1 are the same, FALSE otherwise. |

=A1="oranges" | Returns TRUE if cells A1 contain the word "oranges", FALSE otherwise. |

=A1=TRUE | Returns TRUE if cells A1 contain the Boolean value TRUE, otherwise it returns FALSE. |

=A1=(B1/2) | Returns TRUE if a number in cell A1 is equal to the quotient of the division of B1 by 2, FALSE otherwise. |

#### Example 1. Using the "Equal to" operator with dates

You might be surprised to know that the *Equal to* logical operator cannot compare dates as easily as numbers. For example, if the cells A1 and A2 contain the date "12/1/2014", the formula `=A1=A2`

will return TRUE exactly as it should.

However, if you try either `=A1=12/1/2014`

or `=A1="12/1/2014"`

you will get FALSE as the result. A bit unexpected, eh?

The point is that Excel stores dates as numbers beginning with 1-Jan-1900, which is stored as 1. The date 12/1/2014 is stored as 41974. In the above formulas, Microsoft Excel interprets "12/1/2014" as a usual text string, and since "12/1/2014" is not equal to 41974, it returns FALSE.

To get the correct result, you must always wrap a date in the DATEVALUE function, like this `=A1=DATEVALUE("12/1/2014")`

Note. The DATEVALUE function needs to be used with other logical operator as well, as demonstrated in the examples that follow.

The same approach should be applied when you use Excel's equal to operator in the logical test of the IF function. You can find more info as well as a few formula examples in this tutorial: Using Excel IF function with dates.

#### Example 2. Using the "Equal to" operator with text values

Using Excel's *Equal to* operator with text values does not require any extra twists. The only thing you should keep in mind is that the *Equal to* logical operator in Excel is **case-insensitive**, meaning that case differences are ignored when comparing text values.

For example, if cell A1 contains the word "*oranges*" and cell B1 contains "*Oranges*", the formula `=A1=B1`

will return TRUE.

If you want to compare text values taking in to account their case differences, you should use the EXACT function instead of the *Equal to* operator. The syntax of the EXACT function is as simple as:

Where text 1 and text2 are the values you want to compare. If the values are exactly the same, including case, Excel returns TRUE; otherwise, it returns FALSE. You can also use the EXACT function in IF formulas when you need a case-sensitive comparison of text values, as shown in the below screenshot:

Note. If you want to compare the length of two text values, you can use the LEN function instead, for example `=LEN(A2)=LEN(B2)`

or `=LEN(A2)>=LEN(B2)`

.

#### Example 3. Comparing Boolean values and numbers

There is a widespread opinion that in Microsoft Excel the Boolean value of TRUE always equates to 1 and FALSE to 0. However, this is only partially true, and the key word here is "always" or more precisely "not always" : )

When writing an 'equal to' logical expression that compares a Boolean value and a number, you need to specifically point out for Excel that a non-numeric Boolean value should be treated as a number. You can do this by adding the double minus sign in front of a Boolean value or a cell reference, e. g. `=A2=--TRUE`

or `=A2=--B2`

.

The 1^{st} minus sign, which is technically called the unary operator, coerces TRUE/FALSE to -1/0, respectively, and the second unary negates the values turning them into +1 and 0. This will probably be easier to understand looking at the following screenshot:

Note. You should add the double unary operator before a Boolean when using other logical operators such as *not equal to*, *greater than* or *less than* to correctly compare a numeric and Boolean values.

When using logical operators in complex formulas, you might also need to add the double unary before each logical expression that returns TRUE or FALSE as the result. Here's an example of such a formula: SUMPRODUCT and SUMIFS in Excel.

### Using "Not equal to" logical operator in Excel

You use Excel's *Not equal to* operator (<>) when you want to make sure that a cell's value is not equal to a specified value. The use of the *Not equal to* operator is very similar to the use of *Equal to * that we discussed a moment ago.

The results returned by the *Not equal to* operator are analogous to the results produced by the Excel NOT function that reverses the value of its argument. The following table provides a few formula examples.

Not equal to operator | NOT function | Description |

=A1<>B1 | =NOT(A1=B1) | Returns TRUE if the values in cells A1 and B1 are not the same, FALSE otherwise. |

=A1<>"oranges" | =NOT(A1="oranges") | Returns TRUE if cell A1 contains any value other than "oranges", FALSE if it contains "oranges" or "ORANGES" or "Oranges", etc. |

=A1<>TRUE | =NOT(A1=TRUE) | Returns TRUE if cell A1 contains any value other than TRUE, FALSE otherwise. |

=A1<>(B1/2) | =NOT(A1=B1/2) | Returns TRUE if a number in cell A1 is not equal to the quotient of the division of B1 by 2, FALSE otherwise. |

=A1<>DATEVALUE("12/1/2014") | =NOT(A1=DATEVALUE("12/1/2014")) | Returns TRUE if A1 contains any value other than the date of 1-Dec-2014, regardless of the date format, FALSE otherwise. |

### Greater than, less than, greater than or equal to, less than or equal to

You use these logical operators in Excel to check how one number compares to another. Microsoft Excel provides 4 comparison operates whose names are self-explanatory:

- Greater than (>)
- Greater than or equal to (>=)
- Less than (<)
- Less than or equal to (<=)

Most often, Excel comparison operators are used with numbers, date and time values. For example:

=A1>20 | Returns TRUE if a number in cell A1 is greater than 20, FALSE otherwise. |

=A1>=(B1/2) | Returns TRUE if a number in cell A1 is greater than or equal to the quotient of the division of B1 by 2, FALSE otherwise. |

=A1<DATEVALUE("12/1/2014") | Returns TRUE if a date in cell A1 is less than 1-Dec-2014, FALSE otherwise. |

=A1<=SUM(B1:D1) | Returns TRUE if a number in cell A1 is less than or equal to the sum of values in cells B1:D1, FALSE otherwise. |

#### Using Excel comparison operators with text values

In theory, you can also use the *greater than*, *greater than or equal to* operators as well as their *less than* counterparts with text values. For example, if cell A1 contains "*apples*" and B1 contains "*bananas*", guess what the formula `=A1>B1`

will return? Congratulations to those who've staked on FALSE : )

When comparing text values, Microsoft Excel ignores their case and compares the values symbol by symbol, "a" being considered the lowest text value and "z" - the highest text value.

So, when comparing the values of "*apples*" (A1) and "*bananas*" (B1), Excel starts with their first letters "a" and "b", respectively, and since "b" is greater than "a", the formula `=A1>B1`

returns FALSE.

If the first letters are the same, then the 2^{nd} letters are compared, if they happen to be identical too, then Excel gets to the 3^{rd}, 4^{th} letters and so on. For example, if A1 contained "*apples*" and B1 contained "*agave*", the formula `=A1>B1`

would return TRUE because "p" is greater than "g".

At first sight, the use of comparison operators with text values seems to have very little practical sense, but you never know what you might need in the future, so probably this knowledge will prove helpful to someone.

## Common uses of logical operators in Excel

In real work, Excel logical operators are rarely used on their own. Agree, the Boolean values TRUE and FALSE they return, though very true (excuse the pun), are not very meaningful. To get more sensible results, you can use logical operators as part of Excel functions or conditional formatting rules, as demonstrated in the below examples.

#### 1. Using logical operators in arguments of Excel functions

When it comes to logical operators, Excel is very permissive and allows using them in parameters of many functions. One of the most common uses is found in Excel IF function where the comparison operators can help to construct a logical test, and the IF formula will return an appropriate result depending on whether the test evaluates to TRUE or FALSE. For example:

`=IF(A1>=B1, "OK", "Not OK")`

This simple IF formula returns OK if a value in cell A1 is greater than or equal to a value in cell B1, "Not OK" otherwise.

And here's another example:

`=IF(A1<>B1, SUM(A1:C1), "")`

The formula compares the values in cells A1 and B1, and if A1 is not equal to B1, the sum of values in cells A1:C1 is returned, an empty string otherwise.

Excel logical operators are also widely used in special IF functions such as SUMIF, COUNTIF, AVERAGEIF and their plural counterparts that return a result based on a certain condition or multiple conditions.

You can find a wealth of formula examples in the following tutorials:

#### 2. Using Excel logical operators in mathematical calculations

Of course, Excel functions are very powerful, but you don't always have to use them to achieve the desired result. For example, the results returned by the following two formulas are identical:

IF function: `=IF(B2>C2, B2*10, B2*5)`

Formula with logical operators: `=(B2>C2)*(B2*10)+(B2<=C2)*(B2*5)`

I guess the IF formula is easier to interpret, right? It tells Excel to multiply a value in cell B2 by 10 if B2 is greater than C2, otherwise the value in B1 is multiplied by 5.

Now, let's analyze what the 2^{nd} formula with the *greater than* and *less than or equal to* logical operators does. It helps to know that in mathematical calculations Excel does equate the Boolean value TRUE to 1, and FALSE to 0. Keeping this in mind, let's see what each of the logical expressions actually returns.

If a value in cell B2 is greater than a value in C2, then the expression B2>C2 is TRUE, and consequently equal to 1. On the other hand, B2<=C2 is FALSE and equal to 0. So, given that B2>C2, our formula undergoes the following transformation:

Since any number multiplied by zero gives zero, we can cast away the second part of the formula after the plus sign. And because any number multiplied by 1 is that number, our complex formula turns into a simple =B2*10 that returns the product of multiplying B2 by 10, which is exactly what the above IF formula does : )

Obviously, if a value in cell B2 is less than in C2, then the expression B2>C2 evaluates to FALSE (0) and B2<=C2 to TRUE (1), meaning that the reverse of the described above will occur.

#### 3. Logical operators in Excel conditional formatting

Another common use of logical operators is found in Excel Conditional Formatting that lets you quickly highlight the most important information in a spreadsheet.

For example, the following simple rules highlight selected cells or entire rows in your worksheet depending on a value in column A:

Less than (orange): `=A1<5`

Greater than (green): `=A1>20`

For the detailed-step-by-step instructions and rule examples, please see the following articles:

As you see, the use of logical operators in Excel is intuitive and easy. In the next article, we are going to learn the nuts and bolts of Excel logical functions that allow performing more than one comparison in a formula. Please stay tuned and thank you for reading!

## 1256 comments

Trying again...

IF cell A=Apples and cell B10 but 20 but <30, then return cell C=500.

IF cell A=Grapes and cell B10 but 20 but <30, then return cell C=300.

IF Cell A=Apples and cell B10 but 20 but <30, then return cell C=500. IF cell A=Grapes and cell B10 but 20 but <30, then return cell C=300.

I don't know why I'm not able to publish my complete question. there is more to the above logic that I'm looking to add.

For some reason, it didn't post my complete question.

IF Cell A=Apples and cell B10 but 20 but <30, then return cell C=500. IF cell A=Grapes and cell B10 but 20 but <30, then return cell C=300.

I meant,

IF Cell A=Apples and cell B10 but 20 but <30, then return cell C=500.

IF cell A=Grapes and cell B10 but 20 but <30, then return cell C=300.

Hello, looking for formula for the below logical statement,

IF cell A=Apples and cell B10 but 20 but <30, then return cell C=500.

IF cell A=Grapes and cell B10 but 20 but <30, then return cell C=300.

Appreciate your help!!

cell A1=K, cell A2=L, Cell A3=K

Cell B1=10-Feb-2016, Cell B2=02-Feb-2016, cell B3=15-Feb-2016.

I need equation at cell A4 to show the maximum date relevant to item K (In column A) from the dates in column B, which is 15-Feb-2016.

Please advise me which formula should I use.

Thank you in advance.

iN ONE CELL"32*34*36" ,WANT TO MULTIPLY IN ANOTHER CELL WITHOUT RETYPING .iS IT POSSIBLE?

***HELP!!***

I need a formula for the following. It's kind of a multi-step process:

1. If A1=A2 and B1=B2, then return value TRUE.

2. If A1=A2 and B1B2, then return value FALSE.

3. But if A1A2, then disregard formula/leave blank.

I meant to say:

1. If A1=A2 and B1=B2, then return value TRUE.

2. If A1=A2 and B1 doesn't equal B2, then return FALSE.

3. But if A1 doesn't equal A2, then disregard formula/leave blank.

Hi Cameron,

Try the following formula:

=IF(AND(A1=A2, B1=B2), TRUE, IF(AND(A1=A2, B1<>B2), FALSE, ""))

I know it's confusing, but I ONLY want the B values to equal each other if the A values are equal... If the A values aren't equal, then I want the B values to forget that command and revert to only like values...Here's an example of what I mean:

A1:A7 all have the same value. If B1=B2=B3...=B7 then great! If B1:B7 DON'T have equal values, then I need an error notice. After A1:A7, there is another group of DIFFERENT like-values...A8:A15. For all of these, I need B8=B9=B10...=B15. If they don't, I need an error. Hope that helps.

Cameron,

My previous formula works for 2 cells only (A1 and A2). To compare groups of 7 cells, try the following one:

=IF(AND(COUNTIF($A$1:$A$7, $A1)=7, COUNTIF($B$1:$B$7, $B1)=7), TRUE, IF(AND(COUNTIF($A$1:$A$7, $A1)=7, COUNTIF($B$1:$B$7, $B1)<>7), FALSE, ""))

If cells A1:A7 have the same values and B1:B7 have the same values, the formula returns TRUE.

If cells A1:A7 have the same values but B1:B7 have different values, the formula returns FALSE. You can change this to any error message you want.

Otherwise, the formula returns an empty string.

Hi Svetlana!

Thank you so much for your quick replies. When I tried to enter this last formula, it gave me a notice for a circular reference? I clicked ok, and the formula returned a zero. Any ideas what this means/how to fix?

Secondly, I have an even more complex question for you (if that wasn't already hard enough). What if my first group is A1:A7 but the next grouping is A8:A18? What if it isn't always groups of 7, but it varies group size randomly down column A? Is there any way I can enter a formula to predict this, and always have the corresponding B values equal? (Where B1:B7 are equal and then B8:B18 would be equal, etc.) Again, I just need the formula to return True or False for these groupings. Thanks!!

If one date is greater than another date I need a return value of true and a count of the difference. Example if 02/01/2016 thru 02/06/2016 equals 5 days then true if not false. Also how many day greater or less? I will need the formula to continue throughout the year.

hi,

i want the cell to compare a number with another cell and copy the cell with greater value

I am struggling with this simple task .. can you pls help ?

I have an excel sheet with over 20,000 products with weight in decimals. I am trying to do this :

if weight is greater than 0.00 and/equal 1.0 then "0-1 lbs"

If weight is greater than 1.10 and/equal 2.00 then "1 and 2 lbs"

I am using =IF(AND(A2>0,A2<1),"0-1 lbs","") but this is not working for decimals

examples :

Weight (lbs)

0.10

0.01

0.02

0.03

0.04

0.05

0.06

0.07

0.08

0.09

0.10

0.11

0.12

0.13

Hi Vinay,

Try this one:

=IF(AND(A2>1.1,A2<=2),"1 and 2 lbs", IF(A2>0,"0-1 lbs",""))

Hello I have a weird request. So here is what I can tell you about this problem we have a system that if we reach 10.00 that is 100% if it falls below that then it is greater than 100% if it is greater than 10.00 then it would be lower than 100%. Is there a formula to do in excel that can figure this out or not really?

Hi there, need some help with between formula below is the formula I am trying to create

=if(r38 is between 0.5 and 8.5,U42,if(r38>9,0,if(r38 is between 9 and 14.5,v42,if(r38>14.5,0,if(r38 is between 15 and 18.5,w42,if(r38>18,0,if(r38=18.5 +,X42

Thank you,

the formula type out wrong...

it's

=IF(B18011200;40%*B1)

Hi Celeste,

Our blog engine often mangles formulas in comments, sorry for that.

Try the following formula:

=IF(B1>=1201; 40%*B1, IF(B1>=801; 30%*B1; 20%*B1))

It worked! Thank you Svetlana!!!

I need a help guyz..for eg when x>20 should proceed with a formula or when x<20 takes the other.please help me to create a formula buddies

What formulas you want to see when one of the conditions is met? Also, is 'x' in 'x>20' is a cell reference? Give us more details, so we would be able to help you out.

Hi Svetlana!

I need to automatically calculate, with a formula, for discounts in cell B1:

20% discount: less than $800 orders;

30% discount: orders from $801 to $1,200; and

40% discount: orders over $ 1,201.

I've used:

=IF(B18011200;40%*B1)

and I get the 20% and 40% discount calculation, but the 30% calculation is wrong. Can you correct it for me?

Thanks!

I want to multiply 2 cells, A11 and L11, but if the product is <=0 I want to enter Cell A11.

Hi Marlone ,

Try the following formula:

=IF(A1*L11<=0, A11, A1*L11)

Hello Svetlana could You please help

In cell H-4 I have an amt. 139629.11

In cell I-4 I need if formula showing down the column when copied

if the amt in h4 is same 00 if its grater show the difference if its less show the difference.

I am just an amateur mathematician but I do not know how to bit it

something is missing there

Thanks for Your help in advance. Jozef

Hi Svetlana!

In cell A1 I have the total sum of the order.

I need to automatically calculate, with a formula, for discounts in cell B1:

20% discount: less than $800 orders;

30% discount: orders from $801 to $1,200; and

40% discount: orders over $ 1,201.

Can you please help me?

Thanks!

I wanted to align my stock price bandwise with and if & and formulas please suggest

suppose Cell E Contains following and i wanted priceband 0-2, 2.1-5, 5.1-8, 8.1-12, 12.1-18 & 25+

100000

99990

299900

387666

789000

900000

1015000

1815000

1215000

1315000

2500000

Hi, I'm stuck and looking for help please.

I need to take a range of cells with dollar values and compare them to one cell with another dollar value. The range of cells which has the least dollar amount I need to show up as highlighted in a different colour. For example:

A1 = $100

Compare values in A2-A10, if A6 has the least (cheapest) value ($99) then this cell is highlighted in a stand out colour

Any help is greatly appreciated.