by In this article, you will learn how to build an Excel IF statement for different types of values as well as how to create multiple IF statements.
IF is one of the most popular and useful functions in Excel. Generally, you use an IF statement to test a condition and to return one value if the condition is met, and another value if the condition is not met.
In this tutorial, we are going to learn the syntax and common usages of the Excel IF function, and then take a closer look at formula examples that will hopefully prove helpful to both beginners and experienced users.
IF function in Excel
IF is one of logical functions that evaluates a certain condition and returns one value if the condition is TRUE, and another value if the condition is FALSE.
The syntax of the IF function is as follows:
As you see, IF takes a total of 3 arguments, but only the first one is obligatory, the other two are optional.
Logical_test (required) - the condition to test. Can be evaluated as either TRUE or FALSE.
Value_if_true (optional) - the value to return when the logical test evaluates to TRUE, i.e. the condition is met. If omitted, the value_if_false argument must be defined.
Value_if_false (optional) - the value to return when the logical test evaluates to FALSE, i.e. the condition is not met. If omitted, the value_if_true argument must be set.
Basic IF formula in Excel
To create a simple If then statement in Excel, this is what you need to do:
- For logical_test, write an expression that returns either TRUE or FALSE. For this, you'd normally use one of the logical operators.
- For value_if_true, specify what to return when the logical test evaluates to TRUE.
- For value_if_false, specify what to return when the logical test evaluates to FALSE. Though this argument is optional, we recommend always configuring it to avoid unexpected results. For the detailed explanation, please see Excel IF: things to know.
As an example, let's write a very simple IF formula that checks a value in cell A2 and returns "Good" if the value is greater than 80, "Bad" otherwise:
=IF(B2>80, "Good", "Bad")
This formula goes to C2, and then is copied down through C7:
In case you wish to return a value only when the condition is met (or not met), otherwise - nothing, then use an empty string ("") for the "undefined" argument. For example:
=IF(B2>80, "Good", "")
This formula will return "Good" if the value in A2 is greater than 80, a blank cell otherwise:
Excel If then formula: things to know
Though the last two parameters of the IF function are optional, your formula may produce unexpected results if you don't know the underlying logic.
If value_if_true is omitted
If the 2nd argument of your Excel IF formula is omitted (i.e. there are two consecutive commas after the logical test), you'll get zero (0) when the condition is met, which makes no sense in most cases. Here is an example of such a formula:
=IF(B2>80, , "Bad")
To return a blank cell instead, supply an empty string ("") for the second parameter, like this:
=IF(B2>80, "", "Bad")
The screenshot below demonstrates the difference:
If value_if_false is omitted
Omitting the 3rd parameter of IF will produce the following results when the logical test evaluates to FALSE.
If there is just a closing bracket after value_if_true, the IF function will return the logical value FALSE. Quite unexpected, isn't it? Here is an example of such a formula:
=IF(B2>80, "Good")
Typing a comma after the value_if_true argument will force Excel to return 0, which doesn't make much sense either:
=IF(B2>80, "Good",)
The most reasonable approach is using a zero-length string ("") to get a blank cell when the condition is not met:
=IF(B2>80, "Good", "")
Tip. To return a logical value when the specified condition is met or not met, supply TRUE for value_if_true and FALSE for value_if_false. For the results to be Boolean values that other Excel functions can recognize, don't enclose TRUE and FALSE in double quotes as this will turn them into normal text values.
Using IF function in Excel - formula examples
Now that you are familiar with the IF function's syntax, let's look at some formula examples and learn how to use If then statements in real-life scenarios.
Excel IF function with numbers
To build an IF statement for numbers, use logical operators such as:
- Equal to (=)
- Not equal to (<>)
- Greater than (>)
- Greater than or equal to (>=)
- Less than (<)
- Less than or equal to (<=)
Above, you have already seen an example of such a formula that checks if a number is greater than a given number.
And here's a formula that checks if a cell contains a negative number:
=IF(B2<0, "Invalid", "")
For negative numbers (which are less than 0), the formula returns "Invalid"; for zeros and positive numbers - a blank cell.
Excel IF function with text
Commonly, you write an IF statement for text values using either "equal to" or "not equal to" operator.
For example, the following formula checks the Delivery Status in B2 to determine whether an action is required or not:
=IF(B2="delivered", "No", "Yes")
Translated into plain English, the formula says: return "No" if B2 is equal to "delivered", "Yes" otherwise.
Another way to achieve the same result is to use the "not equal to" operator and swap the value_if_true and value_if_false values:
=IF(C2<>"delivered", "Yes", "No")
Notes:
- When using text values for IF's parameters, remember to always enclose them in double quotes.
- Like most other Excel functions, IF is case-insensitive by default. In the above example, it does not differentiate between "delivered", "Delivered", and "DELIVERED".
Case-sensitive IF statement for text values
To treat uppercase and lowercase letters as different characters, use IF in combination with the case-sensitive EXACT function.
For example, to return "No" only when B2 contains "DELIVERED" (the uppercase), you'd use this formula:
=IF(EXACT(B2,"DELIVERED"), "No", "Yes")
If cell contains partial text
In situation when you want to base the condition on partial match rather than exact match, an immediate solution that comes to mind is using wildcards in the logical test. However, this simple and obvious approach won't work. Many functions accept wildcards, but regrettably IF is not one of them.
A working solution is to use IF in combination with ISNUMBER and SEARCH (case-insensitive) or FIND (case-sensitive).
For example, in case "No" action is required both for "Delivered" and "Out for delivery" items, the following formula will work a treat:
=IF(ISNUMBER(SEARCH("deliv", B2)), "No", "Yes")
For more information, please see:
Excel IF statement with dates
At first sight, it may seem that IF formulas for dates are akin to IF statements for numeric and text values. Regrettably, it is not so. Unlike many other functions, IF does recognize dates in logical tests and interprets them as mere text strings. In other words, you cannot supply a date in the form of "1/1/2020" or ">1/1/2020". To make the IF function recognize a date, you need to wrap it in the DATEVALUE function.
For example, here's how you can check if a given date is greater than another date:
=IF(B2>DATEVALUE("7/18/2022"), "Coming soon", "Completed")
This formula evaluates the dates in column B and returns "Coming soon" if a game is scheduled for 18-Jul-2022 or later, "Completed" for a prior date.
Of course, there is nothing that would prevent you from entering the target date in a predefined cell (say E2) and referring to that cell. Just remember to lock the cell address with the $ sign to make it an absolute reference. For instance:
=IF(B2>$E$2, "Coming soon", "Completed")
To compare a date with the current date, use the TODAY() function. For example:
=IF(B2>TODAY(), "Coming soon", "Completed")
Excel IF statement for blanks and non-blanks
If you are looking to somehow mark your data based on a certain cell(s) being empty or not empty, you can either:
- Use the IF function together with ISBLANK, or
- Use the logical expressions ="" (equal to blank) or <>"" (not equal to blank).
The table below explains the difference between these two approaches with formula examples.
| Logical test | Description | Formula Example | |
| Blank cells | ="" |
Evaluates to TRUE if a cell is visually empty, even if it contains a zero-length string. Otherwise, evaluates to FALSE. |
=IF(A1="", 0, 1)
Returns 0 if A1 is visually blank. Otherwise returns 1. If A1 contains an empty string (""), the formula returns 0. |
| ISBLANK() |
Evaluates to TRUE is a cell contains absolutely nothing - no formula, no spaces, no empty strings. Otherwise, evaluates to FALSE. |
=IF( Returns 0 if A1 is absolutely empty, 1 otherwise. If A1 contains an empty string (""), the formula returns 1. |
|
| Non-blank cells | <>"" | Evaluates to TRUE if a cell contains some data. Otherwise, evaluates to FALSE.
Cells with zero-length strings are considered blank. |
=IF( Returns 1 if A1 is non-blank; 0 otherwise. If A1 contains an empty string, the formula returns 0. |
| ISBLANK() |
Evaluates to TRUE if a cell is not empty. Otherwise, evaluates to FALSE.
Cells with zero-length strings are considered non-blank. |
=IF( Works the same as the above formula, but returns 1 if A1 contains an empty string. |
And now, let's see blank and non-blank IF statements in action. Suppose you have a date in column B only if a game has already been played. To label the completed games, use one of these formulas:
=IF(B2="", "", "Completed")
=IF(ISBLANK(B2), "", "Completed")
=IF($B2<>"", "Completed", "")
=IF(ISBLANK($B2)=FALSE, "Completed", "")
In case the tested cells have no zero-length strings, all the formulas will return exactly the same results:
Check if two cells are the same
To create a formula that checks if two cells match, compare the cells by using the equals sign (=) in the logical test of IF. For example:
=IF(B2=C2, "Same score", "")
To check if the two cells contain same text including the letter case, make your IF formula case-sensitive with the help of the EXACT function.
For instance, to compare the passwords in A2 and B2, and returns "Match" if the two strings are exactly the same, "Do not match" otherwise, the formula is:
=IF(EXACT(A2, B2), "Match", "Don't match")
IF then formula to run another formula
In all of the previous examples, an Excel IF statement returned values. But it can also perform a certain calculation or execute another formula when a specific condition is met or not met. For this, embed another function or arithmetic expression in the value_if_true and/or value_if_false arguments.
For example, if B2 is greater than 80, we'll have it multiplied by 7%, otherwise by 3%:
=IF(B2>80, B2*7%, B2*3%)
Multiple IF statements in Excel
In essence, there are two ways to write multiple IF statements in Excel:
- Nesting several IF functions one into another
- Using the AND or OR function in the logical test
Nested IF statement
Nested IF functions let you place multiple IF statements in the same cell, i.e. test multiple conditions within one formula and return different values depending on the results of those tests.
Assume your goal is to assign different bonuses based on the score:
- Over 90 - 10%
- 90 to 81 - 7%
- 80 to 70 - 5%
- Less than 70 - 3%
To accomplish the task, you write 3 separate IF functions and nest them one into another like this:
=IF(B2>90, 10%, IF(B2>=81, 7%, IF(B2>=70, 5%, 3%)))
For more formula examples, please see:
Excel IF statement with multiple conditions
To evaluate several conditions with the AND or OR logic, embed the corresponding function in the logical test:
For example, to return "Pass" if both scores in B2 and C2 are higher than 80, the formula is:
=IF(AND(B2>80, C2>80), "Pass", "Fail")
To get "Pass" if either score is higher than 80, the formula is:
=IF(OR(B2>80, C2>80), "Pass", "Fail")
For full details, please visit:
If error in Excel
Starting from Excel 2007, we have a special function, named IFERROR, to check formulas for errors. In Excel 2013 and higher, there is also the IFNA function to handle #N/A errors.
And still, there may be some circumstances when using the IF function together with ISERROR or ISNA is a better solution. Basically, IF ISERROR is the formula to use when you want to return something if error and something else if no error. The IFERROR function is unable to do that as it always returns the result of the main formula if it isn't an error.
For example, to compare each score in column B against the top 3 scores in E2:E4, and return "Yes" if a match is found, "No" otherwise, you enter this formula in C2, and then copy it down through C7:
=IF(ISERROR(MATCH(B2, $E$2:$E$4, 0)), "No", "Yes" )
For more information, please see IF ISERROR formula in Excel.
Hopefully, our examples have helped you get a grasp of the Excel IF basics. I thank you for reading and hope to see you on our blog next week!
Practice workbook
Excel IF statement - formula examples (.xlsx file)
4721 comments
Hi, i hope you can help me with this. I'd really appreciate it. I'm not that good with formulas. I need to do a calander. I have a drop down box with every month. I need the calendar to put the dates 1-31 under the right day for each month that is selected from the drop down box. Any suggestings? Please
hi,
I need to have 2 cells which only can have 2 times to use,
if the 3rd data occurred , then it will show nok.
example :
352 5 ok
352 5 ok
353 4 ok
353 4 ok
354 3 ok
354 3 ok
354 3 nok
Hi Svetlana, Can you please help. I have about 50 persons names who must complete +-twenty documents before a following process can start, How can I put that into a If statement. I would like to use a right mark for yes and X for not complete. Then I would like to hyperlink from a summary back to the detailed spread sheet. The summary contains several steps with several document per step.
Your help is appreciated,
Anton
Hello Anton,
To help you better, we need a sample table with your data in Excel and the result you want to get.
You can email it to support@ablebits.com. Please add the link to this article and your comment number.
Can anyone figure this out? IF there is duplicate text in column A (customer's email) THEN add their sales up in column B. (So we can determine a total customer's sales.) Thanks!!
Hi I need to make performance monitor for my team mates,
If >2 mean Poor
2 to 3 mean Good
5 mean excellent
For example:
If these are my students score
exam 1 exam 2 exam 3 exam 4 Description
72 100 100 60 .............
100 50 90 60 ............
then i want to give the description on each of exam (for example good in exam 2 and 3 but bad in exam 1 and 4) How to do like that? please help me?
Hi there! Love your site, and I use it all the time! Thanks for the help in advance.
I have dates 8/22/16-12/31/2016 (past and future)across row 2 from H2:CX2, and data for each date in cells H3:CX3. There are 650 total rows of data for each date.
I am looking to make a column starting in CY3 that provides a simple "Y", "N" if 2 conditions are met for that particular row. The formula will be dragged down to all 650 rows, and each row needs to be tested independently.
1. The date in H2:CX2 is greater than todays date. AND
2. The value in H3:CX3 is greater than 0.
This is what I have right now.
=IF(AND(COUNTIF($H$2:$CX$2,">"&TODAY()),COUNTIF(H3:CX3,">0")), "Y","N")
It reports a Y if the value in H3:CX3 is >0, but ignores the date part. I only want a Y if the value is associated to a future date, and an "N" if the value is from a past date.
Thank you!
I am working in time office, i want to prepare a labour wage sheet. I am giving Food only to those labour who are working at site. we have differencet trade Like mason, carpenter, Cook, washerman etc. but I want to give food allowance USD 05 per day only Mason, Carpenter, Fabricator only. Any one can help me to find out solution by using MS Excel.
I will thankful to you.
Regards
Hi Svetlana,
Can you please guide or help on my concern, It would be of great help.
I have data in sheet1 & almost same data in Sheet2 (eg:- below)
please note-the only difference is in the formation of name of medicine.
Sheet1 Sheet - 2
CLINXA 20GM GEL CLINKA GEL 20GM
CLINXA A 20GM GEL CLINXA A GEL 20GM
CLOBEN G 15GM CREAM CLOBEN G CREAM 15GM
CLOBETAMIL G 20GM CREAM CLOBETAMIL G CREAM 20GM
CLOBIREX G PLUS 10GM CREAM CLOBIREX G PLUS CREAM 10GM
how can i get value (prescription not required) after knowing that sheet1 & sheet2 has same name of medicine regardless the formation of name.
Thanks
Hitesh
Hello.
I need simple logical formula, but not understand.
It is a cell with a value of 1 or 2, and need to be a value corresponding to the name.
Please help to understand how to do it.
Thanks.
=IF(B2=1,”JĀ”,IF(B2=2,”Nē”,”Varbūt”))
Doesn't work :(
=IF(D2=1,”JĀ”,IF(D2=2,”Nē”,”Varbūt”))
This formula doesn't work :(
Dear how i can write this condition please
if total score =8 "high" if it is 6 to less than 8 "medium", if less than 6"low"
thank you
Hi Ahmad,
You can use this formula with nested IF's:
=IF(A1>=8, "high", IF(A1>=6, "medium", "low"))
hello
can i get a support please?
I need a formula that :
if there is date equal date,
if there is another thing equal empty
many thanks
Hello Ghayss,
Because in the internal Excel system, dates are stored as numbers, there is no function that can distinguish dates. The only solution that I can think of is using the ISNUMBER function within IF:
=IF(ISNUMBER(A1), A1, "")
The above formula will return the contents of A1 if there is a date or number in it, an empty string otherwise.
it works !
thanks Svetlana,,,you are Queen !!!
Hi, I try to build a formula which states if a cell contains the text value of "acq Opp ID", then the result should display only the actual ID [(right(Q2,LEN(Q2)-12)], if the cell Q2 does not contain "acq opp ID", then if the result is to be "-" (empty).
Hi KeBo,
Because IF cannot recognize wildcard characters, you can use either SEARCH (case-insensitive) or FIND (case-sensitive) function:
=IF(ISNUMBER(FIND("acq Opp ID",Q2)), RIGHT(Q2,LEN(Q2)-12), "-")
The 3rd option is using COUNTIF with wildcards:
=IF(COUNTIF(Q2,"*acq Opp ID*")>0, RIGHT(Q2,LEN(Q2)-12), "-")
Thank you SO much ! I was kind of on the right track but overthought it :)
Him
I'm trying to do the following.
Having input either S, W or N into a column. I want another column to auto fill as follows, When S = W. When W = S and when N = N.
Can you help?
Thanks
Hi Ken,
You can do this with the following formula:
=IF(A1="s", "W", IF(A1="w", "S", IF(A1="n", "N", "")))
Thanks Svetlana!
Really appreciated :)
Same query as asked by Bhimashankar. How can I use range in "IF" function.
Hi Mitul,
IF can handle arrays only in array formulas. You can find an example here:
Using Excel IF in array formulas
Hi I need a formula for following condition
in a column (sr. A3 to A23 )I have to enter some numbers, each individual number should fall within a range of 5 to 50. A1 is 5 and A2 is 50.
If the more than two values from the data are out of range, statement as "Not Acceptable" in cell A24 should appear. Otherwise "Acceptable"
If nothing has entered in the column from A3 to A23, statement "Pending should appear in cell A24.
Hi Bhimashnakar,
Try this formula:
=IF(COUNTIF(A3:A23, "")=ROWS(A3:A23), "Pending", IF(OR(COUNTIF(A3:A23, "<"&A1)>2, COUNTIF(A3:A23, ">"&A2)>2), "Not acceptable", "Acceptable"))
I require a formula where if the cell is 20 or greater it add the number 20 and if the number is less than 20 it just add whatever number is in the cell. e.g cell F1 has 14 ten it should show 14 and if cell f2 has 23 then should show the number 20 something the formula at the end, but where it doesn't just show F1 is less than 20 but the actual number in that cell? = IF(F1>20,"20",IF(F1<20,"F1"))
Hi Andre,
In Excel formulas, you should never enclose numbers and cell references in quotation marks unless you want to turn them into text strings. As soon as you remove the double quotes, the formula will work just fine:
= IF(F1>20, 20, F1)
Hi
I require a formula that will make up the difference if one cell totals less than £50 and will input the amount into that that cell?
Thanks
Hi! I feel like this one might be a bit silly for this forum, but any help is appreciated :) I'm trying to minimise entering time for a speadsheet that is used quite often.
B3 has a drop down box of crop types (canola, wheat, barley etc.). I need G3 (the excess applicable) to be 10% for canola, 0% for any other selection. If possible, I'd like to keep the "drop down box" option available for the whole G column.
Thanks! :)
HEY, WAT SHOULD THE FORMULA IF I WANT THE VALUE OF A1 IF IT IS MORE THAN O, OTHERWISE VALUE OF B1... ALSO IF BOTH A1 AND B1 HAVE SOME VALUES THEN THE VALUE SHOULD BE TAKEN OF THAT OF CELL A1.
I need a formula that does the following:
If(E13:E10<44,"0")...but if E13:E19 is over 44 the value would be E13 minus 8
Hi Kim,
Use this formula for row 13, and then copy it down to other rows:
=IF(E13<44, 0, E13-8)
Hi,
Please help me to find a formula ... I got below items
In Cell A2=Y, B2=Y, C2=Y and D2=2500
First check if A2=Y then check any or both of B2 or C2 is Y. if any or both of B2 or C2 is Y then return D2 value i.e. 2500
Again if A2=Y but none of B2 or C2 is Y then return zero
Thanks
Hello,
I want make date range selection in two columns as first date of month in one column and last of the particular month from a cell where a already put a drop down list of months from January to December.
e.g. Drop down list cell month- July
should change the two columns automatically as Starting Date and another column Ending Date.
Please help,
Thank You.
It's good formula and i satisfied filling my work life
hi can you advice me if value between A1 and B1 then multiple by C1 and if value between A2 and B2 then multiple by C2 And if value between A3 and B3 hen multiple by C3
Hi DANIEL,
Please put number in 'A1' cell OR 'B1' cell
Please use below formula..
=IF(A1>=1,"Number available in Cell A",IF(B1>=1,"Number available in Cell B","Number Not available in A and B Cells"))
If Number in A1 Cell then output: Number available in Cell A
If Number in B1 Cell then output: Number available in Cell B
If Number Not in A1 and B1 cells output: Number Not available in A and B Cells
IF I WANT TO KNOW IF THE NUMBERS IN CELL A ARE IN CELL B, WHAT COMMANDS WILL I USE?
I hope you can see my full posting this keeps removing part of my question
Hi, I have an if formulae that I want to create. I have 3 commission rates applicable at different age groups. I want to have on formulae to represent these variations.
age is=21 or =41 apply 15%
see below formulae let me know where I'm going wrong? Thanks
=IF(F4=41,L4*15%,0),IF((AND(F4>=21,F4<=40)),"L4*12.5%",0)
Ignore 1st posting
help if the validation check. for example if A1 = USD , B1 >1 , A1 = MYR, B1 < 1 otherwise 1?
Hi Jerome,
Try this:
=IF(A1="USD",B1>1,IF(A1="MYR",B<1,1))
Hi thanks for this however the result is FALSE if use the above formula. can this be put into data validation ?
Yes U put in data validation and let me know if u get any problem.
IF(M15="USD",O15>1,IF(M15="MYR",O15<1,1)) Hi venugopla. this is what i put in data validation. the cell i input will be 015 but no validation check. ie any value can be inputted
Madam, I would like to compare a cell in 'a' worksheet with the values in two columns of 'b' worksheet and would like to get the value from the third column of 'b' worksheet to 'a' work sheet
Example: =IF(AND((B4=1800),(C:C>Sheet1!B:B),(C:C<Sheet1!C:C)),Sheet1!D:D,0)
though the condition is true, it is still giving 0 only. Kindly explain it by using Array formula please.
if column a=rural and col b is less than 25 type non performing else performing.
and if column a=semi urban or urban and col b is less than 50 type non performing or else performing
Hello Svetlana,
I am beginner and don't really have much excel knowledge on complex formulas. here's my question and would be grateful if you can please answer.
I have worksheet with different tabs (named as Sales, marketing, Finance etc) and each tab has invoices recorded with dates, code and the amounts. I want to get the total value of each month for each invoice to a summary sheet. Ex: - I want to get the total value of Month May for code 7000 in all the departments.
Thank you so much for your help in advance!
Hi,
I need to analyse have a preference value for a graph and I tried using an IF formula with a score value below but it doesn't work. Is there a function I missed? Or can someone help me find a better solution? So For example
IF: (1 = Highest, 2 = Medium, 3 = Low) (P2 = 50, Q2 = 40, R2 = 30)
Butter = 1
Light Butter = 2
100% Organic Butter = 3
=IF(P4="1",P2,IF(P4="2",Q2,IF(P4="3",R2,"")))
:(
I want to check Three colums Example (A1 "T",B1"T" ,C1'E") in three Colums two colums "T" Iwant N in D colum, In three colum two colums "E" I want Y in D colum .Please give reply
Reply
Madam ,
I want to check Three coloums Example (A1 "T",B1"T" ,C1'E") in three Coloums two coloums "T" Iwant N in D coloum, In three coloum two coloums "E" I want Y in D coloum .Please give reply
is there a possibility if I select a name from a drop down list then the datas of the selected list must be displayed in next column,
e.g
in B2 i've a drop down list of continents Asia, Australia, america, Africa and if i select Asia in drop down list B2 then countries of Asia must be showed in 'C' column and same goes to other continents.
its possible but you should have a seperate data with a list with all countries. Best way is each continent on seperate sheet and then use indirect and address functions together some lookup and iserror to remove unwanted results, but this is a bit complicated to explain whitout actual data because the number of results varay depends on your choice which means that if there is some other stuff happening in the result display area you will need to give more info.
If you know how to use Pivot Tables thats the really easy way just put the continent into the fillter area the problem is that if you want to use that data afterwards you need to copy it.
a value must be selected from a list then return another value in another cell
Hi,
i wnat to know how i get the value as i want in below
A B C
-67 133 ?
In c lolum value should be only + valuse.
Means if a is -67 the she should show 133 value.
and if B is -67 then also c should show 133 value.
if
A B
Tom Mia Obc
Kon Ali gen
TOM ALI GEN
KON MIA OBC
broy ray sc
what is the formula for column B
b column fill to Mia =obc, ali = gen,ray =sc
Hi Roky
Note: Take old text in A1 column, need to add text in B column, see below formula..
=REPLACE(A1,FIND(" ",A1)+1,4,B1)
I have a value for the row. I want to know if a value (column G) = the min or the max for a range of values, else it is between (mid). the range is also listed in the same row (columns H and I).
I have the following formula:
=IF(G2=H2,"Min",(IF(G2=I2,"Max","Mid")))
All I get is FALSE. and for all possibilities,
when G2=H2
when G2=I2
when G2H2 nor I2
I am not sure why this isn't working.
I made sure the columns G, H and I are numbers, but that doesn't impact things. I am not getting a syntax error.
Thanks
Hi!
I'm trying to get a formula (either an IF function or Conditional Formatting function) to help me assign the proper Customer Name &/or Customer # to an invoice in the proper row, but it's difficult because there are numerous invoices for some customers and a few for others. Here is what the raw data looks like:
Customer # Customer Name Invoice #
123 ABC 123 - ABC <=PLEASE NOTE, not a real inv.#
312456
312376
312789
312654
312333
789 XYQW 789 - XYQW
312421
453 ZZZZZZ 453 - ZZZZZZ
321367
354754
378987
365214
333999
365409
376232
234265
Thanks for your help!
Jim
give an example what is the data and what it should become and i can make you a formula because i dont really get what is happening in your data
Hi I want to make formula for
if value>=5% and if value>=-5% then yes
Hi
i want to know how to get a value if
if e2="rl5" then Return system date - 5 days
or if e2="rl4" then return system date - 3 days
thank you!
Hi Timothy,
You can use the following formula for your Return system date column:
=IF(E2="rl5", "5 days", IF(E2="rl4", "3 days", ""))
I need help to put formula like this
If Column L from another sheet has 35 then then the value 4002 should be taken, if it has 56 then 4004, if it has 38 then 4102, if it has 39 then 4104
Please help
Hi sunny,
U write formula in Sheet1, please put value (eg:35,56,38,39...)in Sheet2..
Please try below..
=IF(Sheet2!L1=35,4002,IF(Sheet2!L1=56,4004,IF(Sheet2!L1=38,4102,IF(Sheet2!L1=39,4104,"Not in Our Range"))))
Thanks......
If there is a value in one of the cells in c5 and i5 then equate it with b4,B10,B16,B22.
NEED HELP PLEASE
I have 2 columns one has a number of calls (G) and number of seconds in the second (H). I want to have the next column to show which calls were over 18 secs and also to include the total number of calls from (G) in that cell. So if one cell in G shows 2 how would I make the IF command work. I am using right now =IF(H2>18,1*1,1*0) and that just allows me to count how many cells are over 18 secs but not the actual call amount from column G.
Thanks,
Pete
Hello,
I have a problem and I can't find a solution anywhere.
I have a sheet with dates of invoices that have been approved for different hospitals and things we need to pay them for. It's a very long sheet with main variants being 'Hospital number', 'Procedure' and 'Date of invoice approval'.
I would like to create a seperate tab with a table generating a formula which could cross check 'Hospital number', 'Procedure' and 'Date of invoice approval' from the other tab - but instead of generating a result in form of 'good' or 'bad' i would like the formula to enter the actual date of invoice approval -into the table. Not sure if this is possible?
Please help!!!???
Hi,
I am wondering if there is a way to make a cell a specific color depending on a value it has. The values come from a formula (VLOOKUP). If excel doesn't find any values then it leaves the cell blank, otherwise it writes the value which can be anything from letters to numbers (so I can't be that specific and therefore not be able to use conditional formating...). I want to color all cells which get a value and leave the blank cells white. Would you know how to tackle this issue?
Thanks!