How to use IF function in Excel: examples for text, numbers, dates, blanks

In this article, you will learn how to build an Excel IF statement for different types of values as well as how to create multiple IF statements.

IF is one of the most popular and useful functions in Excel. Generally, you use an IF statement to test a condition and to return one value if the condition is met, and another value if the condition is not met.

In this tutorial, we are going to learn the syntax and common usages of the Excel IF function, and then take a closer look at formula examples that will hopefully prove helpful to both beginners and experienced users.

IF function in Excel

IF is one of logical functions that evaluates a certain condition and returns one value if the condition is TRUE, and another value if the condition is FALSE.

The syntax of the IF function is as follows:

IF(logical_test, [value_if_true], [value_if_false])

As you see, IF takes a total of 3 arguments, but only the first one is obligatory, the other two are optional.

Logical_test (required) - the condition to test. Can be evaluated as either TRUE or FALSE.

Value_if_true (optional) - the value to return when the logical test evaluates to TRUE, i.e. the condition is met. If omitted, the value_if_false argument must be defined.

Value_if_false (optional) - the value to return when the logical test evaluates to FALSE, i.e. the condition is not met. If omitted, the value_if_true argument must be set.

Basic IF formula in Excel

To create a simple If then statement in Excel, this is what you need to do:

  • For logical_test, write an expression that returns either TRUE or FALSE. For this, you'd normally use one of the logical operators.
  • For value_if_true, specify what to return when the logical test evaluates to TRUE.
  • For value_if_false, specify what to return when the logical test evaluates to FALSE. Though this argument is optional, we recommend always configuring it to avoid unexpected results. For the detailed explanation, please see Excel IF: things to know.

As an example, let's write a very simple IF formula that checks a value in cell A2 and returns "Good" if the value is greater than 80, "Bad" otherwise:

=IF(B2>80, "Good", "Bad")

This formula goes to C2, and then is copied down through C7: Basic IF formula in Excel.

In case you wish to return a value only when the condition is met (or not met), otherwise - nothing, then use an empty string ("") for the "undefined" argument. For example:

=IF(B2>80, "Good", "")

This formula will return "Good" if the value in A2 is greater than 80, a blank cell otherwise: IF formula to return nothing when the condition is not met.

Excel If then formula: things to know

Though the last two parameters of the IF function are optional, your formula may produce unexpected results if you don't know the underlying logic.

If value_if_true is omitted

If the 2nd argument of your Excel IF formula is omitted (i.e. there are two consecutive commas after the logical test), you'll get zero (0) when the condition is met, which makes no sense in most cases. Here is an example of such a formula:

=IF(B2>80, , "Bad")

To return a blank cell instead, supply an empty string ("") for the second parameter, like this:

=IF(B2>80, "", "Bad")

The screenshot below demonstrates the difference: The behavior of the value_if_true argument.

If value_if_false is omitted

Omitting the 3rd parameter of IF will produce the following results when the logical test evaluates to FALSE.

If there is just a closing bracket after value_if_true, the IF function will return the logical value FALSE. Quite unexpected, isn't it? Here is an example of such a formula:

=IF(B2>80, "Good")

Typing a comma after the value_if_true argument will force Excel to return 0, which doesn't make much sense either:

=IF(B2>80, "Good",)

The most reasonable approach is using a zero-length string ("") to get a blank cell when the condition is not met:

=IF(B2>80, "Good", "") The behavior of the value_if_false argument.

Tip. To return a logical value when the specified condition is met or not met, supply TRUE for value_if_true and FALSE for value_if_false. For the results to be Boolean values that other Excel functions can recognize, don't enclose TRUE and FALSE in double quotes as this will turn them into normal text values.

Using IF function in Excel - formula examples

Now that you are familiar with the IF function's syntax, let's look at some formula examples and learn how to use If then statements in real-life scenarios.

Excel IF function with numbers

To build an IF statement for numbers, use logical operators such as:

  • Equal to (=)
  • Not equal to (<>)
  • Greater than (>)
  • Greater than or equal to (>=)
  • Less than (<)
  • Less than or equal to (<=)

