How to use IF function in Excel: examples for text, numbers, dates, blanks

In this article, you will learn how to build an Excel IF statement for different types of values as well as how to create multiple IF statements.

IF is one of the most popular and useful functions in Excel. Generally, you use an IF statement to test a condition and to return one value if the condition is met, and another value if the condition is not met.

In this tutorial, we are going to learn the syntax and common usages of the Excel IF function, and then take a closer look at formula examples that will hopefully prove helpful to both beginners and experienced users.

IF function in Excel

IF is one of logical functions that evaluates a certain condition and returns one value if the condition is TRUE, and another value if the condition is FALSE.

The syntax of the IF function is as follows:

IF(logical_test, [value_if_true], [value_if_false])

As you see, IF takes a total of 3 arguments, but only the first one is obligatory, the other two are optional.

Logical_test (required) - the condition to test. Can be evaluated as either TRUE or FALSE.

Value_if_true (optional) - the value to return when the logical test evaluates to TRUE, i.e. the condition is met. If omitted, the value_if_false argument must be defined.

Value_if_false (optional) - the value to return when the logical test evaluates to FALSE, i.e. the condition is not met. If omitted, the value_if_true argument must be set.

Basic IF formula in Excel

To create a simple If then statement in Excel, this is what you need to do:

  • For logical_test, write an expression that returns either TRUE or FALSE. For this, you'd normally use one of the logical operators.
  • For value_if_true, specify what to return when the logical test evaluates to TRUE.
  • For value_if_false, specify what to return when the logical test evaluates to FALSE. Though this argument is optional, we recommend always configuring it to avoid unexpected results. For the detailed explanation, please see Excel IF: things to know.

As an example, let's write a very simple IF formula that checks a value in cell A2 and returns "Good" if the value is greater than 80, "Bad" otherwise:

=IF(B2>80, "Good", "Bad")

This formula goes to C2, and then is copied down through C7: Basic IF formula in Excel.

In case you wish to return a value only when the condition is met (or not met), otherwise - nothing, then use an empty string ("") for the "undefined" argument. For example:

=IF(B2>80, "Good", "")

This formula will return "Good" if the value in A2 is greater than 80, a blank cell otherwise: IF formula to return nothing when the condition is not met.

Excel If then formula: things to know

Though the last two parameters of the IF function are optional, your formula may produce unexpected results if you don't know the underlying logic.

If value_if_true is omitted

If the 2nd argument of your Excel IF formula is omitted (i.e. there are two consecutive commas after the logical test), you'll get zero (0) when the condition is met, which makes no sense in most cases. Here is an example of such a formula:

=IF(B2>80, , "Bad")

To return a blank cell instead, supply an empty string ("") for the second parameter, like this:

=IF(B2>80, "", "Bad")

The screenshot below demonstrates the difference: The behavior of the value_if_true argument.

If value_if_false is omitted

Omitting the 3rd parameter of IF will produce the following results when the logical test evaluates to FALSE.

If there is just a closing bracket after value_if_true, the IF function will return the logical value FALSE. Quite unexpected, isn't it? Here is an example of such a formula:

=IF(B2>80, "Good")

Typing a comma after the value_if_true argument will force Excel to return 0, which doesn't make much sense either:

=IF(B2>80, "Good",)

The most reasonable approach is using a zero-length string ("") to get a blank cell when the condition is not met:

=IF(B2>80, "Good", "") The behavior of the value_if_false argument.

Tip. To return a logical value when the specified condition is met or not met, supply TRUE for value_if_true and FALSE for value_if_false. For the results to be Boolean values that other Excel functions can recognize, don't enclose TRUE and FALSE in double quotes as this will turn them into normal text values.

Using IF function in Excel - formula examples

Now that you are familiar with the IF function's syntax, let's look at some formula examples and learn how to use If then statements in real-life scenarios.

Excel IF function with numbers

To build an IF statement for numbers, use logical operators such as:

  • Equal to (=)
  • Not equal to (<>)
  • Greater than (>)
  • Greater than or equal to (>=)
  • Less than (<)
  • Less than or equal to (<=)

Above, you have already seen an example of such a formula that checks if a number is greater than a given number.

And here's a formula that checks if a cell contains a negative number:

