How to use Excel COUNTIFS and COUNTIF with multiple criteria

The tutorial explains how to use COUNTIFS and COUNTIF formulas with multiple criteria in Excel based on AND as well as OR logic. You will find a number of examples for different data types - numbers, dates, text, wildcard characters, non-blank cells and more.

Of all Excel functions, COUNTIFS and COUNTIF are probably most often mixed up because they look very much alike and both are purposed for counting cells based on the specified criteria.

The difference is that COUNTIF is designed for counting cells with a single condition in one range, whereas COUNTIFS can evaluate different criteria in the same or in different ranges. The aim of this tutorial is to demonstrate different approaches and help you choose the most efficient formula for each particular task.

Excel COUNTIFS function - syntax and usage

The Excel COUNTIFS function counts cells across multiple ranges based on one or several conditions. The function is available in Excel 2019, 2016, 2013, Excel 2010, and Excel 2007, so you can use the below examples in any Excel version.

COUNTIFS syntax

The syntax of the COUNTIFS function is as follows:

COUNTIFS(criteria_range1, criteria1, [criteria_range2, criteria2]…)
  • criteria_range1 (required) - defines the first range to which the first condition (criteria1) shall be applied.
  • criteria1 (required) - sets the condition in the form of a numbercell referencetext stringexpression or another Excel function. The criteria defines which cells shall be counted and can be expressed as 10, "<=32", A6, "sweets".
  • [criteria_range2, criteria2]… (optional) - these are additional ranges and their associated criteria. You can specify up to 127 range/criteria pairs in your formulas.

In fact, you don't have to remember the syntax of the COUNTIF function by heart. Microsoft Excel will display the function's arguments as soon as you start typing; the argument you are entering at the moment is highlighted in bold.

The syntax of the Excel COUNTIFS function

Excel COUNTIFS - things to remember!

  1. You can use the COUNTIFS function in Excel to count cells in a single range with a single condition as well as in multiple ranges with multiple conditions. If the latter, only those cells that meet all of the specified conditions are counted.
  2. Each additional range must have the same number of rows and columns as the first range (criteria_range1 argument).
  3. Both contiguous and non-contiguous ranges are allowed.
  4. If the criteria is a reference to an empty cell, the COUNTIFS function treats it as a zero value (0).
  5. You can use the wildcard characters in criteria - asterisk (*) and question mark (?). See this example for full details.

How to use COUNTIFS and COUNTIF with multiple criteria in Excel

Below you will find a number of formula examples that demonstrate how to use the COUNTIFS and COUNTIF functions in Excel to evaluate multiple conditions.

How to count cells with multiple criteria (AND logic)

This scenario is the easiest one, since the COUNTIFS function in Excel is designed to count only those cells for which all of the specified conditions are TRUE. We call it the AND logic, because Excel's AND function works this way.

Formula 1. COUNTIFS formula with multiple criteria

Suppose you have a product list like shown in the screenshot below. You want to get a count of items that are in stock (value in column B is greater than 0) but have not been sold yet (value is column C is equal to 0).

The task can be accomplished by using this formula:

=COUNTIFS(B2:B7,">0", C2:C7,"=0")

And the count is 2 ("Cherries" and "Lemons"):

Counting cells with multiple criteria based on AND logic

Formula 2. COUNTIFS formula with the same criteria

When you want to count items with identical criteria, you still need to supply each criteria_range / criteria pair individually.

For example, here's the right formula to count items that have 0 both in column B and column C:

=COUNTIFS($B$2:$B$7,"=0", $C$2:$C$7,"=0")

This COUNTIFS formula returns 1 because only "Grapes" have "0" value in both columns.

COUNTIFS formula with identical criteria

Using a simpler formula with a single criteria_range like COUNTIFS(B2:C7,"=0") would yield a different result - the total count of cells in the range B2:C7 containing a zero (which is 4 in this example).

How to count cells with multiple criteria (OR logic)

As you have seen in the above examples, counting cells that meet all of the specified criteria is easy because the COUNTIFS function is designed to work this way.

But what if you want to count cells for which at least one of the specified conditions is TRUE, i.e. based on the OR logic? Overall, there are two ways to do this - by adding up several COUNTIF formulas or using a SUM COUNTIFS formula with an array constant.

Formula 1. Add up two or more COUNTIF or COUNITFS formulas

In the table below, supposing you want to count orders with the "Cancelled" and "Pending" status. To have it doen, you can simply write 2 regular Countif formulas and add up the results:

=COUNTIF($C$2:$C$11,"Cancelled") + COUNTIF($C$2:$C$11,"Pending")

Counting cells that meet any of the specified criteria

In case each of the functions is supposed to evaluate more than one condition, use COUNTIFS instead of COUNTIF. For example, to get the count of "Cancelled" and "Pending" orders for "Apples" use this formula:

=COUNTIFS($A$2:$A$11, "Apples", $C$2:$C$11,"Cancelled") + COUNTIFS($A$2:$A$11, "Apples", $C$2:$C$11,"Pending")

Another formula to count cells with multiple criteria and OR logic

Formula 2. SUM COUNTIFS with an array constant

In situations when you have to evaluate a lot of criteria, the above approach is not the best way to go because your formula would grow too big in size. To perform the same calculations in a more compact formula, list all of your criteria in an array constant, and supply that array to the criteria argument of the COUNTIFS function. To get the total count, embed COUNTIFS inside the SUM function, like this:

SUM(COUNTIFS(range,{"criteria1","criteria2","criteria3",…}))

In our sample table, to count orders with the status "Cancelled" or "Pending" or "In transit", the formula would go as follows:

=SUM(COUNTIFS($C$2:$C$11, {"cancelled", "pending", "in transit"}))