Above, you have already seen an example of such a formula that checks if a number is greater than a given number.

And here's a formula that checks if a cell contains a negative number:

=IF(B2<0, "Invalid", "")

For negative numbers (which are less than 0), the formula returns "Invalid"; for zeros and positive numbers - a blank cell. A formula to check if a cell contains a negative number.

Excel IF function with text

Commonly, you write an IF statement for text values using either "equal to" or "not equal to" operator.

For example, the following formula checks the Delivery Status in B2 to determine whether an action is required or not:

=IF(B2="delivered", "No", "Yes")

Translated into plain English, the formula says: return "No" if B2 is equal to "delivered", "Yes" otherwise. Using the IF function with text.

Another way to achieve the same result is to use the "not equal to" operator and swap the value_if_true and value_if_false values:

=IF(C2<>"delivered", "Yes", "No")

Notes:

  • When using text values for IF's parameters, remember to always enclose them in double quotes.
  • Like most other Excel functions, IF is case-insensitive by default. In the above example, it does not differentiate between "delivered", "Delivered", and "DELIVERED".

Case-sensitive IF statement for text values

To treat uppercase and lowercase letters as different characters, use IF in combination with the case-sensitive EXACT function.

For example, to return "No" only when B2 contains "DELIVERED" (the uppercase), you'd use this formula:

=IF(EXACT(B2,"DELIVERED"), "No", "Yes") Case-sensitive IF statement for text values.

If cell contains partial text

In situation when you want to base the condition on partial match rather than exact match, an immediate solution that comes to mind is using wildcards in the logical test. However, this simple and obvious approach won't work. Many functions accept wildcards, but regrettably IF is not one of them.

A working solution is to use IF in combination with ISNUMBER and SEARCH (case-insensitive) or FIND (case-sensitive).

For example, in case "No" action is required both for "Delivered" and "Out for delivery" items, the following formula will work a treat:

=IF(ISNUMBER(SEARCH("deliv", B2)), "No", "Yes") IF cell contains partial text.

For more information, please see:

Excel IF statement with dates

At first sight, it may seem that IF formulas for dates are akin to IF statements for numeric and text values. Regrettably, it is not so. Unlike many other functions, IF does recognize dates in logical tests and interprets them as mere text strings. In other words, you cannot supply a date in the form of "1/1/2020" or ">1/1/2020". To make the IF function recognize a date, you need to wrap it in the DATEVALUE function.

For example, here's how you can check if a given date is greater than another date:

=IF(B2>DATEVALUE("7/18/2022"), "Coming soon", "Completed")

This formula evaluates the dates in column B and returns "Coming soon" if a game is scheduled for 18-Jul-2022 or later, "Completed" for a prior date. Excel IF statement with dates.

Of course, there is nothing that would prevent you from entering the target date in a predefined cell (say E2) and referring to that cell. Just remember to lock the cell address with the $ sign to make it an absolute reference. For instance:

=IF(B2>$E$2, "Coming soon", "Completed")

To compare a date with the current date, use the TODAY() function. For example:

=IF(B2>TODAY(), "Coming soon", "Completed")

Excel IF statement for blanks and non-blanks

If you are looking to somehow mark your data based on a certain cell(s) being empty or not empty, you can either:

  • Use the IF function together with ISBLANK, or
  • Use the logical expressions ="" (equal to blank) or <>"" (not equal to blank).

The table below explains the difference between these two approaches with formula examples.

  Logical test Description Formula Example
Blank cells =""

Evaluates to TRUE if a cell is visually empty, even if it contains a zero-length string.

Otherwise, evaluates to FALSE.

 =IF(A1="", 0, 1)

Returns 0 if A1 is visually blank. Otherwise returns 1.

If A1 contains an empty string (""), the formula returns 0.
ISBLANK()

Evaluates to TRUE is a cell contains absolutely nothing - no formula, no spaces, no empty strings.

Otherwise, evaluates to FALSE.

 =IF(ISBLANK(A1), 0, 1)

Returns 0 if A1 is absolutely empty, 1 otherwise.