=IF(B2<0, "Invalid", "")

For negative numbers (which are less than 0), the formula returns "Invalid"; for zeros and positive numbers - a blank cell. A formula to check if a cell contains a negative number.

Excel IF function with text

Commonly, you write an IF statement for text values using either "equal to" or "not equal to" operator.

For example, the following formula checks the Delivery Status in B2 to determine whether an action is required or not:

=IF(B2="delivered", "No", "Yes")

Translated into plain English, the formula says: return "No" if B2 is equal to "delivered", "Yes" otherwise. Using the IF function with text.

Another way to achieve the same result is to use the "not equal to" operator and swap the value_if_true and value_if_false values:

=IF(C2<>"delivered", "Yes", "No")

Notes:

  • When using text values for IF's parameters, remember to always enclose them in double quotes.
  • Like most other Excel functions, IF is case-insensitive by default. In the above example, it does not differentiate between "delivered", "Delivered", and "DELIVERED".

Case-sensitive IF statement for text values

To treat uppercase and lowercase letters as different characters, use IF in combination with the case-sensitive EXACT function.

For example, to return "No" only when B2 contains "DELIVERED" (the uppercase), you'd use this formula:

=IF(EXACT(B2,"DELIVERED"), "No", "Yes") Case-sensitive IF statement for text values.

If cell contains partial text

In situation when you want to base the condition on partial match rather than exact match, an immediate solution that comes to mind is using wildcards in the logical test. However, this simple and obvious approach won't work. Many functions accept wildcards, but regrettably IF is not one of them.

A working solution is to use IF in combination with ISNUMBER and SEARCH (case-insensitive) or FIND (case-sensitive).

For example, in case "No" action is required both for "Delivered" and "Out for delivery" items, the following formula will work a treat:

=IF(ISNUMBER(SEARCH("deliv", B2)), "No", "Yes") IF cell contains partial text.

For more information, please see:

Excel IF statement with dates

At first sight, it may seem that IF formulas for dates are akin to IF statements for numeric and text values. Regrettably, it is not so. Unlike many other functions, IF does recognize dates in logical tests and interprets them as mere text strings. In other words, you cannot supply a date in the form of "1/1/2020" or ">1/1/2020". To make the IF function recognize a date, you need to wrap it in the DATEVALUE function.

For example, here's how you can check if a given date is greater than another date:

=IF(B2>DATEVALUE("7/18/2022"), "Coming soon", "Completed")

This formula evaluates the dates in column B and returns "Coming soon" if a game is scheduled for 18-Jul-2022 or later, "Completed" for a prior date. Excel IF statement with dates.

Of course, there is nothing that would prevent you from entering the target date in a predefined cell (say E2) and referring to that cell. Just remember to lock the cell address with the $ sign to make it an absolute reference. For instance:

=IF(B2>$E$2, "Coming soon", "Completed")

To compare a date with the current date, use the TODAY() function. For example:

=IF(B2>TODAY(), "Coming soon", "Completed")

Excel IF statement for blanks and non-blanks

If you are looking to somehow mark your data based on a certain cell(s) being empty or not empty, you can either:

  • Use the IF function together with ISBLANK, or
  • Use the logical expressions ="" (equal to blank) or <>"" (not equal to blank).

The table below explains the difference between these two approaches with formula examples.

  Logical test Description Formula Example
Blank cells =""

Evaluates to TRUE if a cell is visually empty, even if it contains a zero-length string.

Otherwise, evaluates to FALSE.

 =IF(A1="", 0, 1)

Returns 0 if A1 is visually blank. Otherwise returns 1.

If A1 contains an empty string (""), the formula returns 0.
ISBLANK()

Evaluates to TRUE is a cell contains absolutely nothing - no formula, no spaces, no empty strings.

Otherwise, evaluates to FALSE.

 =IF(ISBLANK(A1), 0, 1)

Returns 0 if A1 is absolutely empty, 1 otherwise.

If A1 contains an empty string (""), the formula returns 1.
Non-blank cells <>"" Evaluates to TRUE if a cell contains some data. Otherwise, evaluates to FALSE.

Cells with zero-length strings are considered blank.

 =IF(A1<>"", 1, 0)