A more compact formula to count cells with multiple criteria and OR logic

In a similar manner, you can count cells based on two or more criteria_range / criteria pairs. For instance, to get the number of "Apples" orders that are "Cancelled" or "Pending" or "In transit", use this formula:

=SUM(COUNTIFS($A$2:$A$11,"apples",$C$2:$C$11,{"cancelled","pending","in transit"}))

Counting cells with multiple criteria_range / criteria pairs and OR logic

You can find a few more ways to count cells with OR logic in this tutorial: Excel COUNTIF and COUNTIFS with OR conditions.

How to count numbers between 2 specified numbers

By and large, COUNTIFS formulas for numbers fall into 2 categories - based on several conditions (explained in the above examples) and between the two values you specify. The latter can be accomplished in two ways - by using the COUNTIFS function or by subtracting one COUNTIF from another.

Formula 1. COUNTIFS to count cells between two numbers

To find out how many numbers between 5 and 10 (not including 5 and 10) are contained in cells C2 through C10, use this formula:

=COUNTIFS(C2:C10,">5", C2:C10,"<10")

A COUNTIFS formula to count numbers between X and Y

To include 5 and 10 in the count, use the "greater than or equal to" and "less than or equal to" operators:

=COUNTIFS(B2:B10,">=5", B2:B10,"<=10")

Formula 2. COUNTIF formulas to count numbers between X and Y

The same result can be achieved by subtracting one Countif formula from another. The first one counts how many numbers are greater than the lower bound value (5 in this example). The second formula returns the count of numbers that are greater than the upper bound value (10 in this case). The difference between the first and second number is the result you are looking for.

  • =COUNTIF(C2:C10,">5")-COUNTIF(C2:C10,">=10") - counts how many numbers greater than 5 and less than 10 are in the range C2:C10. This formula will return the same count as shown in the screenshot above.
  • =COUNTIF(C2:C10, ">=5")-COUNTIF(C2:C10, ">10") - the formula counts how many numbers between 5 and 10 are in the range C2:C10, including 5 and 10.

How to use cell references in COUNTIFS formulas

When using logical operators such as ">", "<", "<=" or ">=" together with cell references in your Excel COUNTIFS formulas, remember to enclose the operator in "double quotes" and
add an ampersand (&) before a cell reference to construct a text string.

In a sample dataset below, let's count "Apples" orders with amount greater than $200. With criteria_range1 in cells A2:A11 and criteria_range2 in B2:B11, you can use this formula:

=COUNTIFS($A$2:$A$11, "Apples", $B$2:$B$11, ">200")

Or, you can input your criteria values in certain cells, say F1 and F2, and reference those cells in your formula:

=COUNTIFS($A$2:$A$11, $F$1, $B$2:$B$11, ">"&$F$2)

Please notice the use of absolute cell references both in the criteria and criteria_range arguments, which prevents the formula from being broken when copied to other cells.

Using cell references in COUNTIFS formulas

For more information about the use of an ampersand in COUNTIF and COUNTIFS formulas, please see Excel COUNTIF - frequently asked questions.

How to use COUNTIFS with wildcard characters

In Excel COUNTIFS formulas, you can use the following wildcard characters:

  • Question mark (?) - matches any single character, use it to count cells starting and/or ending with certain characters.
  • Asterisk (*) - matches any sequence of characters, you use it to count cells containing a specified word or a character(s) as part of the cell's contents.
Tip. If you want to count cells with an actual question mark or asterisk, type a tilde (~) before an asterisk or question mark.

Now let's see how you can use a wildcard char in real-life COUNTIFS formulas in Excel. Suppose, you have a list of projects in column A. You wish to know how many projects are already assigned to someone, i.e. have any name in column B. And because we are learning how to use the COUNTIFS function with multiple criteria, let's add a second condition - the End Date in column D should also be set.

Here is the formula that works a treat:

=COUNTIFS(B2:B10,"*",D2:D10,"<>"&""))

Please note, you cannot use a wildcard character in the 2nd criteria because you have dates rather that text values in column D. That is why, you use the criteria that finds non-blank cells: "<>"&""

The COUNTIFS formula to count entries containing any text in one column and non-blank cells in another column.

COUNTIFS and COUNTIF with multiple criteria for dates

The COUNTIFS and COUNTIF formulas you use for dates are very much similar to the above formulas for numbers.

Example 1. Count dates in a specific date range

To count the dates that fall in a certain date range, you can also use either a COUNTIFS formula with two criteria or a combination of two COUNTIF functions.

For example, the following formulas count the number of dates in cells C2 through C10 that fall between 1-Jun-2014 and 7-Jun-2014, inclusive:

=COUNTIFS(C2:C9, ">=6/1/2014", C2:C9, "<=6/7/2014")

=COUNTIF(C2:C9, ">=6/1/2014") - COUNTIF(C2:C9, ">6/7/2014")

The COUNTIF formula with 2 conditions to count dates in a specific date range

Example 2. Count dates with multiple conditions

In the same manner, you can use a COUNTIFS formula to count the number of dates in different columns that meet 2 or more conditions. For instance, the below formula will find out how many products were purchased after the 20th of May and delivered after the 1st of June:

=COUNTIFS(C2:C9, ">5/1/2014", D2:D9, ">6/7/2014")

The COUNTIF formula to count dates with multiple conditions

Example 3. Count dates with multiple conditions based on the current date

You can use Excel's TODAY() function in combination with COUNTIF to count dates based on the current date.

For example, the following COUNTIF formula with two ranges and two criteria will tell you how many products have already been purchased but not delivered yet.

=COUNTIFS(C2:C9, "<"&TODAY(), D2:D9, ">"&TODAY())