If A1 contains an empty string (""), the formula returns 1.
Non-blank cells <>"" Evaluates to TRUE if a cell contains some data. Otherwise, evaluates to FALSE.

Cells with zero-length strings are considered blank.

 =IF(A1<>"", 1, 0)

Returns 1 if A1 is non-blank; 0 otherwise.

If A1 contains an empty string, the formula returns 0.
ISBLANK()=FALSE Evaluates to TRUE if a cell is not empty. Otherwise, evaluates to FALSE.

Cells with zero-length strings are considered non-blank.

 =IF(ISBLANK(A1)=FALSE, 0, 1)

Works the same as the above formula, but returns 1 if A1 contains an empty string.

And now, let's see blank and non-blank IF statements in action. Suppose you have a date in column B only if a game has already been played. To label the completed games, use one of these formulas:

=IF(B2="", "", "Completed")

=IF(ISBLANK(B2), "", "Completed")

=IF($B2<>"", "Completed", "")

=IF(ISBLANK($B2)=FALSE, "Completed", "")

In case the tested cells have no zero-length strings, all the formulas will return exactly the same results: IF statement for blank and non-blank cells.

Check if two cells are the same

To create a formula that checks if two cells match, compare the cells by using the equals sign (=) in the logical test of IF. For example:

=IF(B2=C2, "Same score", "") Check if two cells contain the same values.

To check if the two cells contain same text including the letter case, make your IF formula case-sensitive with the help of the EXACT function.

For instance, to compare the passwords in A2 and B2, and returns "Match" if the two strings are exactly the same, "Do not match" otherwise, the formula is:

=IF(EXACT(A2, B2), "Match", "Don't match") Case-sensitive IF formula to check if two cells match.

IF then formula to run another formula

In all of the previous examples, an Excel IF statement returned values. But it can also perform a certain calculation or execute another formula when a specific condition is met or not met. For this, embed another function or arithmetic expression in the value_if_true and/or value_if_false arguments.

For example, if B2 is greater than 80, we'll have it multiplied by 7%, otherwise by 3%:

=IF(B2>80, B2*7%, B2*3%) IF formula that runs another formula.

Multiple IF statements in Excel

In essence, there are two ways to write multiple IF statements in Excel:

  • Nesting several IF functions one into another
  • Using the AND or OR function in the logical test

Nested IF statement

Nested IF functions let you place multiple IF statements in the same cell, i.e. test multiple conditions within one formula and return different values depending on the results of those tests.

Assume your goal is to assign different bonuses based on the score:

  • Over 90 - 10%
  • 90 to 81 - 7%
  • 80 to 70 - 5%
  • Less than 70 - 3%

To accomplish the task, you write 3 separate IF functions and nest them one into another like this:

=IF(B2>90, 10%, IF(B2>=81, 7%, IF(B2>=70, 5%, 3%))) Nested IF statement.

For more formula examples, please see:

Excel IF statement with multiple conditions

To evaluate several conditions with the AND or OR logic, embed the corresponding function in the logical test:

For example, to return "Pass" if both scores in B2 and C2 are higher than 80, the formula is:

=IF(AND(B2>80, C2>80), "Pass", "Fail")

To get "Pass" if either score is higher than 80, the formula is:

=IF(OR(B2>80, C2>80), "Pass", "Fail") Excel IF statement with multiple conditions.

For full details, please visit:

If error in Excel

Starting from Excel 2007, we have a special function, named IFERROR, to check formulas for errors. In Excel 2013 and higher, there is also the IFNA function to handle #N/A errors.

And still, there may be some circumstances when using the IF function together with ISERROR or ISNA is a better solution. Basically, IF ISERROR is the formula to use when you want to return something if error and something else if no error. The IFERROR function is unable to do that as it always returns the result of the main formula if it isn't an error.

For example, to compare each score in column B against the top 3 scores in E2:E4, and return "Yes" if a match is found, "No" otherwise, you enter this formula in C2, and then copy it down through C7:

=IF(ISERROR(MATCH(B2, $E$2:$E$4, 0)), "No", "Yes" ) If error formula in Excel.

