by The tutorial shows how to create multiple IF statements in Excel with AND as well as OR logic. Also, you will learn how to use IF together with other Excel functions.
In the first part of our Excel IF tutorial, we looked at how to construct a simple IF statement with one condition for text, numbers, dates, blanks and non-blanks. For powerful data analysis, however, you may often need to evaluate multiple conditions at a time. The below formula examples will show you the most effective ways to do this.
How to use IF function with multiple conditions
In essence, there are two types of the IF formula with multiple criteria based on the AND / OR logic. Consequently, in the logical test of your IF formula, you should use one of these functions:
- AND function - returns TRUE if all the conditions are met; FALSE otherwise.
- OR function - returns TRUE if any single condition is met; FALSE otherwise.
To better illustrate the point, let's investigate some real-life formulas examples.
Excel IF statement with multiple conditions (AND logic)
The generic formula of Excel IF with two or more conditions is this:
Translated into a human language, the formula says: If condition 1 is true AND condition 2 is true, return value_if_true; else return value_if_false.
Suppose you have a table listing the scores of two tests in columns B and C. To pass the final exam, a student must have both scores greater than 50.
For the logical test, you use the following AND statement: AND(B2>50, C2>50)
If both conditions are true, the formula will return "Pass"; if any condition is false - "Fail".
=IF(AND(B2>50, B2>50), "Pass", "Fail")
Easy, isn't it? The screenshot below proves that our Excel IF /AND formula works right:
In a similar manner, you can use the Excel IF function with multiple text conditions.
For instance, to output "Good" if both B2 and C2 are greater than 50, "Bad" otherwise, the formula is:
=IF(AND(B2="pass", C2="pass"), "Good!", "Bad")
Important note! The AND function checks all the conditions, even if the already tested one(s) evaluated to FALSE. Such behavior is a bit unusual since in most of programming languages, subsequent conditions are not tested if any of the previous tests has returned FALSE.
In practice, a seemingly correct IF statement may result in an error because of this specificity. For example, the below formula would return #DIV/0! ("divide by zero" error) if cell A2 is equal to 0:
=IF(AND(A2<>0, (1/A2)>0.5),"Good", "Bad")
The avoid this, you should use a nested IF function:
=IF(A2<>0, IF((1/A2)>0.5, "Good", "Bad"), "Bad")
For more information, please see IF AND formula in Excel.
Excel IF function with multiple conditions (OR logic)
To do one thing if any condition is met, otherwise do something else, use this combination of the IF and OR functions:
The difference from the IF / AND formula discussed above is that Excel returns TRUE if any of the specified conditions is true.
So, if in the previous formula, we use OR instead of AND:
=IF(OR(B2>50, B2>50), "Pass", "Fail")
Then anyone who has more than 50 points in either exam will get "Pass" in column D. With such conditions, our students have a better chance to pass the final exam (Yvette being particularly unlucky failing by just 1 point :)
Tip. In case you are creating a multiple IF statement with text and testing a value in one cell with the OR logic (i.e. a cell can be "this" or "that"), then you can build a more compact formula using an array constant.
For example, to mark a sale as "closed" if cell B2 is either "delivered" or "paid", the formula is:
=IF(OR(B2={"delivered", "paid"}), "Closed", "")
More formula examples can be found in Excel IF OR function.
IF with multiple AND & OR statements
If your task requires evaluating several sets of multiple conditions, you will have to utilize both AND & OR functions at a time.
In our sample table, suppose you have the following criteria for checking the exam results:
- Condition 1: exam1>50 and exam2>50
- Condition 2: exam1>40 and exam2>60
If either of the conditions is met, the final exam is deemed passed.
At first sight, the formula seems a little tricky, but in fact it is not! You just express each of the above conditions as an AND statement and nest them in the OR function (since it's not necessary to meet both conditions, either will suffice):
OR(AND(B2>50, C2>50), AND(B2>40, C2>60)
Then, use the OR function for the logical test of IF and supply the desired value_if_true and value_if_false values. As the result, you get the following IF formula with multiple AND / OR conditions:
=IF(OR(AND(B2>50, C2>50), AND(B2>40, C2>60), "Pass", "Fail")
The screenshot below indicates that we've done the formula right:
Naturally, you are not limited to using only two AND/OR functions in your IF formulas. You can use as many of them as your business logic requires, provided that:
- In Excel 2007 and higher, you have no more than 255 arguments, and the total length of the IF formula does not exceed 8,192 characters.
- In Excel 2003 and lower, there are no more than 30 arguments, and the total length of your IF formula does not exceed 1,024 characters.
Nested IF statement to check multiple logical tests
If you want to evaluate multiple logical tests within a single formula, then you can nest several functions one into another. Such functions are called nested IF functions. They prove particularly useful when you wish to return different values depending on the logical tests' results.
Here's a typical example: suppose you want to qualify the students' achievements as "Good", "Satisfactory" and "Poor" based on the following scores:
- Good: 60 or more (>=60)
- Satisfactory: between 40 and 60 (>40 and <60)
- Poor: 40 or less (<=40)
Before writing a formula, consider the order of functions you are going to nest. Excel will evaluate the logical tests in the order they appear in the formula. Once a condition evaluates to TRUE, the subsequent conditions are not tested, meaning the formula stops after the first TRUE result.
In our case, the functions are arranged from largest to smallest:
=IF(B2>=60, "Good", IF(B2>40, "Satisfactory", "Poor"))
Naturally, you can nest more functions if needed (up to 64 in modern versions).
For more information, please see How to use multiple nested IF statements in Excel.
Excel IF array formula with multiple conditions
Another way to get an Excel IF to test multiple conditions is by using an array formula.
To evaluate conditions with the AND logic, use the asterisk:
To test conditions with the OR logic, use the plus sign:
To complete an array formula correctly, press the Ctrl + Shift + Enter keys together. In Excel 365 and Excel 2021, this also works as a regular formula due to support for dynamic arrays.
For example, to get "Pass" if both B2 and C2 are greater than 50, the formula is:
=IF((B2>50) * (C2>50), "Pass", "Fail")
In my Excel 365, a normal formula works just fine (as you can see in the screenshots above). In Excel 2019 and lower, remember to make it an array formula by using the Ctrl + Shift + Enter shortcut.
To evaluate multiple conditions with the OR logic, the formula is:
=IF((B2>50) + (C2>50), "Pass", "Fail")
Using IF together with other functions
This section explains how to use IF in combination with other Excel functions and what benefits this gives to you.
Example 1. If #N/A error in VLOOKUP
When VLOOKUP or other lookup function cannot find something, it returns a #N/A error. To make your tables look nicer, you can return zero, blank, or specific text if #N/A. For this, use this generic formula:
For example:
If #N/A return 0:
If the lookup value in E1 is not found, the formula returns zero.
=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), 0, VLOOKUP(E1, A2:B10, 2, FALSE))
If #N/A return blank:
If the lookup value is not found, the formula returns nothing (an empty string).
=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), "", VLOOKUP(E1, A2:B10, 2, FALSE))
If #N/A return certain text:
If the lookup value is not found, the formula returns specific text.
=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), "Not found", VLOOKUP(E1, A2:B10, 2, FALSE))
For more formula examples, please see VLOOKUP with IF statement in Excel.
Example 2. IF with SUM, AVERAGE, MIN and MAX functions
To sum cell values based on certain criteria, Excel provides the SUMIF and SUMIFS functions.
In some situations, your business logic may require including the SUM function in the logical test of IF. For example, to return different text labels depending on the sum of the values in B2 and C2, the formula is:
=IF(SUM(B2:C2)>130, "Good", IF(SUM(B2:C2)>110, "Satisfactory", "Poor"))
If the sum is greater than 130, the result is "good"; if greater than 110 – "satisfactory', if 110 or lower – "poor".
In a similar fashion, you can embed the AVERAGE function in the logical test of IF and return different labels based on the average score:
=IF(AVERAGE(B2:C2)>65, "Good", IF(AVERAGE(B2:C2)>55, "Satisfactory", "Poor"))
Assuming the total score is in column D, you can identify the highest and lowest values with the help of the MAX and MIN functions:
=IF(D2=MAX($D$2:$D$10), "Best result", "")
=IF(D2=MAX($D$2:$D$10), "Best result", "")
To have both labels in one column, nest the above functions one into another:
=IF(D2=MAX($D$2:$D$10), "Best result", IF(D2=MIN($D$2:$D$10), "Worst result", ""))
Likewise, you can use IF together with your custom functions. For example, you can combine it with GetCellColor or GetCellFontColor to return different results based on a cell color.
In addition, Excel provides a number of functions to calculate data based on conditions. For detailed formula examples, please check out the following tutorials:
Example 3. IF with ISNUMBER, ISTEXT and ISBLANK
To identify text, numbers and blank cells, Microsoft Excel provides special functions such as ISTEXT, ISNUMBER and ISBLANK. By placing them in the logical tests of three nested IF statements, you can identify all different data types in one go:
=IF(ISTEXT(A2), "Text", IF(ISNUMBER(A2), "Number", IF(ISBLANK(A2), "Blank", "")))
Example 4. IF and CONCATENATE
To output the result of IF and some text into one cell, use the CONCATENATE or CONCAT (in Excel 2016 - 365) and IF functions together. For example:
=CONCATENATE("You performed ", IF(B1>100,"fantastic!", IF(B1>50, "well", "poor")))
=CONCAT("You performed ", IF(B1>100,"fantastic!", IF(B1>50, "well", "poor")))
Looking at the screenshot below, you'll hardly need any explanation of what the formula does:
IF ISERROR / ISNA formula in Excel
The modern versions of Excel have special functions to trap errors and replace them with another calculation or predefined value - IFERROR (in Excel 2007 and later) and IFNA (in Excel 2013 and later). In earlier Excel versions, you can use the IF ISERROR and IF ISNA combinations instead.
The difference is that IFERROR and ISERROR handle all possible Excel errors, including #VALUE!, #N/A, #NAME?, #REF!, #NUM!, #DIV/0!, and #NULL!. While IFNA and ISNA specialize solely in #N/A errors.
For example, to replace the "divide by zero" error (#DIV/0!) with your custom text, you can use the following formula:
=IF(ISERROR(A2/B2), "N/A", A2/B2)
And that's all I have to say about using the IF function in Excel. I thank you for reading and hope to see you on our blog next week!
Practice workbook for download
Excel IF multiple criteria - examples (.xlsx file)
4496 comments
I'm trying to make a Trading Card spreadsheet with lookup pulldowns. how would you use a IF, THEN statement to have, for example: cell A1=(RNA) cell A2=(Ravnica Allegiance), work so that if I type the abbreviation (RNA), (Ravnica Allegiance) shows up. i know i can add the Abbrev. to the list but i have over 123 with one or two added a year. Any help would be great
Hey,
I was wondering how I would be able to make a formula that read; "If these 2 cells equal in value (locator column), then subtracts these amounts (Amounts column), and if the differnece is more than 3, then it is "unbalanced".
Could you help me?
Thanks in Advanced!
I am trying to do an "IF" statement that says put only fields with information and exclude the #N/A in the list.
Please assist.
could you help me out with a formula or a way of getting this done I have:
-----
Work hrs: 40
OT Hrs: 25
What I am trying to do is separate the OT hrs in doubles and triples
----
Doubles 9 hrs
Triples 16 Hrs
----
but the doubles are only to be cap at 9 hrs but if doubles are less than 9 to show the actual value, and if grater than 9 to be max at 9,
and of course triples would show what remaining from the total OT Hrs subtracting the Double OT hrs, and if less than Double OT hrs to be shown as blank....
Thank you guys in advance...♠☻
Hi all,
I am after a formula solution for my spreadsheet, column C has a list of numbers and column B has a time stamp. Column A has a date stamp, I need formula to look at column C match the date in column A and look at time stamp. Anything under a minute for this criteria gets highlighted or even better deleted. As per below it will leave the first line and delete or highlight the last 2 as duplicates (only both being under a minute of the first).
12/03/2019 10:15:29 11
12/03/2019 10:16:15 11
12/03/2019 10:16:24 11
Thank you in advance
Hey I am a QC engineer. Out of the lot i pick 3 samples and inspect it as per the Design, give the result as " OK" OR "NOT OK", based on following conditions
1. "Ok" if All 3 samples conforms to design
2. " ok" if any 2 sample out of 3 confirms to design
1. "Not ok" if any 1 sample only satisfies design out of 3
2." NOT ok", If all 3 samples doesn't satisfy design conditions
please suggest One formula which looks into ALL THE ABOVE CONDITIONS & gives the result as "OK" or "Not ok" automatically once i enter the 3 sample inspected values. i would be forever great full if i get the formula.
Pl help me out with a formula in a cell which contains different combination of letter, and letters has some numbers assigned.
For example, if we write CCT2 in a cell,
where "C" and "T2" are 10 and 20 respectively.
Then, pl help with the formula which will result in the total value of the cell
Like for CCT2 it should write = (10+10+20) = "40"
similarly for other combination like "CT2CT2" it should give (10+20+10+20) = "60"
Like this some more combination are there viz.. CCT2CCT2, CT2CT2 and so-on.
S,Q,N,O are amount fileds. and below are conditions for my requirement.
if s>0 then z=s and aa='o',
if q>0 thenz=q and aa='y',
if n>0 then z=n and aa='f',
if o>0 then z=o and aa='l'.
Can anyone help me with the code. Thank you
I want the formula for this
cut length = 2.750m
choices 6.0m, 7.50m, 9.0m, 10.5m and 12.0m
choose the least wastage in the choices.
Excel if formula for IF A2 is greater than B2 then B2 minus A1 * 12%
Hi,
Col.1 Col.2 Col.3 Col.4 Col.5
Lisa 1,000 USD EUR
Lisa 800 EUR
How do I get 800 to Col.4, Row 1 please?
Hi Svetlana Cheusheva,
I Need help for Formula as below
if there count is 0 to 5 it is come below 5
if there count is 6 to 10 it is come 6 - 10
if there count is 11 to 15 it is come 11-15
if there count is >16 it is come Above 16
I need help writing a formula that will look at the text value in one column and then the numeric value in another column and tell me if it met target or not. Here's what logic I want...
If text in A2 is "Tier 1" and the value in F2 is <=3 then I want it to return "Target Met" and if not then "Target Not Met"
Or
If text in A2 is "Tier 2" and the value in F2 is <=7 then I want it to return "Target Met", and if not then "Target Not Met"
How can I do this? Thanks!
=IF(OR(AND(B4="TIER1",C4<=3),AND(B4="TIER2",C4<=7)),"TARGET MET","TARGET NOT MET")
Dear Mam,
i want to below table blank (yellow color) cells in value column , so please reply me in email with solution.
I'm trying to combine and OR statement with an AND statement:
=IF((OR(ProductLine="ALT", ProductLine="OEM", ProductLine="TEK", ProductLine="VWR")),"OEM",IF(LEFT(ProductLine,1)="Z","Custom","Stock"))
That statement above works perfectly. BUT I need to add one more statement to this formula where product line =NCI then populate "Custom". Something like this: IF(ProductLine="NCI","Custom","Custom". But I cant combine them correctly!!!
Hi, I need your help to write a function with this condition
They condition are
(Payment, Invoice, credit memo, approved expenses) list in a drop-down
1. if payment, the value be reduced from the opening balance
2. if invoice, the value be added to the opening balance
3. also "Credit Memo" and "Approved Expenses"
Pls, I need help. How do I input "deduct 200 for all values lesser than 5000 and 300 for values greater than 5000 on an excel sheet?
Pls, I need help. How do I input "deduct 200 for all values 5000
Column 1 column 2 column 3
Site 1 2 45% 7
Site 2 3 85% 0
Site 3 2 45% 8
Site 4 4 100% 0
Site 5 1 35% 7
In the above table I need a formula where in I want to get my answer in terms of site 3. Condition is that if column 1 has two sites (1 and 3) having same number, then compare the values of those two sites (1 and 3) in column 2, if the value there is also same then compare the value of to sites(1 and 3) in column three and get the max number as the answer. If the value is not same in coloum 2 and 3 of site (1 and 3) then compare the max value of both the site within each colum and get the answer.
I need a formula where the conditions are if there are 2 equal number in column 1, then consider max of the rows having equal number from column 2, if those 2 rows having equal number in columns 1 and same two rows having equal number in column 2 then consider the max value of the representing rows from column 1 and 2.
Hello,
I am trying to write a formula that can sum all the cell 'Amounts' when specific the cells 'Value' have the same number.
A B C D E F G
ValueA AmountA ValueB AmountB ValueC AmountC TotalAmountValue0
0 $5000 0 $3000 1 $2000
In Column G ' TotalAmountValue0' i need to write a formula that sums the amounts when cell A, C and'or E are '0'.
These are the formulas that i used:
=IF(AND(A1=O,C1=0,E1=0),SUM(B1,D1,F1),0) This is not working as E1 is not 0 so its not adding up the values.
=IF(OR.... Not working as is adding up all cells when at least one cell is equal to 0
What formula should i use?
I am trying to write a formula to tell me how many enroller's I need if there are more than 100 enrollees, per week.
Example 4 Weeks, 638 enrollees = 6 enroller's per week.
Can anyone help me?
So what I'm struggling with is the below:
if column "c" has data in it then add columns "c,d,e" but if it doesn't have a value in column "c" then add columns "d & e". Would I be able to use the if statement or is there another statement (function) I should be using?
Hi All
I require assistance with a formula that just cannot nut out.
I have a task list and I would like the status to automatically change dependent on the percentage complete. I am using 0%,25%,50%,75%, and 100% for percentage complete. So if the Percentage complete >0 but <100 status to read In Progress. If percentage complete = 0 status to read Not Started, and if percentage complete = 100% then status to read Complete.
Thanks
Can someone help me I need help? I want to use an if statement to return either 1 or 0 but I want to use that if statement again and if 1 is already available then 2 and then 3 and so on
I need to nest more that 64 IF statements in one formula for option buttons. Is there a way this limit of 64 can be expanded? Or is there a way to start a new set of option buttons within the same sheet without loosing the exiting ones?
Pls support me to fetch the details of two column which are matching for their reverse values ..
For Example ---ambala delhi and delhi ambala are matching for their reverse values ..how to get all those
col a col b col c
ORIGIN DEST WT
AMBALA DELHI 2
DELHI AMBALA 4
JAIPUR RUDRAPUR 1
JAIPUR UDAIPUR 3
RUDRAPUR JAIPUR 4
UDAIPUR AMBALA 3
UDAIPUR AMBALA 2
Hi Friends,
Can anyone help me with the following formula?
> If a cell has the date 11/11/2011, I would like for it to display the word Waiver
> If that same cell has any other date, I would like it to display the applicable date (mm/dd/yyyy)
> If that same cell is empty, I would like to it to display an empty cell. (no words)
Good Afternoon.
I have an issue here that I want help on. In Column A I have 10 options and in Column B I have 2 dorp down Options. Based on selection in Column A and B, Column C returns an answer however I want my Column C to have a drop down where I limit individuals to chose between those drop down options. The drop down options in Column C should be formula driven. (e.g. IF in Column A I have "Left Over" and in column B I have "Non-Usable", in Column C I should have a drop down of 4 options), bare in mind that my options in 8.
hi
can someone tell me the formula of
I have a column of the target and a column of actual. and the max score is define
for example if my target is 5 and I have achieved say 4 and the max score I can get is 15
so i will like 4/5*15 = 12 but if i have achieve more than target how could i restric the ans to 15 only
I've 3 worksheet
1st for final calculation with a fix column number,
2nd for changeable data (each column will be known by sl number) and
3rd for fix data (here only one column so no need number).
I want to auto calculate by changing the calculation sheet fix column number.
my test formula for you:
=if(and(sheet1!$a$1=sheet2!$b$2,(sheet2!b5-sheet2!b10-sheet2!b15+sheet3!b5)>0),sheet2!b5-sheet2!b10-sheet2!b15+sheet3!b5,0)
for fix column no 1; it's working well but if i add more like this
=if(and(sheet1!$a$1=sheet2!$b$2,(sheet2!b5-sheet2!b10-sheet2!b15+sheet3!b5)>0),sheet2!b5-sheet2!b10-sheet2!b15+sheet3!b5,0,if(and(sheet1!$a$1=sheet2!$c$2,(sheet2!c5-sheet2!c10-sheet2!c15+sheet3!b5)>0),sheet2!c5-sheet2!c10-sheet2!c15+sheet3!b5,0))
it does not work, and it shows a message as: You've entered too many arguments for this functions.
please help me.
Average of best six excluding zeros in an array of tests but English is must take subject in excel
How can I find the average score of best six subjects including English as a must regardless of the score using excel
Hi, I know this is probably simple but its driving me crazy. Column E is:Date Submitted and Column A is # of days out (or item not returned).
=IF(AND(E3>0,A30,A3-E3&"R",""))
Please tell me the formula for Student teacher ratio
one teacher is required for 40 students and same 2 teacher is required for 90 students and then 3 teachers are required for 120 students and in addition to it on each 40 student one teacher is required
I need help to create a formula to cover below logic
if cell H8 contains ..1, W8/W7, if cell H8 contains ..2, W8/W6, if cell H8 contains ..3, W8/W5, if cell H8 contains ..4, W8/W4,if cell H8 contains ..5, W8/W3, if cell H8 contains ..6, W8/W2, otherwise W8/W1
Apparently, there is a problem with the formula below
=if((H8="*..1"),W8/W7,if(H8="*..2"),W8/W6,if(H8="*..3"),W8/W5),if(H8="*..4"),W8/W4,if(H8="*..5"),W8/W3),if(H8="*..6"),W8/W2,if(H8="*..7"),W8/W1,W8/W8))
Pls help.
Thank you
Try this
=IF(IFERROR(FIND("1",H8),0)>0,W8/W7,IF(IFERROR(FIND("2",H8),0)>0,W8/W6,IF(IFERROR(FIND("3",H8),0)>0,W8/W5,IF(IFERROR(FIND("4",H8),0)>0,W8/W4,IF(IFERROR(FIND("5",H8),0)>0,W8/W3,IF(IFERROR(FIND("6",H8),0)>0,W8/W2,IF(IFERROR(FIND("7",H8),0)>0,W8/W1,W8/W8)))))))
I have tried it, works correctly.
Thanks
I am trying to add time to a cell depending on a number in another cell. Formula I have is =IFS(F10=1,H10+TIME(4,0,0),F10=2,H10+TIME(48,0,0),F10=3,H10+TIME(72,0,0),F10=4,H10+TIME(432,0,0))
I am only getting a result when F10 is 1. If I change F10 to 2 it defaults to the same time already stated in cell H10. What am I missing from this?
I have a report with list of BOMs in excel format and I'd like to make use of nested if function to work out usage of each component under each BOM. What is the best nested if or best way to compute the usage of each component of each BOM?
Below example of the report
Product Order Order Line Qty
KitA 1234567 1.1 200
Component 1 1234567 1.1..1 200
Component 2 1234567 1.1..2 400
Component 3 1234567 1.1..3 600
Component 4 1234567 1.1..4 200
Component 5 1234567 1.1..5 400
Component 6 1234567 1.1..6 800
KitB 1234568 1.1 300
Component 1 1234568 1.1..1 600
Component 2 1234568 1.1..2 300
Component 3 1234568 1.1..3 900
KitA 1234569 1.1 100
Component 1 1234569 1.1..1 100
Component 2 1234569 1.1..2 200
Component 3 1234569 1.1..3 300
Component 4 1234569 1.1..4 100
Component 5 1234569 1.1..5 200
Component 6 1234569 1.1..6 400
Hey I am trying to make a condition of if value yes then it will multiply first set of logical conditions but if value is "no" then it will multiply by other set of values
=IF(OR(D1="yes",D1="no"),IF(A1=10,A1=100, 1*S1))),IF(A1=10,A1=100, A1*1))))
It does calculate the first set of conditions correctly but ignores the "or" condition
Please Help! Thanks!
for whatever reason the message is not full
=IF(OR(D1="yes",D1="no"),IF(A1=10,A1=100, 1*S1))),IF(A1=10,A1=100, A1*'S1))))
Basically the condition set is that
for whatever reason the message is not full
IF(OR(D1="yes",D1="no"),IF(A1=10,A1=100, 1*S1)))
,IF(A1=10,A1=100, A1*'S1))))
Hi,
I hope you will be able to help me.
I have a data - column with dates and times and the second column with values OPEN or CLOSE.
I need to find a formula to help me calculate time in between values ( please see below example of my data)
Date Formatted Value
30/07/2019 07:37 Open
30/07/2019 07:27 Open
30/07/2019 07:17 Open
30/07/2019 07:12 Closed
30/07/2019 07:02 Closed
30/07/2019 06:52 Closed
30/07/2019 06:43 Open
30/07/2019 06:33 Open
30/07/2019 06:23 Open
30/07/2019 06:13 Open
30/07/2019 06:03 Open
30/07/2019 05:53 Open
30/07/2019 05:43 Open
30/07/2019 05:33 Open
30/07/2019 05:23 Open
30/07/2019 05:13 Open
30/07/2019 05:03 Open
30/07/2019 04:53 Open
30/07/2019 04:43 Open
30/07/2019 04:33 Open
30/07/2019 04:24 Closed
30/07/2019 04:14 Closed
30/07/2019 04:09 Open
30/07/2019 03:59 Open
30/07/2019 03:49 Open
30/07/2019 03:47 Closed
30/07/2019 03:37 Closed
Function Date & Time
FALSE FALSE
FALSE FALSE
Open 30/07/2019 07:17:00
FALSE FALSE
FALSE FALSE
Closed 30/07/2019 06:52:00
FALSE FALSE
FALSE FALSE
FALSE FALSE
FALSE FALSE
FALSE FALSE
FALSE FALSE
FALSE FALSE
FALSE FALSE
FALSE FALSE
FALSE FALSE
FALSE FALSE
FALSE FALSE
FALSE FALSE
Open 30/07/2019 04:33:00
Thank you !
I have a 3 data entry fields. I want a warning to print if anyone enters in more than 1 of the data fields. When I had 2 fields, it worked. This is the formula I have written for the 3 fields. However, it only prints the warning if there are entries in the first 2 fields. If there is an entry in either of the first 2 fields and the third field, the warning isn't printing.
=if(and(a2>0, a3>0, a4>0),"Choose one", "")
Help! Thanks!
Enter this formula in cell B2 =A2>0
Enter this formula in cell B3 =A3>0
Enter this formula in cell B4 =A4>0
Then use this formula
=IF(COUNTIF(B2:B4,"TRUE")>1,"Choose one","")
Hi
I need help For this Formula.
Total Point.
How to used (I used it before long time more than seven years)
Total point Score
=if(H16="A",4*G$14,(if(H16="AB",3.5G$14,(if(H16="B",3*G$14,(if(H16="BC",2.5*G$14,(if(H16="C",2*G$14,(if(H16="CD",1.5*G$14,(if(H16="D",1*G14,(if(H16="E",0.5*G$14,0)))))))))))))))
=IF(H16="A",4*G$14,(IF(H16="AB",3.5*G$14,(IF(H16="B",3*G$14,(IF(H16="BC",2.5*G$14,(IF(H16="C",2*G$14,(IF(H16="CD",1.5*G$14,(IF(H16="D",1*G14,(IF(H16="E",0.5*G$14,0)))
hi...i badly need a help for the following criteria
what formula to write for the following...
to display pass
1.(if a student get 1 credit (50-100 marks) AND 5 passes (40-49) INCLUDING ENGLISH which can be either in the credit or the pass
2.if a student get 2 credits and 3 passes including english which can be either in credit or pass
how to get the output of a certain input when the output of that planning sheet depends upon several inputs in excel
Hi!
I have a file that has a complicated formula that I cannot solve. How can I send it to you to check and correct please?
Hi,
Could you help with a formula like below?
• If Andi 1-20, multiple number by 4
• If Andi 21-40, multiple number by 8
• If Andi 41-60, multiple number by 10
• If Andi 61-80, multiple number by 12
Thank you!
=C6*IFERROR(VLOOKUP($C$6,$A$6:$B$85,2,),"")
I Need a formula to calculate, 3 late marks a 1 half day & 6 late marks as 2 half days & 9 as 3 half days
I am interested in using the IF/AND function with multiple arguments on text, but can't seem to get this to work.
Column H Column I Column J
Classification Level Approved
EX 1 Yes
PM 5 Yes
AS 2 No
EC 6 Yes
MD-MOF 3 Yes
IF column H = EX and Column I = 1,2 or 3 then Column J = Yes
If column H = PM and Column I = 5 or 6 then Column J = Yes
If column H = EC and Column I = 6 or 7 then column J = Yes
If column H = MD-MOF and Column I = 3 then column J = Yes
Anything else in column H or I then column J = No
I'm stumped... any help is appreciated.
First make a table array that have EX, PM, EC, 1, 2, 3, etc...
A1 B1
EX1 Yes
EX2 Yes
=IFERROR(VLOOKUP(G19,$E$18:$F$25,2,FALSE),"No")
First make a table array that have EX, PM, EC, 1, 2, 3, etc...
A B C D E F
1 EX1 Yes =D1&E1 Input Input =IFERROR(VLOOKUP(C1,$A$1:$B$8,2,FALSE),"No")
2 EX2 Yes (EX,PM etc,)(1,2,6 etc.)
3 PM5 Yes
Etc....
Good Afternoon;
I'm having issues creating a formula to calculate & differentiate between columns.
My first column consists of Regular hours worked, Overtime @ 1.5 & Overtime @ 2.0.
All 3 types of hours worked are combined in the same column.
The column to the right of it has all the total values. Ex: Regular Hours Worked - 8Hrs, Overtime @ 1.5 - 4, Overtime @ 2.0 - 1.
How can I create a formula that will differentiate between the type of hours worked & then calculate the hours accordingly?
I need to split up the total hours for each of my employees by Regular Hours Worked, Overtime @ 1.5 & Overtime @ 2.0.
Any help with this would be greatly appreciated.
Thanks in advance
how to use if function with 2 conditions and blank cells also.