by In this quick lesson, you will learn how to filter in Excel dynamically with formulas. Examples to filter duplicates, cells containing certain text, with multiple criteria, and more.
How do you usually filter in Excel? For the most part, by using Auto Filter, and in more complex scenarios with Advanced Filter. Being fast and powerful, these methods have one significant drawback - they do not update automatically when your data changes, meaning you would have to clean up and filter again. The introduction of the FILTER function in Excel 365 becomes a long-awaited alternative to the conventional features. Unlike them, Excel formulas recalculate automatically with each worksheet change, so you'll need to set up your filter just once!
Excel FILTER function
The FILTER function in Excel is used to filter a range of data based on the criteria that you specify.
The function belongs to the category of Dynamic Arrays functions. The result is an array of values that automatically spills into a range of cells, starting from the cell where you enter a formula.
The syntax of the FILTER function is as follows:
Where:
- Array (required) - the range or array of values that you want to filter.
- Include (required) - the criteria supplied as a Boolean array (TRUE and FALSE values).
Its height (when data is in columns) or width (when data is in rows) must be equal to the that of the array argument. - If_empty (optional) - the value to return when no entries meet the criteria.
The FILTER function is only available in Excel for Microsoft 365 and Excel 2021. In Excel 2019, Excel 2016 and earlier versions, it is not supported.
Basic Excel FILTER formula
For starters, let's discuss a couple of very simple cases just to gain more understanding how an Excel formula to filter data works.
From the below data set, supposing you want to extract the records with a specific value in the Group, column, say group C. To have it done, we supply the expression B2:B13="C" to the include argument, which will produce a required Boolean array, with TRUE corresponding to "C" values.
=FILTER(A2:C13, B2:B13="C", "No results")
In practice, it's more convenient to input the criteria in a separate cell, e.g. F1, and use a cell reference instead of hardcoding the value directly in the formula:
=FILTER(A2:C13, B2:B13=F1, "No results")
Unlike Excel's Filter feature, the function does not make any changes to the original data. It extracts the filtered records into the so-called spill range (E4:G7 in the screenshot below), beginning in the cell where the formula is entered:
If no records match the specified criteria, the formula returns the value you put in the if_empty argument, "No results" in this example:
If you'd rather return nothing in this case, then supply an empty string ("") for the last argument:
=FILTER(A2:C13, B2:B13=F1, "")
In case your data is organized horizontally from left to right like shown in the screenshot below, the FILTER function will work nicely too. Just make sure you define appropriate ranges for the array and include arguments, so that the source array and Boolean array have the same width:
=FILTER(B2:M4, B3:M3= B7, "No results")
Excel FILTER function - usage notes
To effectively filter in Excel with formulas, here are a couple of important points to take notice of:
- The FILTER function automatically spills the results vertically or horizontally in the worksheet, depending on how your original data is organized. So, please make sure you always have enough empty cells down and to the right, otherwise you'll get a #SPILL error.
- The results of the Excel FILTER function are dynamic, meaning they update automatically when values in the original data set change. However, the range supplied for the array argument is not updated when new entries are added to the source data. If you wish the array to resize automatically, then convert it to an Excel table and build formulas with structured references, or create a dynamic named range.
How to filter in Excel - formula examples
Now that you know how a basic Excel filter formula works, it's time to get some insights into how it could be extended for solving more complex tasks.
Filter with multiple criteria (AND logic)
To filter data with multiple criteria, you supply two or more logical expressions for the include argument:
The multiplication operation processes the arrays with the AND logic, ensuring that only the records that meet all the criteria are returned. Technically, it works this way:
The result of each logical expression is an array of Boolean values, where TRUE equates to 1 and FALSE to 0. Then, the elements of all the arrays in the same positions are multiplied. Since multiplying by zero always gives zero, only the items for which all the criteria are TRUE get into the resulting array, and consequently only those items are extracted.
The below examples show this generic formula in action.
Example 1. Filter multiple columns in Excel
Extending our basic Excel FILTER formula a little further, let's filter the data by two columns: Group (column B) and Wins (column C).
For this, we set up the following criteria: type the name of the target group in F2 (criteria1) and the minimum required number of wins in F3 (criteria2).
Given that our source data is in A2:C13 (array), groups are in B2:B13 (range1) and wins are in C2:C13 (range2), the formula takes this form:
=FILTER(A2:C13, (B2:B13=F2) * (C2:C13>=F3), "No results")
As the result, you get a list of players in group A who have secured 2 or more wins:
Example 2. Filter data between dates
First off, it should be noted that it's not possible to make up a generic formula to filter by date in Excel. In different situations, you will need to build criteria differently, depending on whether you want to filter by a specific date, by month, or by year. The purpose of this example is to demonstrate the general approach.
To our sample data, we add one more column containing the dates of the last win (column D). And now, we will extract the wins that occurred in a specific period, say between May 17 and May 31.
Please notice that in this case, both criteria apply to the same range:
=FILTER(A2:D13, (D2:D13>=G2) * (D2:D13<=G3), "No results")
Where G2 and G3 are the dates to filter between.
Filter with multiple criteria (OR logic)
To extract data based on multiple OR condition, you also use logical expressions like shown in the previous examples, but instead of multiplying, you add them up. When the Boolean arrays returned by the expressions are summed, the resulting array will have 0 for entries that do not meet any criteria (i.e. all the criteria are FALSE), and such entries will be filtered out. The entries for which at least one criterion is TRUE will be extracted.
Here's the generic formula to filter columns with the OR logic:
As an example, let's extract a list of players that have this or that number of wins.
Assuming the source data is in A2:C13, wins are in C2:C13, and the win numbers of interest are in F2 and F3, the formula would go as follows:
=FILTER(A2:C13, (C2:C13=F2) + (C2:C13=F3), "No results")
As the result, you know which players have won all the games (4) and which have won none (0):
Filter based on multiple AND as well as OR criteria
In situation when you need to apply both criteria types, remember this simple rule: join the AND criteria with asterisk (*) and OR criteria with the plus sign (+).
For example, to return a list of players that have a given number of wins (F2) AND belong to the group mentioned in either E2 OR E3, build the following chain of logical expressions:
=FILTER(A2:C13, (C2:C13=F2) * ((B2:B13=E2) + (B2:B13=E3)), "No results")
And you will get the following result:
How to filter duplicates in Excel
When working with huge worksheets or combining data from different sources, there's often a possibility that some duplicates would sneak in.
If you are looking to filter out duplicates and extract unique items, then use the UNIQUE function as explained in the above linked tutorial.
If your goal is to filter duplicates, i.e. extract entries that occur more than once, then use the FILTER function together with COUNTIFS.
The idea is to get the occurrences counts for all the records and extract those greater than 1. To get the counts, you supply the same range for each criteria_range / criteria pair of COUNTIFS like this:
For example, to filter duplicate rows from the data in A2:C20 based on the values in all 3 columns, here's the formula to use:
=FILTER(A2:C20, COUNTIFS(A2:A20, A2:A20, B2:B20, B2:B20, C2:C20, C2:C20)>1, "No results")
Tip. To filter duplicates based on the values in the key columns, include only those specific columns in the COUNTIFS function.
How to filter out blanks in Excel
A formula for filtering out blank cells is, in fact, a variation of the Excel FILTER formula with multiple AND criteria. In this case, we check whether all (or particular) columns have any data in them and exclude the rows where at least one cell is empty. To identify non-blank cells, you use the "not equal to" operator (<>) together with an empty string ("") like this:
With the source data in A2:C12, to filter out rows containing one or more blank cells, the following formula is entered in E3:
Filter cells containing specific text
To extract cells that contain certain text, you can use the FILTER function together with the classic If cell contains formula:
Here's how it works:
- The SEARCH function looks for a specified text string in a given range and returns either a number (the position of the first character) or #VALUE! error (text not found).
- The ISNUMBER function converts all the numbers to TRUE and errors to FALSE and passes the resulting Boolean array to the include argument of the FILTER function.
For this example, we've added the Last names of players in B2:B13, typed the part of the name we want to find in G2, and then use the following formula to filter the data:
=FILTER(A2:D13, ISNUMBER(SEARCH(G2, B2:B13)), "No results")
As the result, the formula retrieves the two surnames containing "han":
Filter and calculate (Sum, Average, Min, Max, etc.)
A cool thing about the Excel FILTER function is that it can not only extract values with conditions, but also summarize the filtered data. For this, combine FILTER with aggregation functions such as SUM, AVERAGE, COUNT, MAX or MIN.
For instance, to aggregate data for a specific group in F1, use the following formulas:
Total wins:
=SUM(FILTER(C2:C13, B2:B13=F1, 0))
Average wins:
=AVERAGE(FILTER(C2:C13, B2:B13=F1, 0))
Maximum wins:
=MAX(FILTER(C2:C13, B2:B13=F1, 0))
Minimum wins:
=MIN(FILTER(C2:C13, B2:B13=F1, 0))
Please pay attention that, in all the formulas, we use zero for the if_empty argument, so the formulas would return 0 if no values meeting the criteria are found. Supplying any text such as “No results” would result in a #VALUE error, which is obviously the last thing you want :)
Case-sensitive FILTER formula
A standard Excel FILTER formula is case-insensitive, meaning it makes no distinction between lowercase and uppercase characters. To distinguish text case, nest the EXACT function in the include argument. This will force FILTER to do logical test in a case-sensitive manner:
Supposing, you have both groups A and a and wish to extract records where the group is the lowercase "a". To have it done, use the following formula, where A2:C13 is the source data and B2:B13 are groups to filter:
=FILTER(A2:C13, EXACT(B2:B13, "a"), "No results")
As usual, you can input the target group in a predefined cell, say F1, and use that cell reference instead of hardcoded text:
=FILTER(A2:C13, EXACT(B2:B13, F1), "No results")
How to FILTER data and return only specific columns
For the most part, filtering all columns with a single formula is what Excel users want. But if your source table contains tens or even hundreds of columns, you may certainly want to limit the results to a few most important ones.
Example 1. Filter some adjacent columns
In situation when you want some neighboring columns to appear in a FILTER result, include only those columns in array because it is this argument that determines which columns to return.
In the basic FILTER formula example, supposing you wish to return the first 2 columns (Name and Group). So, you supply A2:B13 for the array argument:
=FILTER(A2:B13, B2:B13=F1, "No results")
As the result, we get a list of participants of the target group defined in F1:
Example 2. Filter non-adjacent columns
To cause the FILTER function to return non-contiguous columns, use this clever trick:
- Make a FILTER formula with the desired condition(s) using the entire table for array.
- Nest the above formula inside another FILTER function. To configure the "wrapper" function, use an array constant of TRUE and FALSE values or 1's and 0's for the include argument, where TRUE (1) marks the columns to be kept and FALSE (0) marks the columns to be excluded.
For example, to return only Names (1st column) and Wins (3rd column), we are using {1,0,1} or {TRUE,FALSE,TRUE} for the include argument of the outer FILTER function:
=FILTER(FILTER(A2:C13, B2:B13=F1), {1,0,1})
Or
=FILTER(FILTER(A2:C13, B2:B13=F1), {TRUE,FALSE,TRUE})
How to limit the number of rows returned by FILTER function
If your FILTER formula finds quite a lot of results, but your worksheet has limited space and you cannot delete the data below, then you can limit the number of rows the FILTER function returns.
Let's see how it works on an example of a simple formula that pulls players from the target group in F1:
=FILTER(A2:C13, B2:B13=F1)
The above formula outputs all the records that it finds, 4 rows in our case. But suppose you just have space for two. To output only the first 2 found rows, this is what you need to do:
- Plug the FILTER formula into the array argument of the INDEX function.
- For the row_num argument of INDEX, use a vertical array constant like {1;2}. It determines how many rows to return (2 in our case).
- For the column_num argument, use a horizontal array constant like {1,2,3}. It specifies which columns to return (the first 3 columns in this example).
- To take care of possible errors when no data matching your criteria is found, you can wrap your formula in the IFERROR function.
The complete formula takes this form:
=IFERROR(INDEX(FILTER(A2:C13, B2:B13=F1), {1;2}, {1,2,3}), "No result")
When working with large tables, writing array constants manually may be quite cumbersome. No problem, the SEQUENCE function can generate the sequential numbers for you automatically:
=IFERROR(INDEX(FILTER(A2:C13, B2:B13=F1), SEQUENCE(2), SEQUENCE(1, COLUMNS(A2:C13))), "No result")
The first SEQUENCE generates a vertical array containing as many sequential numbers as specified in the first (and only) argument. The second SEQUENCE uses the COLUMNS function to count the number of columns in the dataset and produces an equivalent horizontal array.
Tip. To return data from specific columns, not all the columns, in the horizontal array constant that you use for the column_num argument of INDEX, include only those specific numbers. For instance, to extract data from the 1st and 3rd columns, use {1,3}.
Excel FILTER function not working
In situation when your Excel FILTER formula results in an error, most likely that will be one of the following:
#CALC! error
Occurs if the optional if_empty argument is omitted, and no results meeting the criteria are found. The reason is that currently Excel does not support empty arrays. To prevent such errors, be sure to always define the if_empty value in your formulas.
#VALUE error
Occurs when the array and include argument have incompatible dimensions.
#N/A, #VALUE, etc.
Different errors may occur if some value in the include argument is an error or cannot be converted to a Boolean value.
#NAME error
Occurs when trying to use FILTER in an older version of Excel. Please remember that it is a new function, which is only available in Office 365 and Excel 2021.
In new Excel, a #NAME error occurs if you accidentally misspell the function's name.
#SPILL error
Most often, this error occurs if one or more cells in the spill range are not completely blank. To fix it, just clear or delete non-empty cells. To investigate and resolve other cases, please see #SPILL! error in Excel: what it means and how to fix.
#REF! error
Occurs when a FILTER formula is used between different workbooks, and the source workbook is closed.
That's how to filer data in Excel dynamically. I thank you for reading and hope to see you on our blog next week!
Download practice workbook
Filter in Excel with formulas (.xlsx file)
101 comments
Your post on how to use excel filter function with multiple criteria was very helpful. Thank you for posting it.
I do have one situation that is not accounted for and hope it is something you could help with.
What if one of the cells that you are looking for a match in contains data on multiple lines. I want to be able to account for that and have the result return.
For example if in Cell B2 I have Nuts [carriage return] bolts, if I am looking for nuts I want the filter function to return data in that row.
Hi! If I understand correctly, you can use a partial match in the conditions of the FILTER function. You can use this guide: How to find substring in Excel. For example:
=FILTER(A2:B10,ISNUMBER(SEARCH("Nuts",B2:B10)))
Hiya
i have a formula =COUNTA(UNIQUE(FILTER('Data List'!C41974:C54033,'Data List'!A41974:A54033=Dashboard!B10))) however i need to base this formula on a year.
the spreadsheet list contains 10 of thousands lines including document name customer name qty and year.
i am trying to calculator the number of unique clients for a specific document name for a specific year
Hi! We have a special tutorial that can help to solve your problem: Count unique values with multiple criteria. I can't recommend a formula to you as I don't have an accurate description of your data.
Using {1,0,1} or {TRUE,FALSE,TRUE} for the include argument of the outer FILTER function to filter non-adjacent columns
works very well on a range of data. Still, it always displays those columns with zero values after converting the range to a Table. Is it a way to completely exclude those columns from showing up? Thanks.
Hello Julian!
If I understand your task correctly, add another condition to the FILTER function to exclude zero values. For example:
=IFERROR(INDEX(FILTER(A2:C13, (B2:B13=F1)*(C2:C13>0)), {1;2}, {1,2,3}), "No result")
When I put the file in share, the filter does not work anymore... Is there a way to change that or is it normal ?
Hello! It’s a common issue that filters may not work as expected in shared Excel files. When a workbook is shared, certain features, like Auto Filter, Advanced Filter, and some sorting and filtering options, can behave differently or may not be available.
The reason could be Excel Online Limitations: Some advanced filtering features available in the Excel desktop app might not be fully supported in Excel Online.
Here are a few steps you can try to resolve the filter issue:
Select All Data: Ensure your table doesn’t have blank rows or columns that might prevent the filter from selecting the entire area.
Remove Blank Rows/Columns: Configuring the data in your Filter area to remove blanks can help.
Unhide Rows/Columns: Hidden rows or columns can interfere with filtering.
Unmerge Cells: Merged cells can cause issues with filtering.
Clear and Reapply Filter: Sometimes, simply clearing the existing filter and applying it again can fix the issue.
The FILTER function works perfectly fine for me. Because my data is in a row, it's returning the results in a row. Is it possible display the results in a column?
My filter results are currently displaying as:
Row 1: Apple, Pears, Bananas
I want it to display as follows:
Column A
Apple
Pears
Bananas
Thanks.
I've worked it out! TRANSPOSE was the function I was looking for.
Great website, it's helped me a lot with the spreadsheet I'm currently working with.
Hi! Here is the article that may be helpful to you: Excel TRANSPOSE function to change columns to rows.
Hello!
I have been using the FILTER formula for a few days now on a new spreadsheet and have the "include" argument based upon the value of a cell (a date) within the same sheet, to check for that date on a different sheet. The issue arises when I update the date in that cell, the FILTER "include" argument immediately returns me my "Not Working" error message I put in, if nothing is found. The odd part is, when I input 10/1/2023 or 10/01/2023, it returns all values of 10/1/2023 from the other sheet. When I input 10/8/2023 or 10/08/2023, I get the "Not Working" error. Nothing changes, except the value I enter in the Cell it is checking. Here is the string I am using, the cell with the date sits in T3:
=FILTER(Master!A:R,(Master!I:I=$T$3)+(Master!J:J=$T$3)+(Master!K:K=$T$3)+(Master!L:L=$T$3)+(Master!M:M=$T$3)+(Master!N:N=$T$3)+(Master!O:O=$T$3)+(Master!P:P=$T$3)+(Master!Q:Q=$T$3)+(Master!R:R=$T$3),"Not Working")
Hi! I can't check a formula that contains unique references to your data, which I don't have. Check what format the dates in your table are written in and what format you enter the dates in T3.
Hello, Alexander!
Yes, they are both of the same Short Date with same MM/DD/YYYY format. 10/1/2023 receives results, but 10/8/2023 and all others give me the "Not Working" which leaves me completely baffled. I cannot figure this one out.
Not sure if this is the right forum but i am trying to use an =AVERAGE formula for a column in a workbook that recalculates when that column is filtered onlycalculating using the visible columns in the dataset.
Hi! To calculate the average based only on the filtered values, try using the AGGREGATE function. For example,
=AGGREGATE(1,5,A1:A20)
I hope it’ll be helpful.
Hi Team, can filter function be used with Len. I am working on extracting numbers from a column that is equal to 4.Hope this makes sense.Thanks
E.g , as an example I want to filter on below and from col B only get length which is = to 4. In this Case , Project - 4444 , 1234 , 8924
Col A Col B
Project 55615
Project 4444
Project 1234
BC Code 8924
Hi! If I understand your task correctly, try the following formula:
=FILTER(A1:B4,LEN(B1:B4)=4)
How do I filter, based on a values in a column, which is dynamic. Example, Column headers are country names, and I need to filter data based on the country name that is entered in cell B1?
Hi! If I understand the question correctly, you cannot select individual columns with the FILTER function. Excel filter works for values in rows. Read carefully the article below and also: Excel Filter: How to add, use and remove.
I find the "Filter cells containing specific text" part very useful (using FILTER, ISNUMBER and SEARCH). I also know that XLOOKUP can be used to find a record using a partial value.
But I find that searching an array where there are multiple occurrences of the value the XLOOKUP method gives me only one result, whereas FILTER-ISNUMBER-SEARCH method gives me results showing all occurrences.
Is it possible to use XLOOKUP to return all occurrences of the value, not just the first occurrence?
Thank you.
Hi XLOOKUP function returns only one value. For returning multiple values, there are other functions that you have correctly named.
As a frequent visitor to this site, especially after we now have many new O365 functions, I miss the 'use case' of concatenating Filter(ed) array results.
My own solution, is this one starting by combining input data before FILTERING:
=SORT(VSTACK(Table1[[Column1]:[ColumnX]];Table2[[Column 4]:[Column X+4]]))
which just mean:
Concatenate equally sized (by same number of columns) two arrrays.
Then Filter the resulting array.
You can concatenate many arrays, just keep the number of columns the same.
As a new aha-experience I found that your site actually do have some ideas for what I proposed:
https://www.ablebits.com/office-addins-blog/combine-ranges-arrays-excel-vstack-hstack/
Sorry, I did not come across this before my earlier posting ;-)
Hi, thank for very helpful article. I am running a sort filter formula to get the top 10 values of a column, but text is included in this column, so I don't get the top 10 values but all those lines that contains text. Could you please advise how I could ignore text and get the right results?
Thanks in advance
Hi!
If you are using the FILTER function and you want only numeric values, use the ISNUMBER function in the conditions. If you describe the problem in more detail and write your own formula, I will try to give more accurate advice.
I used filter option to get a few details from one sheet(sheet A) to another sheet(sheet B), but I want more details to be added in the rows in the sheet B.
Each row has a date column,
when I add older dated rows with the filter option, the row sequence in sheet B changes( the rows shift up or down as per the date)
the rows are shown date wise but the additional details added that were added manually still remain in the same row where they were added before.
how can I add this manual data to the same row as the data that has come through the filter. And have it remain with the same data even if more older dated rows are added.
Hi!
You cannot change any data that is received using the FILTER function. To change the filtered data, use the standard Excel tool. Read more here: Excel Filter: How to add, use and remove
Hello,
I am using the INDEX+FILTER to return specific rows and it works quite well. Is it possible though that I can avoid doubles?
For example if my data is Anna, John, John, Steven and I want to return the first 3 rows matching my criteria, Is there a way to avoid the second John and return Steven instead?
The Formula that I am using is =INDEX(FILTER($B$2:$D$8,$E$2:$E$8=L1),row number)
Hello!
To get only the unique values in the list, add the UNIQUE function to the formula.
=INDEX(UNIQUE(FILTER($B$2:$D$8,$E$2:$E$8=L1)),row number)
Thank you so much! Couldn't find it anywhere. It works just perfect <3
Hi, i'm trying to use the "Filter multiple columns in Excel".
I can't manage to figure out how i'd go about with the following scenario:
For one of the multiple criteria, i want all of the values to be included. For example, there are 10 cities and instead of chosing 1, I want all 10 to be displayed, subject to the other criteria being met. And I also want the ability to then go and switch back to 1 specific city.
Basically, if i select "All", all show up. If I select "Madrid", only Madrid shows up conditioned to the remaining criteria being met, hence I'd need to implement this within the "Filter multiple columns in Excel" structure.
Does anyone know how to do this?
Hi!
You can filter values by multiple conditions using the FILTER function. Please read the above article carefully.
Thanks for the article! Just wondering if the FILTER function can be used with a large number of "include" options. I understand how it would work for a "this or that" type scenario, but I've got a large dataset and want to get the results for about 200 different options. Is there a better option than
= FILTER (Range, (Range = Option 1) + (Range = Option 2) + (Range = Option 3)+ ... + (Range = Option 200))
I am hoping I understand you correctly and am going to offer what I think is a solution to your question as I just figured this out myself and was very pleased with how it worked.
If your "Options" were arranged as a column of values (ie: E1:E200) per se, you could use the following formula to filter your data:
= FILTER(Range, ISNUMBER(MATCH(Range,E1:E200,0)) )
The MATCH function will return numbers in an array the same size of the 'Range' on lines where the 'Options' match. Then the ISNUMBER will convert those matches to a value of TRUE.
Hi!
I don't think there is another solution for a lot of OR conditions using standard Excel features.
Hi!
Thank you for your guide, it is much more useful than many others. Yet i have a problem. Is there any way how to edit filtered data? My situation is: I have a storage, trying to make some kind of "frontend" for users and i need to edit already filtered data. You search for item, you see how many is somewhere, you fill out how many you took from that amout and you update "database". I cant find any useful informations about it. Can you help me please?
Thank you VERY much,
Martin
Hello!
Use Excel Filter to filter the data you need and then correct it.
I also recommend taking a look at this article: Excel Advanced Filter – how to create and use.
I hope I answered your question.
Hello Everyone,
Anyone help me out, I have mentioned below my question.
If A1 is ABC then takes filter list value from 'sheet 1' and if A1 is XYZ then takes filter list value from 'sheet 2'
I have tried this formula with IF function but I get an error.
Hi!
I can't guess which formula doesn't work for you. But this formula works:
=IF(A1="ABC",FILTER('1'!A2:C13, '1'!B2:B13='1'!F1, "No results"),FILTER('2'!B1:M3,'2'!B2:M2= '2'!B6, "No results"))
Hi Everyone,
I have an Excel file for daily reports of a project, each day has a sheet, named the date of that day, so we add a sheet every day.
in the "summary" sheet I want to have a table that automatically:
1 - read the date from a cell in the same table.
2 - look for a sheet with the name of that date
3 - read and bring a value from a cell of that sheet into this new table cell
Can you please let me know if you know how to do it?
Thank you
Hello!
You can use the INDIRECT function. Pay attention to this guide: Creating an Excel dynamic reference to another sheet.
I hope it’ll be helpful. If something is still unclear, please feel free to ask.
Can the array be from another workbook on my server?
The workbook on the server updates every 30 minutes with fresh data, I would like to give my employee a lookup spreadsheet that extracts from the file on the server.
Hello!
I recommend reading this guide: Excel reference to another sheet or workbook (external reference).
To refresh the current tab - press Shift + F9.