by In this article, you will learn how to build an Excel IF statement for different types of values as well as how to create multiple IF statements.
IF is one of the most popular and useful functions in Excel. Generally, you use an IF statement to test a condition and to return one value if the condition is met, and another value if the condition is not met.
In this tutorial, we are going to learn the syntax and common usages of the Excel IF function, and then take a closer look at formula examples that will hopefully prove helpful to both beginners and experienced users.
IF function in Excel
IF is one of logical functions that evaluates a certain condition and returns one value if the condition is TRUE, and another value if the condition is FALSE.
The syntax of the IF function is as follows:
As you see, IF takes a total of 3 arguments, but only the first one is obligatory, the other two are optional.
Logical_test (required) - the condition to test. Can be evaluated as either TRUE or FALSE.
Value_if_true (optional) - the value to return when the logical test evaluates to TRUE, i.e. the condition is met. If omitted, the value_if_false argument must be defined.
Value_if_false (optional) - the value to return when the logical test evaluates to FALSE, i.e. the condition is not met. If omitted, the value_if_true argument must be set.
Basic IF formula in Excel
To create a simple If then statement in Excel, this is what you need to do:
- For logical_test, write an expression that returns either TRUE or FALSE. For this, you'd normally use one of the logical operators.
- For value_if_true, specify what to return when the logical test evaluates to TRUE.
- For value_if_false, specify what to return when the logical test evaluates to FALSE. Though this argument is optional, we recommend always configuring it to avoid unexpected results. For the detailed explanation, please see Excel IF: things to know.
As an example, let's write a very simple IF formula that checks a value in cell A2 and returns "Good" if the value is greater than 80, "Bad" otherwise:
=IF(B2>80, "Good", "Bad")
This formula goes to C2, and then is copied down through C7:
In case you wish to return a value only when the condition is met (or not met), otherwise - nothing, then use an empty string ("") for the "undefined" argument. For example:
=IF(B2>80, "Good", "")
This formula will return "Good" if the value in A2 is greater than 80, a blank cell otherwise:
Excel If then formula: things to know
Though the last two parameters of the IF function are optional, your formula may produce unexpected results if you don't know the underlying logic.
If value_if_true is omitted
If the 2nd argument of your Excel IF formula is omitted (i.e. there are two consecutive commas after the logical test), you'll get zero (0) when the condition is met, which makes no sense in most cases. Here is an example of such a formula:
=IF(B2>80, , "Bad")
To return a blank cell instead, supply an empty string ("") for the second parameter, like this:
=IF(B2>80, "", "Bad")
The screenshot below demonstrates the difference:
If value_if_false is omitted
Omitting the 3rd parameter of IF will produce the following results when the logical test evaluates to FALSE.
If there is just a closing bracket after value_if_true, the IF function will return the logical value FALSE. Quite unexpected, isn't it? Here is an example of such a formula:
=IF(B2>80, "Good")
Typing a comma after the value_if_true argument will force Excel to return 0, which doesn't make much sense either:
=IF(B2>80, "Good",)
The most reasonable approach is using a zero-length string ("") to get a blank cell when the condition is not met:
=IF(B2>80, "Good", "")
Tip. To return a logical value when the specified condition is met or not met, supply TRUE for value_if_true and FALSE for value_if_false. For the results to be Boolean values that other Excel functions can recognize, don't enclose TRUE and FALSE in double quotes as this will turn them into normal text values.
Using IF function in Excel - formula examples
Now that you are familiar with the IF function's syntax, let's look at some formula examples and learn how to use If then statements in real-life scenarios.
Excel IF function with numbers
To build an IF statement for numbers, use logical operators such as:
- Equal to (=)
- Not equal to (<>)
- Greater than (>)
- Greater than or equal to (>=)
- Less than (<)
- Less than or equal to (<=)
Above, you have already seen an example of such a formula that checks if a number is greater than a given number.
And here's a formula that checks if a cell contains a negative number:
=IF(B2<0, "Invalid", "")
For negative numbers (which are less than 0), the formula returns "Invalid"; for zeros and positive numbers - a blank cell.
Excel IF function with text
Commonly, you write an IF statement for text values using either "equal to" or "not equal to" operator.
For example, the following formula checks the Delivery Status in B2 to determine whether an action is required or not:
=IF(B2="delivered", "No", "Yes")
Translated into plain English, the formula says: return "No" if B2 is equal to "delivered", "Yes" otherwise.
Another way to achieve the same result is to use the "not equal to" operator and swap the value_if_true and value_if_false values:
=IF(C2<>"delivered", "Yes", "No")
Notes:
- When using text values for IF's parameters, remember to always enclose them in double quotes.
- Like most other Excel functions, IF is case-insensitive by default. In the above example, it does not differentiate between "delivered", "Delivered", and "DELIVERED".
Case-sensitive IF statement for text values
To treat uppercase and lowercase letters as different characters, use IF in combination with the case-sensitive EXACT function.
For example, to return "No" only when B2 contains "DELIVERED" (the uppercase), you'd use this formula:
=IF(EXACT(B2,"DELIVERED"), "No", "Yes")
If cell contains partial text
In situation when you want to base the condition on partial match rather than exact match, an immediate solution that comes to mind is using wildcards in the logical test. However, this simple and obvious approach won't work. Many functions accept wildcards, but regrettably IF is not one of them.
A working solution is to use IF in combination with ISNUMBER and SEARCH (case-insensitive) or FIND (case-sensitive).
For example, in case "No" action is required both for "Delivered" and "Out for delivery" items, the following formula will work a treat:
=IF(ISNUMBER(SEARCH("deliv", B2)), "No", "Yes")
For more information, please see:
Excel IF statement with dates
At first sight, it may seem that IF formulas for dates are akin to IF statements for numeric and text values. Regrettably, it is not so. Unlike many other functions, IF does recognize dates in logical tests and interprets them as mere text strings. In other words, you cannot supply a date in the form of "1/1/2020" or ">1/1/2020". To make the IF function recognize a date, you need to wrap it in the DATEVALUE function.
For example, here's how you can check if a given date is greater than another date:
=IF(B2>DATEVALUE("7/18/2022"), "Coming soon", "Completed")
This formula evaluates the dates in column B and returns "Coming soon" if a game is scheduled for 18-Jul-2022 or later, "Completed" for a prior date.
Of course, there is nothing that would prevent you from entering the target date in a predefined cell (say E2) and referring to that cell. Just remember to lock the cell address with the $ sign to make it an absolute reference. For instance:
=IF(B2>$E$2, "Coming soon", "Completed")
To compare a date with the current date, use the TODAY() function. For example:
=IF(B2>TODAY(), "Coming soon", "Completed")
Excel IF statement for blanks and non-blanks
If you are looking to somehow mark your data based on a certain cell(s) being empty or not empty, you can either:
- Use the IF function together with ISBLANK, or
- Use the logical expressions ="" (equal to blank) or <>"" (not equal to blank).
The table below explains the difference between these two approaches with formula examples.
| Logical test | Description | Formula Example | |
| Blank cells | ="" |
Evaluates to TRUE if a cell is visually empty, even if it contains a zero-length string. Otherwise, evaluates to FALSE. |
=IF(A1="", 0, 1)
Returns 0 if A1 is visually blank. Otherwise returns 1. If A1 contains an empty string (""), the formula returns 0. |
| ISBLANK() |
Evaluates to TRUE is a cell contains absolutely nothing - no formula, no spaces, no empty strings. Otherwise, evaluates to FALSE. |
=IF( Returns 0 if A1 is absolutely empty, 1 otherwise. If A1 contains an empty string (""), the formula returns 1. |
|
| Non-blank cells | <>"" | Evaluates to TRUE if a cell contains some data. Otherwise, evaluates to FALSE.
Cells with zero-length strings are considered blank. |
=IF( Returns 1 if A1 is non-blank; 0 otherwise. If A1 contains an empty string, the formula returns 0. |
| ISBLANK() |
Evaluates to TRUE if a cell is not empty. Otherwise, evaluates to FALSE.
Cells with zero-length strings are considered non-blank. |
=IF( Works the same as the above formula, but returns 1 if A1 contains an empty string. |
And now, let's see blank and non-blank IF statements in action. Suppose you have a date in column B only if a game has already been played. To label the completed games, use one of these formulas:
=IF(B2="", "", "Completed")
=IF(ISBLANK(B2), "", "Completed")
=IF($B2<>"", "Completed", "")
=IF(ISBLANK($B2)=FALSE, "Completed", "")
In case the tested cells have no zero-length strings, all the formulas will return exactly the same results:
Check if two cells are the same
To create a formula that checks if two cells match, compare the cells by using the equals sign (=) in the logical test of IF. For example:
=IF(B2=C2, "Same score", "")
To check if the two cells contain same text including the letter case, make your IF formula case-sensitive with the help of the EXACT function.
For instance, to compare the passwords in A2 and B2, and returns "Match" if the two strings are exactly the same, "Do not match" otherwise, the formula is:
=IF(EXACT(A2, B2), "Match", "Don't match")
IF then formula to run another formula
In all of the previous examples, an Excel IF statement returned values. But it can also perform a certain calculation or execute another formula when a specific condition is met or not met. For this, embed another function or arithmetic expression in the value_if_true and/or value_if_false arguments.
For example, if B2 is greater than 80, we'll have it multiplied by 7%, otherwise by 3%:
=IF(B2>80, B2*7%, B2*3%)
Multiple IF statements in Excel
In essence, there are two ways to write multiple IF statements in Excel:
- Nesting several IF functions one into another
- Using the AND or OR function in the logical test
Nested IF statement
Nested IF functions let you place multiple IF statements in the same cell, i.e. test multiple conditions within one formula and return different values depending on the results of those tests.
Assume your goal is to assign different bonuses based on the score:
- Over 90 - 10%
- 90 to 81 - 7%
- 80 to 70 - 5%
- Less than 70 - 3%
To accomplish the task, you write 3 separate IF functions and nest them one into another like this:
=IF(B2>90, 10%, IF(B2>=81, 7%, IF(B2>=70, 5%, 3%)))
For more formula examples, please see:
Excel IF statement with multiple conditions
To evaluate several conditions with the AND or OR logic, embed the corresponding function in the logical test:
For example, to return "Pass" if both scores in B2 and C2 are higher than 80, the formula is:
=IF(AND(B2>80, C2>80), "Pass", "Fail")
To get "Pass" if either score is higher than 80, the formula is:
=IF(OR(B2>80, C2>80), "Pass", "Fail")
For full details, please visit:
If error in Excel
Starting from Excel 2007, we have a special function, named IFERROR, to check formulas for errors. In Excel 2013 and higher, there is also the IFNA function to handle #N/A errors.
And still, there may be some circumstances when using the IF function together with ISERROR or ISNA is a better solution. Basically, IF ISERROR is the formula to use when you want to return something if error and something else if no error. The IFERROR function is unable to do that as it always returns the result of the main formula if it isn't an error.
For example, to compare each score in column B against the top 3 scores in E2:E4, and return "Yes" if a match is found, "No" otherwise, you enter this formula in C2, and then copy it down through C7:
=IF(ISERROR(MATCH(B2, $E$2:$E$4, 0)), "No", "Yes" )
For more information, please see IF ISERROR formula in Excel.
Hopefully, our examples have helped you get a grasp of the Excel IF basics. I thank you for reading and hope to see you on our blog next week!
Practice workbook
Excel IF statement - formula examples (.xlsx file)
4719 comments
i have two sheets in the first sheet i have values and emp id and in the second sheet i want that if in the particular row of first sheet if it contains any value grater than 0 then show on the second sheet and if equal to and less than 0 then no show.
like
first sheet have two rows one of which is blank and in the second row value is shown so in the second sheet i want only that second row value
i think u understand what i want to say
i want add A1 cell and B1 cell but result display in B1 cell
i want and a1 cell and b1 cell but result display in b1 cell
I am trying use an IF and OR function. The formula below works perfectly, but the one below that (where the cell A1 is replaced with the words) doesn't work and comes back with #VALUE.
=IF(OR(L6="Research",A1),"","N/A")
=IF(OR(L6="Research","Sales"),"","N/A")
an anybody help??
I have been able to use your answer for Keith on 2nd December, thank you.
Answer:
=IF(OR(L6="Research",L6="Sales"),"","N/A")
Hi, I am trying to display the value in the next column if a value is found from a range. So, I have one workbook with three worksheets.
The first worksheet has a list of ID's numbers and vendor names. Vendor names would repeat in this sheet and the customer ID could repeat if they use more than one vendor.
The second sheet has a distinct list of the vendor names along with a tier rating (1,2,3,4).
I am attempting to lookup the vendor name from sheet 1, find it in the vendor name range from sheet 2, and when found, populate the tier rating.
To take it a step further, though I could do this function separately after I have the first done, I have a 3rd tier that includes a point value associated with the tier rating. I'll be looking to populate the point value for each row in sheet 1 based on their tier.
Any help is appreciated. I am caught on how to display the tier value since I am not simple doing a yes or no of whether the text is found, but needing to display corresponding information when the text is found.
I think I need to use a vlookup, but I am just not have any luck.
A little funny with my repeated post, but I did solve my issue of generating the tier using an index/match formula.
This is an awesome article. I'm having problems though getting it to work if the cell it is referencing is on another tab? For example, if B8 on Sheet 2 is a Y, then I want B9 on Sheet 3 to format with a Y or an N if the B8 on Sheet to is an N and blank if B8 is a blank.
I would like to take the value produced in Cell D28 via this formula =ABS(SUM(D12-D24)), if the Value in D12 is less than D24 and have it show on a second sheet called "Score" in cells G12-N12-U12-AB12-AI12. I am at my wits end. I am constructing a score sheet and the value in D28 is the handicap between the team averages listed in d12 and d24.
Hello, Miss... Can I use "IF" Formula for conditional formatting?
If value in A2 is GREATER than 5% of value of A1, then I want the cell (A2) to be Blue color.
If value in A2 is LESS than 5% of value of A1, then I want the cell (A2) to be Red color.
I already know conditional formatting... But can you please send me the correct formula for the above. Thanks.....
Hello,
Would u please tell me how to do the following in Excel
if the value in the cell greater than by 0.2 of the value of the other cell display as up regulated
if it is less than by 0.2 of the value of the same other cell display as down regulated
other wise diplay as normal.
thanks alot
Please help,
what's the formula for
IF CELL A = GP AND CELL B>3000 ,"H" IF 2000 ,"H" IF 2000 ,"H" IF <150,"L", "M"
THANK A LOT
Is there a way to code a function in this example?
IF a cell contains 1 word (of 3 choices) in A1, then I want the value in B1 to appear in C1.
Hello Keith,
You can enter the following formula in C1:
=IF(OR(A1="word1", A1="word2", A1="word3"), B1, "")
How can i do this for multiple cells and add them all together?
Thank you. It is helpful. I was thinking about some free version of variation as well.
Thanks!
Quick Question:
I wanted to match last names from two excel sheets, then select the values (DOB) to be ported to the other excel sheet. What would be the formula?
Hi Richard,
Please have a look at the Merge Tables for Excel add-in, it may help you with the task:
https://www.ablebits.com/excel-lookup-tables/index.php
=IF(N18<=5,"32A",IF(N18<=5,IF(H18="1x4Cx6","")))
Hi can anybody Correct this Condition
=IF(A3180,(A3+180),IF(A3>540,(A3-540),"")))
Hello Pawan,
Probably you meant this:
=IF(A3>540, A3-540, IF(A3>180, A3+180, ""))
I want create a formula with if condition i am depreciating the value by 33.34% for 1 st year & 2nd Year & 3rd year according to my % of depreciation from the 1st july'16 to 30th june'16 but its not working for current 2016, kindly check the formula & help me.
AA Column type Z column has date Y Colume
=IF(AA429="R",0,ROUNDDOWN(IF($Z$1-Z429<=365,Y429*100%,IF($Z$1-Y429<=730,Y429*66.67%,IF($Z$1-Y429<=1095,Y429*33.34%,1))),))
Hi guys good evening!
How to apply in excel the following formula:
0 - 136 = tax exempted
136 - 2500 = 14% tax
>2500 = 350 plus 25% tax
I can't figure out the "If" Formula.
Cell B26 is blank, 0.00, or greater than 0.00
Cell D26 = 970.53
Cell E26 Formula, to be T1 or T9
Cell F26 Forumla, to be an amount
Cell G26 Forumla, to be an amount
Need the following formulas....
1) For E26... If B26 = nothing, or 0.00, then E26 = "T9" otherwise "T1". For E26 to be "T1", B26 needs to be greater than 0.00.
2) For F26... If B26 = nothing, or 0.00, than F26 = D26 otherwise F26 is to be D26-B26.
3) For G26... If B26 = nothing, or 0.00, then G26 needs to show a zero (not a blank), otherwise G26 is to equal B26.
Thanks for your help.
I am making a weekly schedule for 2 months. I have entered the days of the week in a column. I need that if the day of week be Monday,Wednesday, Friday then output A , and if it be Tuesday, Thursday, Saturday , then B. Please help with the command line.
Cell A1 is calculated and gives a numeric value.(a time value)
I have used IF function so that A1 can only show a maximum of 9:30 even if the calculated value is more than 9:30.
A1 is then used by other cells to calculate other values.
I want to be able to show the value in A1 like so :
If A1 is equal to or greater than 9:30 then show cell value as 9:30
If A1 is less than 9:30 then show that actual value
Can anyone help ?
Thanks
I have a spreadsheet where column E represents the amount of money owed for a monthly payment and column K asks "yes or no?" (using a drop-down list) to whether or not a late fee ($50) should be applied. I'm having trouble creating an "IF" formula that would add $50 to the amount listed in column E "IF" column K answered "Yes". Can someone help?
I have four values in four columns. If first column's value is greater than 0 and the second colummn is equal to zero and third column is greater than 0 and fourth column is equal to 0, i want to type pass in the fifth column. Else fail. Can anyone help to write a formula for this?
IF( AND( $A1>0, $B1=0, $C1>0, $D1=0), "Pass", "Fail")
Hi there, bit of a tricky one here. This works fine, but i have to do this for 11 colums, is there a way so shorten this code?
="Port: "&IF(AND(G2>100,G2100,G3100,G4100,G5100,G6100,G7100,G8100,G9100,G10100,G11100,G12100,G13100,G14100,G15100,G16100,G17100,G18100,G19100,G20100,G21100,G22100,G23100,G24<500),"23,","")
="Port: "&IF(AND(G2>100,G2100,G3100,G4100,G5100,G6100,G7100,G8100,G9100,G10100,G11100,G12100,G13100,G14100,G15100,G16100,G17100,G18100,G19100,G20100,G21100,G22100,G23100,G24<500),"23,","")
="Port: "
&IF(AND(G2>100,G2100,G3100,G4100,G2<500),"A2,","")
And if possible to shorten this, because writing it out for every row 23 time s is a drag
Hai,
i am looking a formula for calculating gratuity as basis of "OnDuty".
i have found the formula to calculate the gratuity for slab basis. but now i am facing one issue, that while applying this formula to a text containing condition its been showing an error.
1. =(IF(Q3-G3+1<=1825,(J3/30)*21/365*(Q3-G3+1),IF(AND(Q3-G3+1=1826),J3/30/365*28*(Q3-G3+1-1825)+(J3/30)*21/365*1825,IF(AND(Q3-G3+1=3651),((J3/30/365*35)*(Q3-G3+1-3650))+(J3/30/365*28*1825)+(J3/30)*21/365*1825,0))))
2. =IF(H3="OnDuty",(IF(Q3-G3+1<=1825,(J3/30)*21/365*(Q3-G3+1),IF(AND(Q3-G3+1=1826),J3/30/365*28*(Q3-G3+1-1825)+(J3/30)*21/365*1825,IF(AND(Q3-G3+1=3651),((J3/30/365*35)*(Q3-G3+1-3650))+(J3/30/365*28*1825)+(J3/30)*21/365*1825,0)))),"")
please reply
=IF(BD2,"Not a Target", "Not a Target, BD2&": "&BC2)
I'm not sure what I am doing wrong? Any ideas?
Hi Sarah,
The syntax of the Excel IF function allows 3 arguments, while your formula has 4. If you can provide some details about the source data and expected result, I will try to help.
Thanks for clear explanations on this IF problem.
Been looking online and trying for hours now and have failed to find a solution to my desired outcome in my workbook.
I have column A with order numbers that look like this, a3er-k8uy. Every order has a base fee of $4.50 which I manually input into column B. I would like column B to fill in the $4.50 any time I input an order number. Is the IF formula the one to use, if so how?
I have a formula that sums my WIP. I want an IF formula to help me mark Error if that sum is over $0.00 and balanced if its $0.00. I have tried but my formula will not pick up unless I manually type 0.
Hi, I missed a symbol in the example I provided with my query. Correct example for the formula I am aiming to apply in cell B1 is =IF(AND(A1"",B1=""),"Display Error Message","Allow selection from list of values for B1")
Thanks
Hi,
I am trying to display an error message using IF function.
Data for one of my columns (say column B) is a list of value. Depending upon the value selected by the user in Column B, I populate the values in column C using the LookUp function.
Column A of my worksheet has a date and if user enters a date for a record in column A, I want the user to select one of the values(from drop down list) in column B. If the user doesn't enters the value in column B and leaves it blank, I want to display an error message.
e.g. =IF(AND(A1"",B1=""),"Display Error Message","Allow selection from list of values for B1)
Pls guide. Thanks
I'm creating time sheets in Excel. I would like for a cell to automatically populate "8" if another cell contains any one of several dates. I am able to use the following formula successfully for one date:
=IF(O9=DATEVALUE("12/23"),8,"")
However, I would like to use multiple dates. For instance, show "8" if cell O9 contains 12/23, 4/14, or 11/24. Otherwise, leave the cell blank.
Any ideas?
Sorry this a cut and paste from me elsewhere. Check if the cell does/does not exist in a named range of cells containing your exception dates.
Hi, sorry I don't have a spreadsheet in front of me to syntax check.
Eg.
IF( OR( A1="Football" , A1="Basketball", A1="Hockey"), "Sport" , "Something Else" )
-OR-
I often flip my IF statements to check for Errors or Exceptions first.
Eg.
Define an area in Formula Tab, MySportList=$L$31:$L$59
Fill these cells with your sports.
IF( ISERROR( VLOOKUP( A1, MySportList, 1, false)), "Something Else", "Sport")
# IF TEST is, if you get an error when trying to lookup the contents of A1 from your list of Sports in cells, L31:L59, then display "Something Else", else display "Sport".
if A1 is 0 print 0 and if B1 is 0 print 0 and if ((A1 and B1)>0) print =A1+B1
IF( OR( A1=0, B1=0), 0, IF( AND( A1>0, B1>0), SUM(A1+B1), "A or B is less than Zero")
Hi Svetlana Cheusheva,
I am facing issue with this formula and need your guidance.
i am preparing a sheet which contains Team attendance and would like to use IF condition. For ex: if a person is coming in the morning shift he has to number as 1, if afternoon it's 2 and Night it's 3, Leave it's 4. How can I write a formula for this. Please advice me on this.
hello Emmanuel again =IF(D8"",D8+8,"OFF") this formula works on a same sheet but picking the source from a different sheet doesn't give me the correct answer example =IF(Sheet1!D3"", D3+8,"OFF". it only gives me 8 without adding the figure in the cell. can you help
I am looking for some help and guidance. in Excel 2007
basically I have 3 cells. In one cell I have a calibration date, In second cell I have due date, and in third cell i have frequency of calibration i.e. quarterly, annually and 2 years. Now at the moment I have to manually change all the dates whenever the due date is up, what I would like to do, is to be able to change the calibration date and for the due date to change automatically based on the frequency of calibration.
Could someone please help me with this issue? Many thank
Hi,
I need a help.
Assume that this values are in one cell "'C3, C4, C6, C10, C11, C12, C16, C17, C18, C22, C23, C24, C30, C31, C33, C34" .
I need a formula that whether C17 is present in that cell or not.
i want to create a formula where =IF(D8"","+8","OFF") where if not blank add 8 and if blank put off. But the formula is not given me the required result
Hello Emmanuel,
Here's the correct syntax:
=IF(D8<>"", D8+8, "OFF")
Hello Svetlana,
I have a conditional formula in Column F and am seeking a conditional formula for Column G. My goal is for Column F to affect Column G, dependent on the parameters I give Column G. I would like for Column G's logic to be as follows:
If F1 is >=6 concurrently <11 [then] if true, G1 = 1. If false, G1 = "".
Thank you for your valuable help.
I want red font color if the logic is false.
Pls. guide me.
with thanks
I have a date format in column e and in column f I have put a formula for it to automatially update it to 3 years later by adding 1095 to column e. Now, I am trying to get column a to turn red 60 days before column f is mature. I have tried conditional formatting but for some reason it doesn't work.
Hi, sorry I don't have a spreadsheet in front of me to syntax check.
Checks:
Column E has numbers that display as text and not text "12/09/2020".
Column F should be the formula =E1+1095 and display 12/09/2023.
Format:
Condition Formatting on Cell Range =$E$1:$E$51 as a formula option.
IF( TODAY() >= (F1 - 60), TRUE, FALSE)
Is it possible to use OR commands in the logic function?
Ie, something along the lines of
=IF(A1="Football" OR "Basketball" OR "Hockey", "Sport", "Something Else")
Thank you in advance
Hi, sorry I don't have a spreadsheet in front of me to syntax check.
Eg.
IF( OR( A1="Football" , A1="Basketball", A1="Hockey"), "Sport" , "Something Else" )
-OR-
I often flip my IF statements to check for Errors or Exceptions first.
Eg.
Define an area in Formula Tab, MySportList=$L$31:$L$59
Fill these cells with your sports.
IF( ISERROR( VLOOKUP( A1, MySportList, 1, false)), "Something Else", "Sport")
# IF TEST is, if you get an error when trying to lookup the contents of A1 from your list of Sports in cells, L31:L59, then display "Something Else", else display "Sport".
Hi,
I need a formula as per below scenarios, can someone help on this:
column 1 = Yes / NO
Column 2 = Rural / Urban
Column 3 = Balance dues in number months shown
below is the requirement :
Column 4 = if line item says Yes and Urban and no. of months due is 2 then 4 should be the resultant. second secenario if line item says No and urban then the 0 should be the resultant in the same cell.
Thanks !
Hi Gene
can you help me develop IF syntax for:
Youth (64)
Hi All,
I have formula in the Cell Z24 i.e. =((V24-L24)*E24)-AD24-AB24-AE24-AC24. Now my requirement to this is when CELL "E24" is "Not ZERO" or "BLANK", then it should process the formula =((V24-L24)*E24)-AD24-AB24-AE24-AC24 else, if CELL "E24" is "ZERO" or "BLANK", then the value in Z24 should be "0".
Any help pls?
Hi, sorry I don't have a spreadsheet in front of me to syntax check.
I often flip my IF statements to check for Errors or Exceptions first.
Eg.
IF( Value(E24) = 0, 0, CALCULATE)
-OR-
IF( OR( E24=0, Trim(E24)="", ISERROR(1/E24) ), 0, CALCULATE)
Hi, so far I have this formula in cell I3 which works. My problem is that I don't know what to add to tell I3 that if D3 is blank then I3 should be blank too. I hope you can help
=IF(D3>100,"50",IF(D3<100,"30"))
I need your help, I have to calculate the interest amount on bases of delayed dates. Ex. 500 days. Base amount-Rs 10,000
Interest rate slab mentioned below
<180 days-18%
365 days-30%
So, I have to pay Interest for first 180 day@18%,Second 185 days@24%, remaining @ 30%.
Can you give the excel formula for the above case.Please
Hi. Please help.
If($CC$2="AC",($CC$5*AC6),IF. . . . .
That is my formula. How do I get that if cell CC2 is not equal to anything, that the cell then stays empty. Cause if I put in "", the return value is 0, and it has to return an empty cell and not 0.
Thanks
if A and D are both less than 75: 0
if A is greater than or equal to 75 and D is less than 75: Calculate (A — 75) = X value.
if D is greater than or equal to 75 and A is less than 75: Calculate (D — 75) = A/D value.
if A and D are both greater than or equal to 75: Calculate [(A — 75) + (D — 75)] = A/D value.
Hello everybody,
I have a task, please help me to prepare it in excel. in one sheet column A, I have some barcode numbers and in coloum B i have its text name. In another sheet I want to make something like if i scan a barcode sticker with scanner and if it is present in Column A, it must display its text value from column B instead of number.
thank you
Hi, how can I extract a specific data based on condition from a range of cells, like below
A1 B1 C1 D1 E1 Result
Pass Pass Pass Fail Pass Fail
Problem Statement: I want to print 'Fail' in result cell if any of cells from A1-E1 has FAIL in it, or else Pass if there is PASS in any of the cells from A1-E1.
Any help is appreciated
Hi Sash,
You can use the following formula:
=IF(COUNTIF(A1:E1, "fail")>0, "Fail", IF(COUNTIF(A1:E1, "pass")>0, "Pass", ""))
Hi, how can I extract a specific data based on condition from a range of cells, like below
A1 B1 C1 D1 E1 F1 Days
35 39 32 34 36 42 Share price
I want to know whether today share price is greater than last 5 days.
If it is greater then alert message needs to be created "YES".
It is easier for 5 days period however in case of 15 days or 30 days or 45 days, it is difficult to track.
Need formula for daily tracking of stock for period of 15 days/30 days/45 days.
Hello!
You can calculate the maximum value of the 5 preceding cells in a row using the formula
=MAX(INDIRECT(CELL("address", INDIRECT("R2C"&(COLUMN(INDIRECT(CELL("address",L2)))-6),0))&":"& CELL("address", INDIRECT("R2C"&(COLUMN(INDIRECT(CELL("address",L2)))-1),0))))
R2 means row 2. You can change the row number.
L2 - cell with the current value.
You can learn more about INDIRECT function in Excel in this article on our blog.
If something is still unclear, please feel free to ask.