by Comparing columns in Excel is something that we all do once in a while. Microsoft Excel offers a number of options to compare and match data, but most of them focus on searching in one column. In this tutorial, we will explore several techniques to compare two columns in Excel and find matches and differences between them.
How to compare 2 columns in Excel row-by-row
When you do data analysis in Excel, one of the most frequent tasks is comparing data in each individual row. This task can be done by using the IF function, as demonstrated in the following examples.
Example 1. Compare two columns for matches or differences in the same row
To compare two columns in Excel row-by-row, write a usual IF formula that compares the first two cells. Enter the formula in some other column in the same row, and then copy it down to other cells by dragging the fill handle (a small square in the bottom-right corner of the selected cell). As you do this, the cursor changes to the plus sign:
To find cells within the same row having the same content, A2 and B2 in this example, the formula is as follows: To find cells in the same row with different values, simply replace the equals sign with the non-equality sign (<>): And of course, nothing prevents you from finding both matches and differences with a single formula: Or The result may look similar to this:
As you see, the formula handles numbers, dates, times and text strings equally well. Tip. You can also compare two columns row-by-row using Excel Advanced Filter. Here is an example showing how to filter matches and differences between 2 columns.
Formula for matches
=IF(A2=B2,"Match","")
Formula for differences
=IF(A2<>B2,"No match","")
Matches and differences
=IF(A2=B2,"Match","No match")=IF(A2<>B2,"No match","Match")
Example 2. Compare two lists for case-sensitive matches in the same row
As you have probably noticed, the formulas from the previous example ignore case when comparing text values, as in row 10 in the screenshot above. If you want to find case-sensitive matches between 2 columns in each row, then use the EXACT function:
=IF(EXACT(A2, B2), "Match", "")
To find case-sensitive differences in the same row, enter the corresponding text ("Unique" in this example) in the 3rd argument of the IF function, e.g.:
=IF(EXACT(A2, B2), "Match", "Unique")
Compare multiple columns for matches in the same row
In your Excel worksheets, multiple columns can be compared based on the following criteria:
- Find rows with the same values in all columns (Example 1)
- Find rows with the same values in any 2 columns (Example 2)
Example 1. Find matches in all cells within the same row
If your table has three or more columns and you want to find rows that have the same values in all cells, an IF formula with an AND statement will work a treat:
=IF(AND(A2=B2, A2=C2), "Full match", "")
If your table has a lot of columns, a more elegant solution would be using the COUNTIF function:
=IF(COUNTIF($A2:$E2, $A2)=5, "Full match", "")
Where 5 is the number of columns you are comparing.
Example 2. Find matches in any two cells in the same row
If you are looking for a way to compare columns for any two or more cells with the same values within the same row, use an IF formula with an OR statement:
=IF(OR(A2=B2, B2=C2, A2=C2), "Match", "")
In case there are many columns to compare, your OR statement may grow too big in size. In this case, a better solution would be adding up several COUNTIF functions. The first COUNTIF counts how many columns have the same value as in the 1st column, the second COUNTIF counts how many of the remaining columns are equal to the 2nd column, and so on. If the count is 0, the formula returns "Unique", "Match" otherwise. For example:
=IF(COUNTIF(B2:D2,A2)+COUNTIF(C2:D2,B2)+(C2=D2)=0,"Unique","Match")
How to compare two columns in Excel for matches and differences
Suppose you have 2 lists of data in Excel, and you want to find all values (numbers, dates or text strings) which are in column A but not in column B.
For this, you can embed the COUNTIF($B:$B, $A2)=0 function in IF's logical test and check if it returns zero (no match is found) or any other number (at least 1 match is found).
For instance, the following IF/COUNTIF formula searches across the entire column B for the value in cell A2. If no match is found, the formula returns "No match in B", an empty string otherwise:
=IF(COUNTIF($B:$B, $A2)=0, "No match in B", "")
Tip. If your table has a fixed number of rows, you can specify a certain range (e.g. $B2:$B10) rather than the entire column ($B:$B) for the formula to work faster on large data sets.
The same result can be achieved by using an IF formula with the embedded ISERROR and MATCH functions:
=IF(ISERROR(MATCH($A2,$B$2:$B$10,0)),"No match in B","")
Or, by using the following array formula (remember to press Ctrl + Shift + Enter to enter it correctly):
=IF(SUM(--($B$2:$B$10=$A2))=0, " No match in B", "")
If you want a single formula to identify both matches (duplicates) and differences (unique values), put some text for matches in the empty double quotes ("") in any of the above formulas. For example:
=IF(COUNTIF($B:$B, $A2)=0, "No match in B", "Match in B")
How to compare two lists in Excel and pull matches
Sometimes you may need not only match two columns in two different tables, but also pull matching entries from the lookup table. Microsoft Excel provides a special function for this - the VLOOKUP function. As an alternative, you can use a more powerful and versatile INDEX MATCH formula. The users of Excel 2021 and Excel 365, can accomplish the task with the XLOOKUP function.
For example, the following formulas compare the product names in columns D against the names in column A and pull a corresponding sales figure from column B if a match is found, otherwise the #N/A error is returned.
=VLOOKUP(D2, $A$2:$B$6, 2, FALSE)
=INDEX($B$2:$B$6, MATCH($D2, $A$2:$A$6, 0))
=XLOOKUP(D2, $A$2:$A$6, $B$2:$B$6)
For more information, please see How to compare two columns using VLOOKUP.
If you don't feel very comfortable with formulas, you can have the job done using a fast and intuitive solution - Merge Tables Wizard.
Compare two lists and highlight matches and differences
When you compare columns in Excel, you may want to "visualize" the items that are present in one column but missing in the other. You can shade such cells in any color of your choosing by using the Excel Conditional Formatting feature and the following examples demonstrate the detailed steps.
Example 1. Highlight matches and differences in each row
To compare two columns and Excel and highlight cells in column A that have identical entries in column B in the same row, do the following:
- Select the cells you want to highlight (you can select cells within one column or in several columns if you want to color entire rows).
- Click Conditional formatting > New Rule… > Use a formula to determine which cells to format.
- Create a rule with a simple formula like
=$B2=$A2(assuming that row 2 is the first row with data, not including the column header). Please double check that you use a relative row reference (without the $ sign) like in the formula above.
To highlight differences between column A and B, create a rule with this formula:
=$B2<>$A2
If you are new to Excel conditional formatting, please see How to create a formula-based conditional formatting rule for step-by-step instructions.
Example 2. Highlight unique entries in each list
Whenever you are comparing two lists in Excel, there are 3 item types that you can highlight:
- Items that are only in the 1st list (unique)
- Items that are only in the 2nd list (unique)
- Items that are in both lists (duplicates) - demonstrated in the next example.
This example demonstrates how to color the items that are only in one list.
Supposing your List 1 is in column A (A2:A6) and List 2 in column C (C2:C5). You create the conditional formatting rules with the following formulas:
Highlight unique values in List 1 (column A):
=COUNTIF($C$2:$C$5, $A2)=0
Highlight unique values in List 2 (column C):
=COUNTIF($A$2:$A$6, $C2)=0
And get the following result:
Example 3. Highlight matches (duplicates) between 2 columns
If you closely followed the previous example, you won't have difficulties adjusting the COUNTIF formulas so that they find the matches rather than differences. All you have to do is to set the count greater than zero:
Highlight matches in List 1 (column A):
=COUNTIF($C$2:$C$5, $A2)>0
Highlight matches in List 2 (column C):
=COUNTIF($A$2:$A$6, $C2)>0
Highlight row differences and matches in multiple columns
When comparing values in several columns row-by-row, the quickest way to highlight matches is creating a conditional formatting rule, and the fastest way to shade differences is embracing the Go To Special feature, as demonstrated in the following examples.
Example 1. Compare multiple columns and highlight row matches
To highlight rows that have identical values in all columns, create a conditional formatting rule based on one of the following formulas:
=AND($A2=$B2, $A2=$C2)
or
=COUNTIF($A2:$C2, $A2)=3
Where A2, B2 and C2 are the top-most cells and 3 is the number of columns to compare.
Of course, neither AND nor COUNTIF formula is limited to comparing only 3 columns, you can use similar formulas to highlight rows with the same values in 4, 5, 6 or more columns.
Example 2. Compare multiple columns and highlight row differences
To quickly highlight cells with different values in each individual row, you can use Excel's Go To Special feature.
- Select the range of cells you want to compare. In this example, I've selected cells A2 to C8.
By default, the top-most cell of the selected range is the active cell, and the cells from the other selected columns in the same row will be compared to that cell. As you can see in the screenshot above, the active cell is white while all other cells of the selected range are highlighted. In this example, the active cell is A2, so the comparison column is column A.
To change the comparison column, use either the Tab key to navigate through selected cells from left to right, or the Enter key to move from top to bottom.
Tip. To select non-adjacent columns, select the first column, press and hold Ctrl, and then select the other columns. The active cell will be in the last column (or in the last block of adjacent columns). To change the comparison column, use the Tab or Enter key as described above.
- On the Home tab, go to Editing group, and click Find & Select > Go To Special… Then select Row differences and click the OK button.
- The cells whose values are different from the comparison cell in each row are colored. If you want to shade the highlighted cells in some color, simply click the Fill Color icon on the ribbon and select the color of your choosing.
How to compare two cells in Excel
In fact, comparing 2 cells is a particular case of comparing two columns in Excel row-by-row except that you don't have to copy the formulas down to other cells in the column.
For example, to compare cells A1 and C1, you can use the following formulas.
For matches:
=IF(A1=C1, "Match", "")
For differences:
=IF(A1<>C1, "Difference", "")
To learn a few other ways to compare cells in Excel, please see:
Formula-free way to compare two columns / lists in Excel
Now that you know Excel's offerings for comparing and matching columns, let me show you our own solution for this task. This tool is named Compare Two Tables and it is included in our Ultimate Suite.
The add-in can compare two tables or lists by any number of columns and both identify matches/differences (as we did with formulas) and highlight them (as we did with conditional formatting).
For the purpose of this article, we'll be comparing the following 2 lists to find common values that are present in both.
To compare two lists, here are the steps you need to follow:
- Start with clicking the Compare Tables button on the Ablebits Data tab.
- Select the first column/list and click Next. In terms of the add-in, this is your Table 1.
- Select the second column/list and click Next. In terms of the add-in, it is your Table 2, and it can reside in the same or different worksheet or even in another workbook.
- Choose what kind of data to look for:
- Duplicate values (matches) - the items that exist in both lists.
- Unique values (differences) - the items that are present in list 1, but not in list 2.
Since our aim is to find matches, we select the first option and click Next.
- This is the key step where you select the columns for comparison. In our case, the choice is obvious as we are only comparing 2 columns: 2000 Winners against 2021 Winners. In bigger tables, you can select several column pairs to compare by.
- In the final step, you choose how to deal with the found items and click Finish.
A few different options are available here. For our purposes, these two are most useful:
- Highlight with color - shades matches or differences in the selected color (like Excel conditional formatting does).
- Identify in the Status column - inserts the Status column with the "Duplicate" or "Unique" labels (like IF formulas do).
For this example, I've decided to highlight duplicates in the following color:
And in a moment, got the following result:
With the Status column, the result would look as follows:
Tip. If the lists you are comparing are in different worksheets or workbooks, it might be helpful to view Excel sheets side by side.
This is how you compare columns in Excel for matches (duplicates) and differences (unique values). If you are interested to try this tool, you are welcome to download an evaluation version using the below link.
I thank you for reading and encourage you to check out other helpful tutorials that we have :)
Available downloads
Compare Excel Lists - examples (.xlsx file)
Ultimate Suite - trial version (.exe file)
546 comments
Hello all,
thank you for this really helpful, have one question though.
I need to compare two files with over 60k rows and columns from A to BD where only certain information was changed and the new file does not contain all rows as the original one. That means first vlookup and than match :/ is it somehow possible?
Thank you for your help...
Hello!
It is impossible to solve this problem with the help of formulas. I recommend using the tool Compare Tables or Compare Two Sheets. It is available as a part of our Ultimate Suite for Excel that you can install in a trial mode and check how it works for free.
Hello Alexander,
Thank you so much for your reply and suggestions.
Have a great day.
How to compare each cell using vba.
example as below
Set 1 Set2 Match/ No match
100 100 Match
200 20 No Match
300 300 Match
800 800 Match
400 0 No Match
600 600 Match
300 300 Match
I have 2 columns. Column 1 has Name and surname and column 2 has full name with the surname. which formula would I use to see which names don't match?
Eg
Column 1 Column 2
John Smith John William Smith
Halley White Halley Brown
Hello!
Please try the following formula:
=IF(COUNTIF(B2,"*"&SUBSTITUTE(A2," ","*")&"*")>0,"Match","Not match")
I hope my advice will help you solve your task.
the article is so helpful. thanks
Thanks!
Good morning,
So first of all, thank you for this post. It helped me with most of what I need. I am missing one example which applies to my case. I am trying to see whether there are any matches in 5 columns where the value I am looking for is "Y". If "Y" is present in more than one of these columns, I want it to return as "Yes" and if not then "No". This is the formula I used: =IF(COUNTIF(J27:M27,I27)+COUNTIF(K27:M27,J27)+COUNTIF(L27:M27,K27)+(L27=M27)="Y","Yes","No")
I am missing one small parameter though. I need to include the logic to that formula where H27 must also have a "N" value.....so it's all of the original formula AND H27 must also have a value of "N". Hopefully, I am making my question clear enough. It's looking for matches in columns I-M while having column H="N".
Any help would be appreciated.
Thank you
Hello!
Add an AND condition to your formula.
=IF(AND(H27="N",COUNTIF(J27:M27,I27)+COUNTIF(K27:M27,J27)+COUNTIF(L27:M27,K27)+(L27=M27)=”Y”),”Yes”,”No”)
Please have a look at this article — IF AND in Excel: nested formula, multiple statements, and more
Hi ,
I am looking for a way to compare two columns of data where in the data is latitude and logitudes. The latitudes are in 9 char (alpha numeric) like N90 80 01 01 and Logitude is 10 char(alpha numeric) lik E111 54 50 89. I want to compare two cells of latitude or longitude to find whether the first 7 char of Latitude and first 8 chars of the longitude are matching. In other words i want to compare only the string of first 7 chars or first 8 chars in two columns.
The examples dont talk about string match or am i missing something. Need help on this.
Hello!
To compare two columns for matches or differences in the same row use formula:
=IF(LEFT(A2,7)=Left(B2,7),"Match","No match")
To compare two columns in Excel for matches and differences —
=IF(COUNTIF(B1:B10,LEFT(A1,7)&"*")>0,"Match","Not match")
I hope my advice will help you solve your task.
Thanks a lot, it saved me lot of time. Thanks again.
Hi...
May I know how to highlight whole row if Column B consists of "Apple" and Column C have the same items. Example below: I wish to highlight whole row of 01, 02, 03, 07, 08 & 09 as they have "Apple" and same item number. Thanks a lot
01 Orange 123-789
02 Pineapple 123-789
03 Apple 123-789
04 Grape 123-456
05 Kiwi 123-456
06 Orange 123-456
07 Kiwi 123-968
08 Pineapple 123-968
09 Apple 123-968
Hello!
If I understand your task correctly, the following conditional formatting formula should work for you:
=COUNTIFS($B$1:$B$10,$B1,$A$1:$A$10,$F$1) > 0
I hope my advice will help you solve your task.
Uncle google answered me :)
I have to change =SUM(E3:E21) to =SUM(VALUE(E3:E21)) to get the correct sum on the last column.
Mystery solved !!!
Hi,
I want to make a sheet like pre-populated with answers.
For examples;
Each row has 5 columns (question number, option A, B, C, D), like below:
Question # 1, has 4 options to pick - A, B, C or D. The correct answer is D.
Question # 2, has 4 options to pick - A, B, C or D. The correct answer is B
Question # 3, has 4 options to pick - A, B, C or D. The correct answer is A.
Next, I want to run my answer through the same sheet without looking
at the pre-populated answers.
My answer like I pick:
Question # 1, has 4 options to pick - A, B, C or D. My picked answer is A.
Question # 2, has 4 options to pick - A, B, C or D. My picked answer is B.
Question # 3, has 4 options to pick - A, B, C or D. My picked answer is C.
At the end, I click on a button or macro, and show me nothing but saying
either you passed (if the given answers are matching with pre-populated
answers - 100%) or failed (showing % scored, i.e. 33.33% in the above case).
Any help?
Thanks
I think, I made too complicated in my question. Just realized after posting, it can be much simplified.
Each row has 3 columns (question number, pre-populated answer and my answer), like below:
Question # 1, D, A
Question # 2, B, B
Question # 3, A, C
At the end, I click on a button or macro, and show me nothing but saying either you passed (if the given answers are matching with pre-populated answers - 100%) or failed (showing % scored, i.e. 33.33% in the above case). Thanks!
Almost there... with the exception of one thing :)
Question # Correct Answer My Answer Result Marking
1 A B FALSE 0
2 C C TRUE 5
3 C D FALSE 0
Somehow, when I do sum on the last column, shows always 0 not 5. I have made last column as properties of it as number. It does not add and treating still somehow like: =IF(C3=B3, "5", "0") instead of its value like 0 or 5. This is where I am stuck now. Any help?
Hi.
I hope I can explain this clearly.
What I am trying to do is compare two columns.
1st column has dates dd-mmm-yyyy.
2nd column has text. i.e. text1, text2, text3, text1...
I would like to count how many times a particular text appears during one month i.e. January.
Thanks.
How can I compare specific digits within two columns? I am working with model numbers, so I need to compare the 8th and 9th digit of one column with the 9th and 10th digits of another column. The two digits in each column go together.
Hello,
Trying to see if it's possible to compare data in list 1 against data in list 2 and output the values that don't match in list 1 in another column.
List 1 (these values are in a single cell, just separated by carriage returns)
CN
SA
NS
RO
List 2 (single value in each row)
CN
NE
NP
RO
Ideally, I'd like to have the formula in an adjacent column to list 1 and output the values that don't match up to any in list 2 that resides in a different sheet. In my example above, I would expect to see 'SA' and 'NS' as the output from the formula. Not sure if there is a function that can look through data as it's formatted in list 1.
Hello!
Please check out this article to learn how to get a list of unique and distinct values in Excel.
I'd recommend you to have a look at our Duplicate Remover tool that can help you to get unique values.
It is available as a part of our Ultimate Suite for Excel that you can install in a trial mode and check how it works for free.
Hi, is it possible to do the one under "How to compare two columns in Excel for matches and differences" but for many columns instead of just comparing one column to a second column?
Thanks
Hello!
Please check out the following article on our blog, it’ll be sure to help you with your task: Excel unique values: how to find, filter, select and highlight
Hope this is what you need.
how can i compare two lists having some spelling mismatch
example
column A column B
Jemal Mohammed JAMAL MUHAMED
Donald trump DANNALD TRAMP
Hello!
What result do you want after comparison?
I'd recommend you to have a look at our Ultimate Suite for Excel - Ablebits Data - Duplicate Remover - Find Fuzzy Duplicates tool that can help you.
It is available as a part of our Ultimate Suite for Excel that you can install in a trial mode and check how it works for free.
Hi, I need help to compare full years outstanding amount with the pre-set credit limit and find out the consecutive month which the outstanding amount had exceeded the credit limit. For example, we had set the credit limit for customer ABC for 5,050. I need to compare with the 12 months outstanding amount and find out 3 consecutive months which the outstanding amount is exceeded 5,050, thanks in advance.
Hello!
I don't have your table, so I cannot recommend any formula for you. I think you should pay attention to how the running total is calculated for the outstanding amount.
How can I detect repeating columns in that work sheet of 6000 columns with 5 rows.
Thank you
hello, thank you for this intuitive guide, but I hve a bootstrap samples of random numbers (1 through 5) generated using randbetween formula with 5 rows and 6000 columns, but I want to know how I can highlight the repeating columns in the 6000 columns using conditional format.
I will be glad to hear from you.
Thank you
Hello Collin!
I think this article on conditional formatting of duplicates will be useful to you.
Hi
What if there two cells with multiple text words within each separated by commas and I want to compare and highlight which of the words in thee two cells are a match or are different?
Hello!
Since the number of words is unknown, it is difficult to write a formula. We have a tool that can solve your task in a couple of clicks: Ablebits Data -- Split Text.
This tool is available as a part of our Ultimate Suite for Excel that you can install in a trial mode and use for free: https://www.ablebits.com/files/get.php?addin=xl-suite&f=free-trial
Hi.
I was just wondering...
What formula should use to reconcile two columns of mixed invoice numbers in order to confirm their existence to both of columns.
2. after the reconciliation to find their differences on their amounts which is the next column of each invoice. See below. Thank you
A1232323 € 50.00 A1232323 € 50.00
A1232324 € 55.00 A1232332 € 60.00
A1232325 € 56.00 A1232333 € 65.00
A1232326 € 57.00 A1232326 € 57.00
Hello!
How to compare two columns is described in detail in the manual above. If you have a problem, please specify which formula you mean and describe the problem in more detail. Thank you.
Dear Alexander thank you for the response.
I tried to read the article but still not find any formula matched.
I will try to be more specific.
Imagine that i am the company A and my creditor is company B.
I have to reconcile the invoices has sent me until now if i had them too in my records.
This is the first formula that i need to find from the two columns the same invoices and colour them.
The second formula which that is the most important is to find the same invoices from the columns which are mixed and try to find if are they have any differences in their amounts and show me the difference if any.
See the below example:
Company A Amount Company B Amount Formula Formula
ABC353536 € 56.00 ABC353538 € 65.00 ABC353536 € -
ABC353537 € 58.00 ABC353536 € 56.00 ABC353537 -€ 2.00
ABC353538 € 65.00 ABC353537 € 60.00 ABC353538 € -
ABC353539 € 70.00 ABC353540 € 78.00 ABC353539 -€ 8.00
ABC353539 € 75.00
As you can see i am missing the invoice ABC353540 this one will be not coloured
Also the invoices that they matched they are also been calculated if they have difference on their amount.
Hello George!
Use the condition formula to select the same accounts using conditional formatting
=NOT(ISERROR(MATCH(A2,$C$2:$C$15,0)))
To select the same accounts with the same amounts, use the formula
=NOT(ISERROR(MATCH(A2&B2,$C$2:$C$15&$D$2:$D$15,0)))
We have a ready-made formula-free solution for your task.
We have a tool that can solve your task in a couple of clicks:
Ablebits Data - Compare Tables
This tool is available as a part of our Ultimate Suite for Excel that you can install in a trial mode and use for 30 days for free: https://www.ablebits.com/files/get.php?addin=xl-suite&f=free-trial
Dear Alexander
Thank you very much for your time.
I will try it and give you the feedback :)
That's amazing!! I am very happy for using it. This is very helpful.
One more thing. Could the second formula show the difference on amount instead of TRUE or False?
Hi,
I'd like to identify the current month is within a start and end date range. So for example I have a start Month of May and and end month of July. I'd like the formula to identify that the current month is within the range and return a yes.
Thank you
hope this also helps from a visual point of view
Start Date || Due Date || Effort || Status || Priority || May || June || etc
April || July. || H || Active.|| P1. || yes|| yes || etc
Hello Michael!
If I understand your task correctly, the following formula should work for you:
=IF(AND(MONTH(TODAY())>=MONTH(A1), MONTH(TODAY())<=MONTH(B1)),TRUE,FALSE)
I hope it’ll be helpful.
Hi I have a slightly different query.
Column A Column B
1 1
0 0
1 0
1 1
1 0
I want to count all those rows which have 1 in both columns. The output should be 2. Kinldy help me in putting the formula.
Hello!
If I got you right, the formula below will help you with your task
=SUM((A:A=1)*(B:B=1))
I hope this will help
Hello,
I have 2 excel with more than 500 row in both excel (peoples name)
Since full names of peoples are not exactly same in both excel but for some name first name is matching and for some name, middle and last name is matching.
so what formula can we use to find matching word between these 2 excel.
thanks.
Hello Shiv!
Please describe your problem in more detail. Write an example of the source data and the result you want to get. It’ll help me understand it better and find a solution for you. Thank you.
did you get a reply
Hi,
I have 2 columns: Column C - having all my dates when my customers require delivery and Column E – having all my dates when I will be finished. I want my dates in Column E to be GREEN if it is less than Column C and RED if it is greater than Column C. Can you assist with a formula or show me how, I’ve tried through conditional formatting and struggling, please assist.
Hello Cherry-Lee!
You need to use conditional formatting. I recommend to study this article on our blog.
Hi
I need to highlight duplicate values in column B where column A = 9 and repeat this process for A=8, A= 7 etc. Column A is a grade and column B is the rank for the grade (I.e if I have 4 grade 9’s, there should be ranks 1-4). I need to identify if there is duplicate ranks within each grade.
Can you help please?
Hello there,
I have 30 questions (from Row 2 to 31 and Row 1 is header row). Column A is for question number, Column B is for correct answer, Column C is student 1 answer, Column D is student 2 answer and so on..
I just want total correct answers for each student in row 32. I dont know if we can do anything with countif or sumif.. but what i did was, I added 1 column in the right for each student and then i put a simple formula if his/her answer matches with column B then 1 else 0, and the summing up in row 32.. is there any way to avoid those extra columns?
Never mind.. i got my answer.. using sumproduct..
Hello!
Use formula =SUM(--(B2:B31=C2:C31))
Hi there,
I need help, bellow here is the scenario.
Column A = Client names
Column B = Manager name
Column C = Sign off date
Identify any records where “Client Name” paired with “Manager name” has answer to “Sign off date” with dates that are not equal.
Hello!
I propose to select the necessary entries using conditional formatting. Read about it on our blog here.
I have an interesting problem. I am developing a project with 7 teams of 15 people on each team. One person may not be on more than one team. I want to find if I have put the same person on more than one team and highlight the name in both cells. I think it is a look for duplicates, but I cannot find a solution across 7 non-contiguous columns. Thank you so much for your help.
Hello Keith!
You can learn more about highlight duplicates in Excel in this article on our blog
Hope you’ll find this information helpful.
NEED HELP.
SCENARIO:
CELL A1= 3/6/2020
CELL B2= EMPTY
CELL C3=+10 DAYS IF A1 HAS DATE, +10DAYS IF B2 HAS DATE AND A1 IS EMPTY, IF BOTH BLANKS IT RETURNS TO ZERO VALUE.
WHAT IS THE FORMULA THIS SCENARIO?
Hello Fred!
If I understand your task correctly, the following formula should work for you:
=IF(A1>0, 10,IF(B2>0, 10,0))
What should i do if I am comparing tow columns with names, but the names dont match exactly.
Example
In Column A: Tom Jones
In Column B: Thomas Jones
when i do a vlookup, it would only match if they both were exact match. i want to show them as a match with my vlookup since they are the same people, what should i do?
Hi I really like your blogs, but I just feel I have to sit down and learn this to understand all the fields etc. which is right now not so possible, I would appreciate if I can get a quick answer for my problem if there is a natural way or thru one of your tools to get this solved.
I'm getting workbooks from my supplier containing info of items and pricing in divided several columns and this is continuously being updated, I would want an easy way to highlight single items of the list that had a price change, and if it went up or down, also adding the new items of the new list, and if there is missing items in the new list due to out of stock.
Thank so much
V.K.
Hello .. I have a small pickle here :-).
I have some data in sheet "XYZ" in Column A and some data in sheet "ABC" in Columns A and B.
I need compare sheet "XYZ" Column A with sheet "ABC" column A and if there is a match on specific row, I need to move data from sheet "ABC" column B to sheet "XYZ" to column B.
For exapmle:
Sheet "XYZ" A3 has match with sheet "ABC" A7. So data from sheet "ABC" B7 will move to sheet "XYZ" B3.
Hope I have described it correctly :-).
I really appreciate you help!
Standa
Just wanted to say you are awesome! and thank you!
COLUNN A COLUMN B COLUMN C
APPLE 2 2.1
APPLE 3 3.8
CARROT 4 4
RADISH 4 4
I WANT TO TALLY ONLY APPLE 2 & APPLE 3 AS BOTH ARE SAME NAME AND IN COLUMN C IGNORE THE FRACTION SO APPLLE IS SAME IN COUMN B & COLUMN C IN FIRST & SECOND ROW . I WANT ONLY FIRST & SECOND ROW
I need an help to sum the value. However, not sure how to sum it if we have common ref more than 1 time and needs to sum the value against each cell?
Thank you so much, as usual, you answered question with multiple varying excel features in a well explained, organized, and documented fashion. The only downside is that you've spoiled me, and I get frustrated with other websites that are not of this caliber.
Thank you, Mike! We'll do our best to keep the bar high :)
Hi,
I have two columns of addresses which I need to match. I have been using the IF function. =IF(B2=C2,"Match ","Not Match").
But the data within the columns differs even though it’s the same address e.g.
B2
123 Haig Court, Chelmsford and storeroom 123 (CM2 0BH)
456 Haig Court, Chelmsford and store room 456 (CM2 0BH)
C2
123 Haig Court, Chelmsford CM2 0BH.
456 Haig Court, Chelmsford CM2 0BH.
We can see both examples the addresses are the same, but clearly, the IF function won’t match them.
Is there a formula which will match part of the string, say up to the first comma ( ,)
thanks
I was an absolute hater of Microsoft Excel .. till I tumbled upon your website / blog. You make it so easy to understand stuff and also provide usable samples/code.
THANK YOU!!!
I need help with a formula please. I'm horrible at Excel. When I enter an amount in Questionnaire B4, I need it to find the same number from a column on Title Search A4-A1003 and fill in the number from the column Title Search B4-B1003. I need that fee to show up on Cover Sheet A22. Thank you so much.
I have 2 sheets that I want to compare to hightlight. On sheet one i have person name and work zone and shift and on second sheet i have the same plus other information. I want to highlight the name on the first sheet if they exist on the second sheet. So a form of conditional formatting with certain criteria for duplication. As I have several people with the same name, the matching of work zone and shift is used to differentiate. Can this be done or is it beyond excel capabilities and I'll just have to keep manually checking?
I want to compare dates, to get Match, Old, or New based on greater that or less than values. I understand the match, how can I add the other two options? There has to be a way to do this...
Perfect answers. Many thanks :-)
I have a file of over 12,000 entries. First name, Last name, etc. per entry. Two of the columns are dates (m/d/y) and I need to calculate how many days have passed between the first
and second dates down the entire 12,000 entries and insert the result of the calculation into a third column next to the proper entry. I cannot find any code that will do that. Can you help?
great. the article is so helpful. thanks
Hi,
I run a vlookup to match 2 sets of data. E,g I have product ID in Sheet 1 Column A. I want to match it with sheet 2 which returns value in column B. Is there a way when I run this Vlookup it can highlight the cells that were not matched from column B?
hello
i'm creating a Lease calculator for that i have a coloum that contains the models of vehiles and another coloum contains Insurance premium of X company and another coloum contains Insurance premium of y company and another coloum contains Insurance premium of X company. and i have created dropdown list to select vehicle models and another dropdown list to select Insurance company. so if i select a vehicle model and a Insurance company the premimum must appear in a cell
please help urgent
how to get value using vlookup by background cell color with cell values,
Hi all, can i do bank reconciliation in excel, with just uploading or copy paste the bank statement and the analysis of cash from our system?, im dealing with 20k lines of reconciling items. thank you for your response
how to count the difference in characters between two cell texts in excel.
for example, Apple and Appde got 2 difference (after 3rd character)