Returns 1 if A1 is non-blank; 0 otherwise.

If A1 contains an empty string, the formula returns 0.
ISBLANK()=FALSE Evaluates to TRUE if a cell is not empty. Otherwise, evaluates to FALSE.

Cells with zero-length strings are considered non-blank.

 =IF(ISBLANK(A1)=FALSE, 0, 1)

Works the same as the above formula, but returns 1 if A1 contains an empty string.

And now, let's see blank and non-blank IF statements in action. Suppose you have a date in column B only if a game has already been played. To label the completed games, use one of these formulas:

=IF(B2="", "", "Completed")

=IF(ISBLANK(B2), "", "Completed")

=IF($B2<>"", "Completed", "")

=IF(ISBLANK($B2)=FALSE, "Completed", "")

In case the tested cells have no zero-length strings, all the formulas will return exactly the same results: IF statement for blank and non-blank cells.

Check if two cells are the same

To create a formula that checks if two cells match, compare the cells by using the equals sign (=) in the logical test of IF. For example:

=IF(B2=C2, "Same score", "") Check if two cells contain the same values.

To check if the two cells contain same text including the letter case, make your IF formula case-sensitive with the help of the EXACT function.

For instance, to compare the passwords in A2 and B2, and returns "Match" if the two strings are exactly the same, "Do not match" otherwise, the formula is:

=IF(EXACT(A2, B2), "Match", "Don't match") Case-sensitive IF formula to check if two cells match.

IF then formula to run another formula

In all of the previous examples, an Excel IF statement returned values. But it can also perform a certain calculation or execute another formula when a specific condition is met or not met. For this, embed another function or arithmetic expression in the value_if_true and/or value_if_false arguments.

For example, if B2 is greater than 80, we'll have it multiplied by 7%, otherwise by 3%:

=IF(B2>80, B2*7%, B2*3%) IF formula that runs another formula.

Multiple IF statements in Excel

In essence, there are two ways to write multiple IF statements in Excel:

  • Nesting several IF functions one into another
  • Using the AND or OR function in the logical test

Nested IF statement

Nested IF functions let you place multiple IF statements in the same cell, i.e. test multiple conditions within one formula and return different values depending on the results of those tests.

Assume your goal is to assign different bonuses based on the score:

  • Over 90 - 10%
  • 90 to 81 - 7%
  • 80 to 70 - 5%
  • Less than 70 - 3%

To accomplish the task, you write 3 separate IF functions and nest them one into another like this:

=IF(B2>90, 10%, IF(B2>=81, 7%, IF(B2>=70, 5%, 3%))) Nested IF statement.

For more formula examples, please see:

Excel IF statement with multiple conditions

To evaluate several conditions with the AND or OR logic, embed the corresponding function in the logical test:

For example, to return "Pass" if both scores in B2 and C2 are higher than 80, the formula is:

=IF(AND(B2>80, C2>80), "Pass", "Fail")

To get "Pass" if either score is higher than 80, the formula is:

=IF(OR(B2>80, C2>80), "Pass", "Fail") Excel IF statement with multiple conditions.

For full details, please visit:

If error in Excel

Starting from Excel 2007, we have a special function, named IFERROR, to check formulas for errors. In Excel 2013 and higher, there is also the IFNA function to handle #N/A errors.

And still, there may be some circumstances when using the IF function together with ISERROR or ISNA is a better solution. Basically, IF ISERROR is the formula to use when you want to return something if error and something else if no error. The IFERROR function is unable to do that as it always returns the result of the main formula if it isn't an error.

For example, to compare each score in column B against the top 3 scores in E2:E4, and return "Yes" if a match is found, "No" otherwise, you enter this formula in C2, and then copy it down through C7:

=IF(ISERROR(MATCH(B2, $E$2:$E$4, 0)), "No", "Yes" ) If error formula in Excel.

For more information, please see IF ISERROR formula in Excel.

Hopefully, our examples have helped you get a grasp of the Excel IF basics. I thank you for reading and hope to see you on our blog next week!

Practice workbook

Excel IF statement - formula examples (.xlsx file)

Table of contents