For more information, please see IF ISERROR formula in Excel.

Hopefully, our examples have helped you get a grasp of the Excel IF basics. I thank you for reading and hope to see you on our blog next week!

Practice workbook

Excel IF statement - formula examples (.xlsx file)

Table of contents

4719 comments

  1. "Monthly Grand Total(Minus Applicable Discount)-The sum of all campaign cost for each month, including postage, envelops and messaging cost. If a high volume discount is applicable, it should be calculated here as well. Keep in mind two conditions must be met before the discount can be calculated: The discount threshold must be greater than zero and the yearly total mail volume value must be greater than the threshold"
    Can you tell me the formula for this, please?

  2. Hi

    please share if function the below mentioned query

    Salary and Wage earners-Such persons whose
    monthly
    salaries or wages :-
    (a) do not exceed rupees 7,500; NIL
    (b) (i) In case of male, exceed Rs. 7,500 but do not
    exceed rupees 10,000;175 per month
    (ii) In case of female, do not exceed Rs 10,000; Nil
    (c) exceeds rupees 10,000 2,500 per annum

  3. I am trying to evaluate a date in the previous cell. If the date is before the 15th of the month I wan the evaluation cell to return the first of the month. If it is equal to or greater than the 16th of the month, I want the evaluation cell to return the 15 of that month. Examples:

    Cell A Date Cell B Returns
    10/8/16 10/1/16
    10/16/16 10/15/16
    11/3/16 11/1/16
    11/22/16 11/15/16

    Any thoughts or suggestions are really appreciated!!!

    Charles

    • Hi Charles,

      Here You Go,(Paste in B1)

      IF(DATE(YEAR(A1),MONTH(A1),DAY(A1))=DATE(YEAR(A1),MONTH(A1),"16"),DATE(YEAR(A1),MONTH(A1),"15")))

    • Hello Charles,

      Try the following formula, where A2 is the date in the "previous cell":

      =IF(DAY(A2)<16, DATE(YEAR(A2), MONTH(A2), 1), DATE(YEAR(A2), MONTH(A2), 15))

  4. This might sound simple but I'm not as bright as I'd like to think. if j48 = 9 then 10, if j48 = 10 then 9. please help

    • Hi George,

      You can use a couple of nested if's like this:

      =IF(J48=9, 10, IF(J48=10, 9, ""))

  5. In Col I Write a formula to give rank to student In Col I Write a formula to give rank to student based on below table (Without using IF Condition)

    Marks Grades
    =33 but less than 60 Pass
    >= 60 but less than 70 3rd Div
    >=70 but less than 80 2nd Div
    >=80 but less than 90 1st Div
    >=90 Distinction

    based on below table (Without using IF Condition)

    Marks Grades
    =33 but less than 60 Pass
    >= 60 but less than 70 3rd Div
    >=70 but less than 80 2nd Div
    >=80 but less than 90 1st Div
    >=90 Distinction

  6. Hi, I wish to use the sumif the range cell data as follow, it is that possible?
    If(A1=B1,C1,0),
    (A2=B2,C2,0),
    (A3=B3,C3,0),.....
    AND I would like the sum of range cell in column C

    All in one formula, is that possible?

  7. I want to say: if a certain cell equals a value and another cell equals a value then use this value

    Ps. above values are txt not numbers.

    what I got so far is IF((B19="General Trading", B20="One Payment"),"27,185","")

    but it isn't working.

    Please help me

    • Hello Mahmoud,

      You have to use an AND statement, like this:
      =IF(AND(B19="General Trading", B20="One Payment"), "27,185", "")

  8. hi,I want to use the if function like

    if the A1 is starting with s, then I1 is equal to B1-C1+D1-E1+F1-G1
    if the A1 is starting with m, then J1 is equal to B1-C1+D1-E1+F1-G1
    if the A1 is starting with z, then K1 is equal to B1-C1+D1-E1+F1-G1

    pls help me with this formula, thanks

  9. Hi I am a basic excel user, I am using excel 2016, my question is:

    I am using the formula =IF(X4030="",TODAY()-W4030) to get the result but if the cell W4030 is blank the result is some strange value, I want excel to display nothing if the cell W4030 is blank, how can i fix this. Please help. Many Thanks

  10. Hi, Svetlana,

    I would appreciate it if you could help me with this

    I am trying to display contents of a table T1 if value of D2 is BAT

    in a Cell E2 =IF((D2="BAT"),T1,"")
    but it gives #value! error. How can I display the table T1?

    T1 table is made up of G7:I11 cells.

    Looking forward to hearing from you

    Thanks in advanced.

    Warm Regards,
    Vilas.

    • Hi Vilas,

      The IF function cannot display the contents of an entire table in a single cell. You can write a formula to extract the data from the upper-left cell of your table, and then copy the formula to an empty range containing the same number of rows and columns as your table does to pull the values from other cells. For example: =IF(D2="BAT", T1, "") Where T1 is the left-most cell of the table.

  11. Hi,

    I have some values in column A(row1:row10) and column B(row1:row5). I need to compare column A values with column B, if any matches means, I need that value in column C.

    Example:

    Column A Column B Column C

    1 5 1
    2 6 2
    3 1
    4 2
    5 8 5
    6
    7
    8 8
    9
    10

    Pls give me the formula to perform above operation

  12. Hi There,

    I want to create a multiple formula as follows:
    =IF(D3=1,16000000,IF(D3=2,12000000,IF(D3=3,5000000,3000000)))

    But, it doesn't work on my Excel 2013. Is there something wrong with the formula?

    Please advise.
    Thanks.

  13. columnA ColumnB
    mango fruit
    apple fruit
    orange fruit
    pepper spice
    salt spice

    How do I input a formula under columnB to have answer either fruit or spice?

  14. i want to formula for whose name or spell starting or includes in name e.g. s the name selected.

    such as suman,sumit ,hans,kiss, then what is the formula for takeing all.

  15. Teacher 1 02:10:05 history
    Teacher 2 09:12:12 social
    Teacher 2 01:12:12 math
    Teacher 2 00:12:12 physics
    Teacher 4 06:12:12 chemistry
    Teacher 2 09:12:12 evs
    Teacher 1 07:12:12 robotics
    Teacher 2 06:12:12 syc
    Teacher 2 02:12:12 health
    Teacher 2 09:12:12 geo
    Teacher 3 02:12:12 indian his
    Teacher 3 01:12:12 french revo
    Teacher 3 01:12:12 language

    here i need to add all the value of the teacher 1.

    i.e., if "teacher 1" is true then it has to display "history,robotics"

    i use the =COUNTIF(A1:A13,"teacher 1") to count the entry of user (teachers)

    and

    i use =SUMPRODUCT(--(A1:A13="teacher 1"),B1:B13) to find the some of the product of an user (teacher)

    and i need your help for the top most "to add all the value of the teacher 1"

  16. All provided learning about excel is very helpful. Thank you Svetlana & team

  17. Hi,
    I want to to create an IF function where the true value will equal the text in a given cell from another sheet. Is it possible to set up?

    thanks

    • Hello BETHAN,

      Sure, you can do that. For example:
      =IF(1=1, Sheet2!A1, "")

  18. Hi want to get
    if i entered yes in A1,then it should return value 5 in B1,and if i entered NO in A1,then it should return value 0 in B1, is it possible to impelement.Please help me

    • Hi Anish,

      Here is the formula for B1:

      =IF(A1="yes", 5, IF(A1="no", 0, ""))

  19. Dear Madam,

    i have a cell for date and need to check the month and another cell will appear text according to the month. Example:

    Jan = Cohort 1
    Feb = Cohort 2

    A1 = 5-Jan-2015 and i want A2 to be equal to Cohort 1

    what is the formula for A2 ?

    Thank u in advance!

  20. hi, I need to replace a cell by searching another cell when contain a specific text, would you please help me to know if it is possible or not?

  21. How do I write this in the "if function" If the Quantity in Stock is less than 50, then the cell should display Order. If not, then the cell should display Ok

  22. how to find cell position in selected area or specifica area
    a b c d
    1
    2 b2
    3
    4 a4 4d

    like this

  23. i m using this formula but it working only till two slabs......

    =IF(I15=90,"120",IF(I15>=100,"124",IF(I15>=125,"130",IF(I15>150,140,IF(I15>175,142.5,IF(I15>225,143,IF(I15>250,144))))))))

  24. Dear Sir/ Madam,

    I have a rate slab.
    how i use slab by if function??? Plz Help

    KG Rate
    90 below 100.00
    90 up 120.00
    100 up 124.00
    125 up 130.00
    150 up 140.00
    175 up 142.50
    200 up 142.50
    225 up 143.00
    250 up 144.00

  25. I have a data set where i have to find if a date is between 1 March 2016 to August 2016) and if they are then yes, else No.

    • Hello Kevin,

      You can use a formula similar to this:

      =IF(AND(A1>DATEVALUE("3/1/2016"), A1

  26. My university boards horses. Monthly boarding fees are due the 3rd day of the month for the current month -- for example, for September, fees were due September 3rd. If they pay after that date, we charge them $5 a day until the 15th, for a possible total of $60.

    I would like to create a formula that will calculate how much they owe if they pay late. For example, if a person paid on September 6, they would owe $15.

    I think I can do an IF function incorporating DATEVALUE. When I tried it with the September 6 example above, I got $55 instead of $15.

    Here is part of the formula I used:

    =IF(O6DATEVALUE("9/4/2016"),5,0)+IF(O6DATEVALUE("9/5/2016"),5,0)

    which continued with the dates to 9/15/16.

  27. I need a formula that will replace the 'YES' or 'NO' with a number as I want to use this formula
    =75+(A1*3) but if that number is below 125 I want it to automatically default to 125.
    Any idea how to do this?

    I also want to be able to do this without adding an additional column?

    Thanks

  28. Hi,

    I need a cell in lets say Column A = a cell in Column B.
    It's a Reference number like this 2016SEP15-1 that needs to appear in Column B as I type it in Column A.

    As what do I set those two Cells? TEXT or GENERAL?
    How do I get them to relate or equal?

    I hope I've described it well.

    Thanks

  29. I have three set of numbers, I want the cell to tell me which on is greater by using 3,2,1.

    Example

    80 3
    50 2
    10 1

    To give me the order my the 3, 2, 1.

  30. Hi this formula correct, pls advive

    =IF(COUNTIF(P112:P133,)=_T110,(T112*0.07))*(1+$I$1)

  31. Hi
    If D5:D12 contains an X I need this to link to another sheet to show as the value of 20. I am trying to link a sheet with ticks/crosses to show the selection with a sheet that then gives these a numerical value

  32. I am a basic coder.I want to know if my cell contains any"text" and I want to take some value from another cell. Is it any Way to do that.

    example=IF(T2="text",pic value from E2)

  33. I am using the following Countifs formula:

    =COUNTIFS(C1:C200,A2,D1:D200,B1)

    The data in columns C and D are text (not numbers).

    This formula generates a zero for those that do not meet this criteria, but I would like it to display nothing (be blank) instead of displaying a zero. Is it possible to do this? THANKS!

  34. I need help formatting a pivot with labels that were not properly repeated prior to emailing it to me.

    Column C2 has a store name and column C12 has a different store name

    =If(C3="",C2,if(c4=c3,c3,___)

    But how to I get it to pick up a different store name without having to lock cell C2? My goal is to formulate this down a spreadsheet of 5,000 lines.

    Is this possible to help with my formatting?

  35. Which Formula Use In This Condition If "This=This=This==True"

  36. Hi Svetlana Cheusheva,
    Your posts helps me a lot in excel and today I am stuck in a situation. Situation is:
    In C:C column I have the codes (BR, DHN, RS, AN and so on), in F:F column I have the months number (6, 7, 10 and so on) and in I:I column fee is mentioned (2500, 4200, 3500 and so on).
    Now I wish to apply a formula in column J2, that whenever there is a code "BR" is mentioned in column C:C then it automatically multiplies the values in column F:F and I:I against the mentioned code and then gives me the sum of total value that will be generated by multiplying the different values in column F:F and I:I.
    If you can help me out.
    Regards
    Abatis

  37. Hi Svetlana Cheusheva,
    Your posts helps me a lot in excel and today I am stuck in a situation. Situation is:
    In C:C column I have the codes (BR, DHN, RS, AN and so on), in F:F column I have the months number (6, 7, 10 and so on) and in I:I column fee is mentioned (2500, 4200, 3500 and so on).
    Now I wish to apply a formula in column J2, that whenever there is a code "BR" is mentioned in column C:C then it automatically multiplies the values in column F:F and I:I against the mentioned code and then gives me the sum of total value that will be generated by multiplying the different values in column F:F and I:I.
    If you can help me out.
    Regards
    Absti

  38. if i want to do something like this then
    1 = 350 then when i type 20 value should go to 700

  39. Col A Col B Col C Col D Col E
    FAIL Total Accuracy
    Account XXX 2 2 =IF(OR(B1="pass","fail"), B2/C2,C2/D2)

    anyone, please help for me to get accuracy calculation in column e
    column b, sometimes pass or fail since this is pivot

  40. I am using a drop down box
    what i am trying to achieve is if the value 1 is selected specific text will appear if the vale 2 is entered specific text will appear and so on. so far i go to the drop down box select format cells custom
    and use this formula [=1]"octagonal";[=2]"round";"not selected";
    this works so far but i can not add options for if 3,4,or 5 are entered
    please please held of offer another solution.

  41. I want to look up a value (B1) in a specific column (B:B). If the value is found then "1", otherwise "0".

  42. Hi
    I am trying to apply a 15% discount if a "Yes" is present or 0% if a "No" is present.

    C5 has my yes/no criteria
    D5 has the amount 15% discount needs to be applied to

    Really struggling to get no errors in my formula

  43. Is there a way to carry over the excess of two numbers to another cell? For example:
    A1=74
    A2=80
    I want to add these two numbers together but it cannot exceed 100. If it does exceed 100, the excess will go to A3.
    How can I do this?

    • Hi John,

      check below...formula

      =IF(A1+A2>100,A1+A2-100,"A1, A2 sum is below to 100")

  44. i want to use the vlookup formula as per the below:-

    =IF(D349=(VLOOKUP(D349,D350:D9883,1,0)),0,VLOOKUP(D349,Stock!A:B,2,0))

    but it create error.

    please check and give solution.

  45. Here is the scenario:

    A technician grabs a piece of PC Desktop RAM and scans a bar-code into "C2" that represents a specific model number.

    The formula I need, needs to take that bar-code scanned, search through an already generated list "L1:L20" and decipher whether to change "A1" into the text "Bin1" or not.

    "Bin1" Representing if the barcode scanned is on the list "L1:L20" or not.

  46. I need help with a formula please.
    I am trying to make a formula that can write the time zone.
    so if the number starts with 458, 541 or 775 then write Pac* and if 340, 506 or 902 then Atl
    is there a way to do that ?

  47. Hi, I am using this formula and would like the answers to come back with a colour (e.g. "Within Budget" to either have green text or a green filled cell and red for any items coming back with "Over PO"). Is this possible? If so how?

    =IF(J14<=J16,"Within Budget","Over PO")

  48. Hi

    Great then =10
    Less than = 8

    what formula using in answer less than value showing

  49. Hi

    am trying to use conditional formatting to create a formula for the below but having difficulties. Please can you help!

    IF cell G3 is "Yes" highlight (Fill with colour) cell G3 to Cell A3

    Many Thanks

    GT

  50. Hey
    I need help with IF form. I now have tryed everything but still can't make it work.

    If C12 is TÖÖ then calculate in F12, E12-D12 if the C12 is ERA then calculate id G12, E12-D12 other wise it should stay empty or 0

Post a comment



Thank you for your comment!
When posting a question, please be very clear and concise. This will help us provide a quick and relevant solution to
your query. We cannot guarantee that we will answer every question, but we'll do our best :)