by In this article, you will learn how to build an Excel IF statement for different types of values as well as how to create multiple IF statements.
IF is one of the most popular and useful functions in Excel. Generally, you use an IF statement to test a condition and to return one value if the condition is met, and another value if the condition is not met.
In this tutorial, we are going to learn the syntax and common usages of the Excel IF function, and then take a closer look at formula examples that will hopefully prove helpful to both beginners and experienced users.
IF function in Excel
IF is one of logical functions that evaluates a certain condition and returns one value if the condition is TRUE, and another value if the condition is FALSE.
The syntax of the IF function is as follows:
As you see, IF takes a total of 3 arguments, but only the first one is obligatory, the other two are optional.
Logical_test (required) - the condition to test. Can be evaluated as either TRUE or FALSE.
Value_if_true (optional) - the value to return when the logical test evaluates to TRUE, i.e. the condition is met. If omitted, the value_if_false argument must be defined.
Value_if_false (optional) - the value to return when the logical test evaluates to FALSE, i.e. the condition is not met. If omitted, the value_if_true argument must be set.
Basic IF formula in Excel
To create a simple If then statement in Excel, this is what you need to do:
- For logical_test, write an expression that returns either TRUE or FALSE. For this, you'd normally use one of the logical operators.
- For value_if_true, specify what to return when the logical test evaluates to TRUE.
- For value_if_false, specify what to return when the logical test evaluates to FALSE. Though this argument is optional, we recommend always configuring it to avoid unexpected results. For the detailed explanation, please see Excel IF: things to know.
As an example, let's write a very simple IF formula that checks a value in cell A2 and returns "Good" if the value is greater than 80, "Bad" otherwise:
=IF(B2>80, "Good", "Bad")
This formula goes to C2, and then is copied down through C7:
In case you wish to return a value only when the condition is met (or not met), otherwise - nothing, then use an empty string ("") for the "undefined" argument. For example:
=IF(B2>80, "Good", "")
This formula will return "Good" if the value in A2 is greater than 80, a blank cell otherwise:
Excel If then formula: things to know
Though the last two parameters of the IF function are optional, your formula may produce unexpected results if you don't know the underlying logic.
If value_if_true is omitted
If the 2nd argument of your Excel IF formula is omitted (i.e. there are two consecutive commas after the logical test), you'll get zero (0) when the condition is met, which makes no sense in most cases. Here is an example of such a formula:
=IF(B2>80, , "Bad")
To return a blank cell instead, supply an empty string ("") for the second parameter, like this:
=IF(B2>80, "", "Bad")
The screenshot below demonstrates the difference:
If value_if_false is omitted
Omitting the 3rd parameter of IF will produce the following results when the logical test evaluates to FALSE.
If there is just a closing bracket after value_if_true, the IF function will return the logical value FALSE. Quite unexpected, isn't it? Here is an example of such a formula:
=IF(B2>80, "Good")
Typing a comma after the value_if_true argument will force Excel to return 0, which doesn't make much sense either:
=IF(B2>80, "Good",)
The most reasonable approach is using a zero-length string ("") to get a blank cell when the condition is not met:
=IF(B2>80, "Good", "")
Tip. To return a logical value when the specified condition is met or not met, supply TRUE for value_if_true and FALSE for value_if_false. For the results to be Boolean values that other Excel functions can recognize, don't enclose TRUE and FALSE in double quotes as this will turn them into normal text values.
Using IF function in Excel - formula examples
Now that you are familiar with the IF function's syntax, let's look at some formula examples and learn how to use If then statements in real-life scenarios.
Excel IF function with numbers
To build an IF statement for numbers, use logical operators such as:
- Equal to (=)
- Not equal to (<>)
- Greater than (>)
- Greater than or equal to (>=)
- Less than (<)
- Less than or equal to (<=)
Above, you have already seen an example of such a formula that checks if a number is greater than a given number.
And here's a formula that checks if a cell contains a negative number:
=IF(B2<0, "Invalid", "")
For negative numbers (which are less than 0), the formula returns "Invalid"; for zeros and positive numbers - a blank cell.
Excel IF function with text
Commonly, you write an IF statement for text values using either "equal to" or "not equal to" operator.
For example, the following formula checks the Delivery Status in B2 to determine whether an action is required or not:
=IF(B2="delivered", "No", "Yes")
Translated into plain English, the formula says: return "No" if B2 is equal to "delivered", "Yes" otherwise.
Another way to achieve the same result is to use the "not equal to" operator and swap the value_if_true and value_if_false values:
=IF(C2<>"delivered", "Yes", "No")
Notes:
- When using text values for IF's parameters, remember to always enclose them in double quotes.
- Like most other Excel functions, IF is case-insensitive by default. In the above example, it does not differentiate between "delivered", "Delivered", and "DELIVERED".
Case-sensitive IF statement for text values
To treat uppercase and lowercase letters as different characters, use IF in combination with the case-sensitive EXACT function.
For example, to return "No" only when B2 contains "DELIVERED" (the uppercase), you'd use this formula:
=IF(EXACT(B2,"DELIVERED"), "No", "Yes")
If cell contains partial text
In situation when you want to base the condition on partial match rather than exact match, an immediate solution that comes to mind is using wildcards in the logical test. However, this simple and obvious approach won't work. Many functions accept wildcards, but regrettably IF is not one of them.
A working solution is to use IF in combination with ISNUMBER and SEARCH (case-insensitive) or FIND (case-sensitive).
For example, in case "No" action is required both for "Delivered" and "Out for delivery" items, the following formula will work a treat:
=IF(ISNUMBER(SEARCH("deliv", B2)), "No", "Yes")
For more information, please see:
Excel IF statement with dates
At first sight, it may seem that IF formulas for dates are akin to IF statements for numeric and text values. Regrettably, it is not so. Unlike many other functions, IF does recognize dates in logical tests and interprets them as mere text strings. In other words, you cannot supply a date in the form of "1/1/2020" or ">1/1/2020". To make the IF function recognize a date, you need to wrap it in the DATEVALUE function.
For example, here's how you can check if a given date is greater than another date:
=IF(B2>DATEVALUE("7/18/2022"), "Coming soon", "Completed")
This formula evaluates the dates in column B and returns "Coming soon" if a game is scheduled for 18-Jul-2022 or later, "Completed" for a prior date.
Of course, there is nothing that would prevent you from entering the target date in a predefined cell (say E2) and referring to that cell. Just remember to lock the cell address with the $ sign to make it an absolute reference. For instance:
=IF(B2>$E$2, "Coming soon", "Completed")
To compare a date with the current date, use the TODAY() function. For example:
=IF(B2>TODAY(), "Coming soon", "Completed")
Excel IF statement for blanks and non-blanks
If you are looking to somehow mark your data based on a certain cell(s) being empty or not empty, you can either:
- Use the IF function together with ISBLANK, or
- Use the logical expressions ="" (equal to blank) or <>"" (not equal to blank).
The table below explains the difference between these two approaches with formula examples.
| Logical test | Description | Formula Example | |
| Blank cells | ="" |
Evaluates to TRUE if a cell is visually empty, even if it contains a zero-length string. Otherwise, evaluates to FALSE. |
=IF(A1="", 0, 1)
Returns 0 if A1 is visually blank. Otherwise returns 1. If A1 contains an empty string (""), the formula returns 0. |
| ISBLANK() |
Evaluates to TRUE is a cell contains absolutely nothing - no formula, no spaces, no empty strings. Otherwise, evaluates to FALSE. |
=IF( Returns 0 if A1 is absolutely empty, 1 otherwise. If A1 contains an empty string (""), the formula returns 1. |
|
| Non-blank cells | <>"" | Evaluates to TRUE if a cell contains some data. Otherwise, evaluates to FALSE.
Cells with zero-length strings are considered blank. |
=IF( Returns 1 if A1 is non-blank; 0 otherwise. If A1 contains an empty string, the formula returns 0. |
| ISBLANK() |
Evaluates to TRUE if a cell is not empty. Otherwise, evaluates to FALSE.
Cells with zero-length strings are considered non-blank. |
=IF( Works the same as the above formula, but returns 1 if A1 contains an empty string. |
And now, let's see blank and non-blank IF statements in action. Suppose you have a date in column B only if a game has already been played. To label the completed games, use one of these formulas:
=IF(B2="", "", "Completed")
=IF(ISBLANK(B2), "", "Completed")
=IF($B2<>"", "Completed", "")
=IF(ISBLANK($B2)=FALSE, "Completed", "")
In case the tested cells have no zero-length strings, all the formulas will return exactly the same results:
Check if two cells are the same
To create a formula that checks if two cells match, compare the cells by using the equals sign (=) in the logical test of IF. For example:
=IF(B2=C2, "Same score", "")
To check if the two cells contain same text including the letter case, make your IF formula case-sensitive with the help of the EXACT function.
For instance, to compare the passwords in A2 and B2, and returns "Match" if the two strings are exactly the same, "Do not match" otherwise, the formula is:
=IF(EXACT(A2, B2), "Match", "Don't match")
IF then formula to run another formula
In all of the previous examples, an Excel IF statement returned values. But it can also perform a certain calculation or execute another formula when a specific condition is met or not met. For this, embed another function or arithmetic expression in the value_if_true and/or value_if_false arguments.
For example, if B2 is greater than 80, we'll have it multiplied by 7%, otherwise by 3%:
=IF(B2>80, B2*7%, B2*3%)
Multiple IF statements in Excel
In essence, there are two ways to write multiple IF statements in Excel:
- Nesting several IF functions one into another
- Using the AND or OR function in the logical test
Nested IF statement
Nested IF functions let you place multiple IF statements in the same cell, i.e. test multiple conditions within one formula and return different values depending on the results of those tests.
Assume your goal is to assign different bonuses based on the score:
- Over 90 - 10%
- 90 to 81 - 7%
- 80 to 70 - 5%
- Less than 70 - 3%
To accomplish the task, you write 3 separate IF functions and nest them one into another like this:
=IF(B2>90, 10%, IF(B2>=81, 7%, IF(B2>=70, 5%, 3%)))
For more formula examples, please see:
Excel IF statement with multiple conditions
To evaluate several conditions with the AND or OR logic, embed the corresponding function in the logical test:
For example, to return "Pass" if both scores in B2 and C2 are higher than 80, the formula is:
=IF(AND(B2>80, C2>80), "Pass", "Fail")
To get "Pass" if either score is higher than 80, the formula is:
=IF(OR(B2>80, C2>80), "Pass", "Fail")
For full details, please visit:
If error in Excel
Starting from Excel 2007, we have a special function, named IFERROR, to check formulas for errors. In Excel 2013 and higher, there is also the IFNA function to handle #N/A errors.
And still, there may be some circumstances when using the IF function together with ISERROR or ISNA is a better solution. Basically, IF ISERROR is the formula to use when you want to return something if error and something else if no error. The IFERROR function is unable to do that as it always returns the result of the main formula if it isn't an error.
For example, to compare each score in column B against the top 3 scores in E2:E4, and return "Yes" if a match is found, "No" otherwise, you enter this formula in C2, and then copy it down through C7:
=IF(ISERROR(MATCH(B2, $E$2:$E$4, 0)), "No", "Yes" )
For more information, please see IF ISERROR formula in Excel.
Hopefully, our examples have helped you get a grasp of the Excel IF basics. I thank you for reading and hope to see you on our blog next week!
Practice workbook
Excel IF statement - formula examples (.xlsx file)
4724 comments
I want to have a narrative for the following:
0 = Not true
1 = Occasionally
2 = Often
3 = Very often
I'm trying to do a formula where, if I type in "1", it would pop up with "Occasionally" in the cell next to it. Basically, whatever number I type, I'd like the narrative to be next to it.
If C10 is "P"then C11 should "N", If C10 is "A" then C11 should "Y", if C10 is "O" then C11 should be "O" how to use the formul for this.
Hi, can anyone please help me with below scenario:
IF A2 is Date(today's Date) then my B2 Should be "completed". and if my A2 is "-" then B2 should be "WIP".
Please help
Hello
Can you help with the formula below.
If J3, J4 J5 <=79.99 turn red
Hello,
Can you please help me with the following formula?
Customer Loan Amount = J2
Customer Interest Rate = K2
Available Interest Rate = L2
I would like to divide $125,000 by the customer loan amount to get value: X
For example a customer with a 250000 loan:
125000/250000 = .5%
If the customer interest rate (K2) and available interest rate (L2) difference is greater than or equal to X, I would like it to return Yes and if the difference is not greater than .5 I would like it to return No
The L2 amount would be changed daily, and applied to the entire column.
The J2 amount has $ I do not know if that effects anything.
Percentage % sometimes used sometimes not.
If there is a blank in any of the applicable values I would like it to not apply the formula.
Right now I have:
=IF(K3-L3>=125000/J3,"YES","NO")
Is this correct?
Thank you for your help.
Best Wishes,
George
So I am using the IF function.
I want to do multiple IF's in 1 Cell.
If A2 is No then Joe
If B2 is No then Benn
If C2 is No then Tom
IF D2 is No then Lee
If E2 is No then Mick
If F2 is No then Anne
If G2 is No then Lynne
If H2 is No then Terri
I need these in 1 formula so in J2 if all were No it would have that list of Names.
Can anyone Help?!?!?!?!?
Hi, i'm really confused trying to fixed this. hope you can help me with this.
=IF(OR(L36="Pending", L36=""), 50, 200)
question: based on the above formula,
i want cell B to formula Yes if cell A contain "pending"
i want cell B to formula EmptyBlank if cell A does not contain "pending"
in cell A contain : text and numeric of different content.
I am trying to figure out how to use IF for a range.
I want to check if Cell A1 is within 52 to 60 to be true. I tried the suggested formula but it is not working. =IF(AND(A1>=52,A2<=60),"OKAY","NO")
Am I missing something?
I need a cell to show a numerical value for ex
If b2 is =999 then f2 =1
what formula do I use?
what I meant was;
If b2 is greater than or equal to 300 or less than or equal to 999 then f2 equals 1
One Order No. has 4 different sku and 3rd coloumn signifies the quantity of units ordered.. Blank space in first column represents that all sku s belong to order no in the above row. This is what I have:
No sku Qty
200090505 DO-NANO-CABLE-WRAP-TEAL 2
DO-PICO-CABLE-WRAP-TAN 2
DO-SMALL-CABLE-WRAP-TEAL 2
DO-TINY-CABLE-WRAP-BEIGE 2
200090494 BRAINSTO-PPS-PLN-NTBKA5 1
DO-SMALL-CABLE-WRAP-BEIGE 1
This is How I want Basically Transpose it in 1 single row: All sku's in 1 single row adjacent to the order:
Column A B C D E F G H I
Order200090505 SKU QTY SKU QTY SKU QTY SKU QTY
Order200090494 SKU QTY SKU QTY
One Order No. has 4 different sku and 3rd coloumn signifies the quantity of units ordered.. Blank space in first column represents that all sku s belong to order no in the above row. This is what I have:
No sku Qty
200090505 DO-NANO-CABLE-WRAP-TEAL 2
DO-PICO-CABLE-WRAP-TAN 2
DO-SMALL-CABLE-WRAP-TEAL 2
DO-TINY-CABLE-WRAP-BEIGE 2
200090494 BRAINSTO-PPS-PLN-NTBKA5 1
DO-SMALL-CABLE-WRAP-BEIGE 1
This is How I want Basically Transpose it in 1 single row: All sku's in 1 single row adjacent to the order:
Column A B C D E F G H I
Order200090505 SKU QTY SKU QTY SKU QTY SKU QTY
Order200090494 SKU QTY SKU QTY
Hi.!
i want your help, i'm using "if" function pls review my function.
=(IF(OR(T23:T27=B14),"01-101-101",IF(OR(B14=U23:U27),"02-101-101",IF(OR(B14=V23:V27),"02-102-101",IF(OR(B14=W23:W27),"03-101-101",IF(OR(B14=X23:X27),"03-102-101"))))))
Note: Example
B14 CELL Contains the word You
T23 Cell contains the word Will
T24 Cell contains the word Smith
T25 Cell contains the word You
T26 Cell contains the word Kill
Hello.
I hope you can help me. I need a total that will add only if the answer if yes. For example. If I have 20 quotes a day but I only sold 10. I only need to add those 10. I need those then to be showing on the total not the other 10.
i want to know how to do in excel if i am going to check if the shipments will be on Jan., feb. mar and so on.. based on the production date..
for example: i have production dates in feb. 1, 10, 26. i want to fall it in category 2, and if march:3 april:4 and so on..
can anyone could help me??
I want to grade students based on marks scored in six units and if score is less than 45% in any unit the result is fail if greater than 45 in all units the result is pass.(To pass student must score above 45% in all the six units)
Formula am using: =IF(C11>=45, "PASS", "FAIL")
C11........J11
HOW CAN I DO IT
What is the function please for the following:
if the sum in D21 is lower than 1000
so
lock the cell in I6
I am trying to read text in columns D5 through D30, and are looking for items equal to CRN. From there I would like to get the value of J5. Every time it picks up CRN in column D I would like it to keep a running total.
Hi,
I am trying to set a formula for C8:
C7 (amount of hours worked, amount will be entered manually in hh:mm format)
C8 - if a person did work more than 36hrs 30mins, then C8 needs to show 36:30 but if less than 36:30 amount should be copied from column C7.
Example:
C7= 32:30
C8= 32:30
Or
C7= 42:00
C8= 36:30
Please help,
Jane
pls help me for the formula IF when it is for 5 times
If Ach is >=95% score 1
>=97% score 2
>=99.6% score 4
>=101% score 5
and >=103% score 6
I have a doc where i have one tab "January 2017" where we enter date of call example "01/03/2017", enter time of call "7:00 am, select from list of call requesting service "Car or Shuttle" then complaint list +10 minutes. I want to continue using this sheet for the entire year, while on tab 2 "Call Summary" count all the calls which i was able to do using =COUNTIFS('January 2017'!I2:I26,"CAR",'January 2017'!J2:J26,"Wait Time +10 min") Now what i need is to have the formula first match Summary Cell A2 which i enter date of 01/03/2017 and match it to all columns of A2:A500 in tab "January 2017" and if they match (all calls matching 1/3/2017) then run formula =COUNTIFS('January 2017'!I2:I26,"CAR",'January 2017'!J2:J26,"Wait Time +10 min")ignore all other dates like those call on 1/5/2017
Hello
i am trying to create a formula which should be reducing a principle amount monthly in a cell. For example if someone gets an advance of say $5,000 to be paid in 10 months, it should post a $500 every month in a particular cell. is that possible..
IN THE A COLUMN HAVING VARIOUS DISPOSITION AND IN B COLUMN HAVING VARIOUS NO'S DIGITS IN CASE OF THE A COLUMN AND B COLUMN MATCHES WITH CONDITION NEED TO DISPLAY AS "ATTEMPT 1" AS LIKE NEED TO WRITE VARIOUS CONDITIONS NEED HELP.
THANKS IN ADVANCE
good day,
I need a formula for
If i fill D14 with value so directly the old value in D13 will have shift to D12 and d13 will take the value entered in D14 and the old value in D12 shift to D11 and old value in D11 shift to D10 and old value in D10 shift to D9
Many thanks
Majed
Good day,
I am trying to make a formula with text value and numbers using if in conditions and it is not work
Example: =IF('January Performance'!EU8=0,$D8="Mining & Survey",Summary!$F$18)
The formula above works, but when I add an option like below:
Example: If('January Performance'!EU8=0,$D8="Mining & Survey",Summary!$F$18,'January Performance'!EU8)
Adding formulas of the same king for multiple selection it's not working.
Example: =IF('January Performance'!EU8=0,$D8="Mining & Survey",Summary!$F$18,'January Performance'!EU8,If('January Performance'!EU8=0,$D8="Wash Plant",Summary!$F$19,'January Performance'!EU8)
Say I have a column with numbers between 0 and 100 I need the next column to display a letter based on that number. So if the number is below 25 I need it to read L between 25 and 50 to read M 50 to 75 H and 75 and above E. How would I go about doing that
Hi,
I am working on one excel where I need to check different scenarios using IF condition but unable to do so. Please can you help me as to how I can work on the same to get the accurate result.
There are more than1 if condition but not able to get the result.
Below is the excel which I am working on along with the condition that need to but fulfil.
Assigned User » Account Calculated User » Account Last Logged On User » Account Asset » Asset Status Asset » Inventory Date Asset » Short Description Asset » Serial Number Asset » Inventory Agent Asset » Physical Inventory Date
SATHISH_KUMAR_G_PANDALA spandala spandala Installed 20-12-2016 II01-FCPP882 FCPP882 SMS Need Result in this column
sridhar_pasupuleti spasupuleti spasupuleti Installed II01-6TKB9F2 6TKB9F2 SMS 25-03-2016 Need Result in this column
Condition Result
Asset Inventory date is blank. Inventory Date is Blank
inventory date non blank,but last logon user is blank Last Logged on User Blank
Last logon user non blank but inventory date more than 90 days Inventory not within 90 days
Asset Physical inventory data current month Recently updated by OSS
Compare Calculated and last logon user. If Different Calculate and Last Logged on User are Different
Compare Calculated and last logon user. If Same, then compare Assigned User and Calculated User. If same. All Users are Same
I have a workbook with 2 tabs. I want to get the value of a cell in tab 1 and based on that value, take the contents of another cell in that same tab and put it into the cell of tab 2.
Example: Tab 1 has verbiage in cell A2 and a value in A3
If the value in A3 = "fail", then take the value in A2 and put it in Tab 2, cell A1.
Hope that makes sense
Thanks!
I need a formula for
If column A is 10 value should be alex
if column b is 11 value should be syam
if column c is 12 value should be das
if column d is 13 value should be mathew etc
Analyze the quality of these volume estimates by categorizing the quality of the annual volume estimate versus the actual annual volumes for each dealership into the following categories:
• Display“Excellent”if the estimate is within 5%(higher or lower)of the actual sales volume. (Hint: For example, if you wanted to determine if the value 26 is within +/– 25% of 40, you would need to test this value to make sure that both 26>=40–.25*40 and 26<=40+.25*40.)
• Display“Good”if the estimate is greater than 5% higher or lower,but within 10% higher or lower of the actual volume.
• Display “Poor” if the estimate is greater than 10% higher or lower.
I've tried everything I can think of and can only get a response of Excellent. Estimate sales are 1540 and Actual sales are 1617
I have a data set where I'm using two criteria to make a calculation, but my if statement is giving "False" as an output. Also, what would be the process if I wanted to include in the formula to calculate the cost based on whether the cost type column is one type vs. the other?
Ex:
Cost Type
AB = Cell e1 Cost = f1
CD = Cell e2 Cost = f2
Columns:
A B C
Cost Type Units Cost Formula
AB 10 10.00 =if(A:A=$E$1,=(B:B/F1))
CD 20 20.00
AB 30 30.00
S.NO NAME TAMIL ENGLISH MATHS SCIENCE SOCIEL TOTAL AVERAGE
1 SURESH 94 69 82 49 36 330 66
2 PRAVEEN 85 68 19 28 59 259 51.8
3 JOHN 88 54 58 69 58 327 65.4
4 DINA 65 55 29 58 54 261 52.2
5 HARSHA 69 89 86 60 59 363 72.6
I WANT TO BELOW 40 MARK TAKING STUDENT RESULT WAS FAIL ABOVE 40 MARK TAKING STUDENT RESULT WAS PASS, KINDLY LET ME KNOW THE IF COMMENT,
=IF(C2>DATEVALUE("01/01/1900"),"EMPTY")*IF(D2>DATEVALUE("01/01/1900"),"BALANCE ")*IF(D2>DATEVALUE("01/01/1900"),"DISPATCHED ")
Hi i am trying to convert Likert survey data in a spreadsheet reflected as Strongly agree, Agree, Disagree and Strongly disagree TO 4,3,2, or 1 respectively in my spreadsheet.
I have tried all kinds of IF options but keep on getting a 0 as "answer". What is wrong with this one for example? Thanks
=IF(J2=Strongly Disagree,”1”,IF(J2=Disagree,”2”,IF(J2=Agree,”3”,IF(J2= Strongly Agree,”4”))))
1,20,000/
I need spell number i.e;inwords
What I am trying to do is to project the next maintenance date based upon the last date the maintenance was performed. Some maintenance occurs every 2 years, every year, every 6 month, every quarter, every month or 3 every week.
Example:
F2 G2 H2
Maintenance Date Maintenance Performed *Maintenance Due
9/14/2015 2Y 9/14/2017
9/15/2015 Y 9/15/2016
9/16/2015 6M 3/16/2015
9/17/2015 Q 12/17/2015
9/18/2015 M 10/18/2015
9/19/2015 W 9/26/2015
*
*Cell H2: the formula will automatically calculate the maintenance date using data in cell F2 ..... BUT one formula will capture all of these criteria and calculate the correct date based upon the data in cell G2.
The date formula is: =DATE(YEAR(F2),(MONTH(F2),DAY(F2)
To project a date the formula for 2 years: =DATE(YEAR(F2)+2,MONTH(F2),DAY(F2))
To project a date the formula for 1 year: =DATE(YEAR(F2)+1,MONTH(F2),DAY(F2))
To project a date the formula for 6 months : =DATE(YEAR(F2),MONTH(F2)+6,DAY(F2))
To project a date the formula for 3 months: =DATE(YEAR(F2),MONTH(F2)+3,DAY(F2))
To project a date the formula for 1 month: =DATE(YEAR(F2),MONTH(F2)+1,DAY(F2))
To project a date the formula for 1 week: =DATE(YEAR(F2),MONTH(F2),DAY(F2)+7))
Now what I want to is to create and if/then, or if/or formula or whatever is correct with all of these formulas so that it pulls the correct date based upon the data in G2.
2Y = 2 Years
Y = 1 Year
6M = 6 Months
Q = Quarter
M = 1 Month
W = 7 days
EXAMPLE: I think the first part of the formula would look like this for IF/THEN or the IF/OR so that searches through the criteria and post the correct date..
=IF(G2)=2Y
I thought the whole formula would look something like this but I don't even know if its correct, just something I came up with in my head...
=IF(G2)=2Y,"DATE(YEAR(F2)+2,MONTH(F2),DAY(F2))","DATE(YEAR(F2)+1,MONTH(F2),DAY(F2))","DATE(YEAR(F2),MONTH(F2)+6,DAY(F2))","DATE(YEAR(F2),MONTH(F2)+3,DAY(F2))","DATE(YEAR(F2),MONTH(F2)+1,DAY(F2))","DATE(YEAR(F2),MONTH(F2),DAY(F2)+7))")
but the formula is not calculating and there are errors
These are my constraints: I must use the "if function" to search for a "phone " in cell box...I know it is awkard. But if I have three cellphone Sony for $500, Samsung for $450,and Apple for $700... how would I set up an "if statement" that would return the price if enter the "word" in a certain cell?
Hi there,
Could someone offer assistance with:
If user selects "No" in column B, then user can enter a number in column C. However...
If the user selects "Yes" in column B, then user cannot enter a number (or anything) in column C.
Thanks so much for the help!
I am trying to use IF statement to get that my dates match, but it gives me false when they are the same dates. Is there another function I should be using for dates because Excel recognizes them as text? IE: 06/02/2004 to 6/02/2004. Is it because the second value is missing a zero in front of it?
Hi Jumana,
Try this:-
Good Good =IF(A2="Good",A2,"Error")
Bad Error =IF(A2="Good",A2,"Error")
Not Good Error =IF(A2="Good",A2,"Error")
enjoy...
Hi,
I want to check if the text in one cell follows directly after text in the cell above. I am not sure how to compare that.
Ex: If Cell A has the words "Good", I want to see if the cell directly below it has the words "Bad". If it is anything other than "Bad" I want it to say ERROR or False.
Hello sabrina,
Please use below text formula to check diffrence between 2 dates insted of datedif:-
=TEXT(C22-B22,"yy") (this will come in d22)
then type in next coloumn =IF(D22<5,"80 Hrs","120 Hrs")
Enjoy ...!!
Hi Peshiyaboy,
Regrettably, this simple solution won't work because the result of the TEXT function is always a text string, even if it looks like a number. Consequently, the IF formula won't work correctly.
Hello, I am having some trouble with using the IF function to calculate the vacation entitlement of employees with a certain tenure.
I would like to stipulate that an employee whose tenure is less than 5 years would get 80 hours of vacation, but if 5 or more years, would get 120 hours of vacation.
On my spreadsheet, column D displays the tenure. NOTE: the tenure is not a straight number, but a calculation made with a =DATEDIF function.
The below formula is what I've been using:
=IF(D2<5, "80", "120")
However, the answer always ends up being 120 even if the value in column D is less than 5 years. Any assistance in helping me correct this would be greatly appreciated, and thank you in advance!
Hello Sabrina,
Most likely, the value in column D is a text string that looks like a number, and it is the source of the problem. To be able to say with certainty, I need to know your formula in D2.
BTW, the result of your IF formula will also be a text string because you enclosed the numbers in quotation marks, and therefore you wont't be able to use those "text-numbers" in other calculations. So, you'd better put it this way: =IF(D2<5, 80, 120)
=1+11+11+11+11+11+11+1
please give me sum formula using this sequence after enter getting result but i want answer in excel formula
I have a meeting in 15 minutes and need some excel help fast.
I have two different excel workbooks. they both contain similar information. What I want is to find out which Product Codes in column A of workbook 1 are also in column B of workbook 2
Not sure if this is a IF or a VLookup situation
Hello,
I think this is a really great site! I’ve learned a lot from everyone’s post.
I was wondering if I could get some help. I am trying to write a formula that looks at a specific cell for a specific text, then looks at another cell for the value and then plugs in a dollar amount based on the value. It’s a tiering system which is looking at the text and based off of that text is trying to determine whether or not a payment is warranted. If I communicated this correctly, I am trying to say the following:
I am looking for the formula to look in cell “I4” for if it says “M”, “G” or “L”. If “G” is in “I4”, then look at “E4” and see what the value is. If the value of “E4” is 0-9 then “0”, if “E4” is 10-20 then “1” and if “E4” is 21 or greater then “3”. If “M” is in “I4”, then look at “E4” and see what the value is. If the value of “E4” is 0-119 then “0”, if “E4” is 200-250 then “1” and if “E4” is 251 or greater then “3”. If “L” is in “I4”, then look at “E4” and see what the value is. If the value of “E4” is 0-1000 then “0”, if “E4” is 1001-1200 then “1” and if “E4” is 1201 or greater then “3”.
This is what we initialed started with, but now we have to expand on it and develop a three tier system rather than it look for one value and place a value in it:
=IFERROR((IF(I4=”M”,COUNTIF(E4,”>=80″),IF(I4=”G”,COUNTIF(E4,”>=120″),IF(I4=”L”,COUNTIF(E4,”>=26″)))))*3,””).
I now need it to look for three different values for each letter and place a new value based off of that value.
I hope that makes sense.
Any and all help would be greatly appreciated!
If nothing else, happy holidays to everyone on this site!
I have this formula so far:
=IF(B4>=1000,1,"0")
But I want that if B4 is greater or equal to 1000 then it gets 1 point for every 1000 or 0 if less than 1000.
please help!!
Hi Khush,
Try this one: =IF(B4>=1000,INT(B4/1000),0)
if the time exceeded 31minutes the result should be "Missed" , if it did not exceeded result should be "ok"
=IF(I10>0,G10-I10,IF(U10>0,G10-U10,O10))
CAN U HELP ME IN THIS FORMULA
G10 IS A SUM OF 3 CELLS
i put a quantity 50 in A1
and A2 is total quantity A2 (A2 IS A SUM OF B1 AND A1)
i want if i put any quantity >0 in C1 or D1 then less the quantity from A2 if i dont put any quantity >0 then show me A1 quantity in A2
can any one help
How I do a formula in excel (column C) to calculate the grade of the persons using the following data.
A B C
Name Points Grade
X 57 F
Y 88 B
X 95 A
W 73 C
Grades
A = 90 - 100%
B = 80 - 89%
C = 70 - 79%
D = 60 - 69%
F = 0 - 59%
Hi luis,
Plz use below one and replay if u have any doubts...
=IF(AND(B2=90),"A",IF(AND(B2=80),"B",IF(AND(B2=70),"C",IF(AND(B2=60),"D","F"))))
HI... check below
=IF(AND(B2=90),"A",IF(AND(B2=80),"B",IF(AND(B2=70),"C",IF(AND(B2=60),"D","F"))))
Sorry to say that .. this is not pasting my orginal formaula,...
i have formula.. but unable to give... while pasting it missed to give some strings...
=IF(AND(B2=90),"A",IF(AND(B2=80),"B",IF(AND(B2=70),"C",IF(AND(B2=60),"D","F"))))