How to find duplicates in Excel: identify, highlight count, filter, and more
The tutorial explains how to search for duplicates in Excel. You will learn a few formulas to identify duplicate values or find duplicate rows with or without first occurrences. You will also learn how to count instances of each duplicate record individually and find the total number of dupes in a column, how to filter out duplicates, and more.
While working with a large Excel worksheet or consolidating several small spreadsheets into a bigger one, you may find lots of duplicate rows in it. In one of our previous tutorials, we discussed various ways to compare two tables or columns for duplicates.
And today, I'd like to share a few quick and effective methods to identify duplicates in a single list. These solutions work in all versions of Excel 2016, Excel 2013, Excel 2010 and lower.
How to identify duplicates in Excel
The easiest way to detect duplicates in Excel is using the COUNTIF function. Depending on whether you want to find duplicate values with or without first occurrences, there's going to be a slight variation in the formula as shown in the following examples.
How to find duplicate records including 1st occurrences
Supposing you have a list of items in column A that you want to check for duplicates. These can be invoices, product Id's, names or any other data.
Here's a formula to find duplicates in Excel including first occurrences (where A2 is the topmost cell):
=COUNTIF(A:A, A2)>1
Input the above formula in B2, then select B2 and drag the fill handle to copy the formula down to other cells:
As you can see in the screenshot above, the formula returns TRUE for duplicate values and FALSE for unique values.
For a duplicate formula to return something more meaningful than the Boolean values of TRUE and FALSE, enclose it in the IF function and type any labels you want for duplicate and unique values:
=IF(COUNTIF($A$2:$A$8, $A2)>1, "Duplicate", "Unique")
In case, you want an Excel formula to find duplicates only, replace "Unique" with an empty string ("") like this:
=IF(COUNTIF($A$2:$A$8, $A2)>1, "Duplicate", "")
The formula will return "Duplicates" for duplicate records, and a blank cell for unique records:
How to search for duplicates in Excel without 1st occurrences
In case you plan to filter or remove duplicates after finding them, using the above formula is not safe because it marks all identical records as duplicates. And if you want to keep the unique values in your list, then you cannot delete all duplicate records, you need to only delete the 2nd and all subsequent instances.
So, let's modify our Excel duplicate formula by using absolute and relative cell references where appropriate:
=IF(COUNTIF($A$2:$A2, $A2)>1, "Duplicate", "")
As you can see in the following screenshot, this formula does not identity the first occurrence of "Apples" as duplicate:
How to find case-sensitive duplicates in Excel
In situations when you need to identify exact duplicates including the text case, use this generic array formula (entered by pressing Ctrl + Shift + Enter):
At the heart of the formula, you use the EXACT function to compare the target cell with each cell in the specified range exactly. The result of this operation is an array of TRUE (match) and FALSE (not match), which is coerced to an array of 1's and 0's by the unary operator (--). After that, the SUM function adds up the numbers, and if the sum is greater than 1, the IF function reports a "Duplicate".
For our sample dataset, the formula goes as follows:
=IF(SUM((--EXACT($A$2:$A$8,A2)))<=1,"","Duplicate")
As shown in the screenshot below, it treats lowercase and uppercase as different characters (APPLES is not identified as a duplicate):
How to find duplicate rows in Excel
If your aim is to dedupe a table consisting of several columns, then you need a formula that can check each column and identify only absolute duplicate rows, i.e. rows that have completely equal values in all columns.
Let's consider the following example. Supposing, you have order numbers in column A, dates in column B, and ordered items in column C, and you want to find duplicate rows with the same order number, date and item. For this, we are going to create a duplicate formula based on the COUNTIFS function that allows checking multiple criteria at a time:
To search for duplicate rows with 1st occurrences, use this formula:
=IF(COUNTIFS($A$2:$A$8,$A2,$B$2:$B$8,$B2,$C$2:$C$8,$C2)>1, "Duplicate row", "")
The following screenshot demonstrates that the formula really locates only the rows that have identical values in all 3 columns. For example, row 8 has the same order number and date as rows 2 and 5, but a different item in column C, and therefore it is not marked as duplicate row:
To show duplicate rows without 1st occurrences, make a little adjustment to the above formula:
=IF(COUNTIFS($A$2:$A2,$A2,$B$2:$B2,$B2,$B$2:$B2,$B2,$C$2:$C2,$C2,) >1, "Duplicate row", "")
How to count duplicates in Excel
If you want to know the exact number of identical records in your Excel sheet, use one of the following formulas to count duplicates.
Count instances of each duplicate record individually
When you have a column with duplicated values, you may often need to know how many duplicates are there for each of those values.
To find out how many times this or that entry occurs in your Excel worksheet, use a simple COUNTIF formula, where A2 is the first and A8 is the last item of the list:
=COUNTIF($A$2:$A$8, $A2)
As demonstrated in the following screenshot, the formula counts the occurrences of each item: "Apples" occurs 3 times, "Green bananas" - 2 times, "Bananas" and "Oranges" only once.
If you want to identify 1st, 2nd, 3rd, etc. occurrences of each item, use the following formula:
=COUNTIF($A$2:$A2, $A2)
In a similar manner, you can count the occurrences of duplicated rows. The only difference is that you will need to use the COUNTIFS function instead of COUNTIF. For example:
=COUNTIFS($A$2:$A$8, $A2, $B$2:$B$8, $B2)
Once the duplicate values are counted, you can hide unique values and only view duplicates, or vice versa. To do this, apply Excel's auto-filter as demonstrated in the following example: How to filter out duplicates in Excel.
Count the total number of duplicates in a column(s)
The easiest way to count duplicates in a column is to employ any of the formulas we used to identify duplicates in Excel (with or without first occurrences). And then you can count duplicate values by using the following COUNTIF formula:
=COUNTIF(range, "duplicate")
Where "duplicate" is the label you used in the formula that locates duplicates.
In this example, our duplicate formula takes the following shape:
=COUNTIF(B2:B8, "duplicate")
Another way to count duplicate values in Excel by using a more complex array formula. An advantage of this approach is that it does not require a helper column:
=ROWS($A$2:$A$8)-SUM(IF( COUNTIF($A$2:$A$8,$A$2:$A$8)=1,1,0))
Because it's an array formula, remember to press Ctrl + Shift + Enter to complete it. Also, please keep in mind that this formula counts all duplicate records, including first occurrences:
To find the total number of duplicate rows, embed the COUNTIFS function instead of COUNTIF in the above formula, and specify all of the columns you want to check for duplicates. For example, to count duplicate rows based on columns A and B, enter the following formula in your Excel sheet:
=ROWS($A$2:$A$8)-SUM(IF( COUNTIFS($A$2:$A$8,$A$2:$A$8, $B$2:$B$8,$B$2:$B$8)=1,1,0))
How to filter duplicates in Excel
For easier data analysis, you may want to filter your data to only display duplicates. In other situations, you may need the opposite - hide duplicates and view unique records. Below you will find solutions for both scenarios.
How to show and hide duplicates in Excel
If you want to see all duplicates at a glance, use one of the formulas to find duplicates in Excel that better suits your needs. Then select your table, switch to the Data tab, and click the Filter button. Alternatively, you can click Sort & Filter > Filter on the Home tab in the Editing group.
After that, click the arrow 
in the header of the Duplicate column and check the "Duplicate row" box to show duplicates. If you want to filter out, i.e. hide duplicates, select "Unique" to view only unique records:
And now, you can sort duplicates by the key column to group them for easier analysis. In this example, we can sort duplicate rows by the Order number column:
How to filter duplicates by their occurrences
If you want to show 2nd, 3rd, or Nth occurrences of duplicate values, use the formula to count duplicate instances we discussed earlier:
=COUNTIF($A$2:$A2, $A2)
Then apply filtering to your table and select only the occurrence(s) you want to view. For example, you can filter the 2nd occurrences like in the following screenshot:
To display all duplicate records, i.e. occurrences greater than 1, click the filter arrow in the header of the Occurrences column (the column with the formula), and then click Number Filters > Greater Than.
Select "is greater than" in the first box, type 1 in the box next to it, and click the OK button:
In a similar manner, you can show 2nd, 3rd and all subsequent duplicate occurrences. Just type the required number in the box next to "is greater than".
Highlight, select, clear, delete, copy or move duplicates
After you've filtered duplicates like demonstrated above, you have a variety of choices to deal with them.
How to select duplicates in Excel
To select duplicates, including column headers, filter them, click on any filtered cell to select it, and then press Ctrl + A.
To select duplicate records without column headers, select the first (upper-left) cell, and press Ctrl + Shift + End to extend the selection to the last cell.
How to clear or remove duplicates in Excel
To clear duplicates in Excel, select them, right click, and then click Clear Contents (or click the Clear button > Clear Contents on the Home tab, in the Editing group). This will delete the cell contents only, and you will have empty cells as the result. Selecting the filtered duplicate cells and pressing the Delete key will have the same effect.
To remove entire duplicate rows, filter duplicates, select the rows by dragging the mouse across the row headings, right click the selection, and then choose Delete Row from the context menu.
How to highlight duplicates in Excel
To highlight duplicate values, select the filtered dupes, click the Fill color button 
on the Home tab, in the Font group, and then select the color of your choosing.
Another way to highlight duplicates in Excel is using a built-in conditional formatting rule for duplicates, or creating a custom rule specially tailored for your sheet. Experienced Excel users won't have any problem with creating such a rule based on the formulas we used to check duplicates in Excel. If you are not very comfortable with Excel formulas or rules yet, you will find the detailed steps in this tutorial: How to highlight duplicates in Excel.
How to copy or move duplicates to another sheet
To copy duplicates, select them, press Ctrl + C, then open another sheet (a new or existing one), select the upper-left cell of the range where you want to copy the duplicates, and press Ctrl + V to paste them.
To move duplicates to another sheet, perform the same steps with the only difference that you press Ctrl + X (cut) instead of Ctrl + C (copy).
This is how you can identify duplicates in Excel using functions and built-in features. To better understand the formulas discussed in this tutorial, feel free to download Identify Duplicates Sample Workbook.
Duplicate Remover - fast and efficient way to locate duplicates in Excel
Now that you know how to use duplicate formulas in Excel, let me demonstrate you another quick, efficient and formula-free way - Duplicate Remover for Excel.
This all-in-one tool can search for duplicate or unique values in a single column or compare two columns. It can find, select and highlight duplicate records or entire duplicate rows, remove found dupes, copy or move them to another sheet. I think an example of practical use is worth many words, so let's get to it.
How to find duplicate rows in Excel in 2 quick steps
To test the capabilities of our Duplicate Remover add-in, I've created a table with a few hundred rows that looks like follows:
As you see, the table has a few columns. The first 3 columns contain the most relevant information, so we are going to search for duplicate rows based solely on the data in columns A - C. To find duplicate records in these columns, just do the following:
- Select any cell within your table and click the Dedupe Table button on the Excel ribbon. After installing the Duplicate Remover add-in, you will find this tool on the Ablebits Data tab, in the Dedupe group.
- The smart add-in will pick up the entire table and ask you to specify the following two things:
- Select the columns to check for duplicates (in this example, these are the Order no., Order date and Item columns).
- Choose an action to perform on duplicates. Because our purpose is to identify duplicate rows, I've selected the Add a status column
Apart from adding a status column, an array of other options are available to you:
- Delete duplicates
- Color (highlight) duplicates
- Select duplicates
- Copy duplicates to a new worksheet
- Move duplicates to a new worksheet
Click the OK button and wait for a few seconds. Done!
As you can see in the below screenshot, all of the rows that have identical values in the first 3 columns have been located (first occurrences are not identified as duplicates).
If you want more options to dedupe your worksheets, use the Duplicate Remover wizard that can find duplicates with or without first occurrences as well as unique values. The detailed steps follow below.
Duplicate Remover wizard - more options to search for duplicates in Excel
Depending on a particular sheet you are working with, you may or may not want to treat the first instances of identical records as duplicates. One possible solution is using a different formula for each scenario, as we discussed in How to identify duplicates in Excel. If you are looking for a fast, accurate and formula-free method, try the Duplicate Remover wizard:
- Select any cell within your table and click the Duplicate Remover button on the Ablebits Data tab, in the Dedupe group. The wizard will run and the entire table will get selected.
- On the next step, you are presented with the 4 options to check duplicates in your Excel sheet:
- Duplicates without 1st occurrences
- Duplicates with 1st occurrences
- Unique values
- Unique values and 1st duplicate occurrences
For this example, let's go with the second option, i.e. Duplicates + 1st occurrences:
- Now, select the columns where you want to check duplicates. Like in the previous example, we are selecting the first 3 columns:
- Finally, choose an action you want to perform on duplicates. As is the case with the Dedupe Table tool, the Duplicate Remover wizard can identify, select, highlight, delete, copy or move duplicates.
Because the purpose of this tutorial is to demonstrate different ways to identify duplicates in Excel, let's check the corresponding option and click Finish:
It only takes a fraction of a second for the Duplicate Remover wizard to check hundreds of rows, and deliver the following result:
No formulas, no stress, no errors - always swift and impeccable results :)
If you are interested to try these tools to find duplicates in your Excel sheets, you are most welcome to download a fully-functional trial version. Your feedback in comments will be greatly appreciated!
And if you like the tools, we will happily offer you the 15% discount, which we provide exclusively to our blog readers. Just use the following coupon code on the order form: AB14-BlogSpo. It is valid for Duplicate Remover as a separate product and as part of Ultimate Suite for Excel.
I thank you for reading and hope to see you on our blog next week!
96 Responses to "How to find duplicates in Excel: identify, highlight count, filter, and more"
The find duplicates formula doesn't work for me.
I have used exactly what you have listed on this page:
=IF(COUNTIF($A$2:$A$8, $A2)>1, "Duplicate", "")
with the exact criteria, but it highlights all cells as duplicates, I have changed the copy series drop down to fill and it doesn't work.
I would really like to get it working, as its really bugging me and also is a very useful formula to know.
thanks
Amit
Dear Amit,
The formula is correct. Just be sure to properly adjust the cell references in the formula, where A2 is first and A8 is the last cell of the range that you want to check for duplicates.
If you have a variable range, you can use the column reference like this:
=IF(COUNTIF(A:A, $A2)>1, "Duplicate", "")
Amit,
The formula was wrong. Try this one, it will work.
=IF(COUNTIF($A$2:$A2, A2)>1,"Duplicate","")
Dear Bekim,
Your formula identifies duplicates without 1st occurrences. The formula mentioned by Amit identifies duplicates in cells A2:A8 including their 1st occurrences. Both formulas are correct, and which one to use depends on a particular task. The following screenshot shows the difference:
Hi,
I need a count of Unique & Duplicate value as 1.
In above formula it counts only duplicates
Receipt Count
2001
2001 1
2002 1
2003
2003 1
2004 1
I have about 1 million e-mail addresses and I want to find all of the duplicates and then delete duplicates.
I do not follow your directions.
What would it cost to send you the list and have you do that for me?
Steve
Hello Steve,
If you have all of the email addresses in a single column, the easiest (and free) way to remove duplicates is using Excel's built-in Remove Duplicates tool, the detailed instructions are here.
If you still cannot achieve the desired result, please send me your worksheet (support@ablebits.com), and I will see if I can help.
Please send me your work sheet and Email ID address. I will finish ASAP.
Hi,
Great tutorial. I'm wondering if there is a way for excel to automatically count a duplicate, show the value (number of duplicates) in another cell and then delete the duplicate while still maintaining that value.
As an example. I'm trying to create a spreadsheet where I enter multiple entries (let say number of packages people have). Like so:
A B
Name # Packages
Alex 1
Michael 1
Amy 1
Alex 1
As above example, when I entered Alex name again, I want Excel to identify that his name is already in the entry and it will automatically add 1 to the first occurrence of Alex and will remove the Alex entry I just made.
I know this can be done in combination with Conditional Formatting where I can change the color of the cell if there is a duplicate. But I wish to make it even better so I could do that automatically.
Basically the algorithm would be:
1.Excel sees there's a duplicate.
2.Plus 1 to the column B of the first occurrence.
3.Delete the duplicate while still maintaining the value of the B column in the first occurrence.
4.Repeat the process if there is more duplicate entry.
So, this is basically a live iteration where Excel is counting and removing while I'm still in the process of entering data. Not just at the end when I'm done with it.
I hope someone can help.
Thanks
Sorry for the messed up example. I don'n how to post a screenshot here in the comment. But the example was Column A (Name) and Column B (#Packages)
Dear Team,
I am Bhagwat Shinde. excel in one problem how to find the duplicate data in large data base vlookup throw please help me.
Below mentioned my mail id please sent suggestion on my mail id.
Regards,
Bhagwat Shinde.
Dear Team
I have some values in Sheet1. I need to show in sheet 1 the duplicates occuring in sheet 2.
For example :I have clients buying mobile credit.
In sheet1,they are listed with their mobile number .In sheet two ,they are buying credit several times during the week .I need to show in sheet1 how many time the client bought credit looks at the duplicated in sheet2.
Note as I update sheet2 on the credit amount ,sheet1 would would recognise the number and count duplicate (number of times credit was bought)
Hi I'm trying to delete(or minus, source 1 minus source 2) cells, if the cells contain the same information from two different source. For example,
source 1 source 2 result
product product product
a123 a123 b123
b123 c123 d123
c123 a123 a123
a123 a123
d123 g123
a123
a123
g123
Is any functions I can use to get the result? (I was thinking to use IF function and VLook to show if there is a match, then filter all the match, delete them. But that won't be reasonable, if some products display more than one times from both sources)
Sorry, format change, example seems awkward
s 1
a123
b123
c123
a123
d123
a123
a123
g123
s 2
a123
c123
a123
result
b123
d123
a123
a123
g123
Dear Ablebits Team,
I have a couple of question I am hoping you can help me with.
Can I use the count duplicate function to create a list of all duplicates and also the amount of each duplicates in each list? I do no want to delete the duplicates as they essentially only have a PO number the same other details are different.
Also, is there a way I can have a tab for data entry which then adds said data to the list of data currently in use.
I can forward a copy of the workbook if you reply via email to the email address provided.
Thank you for your time.
King Regards,
Mark
I am trying to write a formula in conditional formatting that would highlight duplicate values in a column, but only those duplicates with a value >1. I have several 1's in the column, but do not want those to be highlighted. Is there a way to accomplish highlighting only those duplicate values whose value is >1? Thank you ever so much!
Hi Lisa,
Assuming your values are in column A, you can create a conditional formatting rule withe one of these formulas, where A2 is the first and A10 is the last cell with data.
Highlight duplicates including 1st occurrences:
=AND($A2>1,COUNTIF($A$2:$A$10, $A2)>1)
Highlight duplicates without 1st occurrences:
=AND($A2>1, COUNTIF($A$2:$A2, $A2)>1)
Hi Svetlana, thanks so much. I'm afraid I was not clear in my earlier post - I am trying to write a formula in conditional formatting that would highlight duplicate number values in a column, but only those duplicates with a number value >1. Not based on occurrences of the number, but the number value itself.
My number values in the column range from 1 to 5000, and while there will be many "1"s in the column, I do not want those highlighted. Only the duplicate number values greater than "1" (i.e., 2-5000) do I want to highlight.
Is there a way to apply a threshold to the highlight duplicates conditional formatting? Thank you again! Lisa
Hello Lisa,
The formulas do exactly what you describe :)
The difference is that the second formula does not highlight the 1st occurrence of a duplicate number in a column while the first formula does. 1's are ignored in both cases.
For example, if you have number 100 in cells A2 and A3, the 1st formula will highlight both cells, while the 2nd only A3. I've created a simple example for your reference and you can download it here.
Thank you so much Svetlana!
Hello,
I'm wanting to count the number of days worked in a month and ignore the duplicates. For example:
20/05/2016
20/05/2016
21/05/2016
22/05/2016
22/05/2016
The answer should be 3 days because I don't want to count the duplicates.
hi.. i have the same problem here.. do you have a solve?
Hi Svetlana Cheusheva,
While finding duplicates i have used formula "IF(Countif($A$6:$A6,$A6)>1,"Y","N")" this is fine if it works with text, however if used to find duplicates by concatenating numbers and date this formula fails to works....
length of the number is 48 in each cell.... because of this the formula cant validate?
Can you please help me...
Thanks
Sathya
when we value enter in cell it check it is unique and duplicate and if vaue unique it display in another cell and if it duplicate it's ignore the value in excel
How we find duplicate values from the row using with function formula in excel
Hello,
I want to know about countif formula exm.apple in a cell is repeated 4time while a mango is repeated in same cell 10 time. I wnt to give only a unique number to these cell in next column how can i do.mean apple=1 while it is repeated so many time doesn't matter.
How to use refresh in Auto filter
Regards
DrBJR
This works but I have multiple values listed in each cell separated by commas. The find and select function is able to identify each value separately but the conditional formatting formula does not recognize individual values but the cell as a whole. Any ideas?
Hi team,
I have duplicates like this mentioned below . There are around 1000 of such records. I can easily eliminate using duplicate, but here the problem when i take the complete new dump from the system , still i get these since it is not deleted from the system.
serial_number Remarks
SMC18290095 Correct
SMC18290095 Duplicate Serial no.
Rest all the values are same in the excel . In my master file i have identified which is correct and which is duplicate . Now i take a recent new dump from the system (new report) and wanted to bring these remarks mentioned above.
The problem here is it picks only the 1st mentioned Remarks (Correct) for both the duplicates.
Result below when comparing with the master file
serial_number Remarks
SMC18290095 Correct
SMC18290095 correct
Kindly let me know is there any other way to find the duplicates.
Regards
Sudeer
Kindly let me know is there other sheet find valid and invalid formula.
Every tutorial of abletits has nice explanation of excel formulaes, especially by Svetlana Cheusheva. Thanx a lot to this site.
Please show how to find double numbers such double account numbers/Phone Numbers in next cell 1,2,3,4
WHATS WRONG WITH THIS FORMULA? NOT WORKING? USING EXCEL 2016
=IF(COUNTIFS($CU2:$CU59862,CU2, $CA2:$CA59862,CA2, $FL2:$FL59862,FL2, $DA2:$DA59862,DA2, $DV2:$DV59862,DV2) >1, "DUPLICATE ROW","")
THIS FORMULA is NOT WORKING?
But, I want to see that when I put next same number show me 2,3,4,5,6,7, ...........
Please help me.
Thank you for this post, it has helped immensely and I've been able to adjust as required.
I shall now wear my Excel Genius Crown with pride as I work others magic! I'll share this post after a day or two..... I want to feel superior for just a bit
XD
Thank you!
i want create another cell for duplicates values.
I want to filter name and amount with corresponding to category : please help :
Name_______Category_______Amount
Abdul _______Fresh _______5000
Abdul _______Online_______10000
Rac ______ Fresh _______2000
Rac ______ Online_______20000
Abdul________Fresh _______10000
Rac ________Fresh _______2000 ..... Now i want to count Abdul Fresh Amounts only ...... any formula without filtering...!
Result should show in :
Adbul ....... 15000
Rac ......... 4000
is it possible ...? thanks for help if its possible.
MAK
Hello,
Am trying to prevent duplicates for culoum with condition from another coloum.
for example, if coloum b1:b100 contain the word "Store ID" or "Model Number" then countif($e1:$e100,e1)=1
Thanks
thank u mam, ur blog is excellent.
i've a Q.: i want to list the values that occurred more than 1, e.g.-
Column A Column B
a a
b b
a
b
c
a
e
plz explian the formula.
My Date Of Birth is 08.04.1987 how to calculate perfect age as on 01.01.2017
Plz explian the formula.
Using a formula above, I was able to identify duplicate and unique rows based upon 3 separate columns (Barcode, Custodial Account, OSVer) in my spreadsheet. Now that I have the rows identified, I need a formula that will keep only the unique rows where the Barcode and OSVer are duplicates, but the Custodial Accounts are different based upon the most current date contained in the LastHWScan column. My spreadsheet has 50000 rows of data and will change daily.
Barcode CustodialAcct OSVer LastHWScan
315374 11313 10 3/23/2017 0:04
315374 11313 10 3/17/2017 3:39
315376 212 10 3/23/2017 18:14
315376 11376 10 3/17/2017 2:48
315377 11313 10 3/23/2017 14:27
315377 11313 10 3/16/2017 11:35
315381 11313 10 3/23/2017 22:33
315381 11313 10 3/16/2017 15:49
315391 11313 10 3/23/2017 9:54
315391 11313 10 3/16/2017 8:55
315394 11376 10 3/23/2017 18:42
315394 11313 10 3/17/2017 2:29
315396 212 10 3/23/2017 20:38
315396 11376 10 3/15/2017 14:41
The formula can't change the data in another cell. You can create an additional 'Helper' column and, using the next formula, indicate unique rows (CTRL+Shift+Enter to create an array function):
=IF(D2=MAX(IF( ($A$2:$A$15=$A2)*($B$2:$B$15=$B2)*($C$2:$C$15=$C2)=1,$D$2:$D$15,0)),"Unique","")
As a result, you will have something like in the example below. But it will run slow within a large data amount.
Hi!
This article seems to be very interesting, but I have noticed that the formula syntax in my MS Excel is different.
In particular it is:
=COUNTIF(range; criteria)
For example:
To count how many times the value in A1 is repeated in the range A1:A100 the working formula works is:
=COUNTIF(A1:A100;A1)
Then, I suppose that the syntaxes are different and it seems to me that they follow diffent criteria.
In fact, if I used the first formula you indicated, that is
=COUNTIF(A:A, A2)>1
in my MS Excel doesn't work.
Could you help me to understand which criteria I have to use to translate you syntax?
Thank you so much
Ivan
Hello, Ivan,
as you may notice, the arguments are divided by semicolon (;) in your formula, while in ours – by (,) comma. It may happen due to the regional settings for the list separator. Try the formula below and read this topic to find out more.
=COUNTIF(A:A; A2)>1
Thank you so much!
Hi !
I have a problem: i don't know how i find the duplicates with exceptions. For ex.: 1,2,3,2,3,4,2,1. I want to color the duplicates without "1". Can you help me?
Thank you,
Ciprian
I have a spreadsheet with 12,000+ rows that I need to de-dupe. I want to identify the dups, and mark some of those for deletion. My columns headers are: EEID, EEName,CLP1,CLP2,CLP3 - through CLP12
The EEID and EEName columns definitely have duplicates. I want to delete only the records that have blank CLP1 columns.
Example:
EEID EEName CLP1 CLP2
1234 Diana
1234 Diana Analyst Rover
As long as Diana doesn't have any data in the CLP columns, her record can be deleted.
Which formula should I use?
Can you give a formula for the below-
Column1--column2
56-------10
34-------30
14-------20
34-------40
14-------10
Result
56-------10
34-------70
14-------30
Can you give a formula for the below-
Column1--column2
56-------10
34-------30
14-------20
34-------40
14-------10
Result
56-------10
34-------70
14-------30
How to calculate my exact age
My Date of Birth is 08.04.1987
in 01.01.2017 my age ?
Please solve it.
Hello,
How do you check duplicates vaules acroos a number of columns. For instance i have member numbers in Col A whic contains duplicates and i want to check if they all have the same start date & end date in col B and C respectively.
I have collected data from several production batches about the duration of a certain process step.
batch 1 3.4 hours
batch 2 3.6 hours
batch 3 2.8 hours
batch 4 3.1 hours
batch 5 3.5 hours
batch 6 3.1 hours
batch 7 3.6 hours
In the example above, the lowest repeatable duration is 3.1 hours. So, this could be an achievable standard duration for this process step. The following array formula obtains the lowest repeatable duration.
={MIN(IF((COUNTIF($A$1:$A$7;$A$1:$A$7)>1);$A$1:$A$7;MAX($A$1:$A$7)))}
Now, I'm having problems with the next step. The following durations first need to be rounded to 1 decimal, before the lowest repeatable can be found.
batch 1 3.412 hours
batch 2 3.629 hours
batch 3 2.834 hours
batch 4 3.101 hours
batch 5 3.506 hours
batch 6 3.097 hours
batch 7 3.611 hours
Is there a way to incorporate rounding of the numbers into this array formula?
Dear Svetlana.
I have an issue regarding to duplbicates in Excel.
Name Number of apples
Anne 2
Anne 8
Anne 5
Eric 14
Eric 7
What I want to do is to sum up all the number of apples given each name.
So I need the result to be Anne: 15 apples and Eric 21 apples. Do you know how to calculate this? I have used the Sumifs function, but I get this result:
Name Number of apples Total number of apples each person
Anne 2 15
Anne 8 13
Anne 5 5
Eric 14 21
Eric 7 7
So my question is, how can I use a function that just gives me the sum of number of apples every person without showing the sum of the other rows. So I want the result to be this:
Name Number of apples Total number of apples each person
Anne 2 15
Anne 8
Anne 5
Eric 14 21
Eric 7
I would appreciate your help.
Best regard,
R.R.
Dear Rouzbeh Rasai,
The reason why you get the wrong result using SUMIFS function is probably that you did not use absolute cell reference.
Try this formulas:
=SUMIF(A$2:A$6,"Anne",B$2:B$6)
=SUMIF(A$2:A$6,"Eric",B$2:B$6)
As for the result you want to receive, to get it you need to create a VPA macro.
Hi,
I am wondering if someone could help me?
I have some data with 2 columns of interest. One column is the case number and the other is number of days the case took to complete. Given the inadequacies of the search tool available, I have multiple duplicates for some of the cases. Not all cases are duplicated, and those that have been duplicated have been duplicated anywhere between 2 and 6 times. With each case duplicate, I have another time value generated. Some of these time values are the same for all duplicates, some are different, and they are not in numerical order.
What I am trying to do is for each case, to pick out the largest time value.
The example below might make more sense:
What I have- What I want-
CASE TIME CASE TIME
A 2 A 5
A 1
A 5
B 4 B 4
C 3 C 3
C 1
D 4 D 4
D 4
D 4
E 1 E 1
F 2 F 6
F 2
F 6
F 2
F 2
F 2
Hopefully someone can get further with it that I have been able to! Thank you in advance!
(sorry the example, but clearer hopefully!)
What I have-
CASE TIME
A 2
A 1
A 5
B 4
C 3
C 1
D 4
D 4
D 4
E 1
F 2
F 2
F 6
F 2
F 2
F 2
What I want-
CASE TIME
A 5
B 4
C 3
D 4
E 1
F 6
Hello, Hannah,
Please try to solve your task with the help of the Consolidate Sheets tool which is a part of our Ultimate Suite for Excel. You can download its fully functional 14-day trial version using this direct link.
After you install the product, you will find Consolidate Sheets in the Merge section under the Ablebits Data tab. To get the result you need, you should choose the following options on step 2 of the Wizard:
1. Select the “Max” function to consolidate your data from the drop-down list;
2. Choose the “Consolidate by label” option and tick both check-boxes next to “Use header label” and “Use left column label”.
Hope this will help you with your task.
For EX
we have a location
DEL-LON
LON-JFK
MCO-TPA
We have to find that DEL or LON or JFK or MCO or TPA are repeating how many times in each row.
Hello, pankaj,
I'm afraid there's no easy way to solve your task with a formula. Using a VBA macro would be the best option here.
However, since we do not cover the programming area (VBA-related questions), I can advice you to try and look for the solution in VBA sections on mrexcel.com or excelforum.com.
Sorry I can't assist you better.
Hello,
I am using your array formula to count duplicates in a column. In it's current form, it also counts the empty cells as duplicates. Is there a way to make it ignore empty cells?
{=ROWS($A:$A)-SUM(IF( COUNTIF($A:$A,$A:$A)=1,1,0))}
My second questions is - Can you adjust the formula to make it ignore the original in the count?
For example, if a result in the column occured twice it would count two, but only one is the duplicate since the first is the original. I would like it to count only one for each pair or two there are three of the same value, etc.
D
Hi, I'm trying to highlight, and so prevent duplicates in a number of cells. For example if I am designing an appointment time slot of 09:00, 10:00 and 11:00 across B22:B24 how can I get Excel to highlight that configuration if the same slotting is repeated/redesigned in AL22:AL24?
DD MM YYYY DD/MM/YYYY
06 04 2017 06.04.17
25 04 2017 25.04.17
23 03 2017 23.03.17
08 08 2017 08.08.17
02 09 2017 02.09.17
30 12 2014 30.12.14
21 01 2015 21.01.15
29 03 2015 29.03.15
I FILL UP SOME DATE OF BIRTH DEFIRANT CELL(25 DAYS 04 MONTH 2017 YEAR) HOW TO MAKE TOGATHER NEXT CELL 25.04.2017 OR 25/04/2017
PLEASE SOLVE IT.
Hello,
Please try to solve your task with the help of the Merge Cells tool which is a part of our Ultimate Suite for Excel. You can download its fully functional 14-day trial version using this direct link.
After you install the product, you will find Merge Cells in the Merge section under the Ablebits Data tab.
Hope this will help you with your task.
Duplicate of same names not written in the same order
What happen if the information exceeds 255 characters?, I have to compare whole row but if I excced 255 characters i received #VALUE error
Hello,
I need to remove duplicates inside specific cells.
7G4285-49,7G4202-72,7G4202-72,7G4202-72,7G4202-72,7G4202-72,7G4202-72
7G4285-49,7G4285-49,7G4285-49
7G4285-49,7H4202-72,7H4202-72,7H4382-49
7H4203-72,7H4203-72,7H4203-72,7G4282-49,7H4383-49,7G4202-72
7H4382-25,7H4382-49
7H4382-25,7H4382-49
I need to keep only one value for each cell.
Thanks,
Bogdan
Dear Team
I want to extract a data in single formula. Suppose i have 10k Mobile No in my data in single column, i want to extract the count of unique Mobile Number suppose 7K mobile number is unq, so output of 7k updated in column 1 and rest duplicate value is 0. I have using Pivot every time for count the unique mobile no..
Kindly help
Thank you very much, Svetlana for these very comprehensive explanations about "duplicate issue" in Excel. I was trying to find out how to remove duplicates from the file and I have found an easy way in your article. All the best!
Dear Sir/Madam
Please help
I have following data.
A1 = Maths/Bio. Gurpreet,Sandeep
A2 = Physics Kuldeep
A3 = Economics Priyanka
A4 = Maths/Physics Gurpreet, Ramesh
It's a school time table
As I type the name "Gurpreet" in B1 it shows me duplicate
I wish to find if some Teacher's name is repeated in Column A
Create three separate columns. First column has the class name, the second has the teacher's name and the third has another teacher's name.
Separate the teacher's names into two columns.
Then, in a fourth column enter =COUNTIF(B:B,B1)>1
The result will show "TRUE" if it is a duplicate.
If you want to see if the teachers in column C are duplicates, just enter =COUNTIF(C:C,C1)>1 into column D.
Hi,
Thank you for all of the information on here.
I am experiencing a range limit on the use of this calculation? For some reason it is only letting me check 20 rows, anything above that is returning a result of 0. Is this normal?
What I really want to do is check an entire column in a table for values (there is about 1000), but as soon as i do this the returned value is zero. If it is less than 20, the returned value is acurate.
I am using;
=SUM(IF(ISTEXT(A28:A37)*COUNTIF(A28:A37,A28:A37)=1,1,0)) - works
=SUM(IF(ISTEXT(A:A)*COUNTIF(A:A,A:A)=1,1,0)) - total is zero
=SUM(IF(ISTEXT(A1:A37)*COUNTIF(A1:A37,A1:A37)=1,1,0)) - total is zero
Sorry - the comment above was supposed to be on the distinct URL
https://www.ablebits.com/office-addins-blog/2016/04/07/how-to-count-distinct-and-unique-values-in-excel/#count-distinct-excel
Hi all Dear
Can you help my question like this? i want to khnow formula use Auto in Group:
Items Code Expiry Date Auto to Group
1234567 1-Jan-18 01
1234567 2-Feb-18 02
1234567 3-Mar-18 03
1234567 4-Apr-18 04
1234567 5-May-18 05
1234567 1-Jan-18 01
1234567 3-Mar-18 03
1234567 5-May-18 05
Thank all dear.
Dear Svetlana,
I hope you can help me with the following question.
I have a list of cities and some of them are repeated in the list. I would like to extract the row reference of all repeated city names (i.e for a given city: New York - is repeated in row 2, 7, 29, 33 etc).
Is this possible?
thank you,
Kos
Is it possible to get the number the duplicate in order that they appear?
For example
123,1
124
123,2
123,3
125
123,4
Frank:
I don't see any duplicates in this data.
Are you asking to match the first three digits?
how to find duplicate in a single row.
example:
Row1: 23 44 42 44 53 23 this row should be tagged as dulicate
Prakash:
Svetlana recently wrote a very good article on this topic. The article was published here on Ablebits on April 26.
Enter "Find duplicates" in the search box and you'll see the article "How to find duplicates in Excel: identify, highlight count, filter, and more". Click on that link and once you've read the article you'll be able to accomplish what you want.
Hello!
Could we make this:
COUNTIF($A$2:A2,A2) to work in ArrayFormula()?
When I try this
=ARRAYFORMULA(C1:C&COUNTIF($C$1:C, $C$1:C))
It shows a total number in each repeated cell like:
a 4
b 1
c 2
a 4
a 4
a 4
c 2
But I still need to receive
a 1
b 1
c 1
a 2
a 3
a 4
c 2
To have a full column with unique values based on another column with repeats.
Big thanks in advance.
Best
Column1 Column2
0 10
10 20
15 25
in the above ranges 15-20 have been repeated and that has to be spotted and removed
hi
I have a problem with deleting some specific data from large table which already have duplicate value , but I want only to find if my specific data in that table and delete it without removing the other duplicates
dear all,
is that able to find the decimal value from next column:
1101
1102
1103
1101H
1102HR
1103H
good evening sir
i have a problem that
i type some values ie., 2,4,5,7,8,2,9 in a specific cell how to find out duplicate values in excel cell please send forumala for self use it is very need full to me
I have a row with header in row1, for example; Boat1, Boat2, Boat3, Boat4, Boat5 and numbers in the next row, 5, 6, 7, 5, 4. I want to identify the duplicate headers or header/number, which in this case is Boat1, Boat4 or Boat1/5, Boat4/5. Happy for the result to be shown in two separate cells.
Thank you
If duplicate is there, then I want result as first value in row1 against duplicate name. Any one pls. help to get result as mentioned in column3
Eg, below.
Column1---Column2---Column3(RESULT)
1 -------Siva -------1
2------- Kumar -------2
3 -------Suresh ------3
4 -------Siva ------1
5 --------Kumar -----2
I have 55000 entries in a single column 10 digit numbers. I have to find duplicates. But the problem is the numbers may have difference by addition of excess 3 4 digits at the ending or starting.
Highlight duplicate values across multiple worksheets.
I have a workbook with four worksheets. We are clearing out a storage center and listing the bins on worksheet "Empty Bins" as they become empty. Worksheets "Aisle 1", "Aisle 2", and "Aisle 3" list all the bins in the system.
How do compare the data on worksheet "Empty Bins" to the data on the three other worksheets to find and highlight duplicates? Thank you.
Hi,
how can i get the duplication data for example i want the excel to read the data from 6 last alphabet of an email.
Hi
am saikat patra from Howrah in west bengal.
Can anyone help me about if count formula details given below.
colum 1 colum 2
78120 above10days
78121 above10days
78122 abovel0days
78560 above5days
78121 above10days
How to count colum 2 tex wise to colum 1 shipment no without duplicate.
ans should be if above10days basis is "3".
please help me and very much gladfull to you for this.
How can i arrange the Values of duplicate attendance number from below
Attendace Value
168755 41759002
168755 41704067
197119 40316326
197119 40811539
204786 41446987
204786 41025753
285943 41696614
285943 41232806
181907 40538480
181907 40117598
986727 40450723
986727 41072614
768565 40098263
768565 40403845
693968 40455014
693968 40987284
998263 40044440
998263 40928398
366864 41736203
366864 41644887
837218 40222382
837218 40621245
837218 4063258
to
Attendance Value 1 Value 2 Value3
168755 41759002 41704067
197119 40316326 40811539
204786 41446987 41025753
285943 41696614 41232806
181907 40538480 40117598
986727 40450723 41072614
768565 40098263 40403845
693968 40455014 40987284
998263 40044440 40928398
366864 41736203 41644887
837218 40222382 40621245 4063258
Hi,
How can I distinguish repeating brand names? For example:
Gillette --> Gillette 1
Gillette --> Gillette 2
Pantene --> Pantene 1
Gillette --> Gillette 3
Head & Shoulders --> Head & Shoulders 1
Pantene --> Pantene 2
016230240
016259070
012350891
If i would like to add a 6 in front of above number only, example 016 become 6016230240 , the back of 0 will appear 6 also if i find 0 and replace by 6, however i just like to have 6 infront of the number, what is the the process , pls help, thank you..
Hi, I'm using the duplicate formula but trying to add an index part so that it shows up the duplicate reference. Where am I going wrong and how do I correct it? I have: =INDEX(E:E(IF(COUNTIF(F:F,[@WON])>1,"Duplicate","")),0)
I want to show the contents of the duplicate cell from column E, if it has the same contents as another cell in column F. So if row 3 has the same column F value as row 5, I want B3 to show the cell value from E5.
I hope this makes sense.
Thanks