The COUNTIF formula to count dates with multiple conditions based on the current date

This formula allows for many possible variations. For instance, you can tweak it to count how many products were purchased more than a week ago and are not delivered yet:

=COUNTIFS(C2:C9, "<="&TODAY()-7, D2:D9, ">"&TODAY())

This is how you count cells with multiple criteria in Excel. I hope you will find these examples helpful. Anyway, I thank you for reading and hope to see you on our blog next week!

You may also be interested in

1,222 responses to "How to use Excel COUNTIFS and COUNTIF with multiple criteria"

  1. Gino says:

    Hi how can a get a total count for every month thru out the year for example if a user has a yes or no value in a cell i want to get a total of all the yes in that year and show the month where the yes occured?

  2. James C says:

    Hi,
    I'm working on a spreadhseet that needs to show a value of business sold by each agent. sometimes 2 agents will share the business and therefore get 50% each toward target.
    column A and B show which agents are responsible for the business and column C shows the value of the business. I'd like a formula in column D to show exact figure from column C if column B is empty, if column B contains any data then column D should show value from column C/2.
    I'm struggling to make this work, any help would be much appreciated.

    • Rick says:

      Any time you want to check something conditionally, you'll need to use the IF formulas. For your example: =IF(ISBLANK(B3),C3/2,C3)

  3. jorge says:

    excelente
    Quiero bajar este archivo fabuloso.

  4. Nyss says:

    I have a spreadsheet I am trying to use data validation I have an items list, each item has a specific max discount. I have used vlookup to link the data from the list to autopopulate when I type a specific item number. I need to be able to type a percentage up to the max allowed for the item. How do i set up a formula that only allows up to that max discount for the item listed on the invoice. If over that discount I need an error message. Thankyou for your help.

  5. uma tripathi says:

    1. Number of employees from the Sales deparment who joined before July 2006 and have a total experience (prior and present) of more than 10 years?
    Employee Name Department Joining Date Prior Experience
    Prakash Marketing 01-05-2003 2
    Rahul IT 09-01-2008 1
    Rajiv Finance 14-03-2007 0
    Priya Sales 15-12-2009 1
    Amit Marketing 01-06-2002 2
    Karthik IT 16-02-2009 1
    Shobha R&D 23-01-2006 0
    Prateek Manufacturing 01-02-2010 3
    Payal Logistics 01-05-2003 3
    Prashant Finance 15-06-2003 0
    Anil R&D 01-05-2003 5
    Swaroop Marketing 01-01-2009 1
    Tejas Finance 25-01-2010 0
    Raghav Manufacturing 08-11-2004 4
    Sanjeev Manufacturing 01-02-2010 0
    Madhu Finance 14-03-2007 3
    Murali Logistics 14-03-2007 2
    Aravind Sales 15-12-2007 8
    Balaji Marketing 08-11-2004 2
    Mukundan Manufacturing 01-05-2003 3
    Shweta Sales 10-10-2001 0
    Anusha Manufacturing 01-01-2009 0
    Ravi Manufacturing 15-06-2003 1
    Rahul HR 29-04-2005 4
    Ramya IT 09-01-2008 2
    Shriram Marketing 08-08-2008 5
    Sairam R&D 16-02-2009 3
    Srinivasan Finance 08-08-2008 0
    Trisha Manufacturing 23-01-2006 0
    Paul Manufacturing 25-01-2010 1
    Mani Manufacturing 29-04-2005 2
    Venkat Finance 08-11-2004 2
    Abhishek Marketing 12-09-2005 5
    Chanakya Sales 21-12-2004 4
    Daniel Sales 15-06-2003 2
    Rishi Logistics 01-02-2010 3
    Vikram R&D 08-01-2007 3
    Prabhu Sales 01-02-2010 0
    Priya IT 29-04-2005 2
    Mahesh Marketing 15-06-2003 0
    Raj HR 25-01-2010 4
    Suresh Manufacturing 11-07-2008 4

  6. SAMEH says:

    HI.great job
    i want a formula to count a1+a2 as one if a1+a2>0

  7. albert says:

    Hi, would like to seek help.

    if i would like to subtract the total sum of COUNTIF "Yes" from another part that i have Sum up, how can i do so?

    Example:
    =COUNTIF(K16:AG16,"yes") : Probably i got 3 for countif (but i want to subtract it from another number)

    can i do so? tq

  8. Jen says:

    I'm trying to count the number of times a specific item ships within a specified month (column B contains the ship dates and column C contains the items). How can I do a COUNTIFS formula where one criteria is the ship month and the other criteria is the item. All the "countifs with dates" explanations I've seen only ever explain how to use the formula with ONLY dates but not with dates and another criteria. Is it even possible? (also my spread sheet has empty cells in between some dates. I've seen elsewhere that that can mess with the counting function when dates are involved)

    i.e. SHIP ITEM
    Thursday, January 23, 2020 Solenoid
    Thursday, January 23, 2020 Sensor

    Tuesday, January 28, 2020 Sensor

    Monday, February 3, 2020 Electromagnet
    Monday, February 3, 2020 Solenoid

    So basically, I need a formula that can tell me that 2 sensors ship in January.

  9. Kenneth Dupont says:

    I have a file with say 100 records . Each record has 20 numeric cells with a number (1 thru 80) eg 2 5 6 17 20 28 30 33 42 50 54 55 60 69 70 71 72 73 75 80 each in its own cell. Note that the record contains 6 20 33 55 . I want to filter all records in the 100 records that contain 6 20 33 and 55. My records have record numbers eg ( 23456) and a cell stamped with N or Y. Format: Each of the 100 records --- File Number, , Y/N. I actually have 50,000 records. I did this once 5 years ago and cant remember how. Thank you Ken Dupont
    by the way this is for checking the frequency 4 numbers occur. 25 years ago said Avg 340 games.

  10. Toks says:

    Hi. I have a column with three texts. Let me say A, B & C. I want to count the number of times A occurs, B occurs and C occurs between TIME1 & TIME2. Both time are the ame date.
    Thank you

  11. Monique says:

    I am trying to create a formula that will allow me to select certain dates for the month so I can obtain a total. Unfortunately my spreadsheet is titled with dates and below the dates there are subtitles that need to be added per date.
    For example I want to gather only the dates that fall on a Monday and grab the cell totals for those dates only. Please help.
    Column A Column B
    7/12/19
    1 45.62
    2 6.52
    3 18.52
    4 154.52
    7/13/19
    1 93.92
    100 101.52
    500 100.32

  12. SG says:

    Hi!

    I'm working on compiling data into three different scenarios. I need to do the following:
    1) identify if the institutions have the same ID
    2) if they have the same ID, then I need to identify if they have 1 of 3 criteria, 2 of 3 criteria, or 3 of 3 criteria

    I tried using IF & COUNTIF but it's not working the way I intended

  13. Tiffany Holliday says:

    I'm trying to figure out what a COUNTIF formula means on a sheet I didn't create. The Range is text rather than specifying a cell range and I can't figure out what data that range is connected to. The formula is =COUNTIF(Round 2,AC$4) and I can't figure out what "Round_2" connects to. There is another sheet within workbook with a cell named "Round 2" but the data there doesn't seem to be applying to this formula.

  14. rashid says:

    assalam o alaikum
    i want to count qty how many cell of colum 1 date empty of secound column
    example
    column 1 column
    17-01-2020
    17-01-2020
    18-01-2020 245
    18-01-2020
    18-01-2020 254
    now how we use formula 17 -01-2020 02 cell is empty and 18-01-2020 is 02

  15. shanavas says:

    Kindly share the formula for below,
    Monthly profit share to be distributed based on attendance. Kindly advise

  16. Simon Jamboe says:

    Am having a problem with some problem and am asking of help.
    We want customers to receive a coupon based on the department they purchased from.
    Coupon amounts by department:
    Electronics—$25 coupon.
    Toys—$20 coupon.
    Sports—$15 coupon.
    Shoes—$10 coupon.
    Every other department—$5 coupon.
    Create a column named “Coupon.”
    Create a formula that displays the coupon amount for each customer based on department.
    Remember! The standards of professionalism require that you DO NOT include numbers in formulas if the numbers might change in the future. These coupons will change in the future.
    Create a column named “Promotion.”
    Create a formula to enter $10 if the customer purchased books or shoes.
    If you forgot how to create “OR” functions inside.
    When a customer calls, we want our staff to quickly find the customer and information. Create a dashboard.
    Create a customer drop down list using data validation.
    Below the list displays the appropriate corresponding information: email, gender, new sales, department, coupon, and promotion.

  17. FABIOLA P VANEGAS says:

    I am trying to figure out a countifs formula inorder to determine how many scores are above 8 during the year 2020.
    Column 1 Column 2
    2/21/2020 14
    1/9/2020 7.2
    11/9/2019 9.5
    2/20/2019 6.0

    Which would be only 1.
    Thank you in advance. :)

  18. Siddharth says:

    Hi,
    I'm using countifs and need to count the data date wise but the result is coming 0 everytime. For the same I have used 2 different ways, one using today() and another by inserting required date but the outcome is same.

  19. Askar says:

    Hello,
    I need to get the count based on specific criteria from two tables.
    the header will be
    emp name, Batch number. This will be the master base data. From this, I need to make an overview that shows a specific batch count for each employee.

    The emp name will be repeated.

  20. MLC says:

    I have a spreadsheet where cells contain answers to a multi-response question. Cells can contain any combination of responses from A - J. I need a way to count the number of cells that contain (for example) A, C, or E. If a cell contains more than one of these, I don't want it to be counted twice. For example:

    Cell 1: A, B, D
    Cell 2: A, C, E
    Cell 3: B, D, E
    Cell 4: B, D, G, J

    The total count of cells that contain A, C, OR E is 3. Using the OR formula above, we would get a total of 5, as the count for A is 2, the count for C is 1, and the count for E is 2. Is there any way to do this?

    • Hello MLC!
      If I understand your task correctly, the following formula should work for you:

      =SUM(COUNTIFS(A1:A16,{"*A*";"*C*";"*E*"}))-SUM(COUNTIFS(A1:A16,{"*A*C*";"*C*E*";"*A*E*"}))

      This is an array formula and it needs to be entered via Ctrl + Shift + Enter, not just Enter.

  21. Habib says:

    Hi There,
    I'm looking for a formula that count the different between specific cells. I have 100 cells contains reading and I want to count if different for instant between 6th cell and 1st cell is more than 10, similarly I want to do it for cell 24th and 48th, 72nd and 96th,....

    thanks,

  22. Noby says:

    R80874 17/03/2020 CREDIT ABDULLA PHARMACY 1 294.91 0.00 0.00 294.91
    R80873 17/03/2020 CREDIT AHLAN PHARMACY(AJN) 2 424.34 0.00 0.00 424.34
    R80872 17/03/2020 CREDIT AL HAYER PHARMACY 3 481.50 0.00 0.00 481.50
    R80912 17/03/2020 CREDIT AL KHALEEJ PHARMACY 4 379.51 0.00 0.00 379.51
    R80865 17/03/2020 CREDIT CASH CUSTOMER 5 698.16 0.00 0.00 698.16
    R80903 17/03/2020 CREDIT CASH CUSTOMER 6 675.00 0.00 0.00 675.00
    R80875 17/03/2020 CREDIT CONCORD DRUG STORE 7 6230.00 0.00 0.00 6230.00
    R80880 17/03/2020 CREDIT CONCORD DRUG STORE 7 319.00 0.00 0.00 319.00
    R80911 17/03/2020 CREDIT GHANTHOOT PHARMACY 8 250.06 0.00 0.00 250.06
    R80886 17/03/2020 CREDIT LEAH PHARMACY 9 569.89 0.00 0.00 569.89
    R80907 17/03/2020 CREDIT LEAH PHARMACY 9 181.05 0.00 0.00 181.05
    R80910 17/03/2020 CREDIT UM GHAFA PHARMACY 10 517.54 0.00 0.00 517.54
    11020.96

    I NEED THE TOTAL NUMBER OF CUSTOMER AND COUNT CASH AS SINGLE
    CUSTOMER
    HERE 2 CASH CUSTOMERs COUNT IT AS 2 CUSTOMERs

  23. Habacuque says:

    Thanks!

  24. Abdul Amin Khan says:

    I Want to numeric precedence with multiple occurrences of String in Specified Range
    Like
    A1 Amir
    A2 Amir
    A3 Amir

    Result Will
    A1 Amir1
    A2 Amir2
    A3 Amir3

    can you help me on this its urgent

  25. Lawrence says:

    Thank you. This is THE tutorial on using AND and/or OR commands with Countifs.

    Thank you, thank you, thank you!

  26. Jason Simon says:

    Hi,

    I am attempting to track the frequency that sales person makes calls in a selected date range. The formula is adding up the number of times it says Matt Elkin as well as the number of time any of those dates were mentioned. I want it to count those dates only if it says Matt Elkin.

    G2/F2 - start and end dates

    =COUNTIFS(Database!M2:M9359, "Matt Elkin") + COUNTIFS(Database!G2:G10000,">="&G2,Database!G2:G10000,"<="&F2)

  27. Tara Fitzgerald says:

    Here is my formula. I am trying to count if column K, D, and E meets these criteria. Column K must have Winston. Column D must have Win7 to Win10. Column E has several criteria.
    =SUM(COUNTIFS(K:K,"WINSTON",D:D,"Win7 to Win10",E:E,{"Deferred","Discovered",Discovered by Local IS","Failed 10 Push","Local ITS Support","Not Delivered","Not Found","Special Config on Order"}))

    • Hello Tara!
      If I understand your task correctly, maybe the following formula should work for you:

      =SUMPRODUCT(--(D1:D10="Win7 to Win10"), --(K1:K10="WINSTON"), IFERROR(MATCH(E1:E10,{"Deferred";"Discovered";"Discovered by Local IS"},0),0))

      I hope this will help, otherwise please do not hesitate to contact me anytime.

  28. dhanapal says:

    how i count the how many cities particular sales person doing the sales in the particular month (For Eg. Sales man "A" do the sales in the month of "Jan" how many cities covered and how many customers billed in the month of jan and feb, etc)

    columns are in the worksheets are below,
    Month City Sales Employee Name Invoice Number Invoice Date party Name productName Qty Rate Sales Value
    kindly help

  29. aaa says:

    Salary Grade Range
    A 0-300,000
    B 300,001-400,000
    C 400,001-800,000
    D 800,001-1,000,000
    E Above 1,000,000

    get the salary range

    • Hello!
      If I understand your task correctly, you need to use an approximate search VLOOKUP.
      Write down all income rates in one column, for example:
      0
      300000
      400000
      500000
      ......
      In the second column B, indicate the name of the range A, B, C, D ...
      If salary is indicated in cell D1, this formula will return the name of the range

      = VLOOKUP (D1, A1: B10,2,1)

      You can learn more about approximate match in VLOOKUP in this article on our blog.
      Hope you’ll find this information helpful.

  30. Ivory Armstrong says:

    Hi. I have created an attendance spreadsheet with a drop down list allowing multiple selections of: A, B, C, D, E, NP. If NP is selected nothing needs to happen as the client was Not Present. The other options will demonstrate what activities the clients participated in if they did attend A, E, D or A, B, C, etc. I need another cell to calculate all dates client attended and has choices from A-E as 2.
    Ex: on 12/29 the client attended and participated in 3 activities, on 12/30 client participated in 1 and 12/31 client participated in 2. I need each of these cells to equate to 2- so the total should be 6 units. It should not matter what activates the client is participating in, but if they attend that should equal 2 units for the day. I need this to be able to equate no matter what order the drop down items are placed.
    So with this example the total should be 6
    12/28 12/29 12/30 12/31 TOTAL
    B,D,E D B,C 4

  31. Katelyn says:

    I have a spreadsheet that has three columns I am working with...Column C that has Dates Sampled, Column H that has Quantity, and Column K that has Aggregate type. I need to have a formula that will give the Quantity of X aggregates for each quarter by using the dates sampled to determine the quarters. Is this something I will be able to do with the CountIf function? TIA

  32. ashok says:

    I have Count like COUNTIF((C4,F4,I4,L4),">0"), result are not find.
    please help.

  33. rachel says:

    Hi,
    Please can you help!
    I am creating a reporting sheet in excel for different information from throughout the workbook.
    I would like to create a formula that can tell me how many times the word "Late" appeared within in a month. The data will be pulled from another sheet to the reporting sheet.
    My date column is B date 24/04/2020 and Late column is F.
    Thank you for any advice.

    • Hi Rachel,
      You may use the array function below to count the number of values on several sheets:

      =SUM(IFERROR(COUNTIFS(INDIRECT("'"&$E$2:$E$32&"'!F:F"),A3, INDIRECT("'"&$E$2:$E$32&"'!B:B")," >="&DATE(YEAR(A4),MONTH(A4),1), INDIRECT("'"&$E$2:$E$32&"'!B:B")," <="&EOMONTH(A4,0)),0))

      Where A3 is the criterion to search values by (in your case, it is Late);

      F:F is the searching range on each sheet;

      A4 states for the date you conduct the search by. Note! The dates you apply the formula to should be of the same month as the one in A4;

      B:B is the dates range on each sheet;

      $E$2:$E$32 - the list of the sheets to make the search in.

      Since the formula above is the array function, please don't forget to use the Cthr+Shift+Enter combination to apply it.
      Hope it'll help you with your task.

  34. Tilly Hall says:

    Hi there,
    I am trying to combine these formulas so that both criteria must be true for it to be counted however as my ranges are different sizes this is problematic, is there a way to combine these?

    =COUNTIF('Volunteer Call Handler Form APRIL'!Q:V,"XXXXXXX - recent") COUNTIF('Volunteer Call Handler Form APRIL'!G:G,"Inbound"))

    Thanks, Tilly

  35. steve says:

    Hi,
    I am trying to count, for example the number of occurrences of a particular text , say "SP", in a row from column c to column dd - OK so far. But now I want to only count the occurrences in the row where the date in column A = today(). The table has multiple (consecutive) dates in column A. Is it possible to do this with a formula? Maybe countif with offset and match somehow? Thanks for looking.

    • Hello Steve!
      Use the paragraph in this guide above "Count cells with multiple criteria (AND logic)". One of the conditions is A1 = TODAY ()

      • steve says:

        Alexander, Thanks for your help.
        I am trying to put a formula in a single cell which will, each day, count up occurrences of eg. "Y" and show the total - not once per row, but just a single cell, showing just the current days completeness (="Y"). I have tried =COUNTIFS($A$1:$A$21, "="& "Today()",$C$1:$N$21, "="& "Y") but this gives #Value! as result. Any further ideas? Cheers. Sample data follows:

        04-May EL EL EL EL EL EL
        05-May SJ Y SJ Y SJ Y SJ Y SJ Y SJ Y
        06-May EL y EL y EL y EL y EL y EL y
        07-May LR y LR y LR y LR y LR y LR y
        08-May SJ Y SJ Y SJ Y SJ Y SJ Y SJ Y
        09-May LR Y LR Y LR Y LR Y LR Y LR Y
        10-May EL Y EL Y EL Y EL Y EL Y EL Y
        11-May SJ SJ SJ SJ SJ SJ
        12-May LR LR LR LR LR LR
        13-May EL EL EL EL EL EL
        14-May SJ SJ SJ SJ SJ SJ
        15-May LR LR LR LR LR LR
        16-May EL EL EL EL EL EL
        17-May SJ SJ SJ SJ SJ SJ
        18-May LR LR LR LR LR LR
        19-May EL EL EL EL EL EL
        20-May SJ SJ SJ SJ SJ SJ
        21-May LR LR LR LR LR LR

        • steve says:

          Cracked it. Thanks for your inspiration Alexander. Here is what I used …
          =COUNTIF(INDIRECT("C" & 3+MATCH(TODAY(),A4:A31)):INDIRECT("DD" & 3+MATCH(TODAY(),A4:A31)),"Y")

        • Hello Steve!
          The data ranges that you use in the COUNTIFS function must be the same in size. That is, if the first is 1 column, then the second is also 1 column. And you have a second range - 12 columns.
          Please try the following formula:

          =SUMPRODUCT(--(($A$1:$A$21)=TODAY()), (C1:C21="Y")+(D1:D21="Y")+(E1:E21="Y"))

          Add it yourself to column N.
          I hope it’ll be helpful.

  36. francesca says:

    Hi!!
    Thank you so much for your help. I am trying to do a COUNTIFS with multiple criteria. I tried using SUM(COUNTIFS and it did work in the beg but now I need to add more criteria. What I am pretty much trying to do is to put the following formula into ONE - the first part searches for MPS[Warehouse] "AAA" and the second for "BBB".
    =SUM(COUNTIFS(MPS[Work Ticket Status], {"NEW","MRD","PRD","PIC","PUR"}, MPS[Warehouse], {"AAA"}, MPS[NEW Production Start Date], ">=5/1/2020", MPS[NEW Production Start Date], "<"&TODAY(),MPS[NEW Production Start Date], "=5/1/2020", MPS[NEW Production Start Date], "<"&TODAY(),MPS[NEW Production Start Date], "<=5/30/2020"))

    - BECAUSE the next thing I need to do is to use this formula to count the ones that are NOT "AAA" or "BBB" and that is the real problem begin! (In fact I have more than just 2 warehouses, this was just an example).

    • Hello Francesca!
      You can use something like this formula.

      =SUM(COUNTIFS(A19:A25,{"NEW","MPD","PRD","PIC","PUR"}, B19:B25,{"AAA","BBB"}, C19:C25,">=5/1/2020", C19:C25,"< "&TODAY(), C19:C25,"<=5/30/2020"))

    • There is an error in your formula.
      Conditions
      MPS [NEW Production Start Date], “> = 5/1/2020”
      and
      MPS [NEW Production Start Date], "= 5/1/2020”
      contradict each other.
      It will be executed only
      MPS [NEW Production Start Date], "= 5/1/2020”.
      Condition
      MPS [NEW Production Start Date], “< " & TODAY () repeated twice.

    • I hope this will help, otherwise please do not hesitate to contact me anytime.

  • Juan Romo says:

    Hello , I'm trying to count a name that is in another column with certain date range and count only the names that have a text in another column , could you please help with what formula to use.

    • Hello Juan Romo!
      I’m sorry but your task is not entirely clear to me.
      For me to be able to help you better, please describe your task in more detail. Please let me know in more detail what you were trying to find. It’ll help me understand it better and find a solution for you. Thank you.

  • Gangainathan says:

    I need a formula for counting the number of columns in a row with values greater than 5.
    Ex. Out of Column B , D , G - B1 & G1 has the value greater than 5, so I need to get count as 2.. How is it possible.

  • TopSnipe says:

    I am trying count the number of assets in a given location within a given range of operating hours. I have successfully used "=countifs($F:$F,"EVT",$G:$G,",9999.9"). My problem is determining the formula for counting the number of assets with operating hours between 10000 and 19999.9 hours. Thanks.

    • Hello!
      I’m sorry but your task is not entirely clear to me.
      Your formula cannot work. There may have been an error copying it. Please let me know in more detail what you were trying to find, what formula you used and what problem or error occurred. Give an example of the source data and the expected result. It’ll help me understand it better and find a solution for you. Thank you.

  • James says:

    Hi,

    I have some problem getting the formula for my excel file. it took me to much time to solve it even now i cant figure it out. i dont have really much knowledge on excel though. would you mind helping me to create a formula to condense all equal date with another criteria.Example columnA(Dates) columnB(text).To make it more clearer. All May 5,2020 in column A and technical in column B will be count as one.

  • Susan says:

    Hi,
    I'm doing a race night and want to write the names of all the people who have placed a bet in one cell. In another column I then want to count number of the names in the first cell.
    Eg. (Tom,Dick,Harry) count = 3
    Is there a formula that could do this please?

  • Furqan says:

    Hi. I have a query.
    I want to count how many times a certain thing was came among 2 columns, with two conditions.
    Eg.
    A= aa as ad af
    B= 12 21 22 13
    C= Dates day wise

    I wanna count how many times AS was with 12 condition at a certain date from C.....

    Anyone can help?

    • Hello!
      I hope you have studied the recommendations in the above tutorial. Please specify detailed and accurate what you were trying to find, what formula you used and what problem or error occurred. It’ll help me understand the problem you faced better and help you.

  • Saritha says:

    Hi,
    I need to use the countifs function where the reference range are values extracted through a formula. I do not want to change the reference value from formula to values. Could you help!

    Thanks in advance!

    • Hello!
      I’m sorry but your task is not entirely clear to me. For me to be able to help you better, please describe your task in more detail. Please specify what you were trying to find, what formula you used and what problem or error occurred. Give an example of the source data and the expected result.
      It’ll help me understand it better and find a solution for you. Thank you.

  • Jo says:

    Hi, I have a spreadsheet which has multiple dates in it, as well as multiple locations. It is for commencement of employees and tracking of probations.
    There is a column for locations, as well as a column for programmed start date, actual start date, programmed completion date and actual completion date. I am tracking to identify one month late and three months late for both start and finish for all four locations. The current formula I am trying is: =COUNTIFS(Table4[OPU],"Cq",Table4[Probation Start Due Date],(DAYS(Table4[Probation Start Due Date],Table4[Probation Commenced]>30))), however it is not identifying any data. I would really appreciate some help.. cheers, Jo

  • John says:

    Hi
    I'm trying to set up spreadsheet for my darts team that records players' stats.I record their averages, high score and number of scores between set criteria, (ie, total number of scores below 19, 20-39, 40-59, etc.)
    I need a formula to reference the player with their scores, within three or more games, so I don't have to do each separately
    I hope this makes sense?
    Best regards
    John

    • Hello John!
      I’m sorry but your task is not entirely clear to me.
      Please describe your problem in more detail. Include an example of the source data and the result you want to get. It’ll help me understand your request better and find a solution for you. Thank you.

  • jibade says:

    please i have data set like
    84
    9
    65
    85
    41
    33
    20
    20
    86
    25
    40
    45
    36
    82
    2
    18
    36
    66
    19
    51
    63
    71
    35
    31
    42
    all i want to do is to get count for the first numbers only thanks!

  • Vinayak Patil says:

    Hi Could you please help me on how to count specific letter from all ODD column or even column?

    • Hello!
      I’m sorry but your task is not entirely clear to me. For me to be able to help you better, please describe your task in more detail. Please specify what you were trying to find, what formula you used and what problem or error occurred. Give an example of the source data and the expected result.
      It’ll help me understand it better and find a solution for you. Thank you.

  • Susan Miller says:

    Ive got the syntax working for a single column

    =COUNTIFS($C:$C,"*Mon*" & "*Jan*",$D:$D,1)

    which gives me Mon, Jan, Employee 1

    now I want to do
    =COUNTIFS($C:$C,"*Mon*" & "*Jan*",

    Mon, Jan, employee 2

    $D:$E,1)

    so Im now looking in two columns D:E for employee 2, but the syntax wont work. Any help please

  • Dhar says:

    Hi, how to add any number to existing countif function. By automatically like countif(c1:g1,c82+2)

  • Wayne Nimblette says:

    Hi,I'm trying to use countifs statement to add 3 certain elements of a table if all are present.

    My formula is =COUNTIFS(O24:O31,U24,P24:P31,AA36,J24:J30,AA36)

    O23:O31 holds Yes/No

    P24:P31 holds a number value

    J24:J30 holds a number value

    I'm happy with the ranges and the criteria are set values.

    The formula works if you have any two elements i.e O24:O31 and J24:J30 or J24:J30 and P24:P30 however once i add the third element it does work.

    any help would be appreciated

  • aimee says:

    Hi,

    I want to count how many times the value = "yes" in column F on data sheet.

    this is fine, however, I want this to be date dependent criteria.

    Count how many times "yes" appears within a date range specified on reporting sheet, G8 (start date) & J8 (end date).

    The corresponding date for "Yes" column is in "g3" on the data sheet.

    I currently have:
    COUNTIFS(Data!F3:F68, "Yes") + COUNTIFS(Data!G3:G61,">="&Reporting!G8,Data!G3:G61,"<="&Reporting!J8)

    But this is counting how many times "yes" appears AND how many times the date appears which is duplicating my data.

    Thank you, Hope that makes sense!

  • SD says:

    My queson is to display the last entered number position and that will automatically change the value in another cell.
    If suppose, in a column Sr.No. 1,2,3,4,5,6,7 now the last no. is 7 if I enter 8,9,10,...the another which is having the reference will catch the latest entry inthis case 10 and update his cell value.

  • Sangami says:

    Hi,

    I have two columns with huge number of data in it. Coulmn A has the list of applications and Column has the list of servers. Each application hits different servers . Want to know on the count of application per server using a formula.

  • Ant Taylor says:

    Hi
    I have a data set where in row 2 I have headings of "Squad", "Mins", "Goals", "Assists" and these repeat several times across the row. I'm trying to find a formula which counts the number cells under any of the "Mins" columns which are greater than 0, but only when the number in the "Squad" column is greater than 11.
    I can do a simple count of the first part (=COUNTIFS($N$2:$KG$2,"Mins",N41:KG41,">0") however I am unsure how to add the second part to only count this IF $N$2:$KG$2,"Squad",N41:KG41,">11".

    Have you got any thoughts about how I can add this IF element? I have tried a few combinations but the best i get is a #VALUE! error. Any help much appreciated.

  • Abdullah says:

    Hi,
    Can you provide your help regarding a specific formula:
    I want to do a calculation in which I want to exclude character which lies in a sequence.
    For example. I have 10 numbers: 1, 3, 5, 10, 2000, 2001, 2002, 3052, 3053, 3054.
    Now, I want to count 1 and ignore 3, 5, 10 mean to ignore the up to 10 number in consective orders. Similiartly I want to count just 2001 and 3052 and want to ignore other number from counting. I have to do this calculation in up to 100K.
    If you provide your help I will be very thankful.
    Best
    Abdullah

  • Adam says:

    Hello
    I have a table of data, on column of which is either ***, ** or * depending on the prioritisation of that row. If I now want to do a countifs function, how would I insert a condition that a row has *** for that specific criteria? I tried using a tilde, " " but cant get it right
    Thanks!

    Adam

  • Adam Bastin says:

    Hi Alexander
    Thanks - that works perfectly!
    Adam

  • Arie says:

    Hello,
    I am in need of assistance locating the right formula for my workbook.
    in sheet1-I have a list of names, with a current fourmula " =COUNTIF('Element Core'!A2:A500,'Agent Assignment'!D41)" to capture how much data from each tab they are assigned too.
    In sheet2-Shows the actual amount of cells each agent has been assigned to in column A, i would like to somehow divide the completed task in column B of sheet 2 to the total number they have been assigned to in sheet 1.
    example
    agent Name - # of cells Assigned too(from sheet 2)
    Tom Jerry - 40
    I would like to divide 40 by what the agent has already completed in sheet2 on column B.

    Thank you.

    • Hello!
      If I understand correctly, then you just need to divide the values from column A by the values from column B. I suppose that the number of completed tasks can be calculated with approximately the same formula as the number of assigned tasks. But there is no information in your question about this.
      Please describe your problem in more detail. It’ll help me understand it better and find a solution for you.

  • Dr Sajith Kumar says:

    In a range, is there any formula where i can pick

    how many 1s, how many 2s, how many 3s etc... in one step

  • Jenn A says:

    I am trying to count the new number of impacted individuals for today (prefer, workdays), I also have a number of other criteria. This is the current formula I use to use to count the total number =COUNTIFS(AN2,"=*?*",P2,"=No",D2,"=Reserve"). I would like a way to count only the new ones added today. I have a entry date column in J2.

    Thanks in advance

  • md.Shamchur Rahman says:

    Excellent Example

  • Post a comment



    Thank you for your comment! When posting a question, please be very clear and concise. This will help us provide a quick and relevant solution to your query. We cannot guarantee that we will answer every question, but we'll do our best :)
    60+ professional tools for Excel
    60+ professional tools for Excel
    2019–2007 to do your daily work
    Incredible product, even better tech support…AbleBits totally delivers!
    Deborah Bryant
    Anyone who works with Excel is sure to find their work made easier
    Jackie Lee
    The best spent money on software I've ever spent!
    Patrick Raugh
    Ablebits is a fantastic product - easy to use and so efficient.
    Debra Celmer
    Excel is at its best now
    Annie C.
    I don't know how to thank you enough for your Excel add-ins
    Jennifer Morningstar
    Anybody who experiences it, is bound to love it!
    Kumar Nepa
    AbleBits suite has really helped me when I was in a crunch!
    Nelda Fink
    I have enjoyed every bit of it and time am using it
    Christian Onyekachi Nwosu
    It's the best $100 we've ever spent!
    Mike Cavanagh
    I love the program, and I can't imagine using Excel without it!
    Robert Madsen
    One word… WOW!
    Dave Brown
    Love the products!
    David Johnston
    It is like having an expert at my shoulder helping me…
    Linda Shakespeare
    Your software really helps make my job easier
    Jeannie C.
    Thanks for a terrific product that is worth every single cent!
    Dianne Young
    I love your product
    Brad Gibson
    Awesome!!!
    Sheila Blanchard