4731 comments

  1. Hi,
    I am looking for a formula to add 21 days to a date if a certain phrase is in another column. For example - A2 is 01/08/2016, if B2 says 'PA1' I would like C2 to add 21 days to the date in A1. I have so far got =IF(ISNUMBER(SEARCH("PA1",B2)),"A2+21","") which works as far as getting C2 filled with an answer but I can't make the sum "A2+21" work as a formula - can anyone help?

    Thanks

    • Sorry - Just read back - should read, A2 is 01/08/2016, if B2 says 'PA1' I would like C2 to add 21 days to the date in A2

  2. Hi,
    This is a formula for 2 energy use efficiencies one for gaining weight, one for weight loss. Obviously I have the syntax wrong, but I can't work out what the error is. I would be really grateful if you could help me.

    =IF(L7>0,[(L7*0.92*18)/(0.0043*((0.172*$L$3)-1.707))], [(L7*0.92*18)/0.8])

  3. Hi .
    Can you pls. Help yo formulate a formula inside a single cell. The condition is this for dates.
    1. I both cell is empty result is empty.
    2. If thedifference of two dates is > 0 answer is 0, if not result is 1
    3. If one cell is empty result is 0
    4. If both dates are equal result is 1

    Pls. Help tnx

  4. Hello,

    I have two different dates in two different cells (A1 = 4/12/1993 and B1 = 04/05/1993) and i want to verify if the two dates fall in the same quarters. If two dates are within the same quarter, the data "passed" if outside of 89 days, it fails...

    thanks for your help....

  5. need help.
    on A column we have names like sam, nick, ... on G column we have $ amount, how calculate from xxx row till yyy row all $ for sam ?
    thank you for help

  6. I believe I need to combine an IF function and a SUMIF function...but not 100% sure (all I know is it is not working). I was able to do a SUMIF formula to have it add up invoice dollar amounts if the vendor equaled a certain name. That is great for a total amount owed; however, what I am having issues with is when giving it a criteria, like if the invoice date is =< 12/31/15, then add up only those invoices that are before that date and that are from a certain vendor. I am trying to enter this formula into a summary table...so this would help a lot!

  7. Hi Svetlana,

    Hope you can help me on this tough one and thank you in advance for any help you can give.

    So I have created an Excel spreadsheet which I'm tracking snow removal times that happen during the winter so I can charge my customers. Row 1, I have the times that have been summed up. Row 2 where I a value that been calculated from Row 1 to get number of times 15 mins fits in it (For example, a cell in Row 1 would show 1:20 minutes and I divide that by 15 minutes which should give me a value of 8. Now here's the problem, I been trying to use the "IF" function in Row 2 to perform a function say if the time in Row 1 is less than 15 minutes than the value should be 0 or if it's 15 or more than I divide that by 15.

    Any suggestion what I could do? Thank you in advance for any help you can give!

    Gary

    • Hi Gary,

      I believe this formula does what you need:
      =IF(A$1*1440>=15, A$1*1440/15, 0)

  8. Very Excel illiterate...please help if you can! I have been using this formula (which I did not create) to calculate data for vacation, sick time, personal days, etc. on our time sheets:
    =SUM(IF(ISNUMBER(SEARCH("v",J9:AN9)),IF(ISNUMBER(J9:AN9),J9:AN9,(LEFT(J9:AN9,IF(ISNUMBER(FIND(".",J9:AN9)),3,1)))*1),0))+SUM(IF(ISNUMBER(SEARCH("v",AC8:AN8)),IF(ISNUMBER(AC8:AN8),AC8:AN8,LEFT(AC8:AN8,IF(ISNUMBER(FIND(".",AC8:AN8)),3,1)))*1),0)-AB6
    Example:
    Cell J9 - 1.50v
    Cell K9 - 1.50v
    Formulated cell returns the correct value of 3.
    The problem is when numbers with 2 decimal places (other than '0') are used:
    1.25v plus 1.25v returns a value of 2.4
    I'm thinking it has something to do with using the letter 'v', in this case...maybe I'm wrong!
    I've tried to format the cell different ways but I've had no success.
    Sure hope you can help! Thanks!

  9. Dear,
    Can you please in using IF command for the below
    <32.7 Lower
    32.8 to 39.4 Moderate
    40 to 46.1 High
    46.6 Very High

  10. I want to use IF function, for a cell contains email address then the resulting cell will return with a numeric value as 1 and if there is written as "NA" then return a numeric 0 (zero), so that at last I can count by using sum function to add and get how many emails are there in my sheet. Please give me the solution.

    • Hi Kamesh,

      You can use a formula similar to this:
      =IF(A1="NA", 0, IF(ISTEXT(A1), 1, ""))

  11. Nice greet tutorial of if function, very useful and informative

  12. I want to put a formula for assigning a person job from a start date to end date .

    How to put a formula to ensure that person is not reassigned during the given start and end date.

    Regards
    Ravi

  13. I want to write a function that will evaluate if a cell is >1, and if it is, copy the text in any designated cell and copy that text to another cell

    Thanks

    • Hi Don,

      You can use a formula similar to this:
      =IF(A1>1, B1, "")

      Where A1 is the cell to evaluate, and B1 is the cell to copy the text from.

  14. Hi,
    Excel has always been my downfall. I need your help please.

    I need for D5 to show as either 0% or 25% data is from
    D4:D14 which would either contain Yes, No and blanks , Should any of the cells fro 4-14 contain a no then D5 should show as 0% and if 4-14 cells have a YES including the blanks then D5 should show as 25%.

    Your help is much appreciated.

    • Hi Michele,

      Try this one:
      =IF(COUNTIF(D4:D14, "no")>0, 0%, 25%)

  15. what formula can i used for this
    Good 4.00-4.59
    Average 3.00-3.59
    Fair 2.00-2.59
    Poor 1.00-1.59

    if the result would be 5 i want to automatically give the corresponding rating equivalent. please help thanks.

  16. I have 3 Worksheet, one is for purchase statement, second is for sales statement and another is for stock statement. Now in purchase & sales statement against all different types of equipments there are serial no. (eg. ASHD-0674) Suppose I have purchased 25 nos. different equipments which has 25 different types of serial nos. and I have sold 19 Nos. equipments out of 25 Nos. purchased. Now in Stock Statement I want to see which serial nos. of equipments I Purchased, sold and which serial nos. in my stock. Please clarify.

  17. Hi,

    Please help to solve my query, I want to pick city name in separate column from excel formula.

    INST_ADDR Output Required
    asasdsdddAzadpur, Azadpur New Delhi, New Delhi, 110033 Azadpur
    asasdsdddGreater Noida New Delhi, New Delhi, 110033 Greater Noida
    asasdsdddNoida New Delhi, New Delhi, 110033 Noida
    dfdfdfdGurgaon,New Delhi, New Delhi, 110033 Gurgaon
    1fdfdf11 GK New Delhi, New Delhi, 110075 GK
    dfdfdfdDwarka,New Delhi, New Delhi, 110033 Dwarka
    dfdfdfdGhaziabad,New Delhi, New Delhi, 110033 Ghaziabad

    Regards,

    neeraj Kaushik

  18. I have a column in Excel. User points to a cell in the column. A drop down menu populated as follows: 1/4 in screws, 1/4 in screws, 1.2 in screws. When the user selects any one of these, the associated part number is entered in the cell. How do I do it in Excel?

  19. Hello,

    I have been attempting to figure out a formula for an issue I have for a while. I'll try my best to explain it, but referring to my below examples may be your be more helpful. I have a 86K plus spreadsheet in which I need to combine multiple cells into a single cell if certain criteria are met.

    Raw Data Example:
    A 1 2 3
    B 23456 Coffee
    C 8975 Tea
    D 99238 Soda
    E 23456 Tea
    F 23456 Soda
    G 8975 Soda

    I need a cell in column 3 to combine what column 2 has every time a number in column 1 matches.

    What needs to happen Example:

    A 1 2 3
    B 23456 Coffee Coffee;Tea;Soda
    C 8975 Tea Tea;Soda
    D 99238 Soda Soda
    E 23456 Tea Coffee;Tea;Soda
    F 23456 Soda Coffee;Tea;Soda
    G 8975 Soda Tea;Soda

    Thank you,
    Ashley

  20. Salary Exemption Salary 0 100000@15%
    @25%
    1,485,079 400,000 1,085,079 4,000 15,000 246,270
    300,000 350,000 524,759 4,000 15,000 106,190

    I need if the Annual Salary is More then 400000 or 350000 multiply 1% on Exemption otherwise multiply 1% on A

  21. Hi, please can you help me, I am busy with a deal comm excel sheet, I need to create a drop down box with "inclusive / exclusive" and then when either button is clicked the value on the formula needs to be linked from the selling price. How do I do this?

  22. I've 5 different sheets of data with heading of each sheet is Normal /Urgent / very urgent / Platinum / Emergency and each having different data. if the order is urgent then it should select data from Sheet "URGENT" for that particular country / product / kg / rate. I've around 50 countries and 400 destinations. Pls advise how to create a formula for this complexity.

  23. Sir/Madam

    I wanted to know the IFCOUNT condition for bank use for example
    State Bank of India put the NEFT charges for other banks except SBI the criteria is

    UPTO AMOUNT CHARGES
    10000/- 2.87
    10001 100000/- 5.75
    100001 200000/- 17.25
    200000 ABOVE 28.75

    requesting you to help in this regard.

    Thanks & Regards
    Ibrahim Khan

    • Hi Ibrahim,
      Please consider amount in A1 cell.. then follow below formula...

      =IF(A1>200000,A1*28.75,IF(A1>100000,A1*17.25,IF(A1>10000,A1*5.75,A1*2.87)))

  24. Hi,

    Ive created a dropdown list (periods 12) to pull data for various months depending on the period selected. I have 2 summaries, In the month, which pulls the current month and for that I used sumifs and used the display in the dropdown box as the condition for result, however for year to date which requires summation of more than one period I am having difficulty figuring out what function would allow me to link to the drop box to automatically update. Currenty I am using if and have 12 stipulation which is quite long (eg if(a2=y1,sum y7:y8, if(a2=y2,sumy7:y9.....etc have to do this for 12 periods. Can you help?

  25. Hi,
    I am trying to do an IF function where Excel would return:
    1 when the cell has Monday in it
    2 when the cell has Tuesday in it
    3 when the cell has Wednesday in it, and so on.
    The cell that has the weekday (Monday) in it has a formula =A3 where the cell A3 would be a date. For example, A3 = 13/7/2016, B3 has a function =A3 (formatted to return 'Wednesday'), C3 would have an IF function returning '3'.
    How do get this IF function to work?

  26. can someone help me how to compute

    if A5 is equal and not less than to 7083 then compute for (A5-7083)*.20 + 354.17. or if A5 is equal or not less than to 10,000 then compute for (A5-10,000)-.25+937.50

    • I don't understand your question 354.17 "or" if A5...
      should be "And"?
      Try this:
      =IF(AND(A5>=7083,A5=10000,(A5-10000)-0.25+937.5,))

  27. Can someone help me please?
    I need a formula showing the following:
    =IF(B10>=50,"50",IF(B10<=51,"SUM(B10+B13)"))

    If the field B10 is greater than 50, then it should be 50, if the field B10 is less than 50, then it should be the sum of B10 + B13.
    But with the way the formula is written, if B10 is less then 50, then it showings SUM(B10+B13) in the field instead of the sum of B10 plus B13.

    • You can change:
      =IF(B10>=50,"50",IF(B10<=51,SUM(B10+B13)))

  28. Please let me know formula for converting numbers of 1,00,00,000 & 10,00,000 & 10,000 & 1000 & 100 & 10 & 1 digits in text format in other cell in excel.

  29. Hi
    Could someone help me with a formula

    Create a formula for each title under the heading re-order to display the text order if the remainnin stock is below 3 or no if not

  30. I have a drop down list for customer number and wanted for the customer name to populate when the customer number is typed in. Would this be a "if" command. If so can anyone assist.

  31. Hi, I have a problem with loop.
    The idea is that i enter a number at A1

    I want to know if the number
    ====================================
    less than of equal to 100 13

    101 to 500 7

    501 to 1000 7

    every 1 to 500 thereafter 6
    ====================================

    For example, i enter 450, the result is 13.
    550, the result is 13+7=20.

    I just know one step. "IF(A1<=500,13)"

    Please help.

    • ====================================
      less than of equal to 100 = 13

      101 to 500 = 7

      501 to 1000 = 7

      every 1 to 500 thereafter = 6
      ====================================

  32. Hi,
    I have a problem where I have to write if function in Excel VBA as follows:

    Module1 = Cells(j, 80).Value
    Module2 = Cells(j, 81).Value

    Module29 = Cells(j, 108).Value
    Module30 = Cells(j, 109).Value

    If Module1 = "A" Then
    Cells(i, 9) = Module1
    End If

    If Module1 = "B" Then
    Cells(i, 9) = "Good”
    End If

    If Module2 = "A" Then
    Cells(i, 10) = Module1
    End If

    If Module2 = "B" Then
    Cells(i, 10) = "Good”
    End If

    I have to input 30 times from Module1 to Module30.

    I have changed Module1 to “Module” & k (k for next loop is added).
    It does not work.
    Module1 not equal to “Module” & k

    Amended
    For k = 1 To 30
    If "Module" & k = "A" Then
    Cells(i, k + 8) = "Module" & k
    End If

    If "Module" & k = "B" Then
    Cells(i, k + 8) = "Good”
    End If
    Next

    Can I use this method in “If” fuction? How to solve?
    Many thanks.

  33. hiii sir,
    please find the following details, in credit column some amt is there that amt should be come automatically to particular column which i have mentioned,

    please help me which formula i have to apply.
    cr amt name bs kr sn
    6123 DC
    4450 BS
    1871 SN
    1871 SN
    887 KR
    6711 BS

  34. I'm trying to get the cell to return a blank if it finds the referenced cell also blank:

    =IF(F3"CodeList",LEN(D3),IF(F3="CodeList","0",IF(ISBLANK(F3),AZ3,BZ3)))

    =IF(F3"CodeList",LEN(D3),IF(F3="CodeList","0",IF(ISBLANK(F3),"","")))

    I tried it both ways, using known blank cells that will always be blank (AZ and BZ), and also using "". It performed the first two in the formula, but always returns a "0" if the cell is blank.

    Also took off the [value_if_false] at the end of the formula to mirror what I was seeing in here, but didn't work either. Always getting a "0" when = CodeList or is blank.

  35. HOW DO I FORMULATE IF THE "VALUE_IF_TRUE" IS A COMBINATION OF 2 WORDS FROM DIFFERENT CELLS.

    =IF(C49="2",I47&" "&D8,IF(C49="1"," "," "))
    THE I47&" "&D8 SHOULD BE WHAT IS WRITTEN IN CELL I47 AND CELL D8

  36. if cell contain text how to count

  37. How to write the formula to count the no of Sundays beet ween two dates (ex-30/06/2016 beet ween 15/07/2016)

    • Hi jayantha,

      You can use the following formula:

      =INT((WEEKDAY(A1-1)-A1+B1)/7)

      Where A1 is the start date and B1 is the end date.

  38. Hi,
    I am interested to set a formula to process student's marks.

    If (A1-B1)or (B1-A1)is less than 17, D1 is (A1+B1)/2

    But If (A1-B1)or (B1-A1)is more than or equal to 17, D1 will be average of C1 and either A1 or B1 which is closer to C1.

    Thanks in advance

  39. i have question for you,

    based on my excel sheet two column is there example document type and posting key column is one sheet if this column match in second sheet document type and posting key column i have to update the remain second sheet data to first sheet.

    please help on this query!!!

    regards,
    siddesh

  40. Hello, Sanket,
    Please try the following formula:
    =IF(B4>DATEVALUE("11/14/2015"),"15%", IF(B4>DATEVALUE("05/31/2015"), "14.5%", "14%"))

  41. Hi I Wanted to Set Excel Formula For The Three Condition Like
    1.If The Date Fall Before 31.05.2015 The Rate Of Service Tax Will Be 14%
    2.If The Date Fall Before 14.11.2015 The Rate Of Service Tax Will Be 14.5%
    3.If The Date Fall After 14.11.2015 The Rate Of Service Tax Will Be 15% What Would Be The Formula For That Said Question

    • r u get answer?

  42. I am trying to use an "if" function that looks at the closing value of the loan principal column (D)... if the value is negative (loan is paid off), the function will populate the specific month the loan value turns negative (the qrtly payment dates are contained in column A), into a cell at the top of the page. Is this possible?

  43. Hi,

    Is there a way to display a value based on information across 2 cells. So for example I have 2 products with data detailing the month purchased so want the output to detail the product purchased or both. So the example below the value would come back under product bought for Cust 1 "Both", Cust 2 and 3 "Product 1" and Cust 4 "Product 2"

    Cust number Product bought Product 1 Product 2
    1 February April
    2 March None
    3 January None
    4 None August

    Thanks,

    Lee

    • Hello, Lee,
      Please try the following formula: =IF(AND(ISBLANK(C2),ISBLANK(D2)),"None",IF(AND(ISBLANK(C2),NOT(ISBLANK(D2))),"Product 2",IF(AND(NOT(ISBLANK(D2)),ISBLANK(D2)),"Product 1","Both")))

  44. Hi
    I just want the if formula to return the same value that is in a particular cell, or make a caculation.
    it reads like this right now =IF(F3=" ",C3,((C3+F3)/2)).
    In case cell F3 is empty, i want to display the same value that is in cell c3. However, if f3 is not empty, I want to calculate the average)...
    right now it is just returning to me the result of average calculation ((C3+F3)/2) even if the f3 is empty...

    Can you help ?

    • Hello Rob!

      In your formula, there is a space between the quotation marks =IF(F3=" ",...).
      Remove it and the formula will work fine: =IF(F3="",C3,((C3+F3)/2))

      • Awesome !!!
        Thank you !

        How can I submit some more questions, but using the actual file/spreadsheet ?
        I have some Pivot Table related questions and i think it's hard to explain...

        Thank you Andrei for your help !

  45. Hello Svetlana,

    I have a seemingly simple formula, not sure why it doesn't work on me!

    =IF(ISNUMBER(SEARCH(OR("May-16",AX3),OR("Apr-16",AX3),OR("Mar-16",AX3))),1,0)

    I need a 0 or a 1 if the value in AX3 equals Mat-16, Apr-16 or Mar-16.

    This doesn't work either =IF(OR(AX3="Mar-16",AX3="Apr-16", AX3="May-16"),1,0)

    Please help!
    Many thanks in advance

    • Hello Anon!

      You cannot compare a date with the text string "Apr-16".
      Use the following formula instead: =IF(AND(YEAR(AX3)=2016,OR(MONTH(AX3)=3,MONTH(AX3)=4,MONTH(AX3)=5,)), 1, 0)

  46. if i type A1 in cell B1 then i want the values in A1 in C1, please ans

    • Hello Ajay,

      You can enter the following formula in C1:
      =INDIRECT(B1)

  47. I want the cell to increase by $1.00 for every 6 pieces. So if I have 13 pieces it should be $3. I created this formula but it's not correct, please help.

    =IF(B32<=6,"$1.00") OR(B32,7==13,"$2.00""∞")

  48. Hello!

    Can you help me to create this formula:
    1 to 4 = LOW
    5 to 9 = MEDIUM
    10 to 14 = HIGH

    Thanks in advance :)

    • Hello Roy!
      You can use this formula: =IF(AND(A1>0,A1<=4),"LOV",IF(AND(A1<=9, A1>4), "MEDIUM", IF(AND(A1<=14, A1>9),"HIGH", "out of range")))

  49. If a value in cell A is false and the value in cell B is within the range in cell C and D (assuming cell C if 99.0% and cell D is 100%), enter the value in cell E. Please help me in creating f formula for that. Thanks

  50. Hi! Can you please help me with this?
    For example: I want a cell to display "done" if material down and machine down was met and if not, it will display "attention".
    =IF((AND(Z3="Material Down","Machine Down")),"Done","ATTENTION")

    • Hello Dev Reyes!

      In the AND statement, you forgot to specify the cell that should contain "Machine Down". For example:
      AND(Z3="Material Down",Y3="Machine Down")

      And the whole formula would be:
      =IF((AND(Z3="Material Down",Y3="Machine Down")),"Done","ATTENTION")

Post a comment



Thank you for your comment!
When posting a question, please be very clear and concise. This will help us provide a quick and relevant solution to
your query. We cannot guarantee that we will answer every question, but we'll do our best :)