by In this article, you will learn how to build an Excel IF statement for different types of values as well as how to create multiple IF statements.
IF is one of the most popular and useful functions in Excel. Generally, you use an IF statement to test a condition and to return one value if the condition is met, and another value if the condition is not met.
In this tutorial, we are going to learn the syntax and common usages of the Excel IF function, and then take a closer look at formula examples that will hopefully prove helpful to both beginners and experienced users.
IF function in Excel
IF is one of logical functions that evaluates a certain condition and returns one value if the condition is TRUE, and another value if the condition is FALSE.
The syntax of the IF function is as follows:
As you see, IF takes a total of 3 arguments, but only the first one is obligatory, the other two are optional.
Logical_test (required) - the condition to test. Can be evaluated as either TRUE or FALSE.
Value_if_true (optional) - the value to return when the logical test evaluates to TRUE, i.e. the condition is met. If omitted, the value_if_false argument must be defined.
Value_if_false (optional) - the value to return when the logical test evaluates to FALSE, i.e. the condition is not met. If omitted, the value_if_true argument must be set.
Basic IF formula in Excel
To create a simple If then statement in Excel, this is what you need to do:
- For logical_test, write an expression that returns either TRUE or FALSE. For this, you'd normally use one of the logical operators.
- For value_if_true, specify what to return when the logical test evaluates to TRUE.
- For value_if_false, specify what to return when the logical test evaluates to FALSE. Though this argument is optional, we recommend always configuring it to avoid unexpected results. For the detailed explanation, please see Excel IF: things to know.
As an example, let's write a very simple IF formula that checks a value in cell A2 and returns "Good" if the value is greater than 80, "Bad" otherwise:
=IF(B2>80, "Good", "Bad")
This formula goes to C2, and then is copied down through C7:
In case you wish to return a value only when the condition is met (or not met), otherwise - nothing, then use an empty string ("") for the "undefined" argument. For example:
=IF(B2>80, "Good", "")
This formula will return "Good" if the value in A2 is greater than 80, a blank cell otherwise:
Excel If then formula: things to know
Though the last two parameters of the IF function are optional, your formula may produce unexpected results if you don't know the underlying logic.
If value_if_true is omitted
If the 2nd argument of your Excel IF formula is omitted (i.e. there are two consecutive commas after the logical test), you'll get zero (0) when the condition is met, which makes no sense in most cases. Here is an example of such a formula:
=IF(B2>80, , "Bad")
To return a blank cell instead, supply an empty string ("") for the second parameter, like this:
=IF(B2>80, "", "Bad")
The screenshot below demonstrates the difference:
If value_if_false is omitted
Omitting the 3rd parameter of IF will produce the following results when the logical test evaluates to FALSE.
If there is just a closing bracket after value_if_true, the IF function will return the logical value FALSE. Quite unexpected, isn't it? Here is an example of such a formula:
=IF(B2>80, "Good")
Typing a comma after the value_if_true argument will force Excel to return 0, which doesn't make much sense either:
=IF(B2>80, "Good",)
The most reasonable approach is using a zero-length string ("") to get a blank cell when the condition is not met:
=IF(B2>80, "Good", "")
Tip. To return a logical value when the specified condition is met or not met, supply TRUE for value_if_true and FALSE for value_if_false. For the results to be Boolean values that other Excel functions can recognize, don't enclose TRUE and FALSE in double quotes as this will turn them into normal text values.
Using IF function in Excel - formula examples
Now that you are familiar with the IF function's syntax, let's look at some formula examples and learn how to use If then statements in real-life scenarios.
Excel IF function with numbers
To build an IF statement for numbers, use logical operators such as:
- Equal to (=)
- Not equal to (<>)
- Greater than (>)
- Greater than or equal to (>=)
- Less than (<)
- Less than or equal to (<=)
Above, you have already seen an example of such a formula that checks if a number is greater than a given number.
And here's a formula that checks if a cell contains a negative number:
=IF(B2<0, "Invalid", "")
For negative numbers (which are less than 0), the formula returns "Invalid"; for zeros and positive numbers - a blank cell.
Excel IF function with text
Commonly, you write an IF statement for text values using either "equal to" or "not equal to" operator.
For example, the following formula checks the Delivery Status in B2 to determine whether an action is required or not:
=IF(B2="delivered", "No", "Yes")
Translated into plain English, the formula says: return "No" if B2 is equal to "delivered", "Yes" otherwise.
Another way to achieve the same result is to use the "not equal to" operator and swap the value_if_true and value_if_false values:
=IF(C2<>"delivered", "Yes", "No")
Notes:
- When using text values for IF's parameters, remember to always enclose them in double quotes.
- Like most other Excel functions, IF is case-insensitive by default. In the above example, it does not differentiate between "delivered", "Delivered", and "DELIVERED".
Case-sensitive IF statement for text values
To treat uppercase and lowercase letters as different characters, use IF in combination with the case-sensitive EXACT function.
For example, to return "No" only when B2 contains "DELIVERED" (the uppercase), you'd use this formula:
=IF(EXACT(B2,"DELIVERED"), "No", "Yes")
If cell contains partial text
In situation when you want to base the condition on partial match rather than exact match, an immediate solution that comes to mind is using wildcards in the logical test. However, this simple and obvious approach won't work. Many functions accept wildcards, but regrettably IF is not one of them.
A working solution is to use IF in combination with ISNUMBER and SEARCH (case-insensitive) or FIND (case-sensitive).
For example, in case "No" action is required both for "Delivered" and "Out for delivery" items, the following formula will work a treat:
=IF(ISNUMBER(SEARCH("deliv", B2)), "No", "Yes")
For more information, please see:
Excel IF statement with dates
At first sight, it may seem that IF formulas for dates are akin to IF statements for numeric and text values. Regrettably, it is not so. Unlike many other functions, IF does recognize dates in logical tests and interprets them as mere text strings. In other words, you cannot supply a date in the form of "1/1/2020" or ">1/1/2020". To make the IF function recognize a date, you need to wrap it in the DATEVALUE function.
For example, here's how you can check if a given date is greater than another date:
=IF(B2>DATEVALUE("7/18/2022"), "Coming soon", "Completed")
This formula evaluates the dates in column B and returns "Coming soon" if a game is scheduled for 18-Jul-2022 or later, "Completed" for a prior date.
Of course, there is nothing that would prevent you from entering the target date in a predefined cell (say E2) and referring to that cell. Just remember to lock the cell address with the $ sign to make it an absolute reference. For instance:
=IF(B2>$E$2, "Coming soon", "Completed")
To compare a date with the current date, use the TODAY() function. For example:
=IF(B2>TODAY(), "Coming soon", "Completed")
Excel IF statement for blanks and non-blanks
If you are looking to somehow mark your data based on a certain cell(s) being empty or not empty, you can either:
- Use the IF function together with ISBLANK, or
- Use the logical expressions ="" (equal to blank) or <>"" (not equal to blank).
The table below explains the difference between these two approaches with formula examples.
| Logical test | Description | Formula Example | |
| Blank cells | ="" |
Evaluates to TRUE if a cell is visually empty, even if it contains a zero-length string. Otherwise, evaluates to FALSE. |
=IF(A1="", 0, 1)
Returns 0 if A1 is visually blank. Otherwise returns 1. If A1 contains an empty string (""), the formula returns 0. |
| ISBLANK() |
Evaluates to TRUE is a cell contains absolutely nothing - no formula, no spaces, no empty strings. Otherwise, evaluates to FALSE. |
=IF( Returns 0 if A1 is absolutely empty, 1 otherwise. If A1 contains an empty string (""), the formula returns 1. |
|
| Non-blank cells | <>"" | Evaluates to TRUE if a cell contains some data. Otherwise, evaluates to FALSE.
Cells with zero-length strings are considered blank. |
=IF( Returns 1 if A1 is non-blank; 0 otherwise. If A1 contains an empty string, the formula returns 0. |
| ISBLANK() |
Evaluates to TRUE if a cell is not empty. Otherwise, evaluates to FALSE.
Cells with zero-length strings are considered non-blank. |
=IF( Works the same as the above formula, but returns 1 if A1 contains an empty string. |
And now, let's see blank and non-blank IF statements in action. Suppose you have a date in column B only if a game has already been played. To label the completed games, use one of these formulas:
=IF(B2="", "", "Completed")
=IF(ISBLANK(B2), "", "Completed")
=IF($B2<>"", "Completed", "")
=IF(ISBLANK($B2)=FALSE, "Completed", "")
In case the tested cells have no zero-length strings, all the formulas will return exactly the same results:
Check if two cells are the same
To create a formula that checks if two cells match, compare the cells by using the equals sign (=) in the logical test of IF. For example:
=IF(B2=C2, "Same score", "")
To check if the two cells contain same text including the letter case, make your IF formula case-sensitive with the help of the EXACT function.
For instance, to compare the passwords in A2 and B2, and returns "Match" if the two strings are exactly the same, "Do not match" otherwise, the formula is:
=IF(EXACT(A2, B2), "Match", "Don't match")
IF then formula to run another formula
In all of the previous examples, an Excel IF statement returned values. But it can also perform a certain calculation or execute another formula when a specific condition is met or not met. For this, embed another function or arithmetic expression in the value_if_true and/or value_if_false arguments.
For example, if B2 is greater than 80, we'll have it multiplied by 7%, otherwise by 3%:
=IF(B2>80, B2*7%, B2*3%)
Multiple IF statements in Excel
In essence, there are two ways to write multiple IF statements in Excel:
- Nesting several IF functions one into another
- Using the AND or OR function in the logical test
Nested IF statement
Nested IF functions let you place multiple IF statements in the same cell, i.e. test multiple conditions within one formula and return different values depending on the results of those tests.
Assume your goal is to assign different bonuses based on the score:
- Over 90 - 10%
- 90 to 81 - 7%
- 80 to 70 - 5%
- Less than 70 - 3%
To accomplish the task, you write 3 separate IF functions and nest them one into another like this:
=IF(B2>90, 10%, IF(B2>=81, 7%, IF(B2>=70, 5%, 3%)))
For more formula examples, please see:
Excel IF statement with multiple conditions
To evaluate several conditions with the AND or OR logic, embed the corresponding function in the logical test:
For example, to return "Pass" if both scores in B2 and C2 are higher than 80, the formula is:
=IF(AND(B2>80, C2>80), "Pass", "Fail")
To get "Pass" if either score is higher than 80, the formula is:
=IF(OR(B2>80, C2>80), "Pass", "Fail")
For full details, please visit:
If error in Excel
Starting from Excel 2007, we have a special function, named IFERROR, to check formulas for errors. In Excel 2013 and higher, there is also the IFNA function to handle #N/A errors.
And still, there may be some circumstances when using the IF function together with ISERROR or ISNA is a better solution. Basically, IF ISERROR is the formula to use when you want to return something if error and something else if no error. The IFERROR function is unable to do that as it always returns the result of the main formula if it isn't an error.
For example, to compare each score in column B against the top 3 scores in E2:E4, and return "Yes" if a match is found, "No" otherwise, you enter this formula in C2, and then copy it down through C7:
=IF(ISERROR(MATCH(B2, $E$2:$E$4, 0)), "No", "Yes" )
For more information, please see IF ISERROR formula in Excel.
Hopefully, our examples have helped you get a grasp of the Excel IF basics. I thank you for reading and hope to see you on our blog next week!
Practice workbook
Excel IF statement - formula examples (.xlsx file)
4719 comments
hi,
i have this check list with a checkbox, and i need to know how i can make the question status cell to display a text(done, pending) while changing the cell color (red to green),when i select one of the checkbox answer.
ex. do you have a list of traces on PCB? []yes []no []n/a [question status]
Case Qty (CQ) = 20
Max Level (MQ) = 18
Min Level (MiQ) = 8
Quantity on Hand (QOH) = 5
Reorder Level (ROL) = If(QOH<=MiQ,MQ-MiQ,0)
Reorder Quantity (ROQ) = ?
I want to have ROQ as.... If ROL is Zero then Zero, If ROL is Less than 60% of CQ then CQ, if ROL is greater than 60% of CQ then zero. Pl advice.
Hi Sreedhar
Please let me know if it is working for you...
=IF(ROL=0,0,IF(ROL 0.6*CQ,0)))
I have a cell that contains: Check # 0000
In other words, Check # 0000 - 9999
Can you recommend an If Formula. I have tried
=IF(A1="Deposit","Deposit",IF(A1="Check","Check"))
This works only if I have Check in the cell but with the number sign and numbers it returns a false value. Does anyone have a solution?
Hi William,
Try this one
=IF(A1="Deposit",A1,IF(SEARCH("Check",A1),A1))
Please let me know if it is working...
Hi, Svetlana,
I'm a bit stuck on finding a formula that will suit my needs. My spreadsheet has column A: first name; column B: last name; column C: type of training; column D: date of training.
I need a formula that will look at column A, B, and C and if they match any other row in column A, B, and C I need it to select the most recent date.
this will remove all duplicate training and keep only their most current training record.
Any suggestions? i'm stumped on this one.
is this something you can help me with? i'd really appreciate it. I'm in a time crunch and I have no one else to ask for help.
Hi Amanda,
You can simply sort your table by column D (most recent dates will be at the top), and then use the standard Excel Remove Duplicates tool to find duplicates in columns A, B, C and delete them.
If it is not the case, then send us a small sample workbook with your data at support@ablebits.com including the expected result, and our support team will try to help.
Svetlana,
I'm trying to avoid having to do this manually as the workbook is very large and will continue to get larger. I have emailed you a copy of the workbook as well as what i'm looking for.
Thank you,
Amanda
I want a function which will solve my query as mentioned below.
A B C D E
1 71501 giri 1
1 76597 sekhar 1
1 71503 satish 1
I want value of column C in column E If value of column A and particular value of column B match with value in column D
for example my requirement is column E = "sekhar"
please help.
Svetlana Cheusheva,how can u do, i tell u when i come back..........soonnnnnnn
Hi I want to include a value from a list in my IF formula.
=IF(A18 ="Other" ), D18, (SUM((D18+E18)*F18))
so basically if the value from the list in cell A18 = the word Other (that's a value in the List) I want to display the value in cell D18 if Other is not displayed in A18 then I want the Sum calculation to be done.
Is this possible?
Hi Bel,
Try this one..
=IF(A18="Other",D18,SUM(D18,E18)*F18)
Awesome! Thanks so much for your help Prasenjit!
Alternatively, you can put it in this way:
=IF(A18 ="Other"), D18, (D18+E18)*F18))
Hi,
I need to check the over all strength based on five cell values where each cells have different conditions to meet. It all pass the condition i would say 100%, if any four condition pass, then 75%, similarly for 1 & 2 & 3pass condition. if all fails it is 0%.
For all pass my condition is If(and(a1>=n,a2="Yes", a3<=y, a4z, a5>=100%), 100%, ).
I need to know how to get number of pass criteria and based on that allocating the strength percentage. Is it easy to nested if or need to any other function or method.
Please Suggest.
Regards,
Jai
Hi Jai,
If the Pass criteria can be used in any order, e.g. 1st, 3rd and 5th, then you'd better use the CHOOSE function:
=CHOOSE((IF(A1>4,1,0)+IF(A2="Yes",1,0)+IF(A3<3,1,0)+IF(A4>=6,1,0)+IF(A5=100%,1,0)),0%,20%,40%,50%,75%,100%)
Just change the conditions for each cell as you want.
The principle is as follows: each IF statement returns either 1 or 0 depending whether the conditions are met or not. The sum of the IFs' results varies from 0 to 5.
The CHOOSE function returns 0%,20%,40%,50%,75%,100% (you can also modify this part if needed) according to the sum of the IF functions' results.
Thanks...I got the solution................
Hi, I want to enter a formula for the following situation:
If the cell contains specific text, then calculate x-y, otherwise x
I was trying if(B1="text",A1-D1,A1) but it is not working
Hi Chacon,
The formula looks correct, I don't see any reason for it not working. You can try it on a blank sheet and you will see it does work. Maybe the problem is in the source data?
In a specific cell I am wanting it to tell me If a Response is LESS than 28 days old it is Outstanding & If it is MORE than 28 days old it is Overdue (this I can do) BUT I also want it to tell me if another cell on the same sheet contains 'Yes' it overides the previous command and that cell needs to read Complete but if that cell is blank it will ignore the rule. At the minute I have this:- =IF((E3-B7)>28,"Overdue","Outstanding"),IF(M9="Yes","Complete","0")
Hi Jen
Try this one
=IF(M9="Yes","Complete",IF((E3-B7)>28,"Overdue","Outstanding"))
I want to calculate age between 0-14, 15-24, 25-59 and 70+ from single age registered over the months in input sheet to analysis sheet. I want to know the formula;
the logic is if a person of 24 age is registered in January, 2014 then it should be counted in 14-24 age group in analysis sheet.
Thanks
You can calculate it using the COUNTIF function.
Here are the formulas to count age 14 – 24.
If dates are entered as text, e.g. " January, 2014":
= COUNTIFS($A$2:$A$100, "<=24", $A$2:$A$100, ">=14", $B$2:$B$100, "January, 2014")
If the date is formatted like this 1/10/2014, please use this formula:
=COUNTIFS($A$2:$A$100, "<=24", $A$2:$A$100, ">=14", $B$2:$B$100, "<=1/31/2014", $B$2:$B$100, ">=1/11/2014")
if a1>20 and b1> 50 add a1+b1 if if a1<20 and b1< 50 do nothing
please i need help on that
Hi Shabtom,
Here you go:
=IF(AND(A1>20, B1<50), A1+B1, "")
A B C D
1 a:5 b:4 a:26 b:3
2 a:4 b:45 a:6 b:18
3 M3 a:50 b:40 a:26 b:30
how to use IF function on above data. i want to print:
1) let's say, if the number after the colon [:] equal or more than 5, then just print "a" or "b"
2)if the number after the colon [:] is less than 5 then print "X".
Sorry, I am not sure I can follow you. Can you try to explain in other words?
Hi, Svetlana,
I'm a bit stuck on finding a formula that will suit my needs. My spreadsheet has column A: first name; column B: last name; column C: type of training; column D: date of training.
I need a formula that will look at column A, B, and C and if they match any other row in column A, B, and C I need it to select the most recent date.
this will remove all duplicate training and keep only their most current training record.
Any suggestions? i'm stumped on this one.
If it helps, I can certainly send you a copy of the workbook that I'm trying to do this in.
I have following formula but it writes the result as only A even condition not satisfied
=IF(F4="","",IF(ISERROR(VLOOKUP($D$4,Sheet5!D:D,4,0)),"A","B"))
Please Help me
Hi Kumar,
First off, please check the VLOOKUP range. Currently it contains just one column (D) and naturally Excel returns an error. You probably meant:
VLOOKUP($D$4,Sheet5!D:G,4,0)
hi i am not sure if i will explain it correct but i need help i need a formula to say if c2>d2 then true 3 false 0 and if c2=d2 then true 1 false 0
thanks very much
Hi!
Try this one:
=IF(C2>D2, 3, IF(C2=D2, 1, 0))
I am trying to come up with an IF statement that put a name only if the column to the left of it is not blank. However, there are formulas in the columns to the left that make some of them look blank, even though the actual cell is not blank. What formula can I use to return a blank if the cell has a formula, but is blank?
I started with this, but I don't know how to exclude the formula.
=IF(ISBLANK(B8)," ","Clarence")
Hi Janna,
If my understanding of the task is correct, replacing ISBLANK(B8) with B8="" should work a treat:
=IF(B8=""," ","Clarence")
is there a way to concatenate more than 3 IF functions
Sure, you can include as many as you want as long as the total number of arguments in the formula does not exceed 255.
You can find more info about the the CONCATENATE function as well as other alternatives to nested IF in the following article:
https://www.ablebits.com/office-addins-blog/excel-if-function-multiple-conditions/
i will try my best to explain......let's say we have 1,500 users in c25
Heading:
Login's per Month............................Fee
e25 = 1-1999 ..........................f25 = $10.00
e26 = 2,000 - 4,999....................f26 = $6.00
e27 = 5,000 - 9,999....................f27 = $4.00
if c25 is between 1 and 1999 logins how do we make c28 = f25 or $10.00
if c25 is between 2,000 and 4,999 logins how do we make c28 = f26 or $6.00
if c25 is between 5,000 and 9,999 logins how do we make c28 = f27 or $4.00
We would like to plug the number into c25 and then c28 will change to what ever the fee is.
thank you soooooooo much
LC3
I think you can concatenate 3 IF functions in this way:
=IF(AND(C25>=1, C25<=1999), F25, "") &IF(AND(C25>1999, C25<=4999), F26, "") &IF(AND(C25>4999, C25<=9999), F27, "")
Please note that if a value in cell C28 is outside of 1-9,999 range, the formula will return an empty string.
i'm very new at this I preformed a If and put it into cell c28 and got no return, I do put the formula in where I want the change to occur correct?
You put the formula in the cell where you want the result to appear.
Excellent, THANK YOUUUUUUUUUUUUUU
Thank Svetlana... This conversation was a great help for me.
Hi,
I need to modify the following formula so that when cells B2 or C2 are blank then the output cell is also blank.
=IF(OR(C2-B2>30,C2>DATEVALUE("12/13/14")),"No","Yes")
Currently it defaults to "Yes" when they are blank. Can you help me with this? Thank you.
Hi Blas,
Try a nested IF that checks for blanks, like this:
=IF(OR(C2-B2>30, C2>DATEVALUE("12/13/2014")), "No", IF(AND(B2="",C2=""), "", "Yes"))
It worked but I changed the nested IF to OR instead of AND. Thank you very much Svetlana.
I Love You! spot on
Please can you help me with this 1
If a range of cells (A1:A100) have another cell's data(B1) I want it to return the amount of times that reoccurs into cell C1
I need to be able to repeat the formula down C column for adding up different data in B1, B2, B3, etc column
Any Help much appriciated!
Column A is lots of different part numbers that repeat sometimes (purchases)
Column B is the part numbers aranged in numerical order (stock list)and one of each
Column C is the total of times it was Purchased
Hope that is clear enough!
Hi Andrew,
I believe the COUNTIF function is better suited for this job. Here's the formula for cell C1, and you can drag it down to other cells in column C:
=COUNTIF($A$1:$A$100, B1)
Hi TanMan,
Try this one:
=IF(A3>6.5, "c", IF(A3<4.5, "a", "b"))
Hi, what if I want to do the opposite:
=IF('Enter Scores'!B7="D", "3",IF('Enter Scores'!B7="B","5.10",IF('Enter Scores'!B7="C","4.50",IF('Enter Scores'!B7="E","1.50",IF('Enter Scores'!B7="F","0",IF('Enter Scores'!B7="A,"6"))))))
Basically each letter has a number value, if A is entered to B7 on another sheet then the number 6 should show up on the current sheet in the appropriate cell.
I've added this function to a number of cells and I can't use a =SUM(B6:B12) function because the numbers aren't really 'numbers' according to excel.
I've formated the cells to recognise the number; but I can't seem to get them to add up; I only get a total of 0.00
MAybe I need to use another function entirely
looking for some assistance on a formula.
I have the number 5 in cell a3
I need in cell b3 if a3 is > 6.5 then I need a letter "c" inputted / if a3 is < 4.5 then I need a letter "a" inputted / and if the a3 is between 4.5 and 6.5 then I need a letter "b" inputted in cell b3
I tried to do all of this and correcting the errors don't make sense
any help would be appreciated
Plead help, I need a formula to do the following:
If A1=Y then both B1 and C1 should either be N or blank, or IF B1=Y then both A1 and C1 should either be N or blank, or IF C1=Y then both A1 and B1 should either be N or blank.
What I mean is there should only be one Y in any of the cells A1,A2 and A3. Otherwise display error message if there is more than one Y.
Hi Ticia,
The following formula displays "error" if there is more than one Y in any of the cells A1, B1 and C1, it returns an empty string in all other cases.
=IF(AND(A1="Y", B1<>"Y", C1<>"Y"), "", IF(AND(A1<>"Y", B1="Y", C1<>"Y"), "", IF(AND(A1<>"Y", B1<>"Y", C1="Y"), "", "error")))
Hopefully this is what you are looking for.
Hi Svetlana,
Thanks for your prompt response. The formula does not seen to work, probably because of where I have placed it. Where can I put the formula to make it work? I placed the formula in data validation -> settings -> allow -> custom -> formula.
Ticia,
Simply copy it into a cell where you want the error message to be displayed.
Can you help me with this:
IF(D4="DSSM", "B4-210"), IF(D4="DSSM", "B4-180")
Hi Rawle,
I am not sure I fully understand what the formula is supposed to do. If you can explain the conditions to me, I will try to help.
somehow I cannot put does not equal, therefore I will put it in text, in the last bit, the argument is AU19 does not equal zero.
Hello Ganaa,
Try the following IF statement:
IF(AND('12'!AU190<>"",'12'!AU190<>0),"Required","")
Quried
sorry, the last bit looks like this. IF('12'!AU190,"Required","")))
Hello,
I desperately need help on below case. I am combining two reports, on sheets 12 and 13. With below formula I should be seeing "Required" in the cell because '12'!AU19 is not blank nor zero. Other cells with the same circumstances shows "Required" with no problem. When I evaluate this formula on '12'!AU190 it will actually say that it contains a constant.
=IF('12'!CQ190,'12'!CQ19,IFERROR(INDEX('13'!$A$1:$ABG$1466,MATCH('Draft (2)'!$A19,'13'!$A:$A,0),MATCH('Draft (2)'!AU$1,'13'!$1:$1,0)),IF('12'!AU190,"Required","")))
If you could help me on this it would be great. Thank you.
I need an If formula that will provide me with a value that is deterimed by the data validations that are selected contain different text selections:
for example: If cell D2 that has been selected from a data validation that has the text "No Show" or the text "Cancelled" then I want cell G2 to enter a value of 50 ... if it has any other text, then enter the value as 200 in cell G2
Any way of doing this?
Thanks
Hi Sheldon,
The solution is to use the OR function in IF's logical test, like this:
=IF(OR(D2="No Show", D2="Cancelled"), 50, 200)
i need help with this formula
"if d4 equal 0 display 0, if d4 is greater than 0 but less than 9 display 1"
Hi Tahsa,
Here you are:
=IF(AND(D4>0,D4<9),1,IF(D4=0,0,""))
Thank you Svetlana.
This was extremly helpful
That is great thank you Svetlana just what I needed
I need to make a an if formula that will tell me yes if something matches but then also has a text and amount for if the match is not correct. So I need a =if(A1=B1,"Yes" and then if A1 doesn't = B1 for the formula to say "Difference noted of (A1-B1)" to say how much the difference is while also having text in the same false side of the if function.
Can you help me?
Hi Zach,
You were almost there :)
=IF(A1=B1,"Yes","Difference noted of "&A1-B1)
Thank you! Worked perfectly :)
J21's % & M21's % are added together then devide by 2 to get a % that can be used
The this help
Here you go:
=IF(AND(J21>0, M21>0), (J21+M21)/2, IF(J21>0, J21, IF(M21>0, M21,"")))
hi Svetlana,
i have 3 dates and wish to use these dates for formula calculation, can you help me? all dates have some different rates applicable
Could you help with this project?
If J21's % is > then 0 then put that % in K18
If M21's % is > then 0 then put that % in K18
But if J21 & M21 %'s are > then 0 then devied
By 2 then put the result in K18 as a %
Only 1 of the 3 formula's can be true at
a time
Thank you
Hi Gene,
The first 2 conditions are clear. As for "if J21 & M21 %'s are > 0", which value shall we divide by 2?
Hi I am looking for a forumlar to completed the following calculation in a cell:
If A1 > 200,000 cell = A1-200000 but if A1>1,000,000 cell = 800,000
Please can you help me out with this formula
Hi Chris,
The following nested IF formula might work a treat:
=IF(A1>1000000, 800000, IF(A1>200000, A1-200000, ""))
This was very informative, can you help with this formula please?
If Cells in E:E = value "YES" AND Cells in F:F date older than 6 months then calculate result of Cell in B:B - (minus) a number "6"
Hi Sami,
Excel cannot understand the "month duration" because the number of days in each month varies. So, here is the formula as per your conditions, except that dates in column F are older than 180 days rather than 6 months:
=IF(AND(E1="yes", TODAY()-F1>180), B1-6, "")
Thank you for the formula, It did not work, I have the date sat with date value but the input just blank... if I leave F1 blank I get the results I need but, F1 "date" is important.
Hi
I want to put in an IF function that returns different text depending of the numerical value of the cell next to it. e.g. if the number is less than 43 - "poor", 43-50 "average", 51-70 "above average" etc....
I know I have to set up some cells with the lower value of each range and the text next to each one (pivot table?) but I can't remember the formula for saying - if it is less that A1 then print "textA" etc..
Hello Fo,
You can use a nested If formula like this:
=IF(A2>=51, "above average", IF(A2>=43, "average", "Poor "))
You can find an example very close to your task as well as a few alternative formulas in this article - Using nested IF functions in Excel
yea
Hi Svelana !!
I have two excel sheet containing a list of peoples, but there is some error e.g. font, spelling etc.
Pls help me to find the code of peoples from one sheet to other.
Hi Summy,
To find typos and other similar data that differ in 1 to 10 characters, you can use our Fuzzy Duplicate Finder add-in:
https://www.ablebits.com/excel-find-similar/index.php
If you want to locate font/color differences, more advanced tools are required.
Hi Dome help with a formula
I have a weight of 450 in cell a1, i need a if formula to say if a1 greater than 470.1 but less than 500 then pick up value in cell a2 on this occasion -.3.
can you help
thank you
Hi Stephen,
Here you go:
=IF(AND(A1>470, A1<500), A2, "")
i have 2 sheets, i want have the value 1 inputted on sheet two when/if it matches the date from sheet one. Basically i have set the work schedule up so that when an employee is put in a work spot, it adds 1 on the second sheet indicating the employee has work on that date. it's a daily schedule, so i am trying to automate the two sheets. so when i put someone to work it auto populates under the correct date on both sheets. if the are not working it should show 0
this is what i have so far, but not working...just shows false
=SUM(SUM(C2:C2)=1,IF('New daily - Table 1 - Guelph'!D6,D6)='Days worked test draft'!O1,O1) ="1"
Column C2 shows if a person works or not, then the row to the right are the dates for the month
any help would be greatly appreciated
How about: =IF(SUM(T7:AE7)=N7, 0, F5*H8). Is there an excel command to make the calculation in the second value work?
Hi Bob,
Your formula does work. If the sum in T7:AE7 is not equal to N7, the value in F5 is multiplied by H8. Or are you looking for something else?
Can you please look into the formula; where I am doing wrong...
IF(A1,B1,C1>=85%,"Tk 300",IF(A1,B1>=85%,C1=85%,B1=85%,A1=85%,B1,C1=85%,A1,C1=85%,A1,B1<85%,"Tk 100","0")))))))
Thanks for your reply.
I will try again.
Thanks
Can you please look into the formule; where I am doing wrong...
=IF(SUM(T7:AE7)=N7, "GOOD", "Check again")
This formula is returning 'Check again' though the sum(T7:AE7)=N7
Regards,
Pavan
Forgot to mention...
N7 is a result of a formula (for eg: C19*I6)
Thanks,
Pavan
Hi Pavan,
I don't see anything wrong with the formula. I've done a couple of quick tests and it worked perfectly. Maybe it makes sense to double check the sum?
forgot to mention...
here, N7 is again result of some other formula (eg: C19*I6)
Thanks,
This does not really matter, your formula should work anyway. If against all expectations it doesn't, you can send your sample worksheet at support@ablebits.com and we will try to figure this thing out.
use:
IF(round(SUM(T7:AE7);2)=round(N7;2), "GOOD", "Check again")
or the amount of signs you actually need usually 2 is enough :)
Hi,
=IF(SUM(T7:AE7)<=N7,"Good","Ccheck Again")
If you Want use greater than or less than on that formulas you can use this try Once.
Could you help with this formula?
"J21" = "%" and "M21" = "%" "K18" is the result but the are 3 answer.
J21 is > than 0
M21 is > than 0
J21 & M21 are > than 0 And needs to be
/ by 2
Hope you follow what I am looking for
Thank You
Hi Gene,
I understand that you have some percentages in cells J21 and M21, but all the rest is befogged.
Can you please try to formulate the task in the following way?
If J21 >0, then we do what?
If M21 >0, then we do what?
If J21 and M21 >0, then we do what?
If J21%>0 then put % in K18 as that %
If M21%>0 then put % in. K18 as that %
If M21 & J21 %>0 then devied by 2 then put
That % in K18
Only 1 of the 3 formula's can be true at a
Time and it's % in put in K18
Hope this is better for you to see what I want
Thank you
Hi!
It's not quite clear which value shall be divided by 2 if both J21 and M21 are greater than 0. The following formula divides the sum of values in the above mentioned cells:
=IF(AND(J21>0, M21>0), (J21+M21)/2, IF(J21>0, J21, IF(M21>0, M21,"")))
If you are looking for something else, then replace (J21+M21)/2 in the formula with the right value.
Svetlana i am having a data which is update by team daily.
Now i want 3 things to get from that data
1:updated
2:Missed to Update
3:Coming soon
Hi Vivek,
Excel formulas are not able to respond to a data change. Probably this can be done by using a VBA macro.
Hi,
Is this function just for one by one ? how if i want all of the data from one column like i want the data of column B with more than 1000 will go for high, the range 500-999 will go for medium and range 1-500 to low. Do i need to copy the formula and paste it one by one or it can help me comes out everything in one time, i have 19k data from that column
As I understand, it should be like this
in cell(k18)=if(and(j21>0,m21>0),(j21+m21)/2,0)
in col write a formula to give rank to student based on below table(without using if condition)
marks:=33 but less than 60,>=60 but less than 70,>=70 but less than 80,>=80 but less than 90,
>=90
grades:= <33,"Fail",<60,"pass",<70,"3rd div",<80,"2nd div",90,"distinction
plz solve this question
I'm trying to figure out a formula that will compare two columns "dates" and then produce the greater value of the two columns in the third column. Can you please help?
Hi Shannon,
Assuming that you have dates in columns A and B, the formula is as follows:
=IF(A1>B1, A1, B1)
Hi,
I Have a Data My software needs to work 99.99% availability when measured on Monthly basis If the downtime exceeds 60 min in a month for every 30 min Penalty should be calculated on Quarterly Payment of rs 10000 can u design a methodology with formula with calculated output.
Hi,
I read above that excel doesn't recognize dates unless wrapped in DATEVALUE.
I had the above formula that you gave and it doesn't always work. In my case one of my columns could possibly have a 0 or be blank.
My formula is in column A my date columns are D and G. So I had
=IF(G2>D2, G2,D2)
G is the column that sometimes could have a 0 or be blank (the data is pulled from another system.
Also, my formula doesn't recalculate once I update the data in column G. Any thoughts? I have auto calc turned on.
I am needing the cell in sheet two to = a cell in sheet one. it is a date. But if there is not a date in sheet one,yet, I want the cell in sheet two to show as blank/empty and then when the date is put in the cell in sheet one i want it to show the date in sheet two.
can you please help?
=IF(A2=5, "OK", "Wrong number")
BUT I WANT TO VALUE OF A1 CELL AT "Wrong number" POSITION
Hi!
If my understanding is correct, you simply need to replace "Wrong number" with A1 like this:
=IF(A2=5, "OK", A1)
The formula returns "OK" if A2 is equal to 5, otherwise it picks a value from cell A1.
If you want something different, please clarify.
Hi, I want to enter a formula that will give me a result only if there is a value > 0 in a row
i.e. if A1=0 then give me B1. But if B1=0 then give me B2 etc.
Can anyone help? I've got this so far, but it just gives me 0:
=IF(R2=0,S2,IF(S2=0,T2))
=IF(OR(A1=0,B1,B1=0),B2) u try this.
=IF(OR(A1=0,B1),IF(B1=0,B2))
I have 2 cells within Excel that I would like to apply the if function to, but I am not sure how to setup it up properly. Right now it reads:
=IF(T11=R13,"Ok","Check Total")
But, I want the formula to take in account if T11 is less than or greater than R13 by "5 units or 5 increments" to indicate "OK" not just equals to. How would I setup my formula?
Thank you in advance!
I have 2 cells within Excel that I would like to apply the if function to, but I am not sure how to setup it up properly. Right now it reads:
=IF(T11=R13,"Ok","Check Total")
But, I want the formula to take in account if T11 is less than or greater than R13 by "5 units or 5 increments" to indicate "OK" not just equals to. How would I setup my formula?
Thank you in advance!
Check Below Formula Once
=IF(OR(T11R13),"5units/5increments","Ok")
=IF(OR(T11R13),"","")
How do I get to extrapolate for if A#=0, B# without just typing =IF(OR(A1=0,B1),IF(A2=0,B2),IF(A3=0,B3),IF(A4=0,B4)) and on and on
=if(L4,"Half Yearly,180,If(L4,"Quarterly",90,if(L4,"Yearly",365)))
I work at a school, and i manage the book shop over there, so i want to keep my record straight for my boss, i forget things so fast :) and also my purchase record, thats why i want to set a formula to fastly enter. i deal with notebooks, diaries and artpads, so I want a formula for text and numbers both, for example if i write 'D' in a cell, the formula will write the amount of '55' for a Diary, and so on for notebook, i mean if i write 'N' for notebook, the formula will write the amount '50' for me. I just want to set that formula. So i can deal with other customers also.
=IF(A2="D","55",IF(A2="N","50"))
:)
=IF(OR(A1=0,B10),B1,B2)
This is your solution mate :)
enjoy it
How can I get a sum on page 1 cell D23 of numerical value from page 2 cells in column D if equal to specific text in column J?
if only you'd be my professor
IF A2's value = O then take date from B2 And IF A2's value = D then take date from C2 And IF A2's value = K then take date from D2
Hello AJAY,
Here you go:
=IF(A2="O",B2,IF(A2="D",C2,IF(A2="K",D2,"")))
It worked! Thank you Svetlana
If in place of Date in B2 there is alphanumeric text, then?
Hello Arnab,
It does not make any difference, the formula pulls any value from B2.
i need to find the maximum value and to show its time from the column of time. each value has got its specific time which is on the same row but different columns.
A formula please.
Thank You in Advance.
Hello Japhetmunnah,
This can be done using a VLOOKUP formula, like this:
=VLOOKUP(MAX(A1:A10), A1:B10, 2)
Where A is the column where you look up for max value, and B is the column containing times, 2 is the column number (col_index_num) in table array from which the value should be returned.
Do you help me? How to create tables in excel?
I am working in an excel file right now.
I wanted to show that when either of the two (2) columns have answered yes, it will be counted as 1.
Example. A1 has answered yes while B1 has answer no; therefore, the value will be 1.
Need your help on this.
Hello, Joboy,
try this formula:
=IF(OR(A1="yes",B1="yes"),1,"")
Note, that if neither of the cells have "yes", the cell with the formula will remain empty.
Hi
I want know the formula which applies only when value is above 0
Dear Sir,
I am very kind, that the formula is fantastic , i was in big trouble when i check this formula and its perfectly working. thanks a lot for your help.
best regards.
Hi Sveta,
I am doing a pivot table from a sheet which contains formula, but the pivot table always counts the supposedly blank cells but with formula, is there anyway to avoid this?
=IF((Data!$D$11="Concrete"),SUM((SUM($B$40*9)/1.3)*0.865/Data!$B$26),SUM((SUM($B$40*9)/1.3)/Data!$B$26))
I am trying to use the above if statement to calculate a value based on the value selected in Data!D11. The choices in a drop down D11 are Concrete or Frame. My logic being if D11=Concrete then do the first formula but if false (Frame) do the second formula. When Concrete is put into D11 this works correctly but if Frame is selected the value is not correct. I can put the second false formula in another cell and it calculates correctly. Can someone tell me how to fix this.
Rick
I am attempting to devise a formula that will assist me to calculate the payroll for my employees. It needs to address number of hours worked & then various rates of pay for those hours.
So far I have come up with the following:
=IF(AJ6>=3,(AJ6-3)*AN6+(3*AK6))+IF(AJ6>=3,(AH6-AJ6)*AI6)+IF(AJ6=3 - in the first instance I need a 0 recorded if cell
AJ6> cell AH6
- should that not be the case then I need the following calculation to take place (cell AH6 - cellAJ6)*cell AI6 (where cells AH & AJ are hours worked & cell AI is a rate of pay.
My many attempts have been close but do not seem to recognise the IF/OR component - I need this because if it calculates a negative number as it can in the first instance it decreases the pay of my employees.
Can someone out there help me?