by Microsoft Excel provides several functions purposed for counting different kinds of cells, such as blanks or non-blanks, with number, date or text values, containing specific words or character, etc.
In this article, we will focus on the Excel COUNTIF function that is purposed for counting cells with the condition you specify. First, we will briefly cover the syntax and general usage, and then I provide a number of examples and warn about possible quirks when using this function with multiple criteria and specific types of cells.
In essence, COUNTIF formulas are identical in all Excel versions, so you can use the examples from this tutorial in Excel 365, 2021, 2019, 2016, 2013, 2010 and 2007.
COUNTIF function in Excel - syntax and usage
Excel COUNTIF function is used for counting cells within a specified range that meet a certain criterion, or condition.
For example, you can write a COUNTIF formula to find out how many cells in your worksheet contain a number greater than or less than the number you specify. Another typical use of COUNTIF in Excel is for counting cells with a specific word or starting with a particular letter(s).
The syntax of the COUNTIF function is very simple:
As you see, there are only 2 arguments, both of which are required:
- range - defines one or several cells to count. You put the range in a formula like you usually do in Excel, e.g. A1:A20.
- criteria - defines the condition that tells the function which cells to count. It can be a number, text string, cell reference or expression. For instance, you can use the criteria like these: "10", A2, ">=10", "some text".
And here is the simplest example of Excel COUNTIF function. What you see in the image below is the list of the best tennis players for the last 14 years. The formula =COUNTIF(C2:C15,"Roger Federer") counts how many times Roger Federer's name is on the list:
Note. A criterion is case insensitive, meaning that if you type "roger federer" as the criteria in the above formula, this will produce the same result.
Excel COUNTIF function examples
As you have just seen, the syntax of the COUNTIF function is very simple. However, it allows for many possible variations of the criteria, including wildcard characters, the values of other cells, and even other Excel functions. This diversity makes the COUNTIF function really powerful and fit for many tasks, as you will see in the examples that follow.
COUNTIF formula for text and numbers (exact match)
In fact, we discussed the COUNTIF function that counts text values matching a specified criterion exactly a moment ago. Let me remind you that formula for cells containing an exact string of text: =COUNTIF(C2:C15,"Roger Federer"). So, you enter:
- A range as the first parameter;
- A comma as the delimiter;
- A word or several words enclosed in quotes as the criteria.
Instead of typing text, you can use a reference to any cell containing that word or words and get absolutely the same results, e.g. =COUNTIF(C1:C9,C7).
Similarly, COUNTIF formulas work for numbers. As shown in the screenshot below, the below formula perfectly counts cells with quantity 5 in Column D:
=COUNTIF(D2:D9, 5)
In this article, you will find a few more formulas to count cells that contain any text, specific characters or only filtered cells.
COUNTIF formulas with wildcard characters (partial match)
In case your Excel data include several variations of the keyword(s) you want to count, then you can use a wildcard character to count all the cells containing a certain word, phrase or letters as part of the cell's contents.
Suppose, you have a list of tasks assigned to different persons, and you want to know the number of tasks assigned to Danny Brown. Because Danny's name is written in several different ways, we enter "*Brown*" as the search criteria =COUNTIF(D2:D10, "*Brown*").
An asterisk (*) is used to find cells with any sequence of leading and trailing characters, as illustrated in the above example. If you need to match any single character, enter a question mark (?) instead, as demonstrated below.
Tip. It is also possible to use wildcards with cell references with the help of the concatenation operator (&). For example, instead of supplying "*Brown*" directly in the formula, you can type it in some cell, say F1, and use the following formula to count cells containing "Brown": =COUNTIF(D2:D10, "*"&F1&"*")
Count cells beginning or ending with certain characters
You can use either wildcard character, asterisk (*) or question mark (?), with the criterion depending on which exactly result you want to achieve.
If you want to know the number of cells that start or end with certain text no matter how many other characters a cell contains, use these formulas:
=COUNTIF(C2:C10,"Mr*") - count cells that begin with "Mr".
=COUNTIF(C2:C10,"*ed") - count cells that end with the letters "ed".
The image below demonstrates the second formula in action:
If you are looking for a count of cells that start or end with certain letters and contain the exact number of characters, you use the Excel COUNTIF function with the question mark character (?) in the criteria:
=COUNTIF(D2:D9,"??own") - counts the number of cells ending with the letters "own" and having exactly 5 characters in cells D2 through D9, including spaces.
=COUNTIF(D2:D9,"Mr??????") - counts the number of cells starting with the letters "Mr" and having exactly 8 characters in cells D2 through D9, including spaces.
Tip. To find the number of cells containing an actual question mark or asterisk, type a tilde (~) before the ? or * character in the formula. For example, =COUNTIF(D2:D9,"*~?*") will count all cells containing the question mark in the range D2:D9.
Excel COUNTIF for blank and non-blank cells
These formula examples demonstrate how you can use the COUNTIF function in Excel to count the number of empty or non-empty cells in a specified range.
COUNTIF not blank
In some Excel COUNTIF tutorials and other online resources, you may come across formulas for counting non-blank cells in Excel similar to this one:
=COUNTIF(A1:A10,"*")
But the fact is, the above formula counts only cells containing any text values including empty strings, meaning that cells with dates and numbers will be treated as blank cells and not included in the count!
If you need a universal COUNTIF formula for counting all non-blank cells in a specified range, here you go:
Or
This formula works correctly with all value types - text, dates and numbers - as you can see in the screenshot below.
COUNTIF blank
If you want the opposite, i.e. count blank cells in a certain range, you should adhere to the same approach - use a formula with a wildcard character for text values and with the "" criteria to count all empty cells.
Formula to count cells not containing any text:
Since an asterisk (*) matches any sequence of text characters, the formula counts cells not equal to *, i.e. not containing any text in the specified range.
Universal COUNTIF formula for blanks (all value types):
The above formula correctly handles numbers, dates and text values. For example, here's how you can get the number of empty cells in the range C2:C11:
=COUNTIF(C2:C11,"")
Please be aware that Microsoft Excel has another function for counting blank cells, COUNTBLANK. For instance, the following formulas will produce exactly the same results as the COUNTIF formulas you see in the screenshot above:
Count blanks:
=COUNTBLANK(C2:C11)
Count non-blanks:
=ROWS(C2:C11)*COLUMNS(C2:C11)-COUNTBLANK(C2:C11)
Also, please keep in mind that both COUNTIF and COUNTBLANK count cells with empty strings that only look blank. If you do not want to treat such cells as blanks, use "=" for criteria. For example:
=COUNTIF(C2:C11,"=")
For more information about counting blanks and not blanks in Excel, please see:
COUNTIF greater than, less than or equal to
To count cells with values greater than, less than or equal to the number you specify, you simply add a corresponding operator to the criteria, as shown in the table below.
Please pay attention that in COUNTIF formulas, an operator with a number are always enclosed in quotes.
| Criteria | Formula Example | Description |
|---|---|---|
| Count if greater than | =COUNTIF(A2:A10,">5") | Count cells where value is greater than 5. |
| Count if less than | =COUNTIF(A2:A10,"<5") | Count cells with values less than 5. |
| Count if equal to | =COUNTIF(A2:A10,"=5") | Count cells where value is equal to 5. |
| Count if not equal to | =COUNTIF(A2:A10,"<>5") | Count cells where value is not equal to 5. |
| Count if greater than or equal to | =COUNTIF(C2:C8,">=5") | Count cells where value is greater than or equal to 5. |
| Count if less than or equal to | =COUNTIF(C2:C8,"<=5") | Count cells where value is less than or equal to 5. |
You can also use all of the above formulas to count cells based on another cell value, you will just need to replace the number in the criteria with a cell reference.
Note. In case of a cell reference, you have to enclose the operator in quotes and add an ampersand (&) before the cell reference. For example, to count cells in the range D2:D9 with values greater than a value in cell D3, you use this formula =COUNTIF(D2:D9,">"&D3):
If you want to count cells that contain an actual operator as part of the cell's contents, i.e. the characters ">", "<" or "=", then use a wildcard character with the operator in the criteria. Such criteria will be treated as a text string rather than a numeric expression. For example, the formula =COUNTIF(D2:D9,"*>5*") will count all cells in the range D2:D9 with contents like this "Delivery >5 days" or ">5 available".
Using Excel COUNTIF function with dates
If you want to count cells with dates that are greater than, less than or equal to the date you specify or date in another cell, you proceed in the already familiar way using formulas similar to the ones we discussed a moment ago. All of the above formulas work for dates as well as for numbers. Let me give you just a few examples:
| Criteria | Formula Example | Description |
|---|---|---|
| Count dates equal to the specified date. | =COUNTIF(B2:B10,"6/1/2014") | Counts the number of cells in the range B2:B10 with the date 1-Jun-2014. |
| Count dates greater than or equal to another date. | =COUNTIF(B2:B10,">=6/1/2014") | Count the number of cells in the range B2:B10 with a date greater than or equal to 6/1/2014. |
| Count dates greater than or equal to a date in another cell, minus x days. | =COUNTIF(B2:B10,">="&B2-"7") | Count the number of cells in the range B2:B10 with a date greater than or equal to the date in B2 minus 7 days. |
Apart from these common usages, you can utilize the COUNTIF function in conjunction with specific Excel Date and Time functions such as TODAY() to count cells based on the current date.
| Criteria | Formula Example |
|---|---|
| Count dates equal to the current date. | =COUNTIF(A2:A10,TODAY()) |
| Count dates prior to the current date, i.e. less than today. | =COUNTIF(A2:A10,"<"&TODAY()) |
| Count dates after the current date, i.e. greater than today. | =COUNTIF(A2:A10,">"&TODAY()) |
| Count dates that are due in a week. | =COUNTIF(A2:A10,"="&TODAY()+7) |
| Count dates in a specific date range. | =COUNTIF(B2:B10, ">=6/1/2014")-COUNTIF(B2:B10, ">6/7/2014") |
Here is an example of using such formulas on real data (at the moment of writing today was 25-Jun-2014):
Excel COUNTIF with multiple criteria
In fact, Excel COUNTIF function is not exactly designed to count cells with multiple criteria. In most cases, you'd use its plural counterpart, the COUNTIFS function to count cells that match two or more criteria (AND logic). However, some tasks can be solved by combining two or more COUNTIF functions in one formula.
Count values between two numbers
One of the most common applications of Excel COUNTIF function with 2 criteria is counting numbers within a specific range, i.e. less than X but greater than Y. For example, you can use the following formula to count cells in the range B2:B9 where a value is greater than 5 and less than 15.
=COUNTIF(B2:B9,">5")-COUNTIF(B2:B9,">=15")
How this formula works:
Here, we use two separate COUNTIF functions - the first one finds out how many values are greater than 5 and the other one gets a count of values greater than or equal to 15. Then, you subtract the latter from the former and get the desired result.
Count cells with multiple OR criteria
In situations when you want to get several different items in a range, add 2 or more COUNTIF functions together. Supposing, you have a shopping list and you want to find out how many soft drinks are included. To have it done, use a formula similar to this:
=COUNTIF(B2:B13,"Lemonade")+COUNTIF(B2:B13,"*juice")
Please pay attention that we've included the wildcard character (*) in the second criterion, it is used to count all kinds of juice on the list.
In the same manner, you can write a COUNTIF formula with several conditions. Here is an example of the COUNTIF formula with multiple OR conditions that counts lemonade, juice and ice cream:
=COUNTIF(B2:B13,"Lemonade") + COUNTIF(B2:B13,"*juice") + COUNTIF(B2:B13,"Ice cream")
For other ways to count cells with OR logic, please see this tutorial: Excel COUNTIF and COUNTIFS with OR conditions.
Using COUNTIF function to find duplicates and unique values
Another possible usage of the COUNTIF function in Excel is for finding duplicates in one column, between two columns, or in a row.
Example 1. Find and count duplicates in 1 column
For example, this simple formula =COUNTIF(B2:B10,B2)>1 will spot all duplicate entries in the range B2:B10 while another function =COUNTIF(B2:B10,TRUE) will tell you how many dupes are there:
Example 2. Count duplicates between two columns
If you have two separate lists, say lists of names in columns B and C, and you want to know how many names appear in both columns, you can use Excel COUNTIF in combination with the SUMPRODUCT function to count duplicates:
=SUMPRODUCT((COUNTIF(B2:B1000,C2:C1000)>0)*(C2:C1000<>""))
We can even take a step further and count how many unique names there are in Column C, i.e. names that do NOT appear in Column B:
=SUMPRODUCT((COUNTIF(B2:B1000,C2:C1000)=0)*(C2:C1000<>""))
Tip. If you want to highlight duplicate cells or entire rows containing duplicate entries, you can create conditional formatting rules based on the COUNTIF formulas, as demonstrated in this tutorial - Excel conditional formatting formulas to highlight duplicates.
Example 3. Count duplicates and unique values in a row
If you want to count duplicates or unique values in a certain row rather than a column, use one of the below formulas. These formulas might be helpful, say, to analyze the lottery draw history.
Count duplicates in a row:
=SUMPRODUCT((COUNTIF(A2:I2,A2:I2)>1)*(A2:I2<>""))
Count unique values in a row:
=SUMPRODUCT((COUNTIF(A2:I2,A2:I2)=1)*(A2:I2<>""))
Excel COUNTIF - frequently asked questions and issues
I hope these examples have helped you to get a feel for the Excel COUNTIF function. If you've tried any of the above formulas on your data and were not able to get them to work or are having a problem with the formula you created, please look through the following 5 most common issues. There is a good chance that you will find the answer or a helpful tip there.
1. COUNTIF on a non-contiguous range of cells
Question: How can I use COUNTIF in Excel on a non-contiguous range or a selection of cells?
Answer: Excel COUNTIF does not work on non-adjacent ranges, nor does its syntax allow specifying several individual cells as the first parameter. Instead, you can use a combination of several COUNTIF functions:
Wrong: =COUNTIF(A2,B3,C4,">0")
Right: =COUNTIF(A2,">0") + COUNTIF(B3,">0") + COUNTIF(C4,">0")
An alternative way is using the INDIRECT function to create an array of ranges. For example, both of the below formulas produce the same result you see in the screenshot:
=SUM(COUNTIF(INDIRECT({"B2:B8","D2:C8"}),"=0"))
=COUNTIF($B2:$B8,0) + COUNTIF($C2:$C8,0)
2. Ampersand and quotes in COUNTIF formulas
Question: When do I need to use an ampersand in a COUNTIF formula?
Answer: It is probably the trickiest part of the COUNTIF function, which I personally find very confusing. Though if you give it some thought, you'll see the reasoning behind it - an ampersand and quotes are needed to construct a text string for the argument. So, you can adhere to these rules:
If you use a number or a cell reference in the exact match criteria, you need neither ampersand nor quotes. For example:
=COUNTIF(A1:A10,10)
or
=COUNTIF(A1:A10,C1)
If your criteria includes text, wildcard character or logical operator with a number, enclose it in quotes. For example:
=COUNTIF(A2:A10,"lemons")
or
=COUNTIF(A2:A10,"*") or =COUNTIF(A2:A10,">5")
In case your criteria is an expression with a cell reference or another Excel function, you have to use the quotes ("") to start a text string and ampersand (&) to concatenate and finish the string off. For example:
=COUNTIF(A2:A10,">"&D2)
or
=COUNTIF(A2:A10,"<="&TODAY())
If you are in doubt whether an ampersand is needed or not, try out both ways. In most cases an ampersand works just fine, e.g. both of the below formulas work equally well.
=COUNTIF(C2:C8,"<=5")
and
=COUNTIF(C2:C8,"<="&5)
3. COUNTIF for formatted (color coded) cells
Question: How do I count cells by fill or font color rather than by values?
Answer: Regrettably, the syntax of the Excel COUNTIF function does not allow using formats as the condition. The only possible way to count or sum cells based on their color is using a macro, or more precisely an Excel User-Defined function. You can find the code working for cells colored manually as well as for conditionally formatted cells in this article - How to count and sum Excel cells by fill and font color.
4. #NAME? error in the COUNTIF formula
Issue: My COUNTIF formula throws a #NAME? error. How can I get it fixed?
Answer: Most likely, you have supplied an incorrect range to the formula. Please check out point 1 above.
5. Excel COUNTIF formula not working
Issue: My COUNTIF formula is not working! What have I done wrong?
Answer: If you have written a formula which is seemingly correct but it does not work or produces a wrong result, start by checking the most obvious things such as a range, conditions, cell references, use of ampersand and quotes.
Be very careful with using spaces in a COUNTIF formula. When creating one of the formulas for this article I was on the verge of pulling my hair out because the correct formula (I knew with certainty it was right!) wouldn't work. As it turned out, the problem was in a measly space somewhere in between, argh... For instance, look at this formula:
=COUNTIF(B2:B13," Lemonade").
At first sight, there is nothing wrong about it, except for an extra space after the opening quotation mark. Microsoft Excel will swallow the formula just fine without an error message, warning or any other indication, assuming you really want to count cells containing the word 'Lemonade' and a leading space.
If you use the COUNTIF function with multiple criteria, split the formula into several pieces and verify each function individually.
And this is all for today. In the next article, we will explore several ways to count cells in Excel with multiple conditions. Hope to see you next week and thanks for reading!
1038 comments
Is it possible to use countif function in whitch criteria is text in comment attached to the cell?
Greetings, Svetlana!
First let me tell you how impressed I am with the clarity of your explanations. Your written English is more lucid than that of most native speakers— seriously! My hat’s off!
Let me try to explain what I want to do here, and please bear in mind that I’m a novice.
I’m in the midst of trying to create a calculator in Excel (2010) that will enable our sales support personnel in a large financial services brokerage agency to efficiently and accurately return guaranteed/non-guaranteed lifetime annual income results from our brokered line of fixed indexed annuity products, given varied investment input, and each product’s individual growth and payout parameters. This would allow us to give very accurate and definitive advice to our contracted agents about which annuity contracts would be most appropriate for given clients.
The four unwieldy IF/AND statements which are copied and pasted below result from each of 4 possible value output combinations obtained from two binary decision points (which are interfaced with two independent groups of two form control radio buttons). I have tested each of the four IF/AND statements separately and they return correct output.
1)
IF(AND(F2=1,I2=1,C5<=44),"NA",IF(C5<=54,0.040,IF(C5<=59,0.045,IF(C5<=64,0.050,IF(C5<=69,0.055,IF(C5<=74,0.060,IF(C5=80,0.070))))))))
2)
IF(AND(F2=2,I2=1,C5<=44),"NA",IF(C5<=54,0.035,IF(C5<=59,0.040,IF(C5<=64,0.045,IF(C5<=69,0.050,IF(C5<=74,0.055,IF(C5=80,0.065))))))))
3)
IF(AND(F2=1,I2=2,C5<=44),"NA",IF(C5<=54,0.030,IF(C5<=59,0.035,IF(C5<=64,0.040,IF(C5<=69,0.045,IF(C5<=74,0.045,IF(C5=80,0.055))))))))
4)
IF(AND(F2=2,I2=2,C5<=44),"NA",IF(C5<=54,0.025,IF(C5<=59,0.030,IF(C5<=64,0.035,IF(C5<=69,0.040,IF(C5<=74,0.050,IF(C5=80,0.060))))))))
Let me add that each successive statement after the first simply reduces each of the whole series of nested IF outputs by .05.
Here are my two questions with regard to all the foregoing:
1) How do I integrate the four IF/AND statements into a single statement that will correctly function in concert with the radio buttons and return a single correct output?
2) Does Excel provide some function or other way of reducing the complexity of the nested IF statements?
If you can help me with those questions, I’d be much obliged.
With kind regards,
Bill Hunter
Hello Bill,
Thank you very much for your kind words! For me to understand the task better, please reply to my email with a small sample of your data, formulas and expected results. (I've removed your email address from this blog for security reasons).
When are you gonna add windows 11
Thank you!
… Here is what I am trying to do:
=COUNTIF(H1179:H3396,TODAY())
This is my current formula I use to determine how many units are processed for the day…Fortunately / Unfortunately I processed 87 installs yesterday from 3 ICSB locations so my formula doesn’t provide me with a quick answer to Marks daily question of “How many do we have done today” so I sit here and count them manually soooo I want to add to it:
(D1179:D3396,”Carol Stream”)
Basically I want a formula that I can utilize for each location that only counts the installs done for that location and not all installs done within a range that are dated for TODAY.
If you can help it would be appreciated!!
Thanks
Good day all hope someone can help me
ok here it goes hope it makes sense
I need a line written for a worksheet of mine that does the following
i have items that are being sold call it a orange
then i have a date that it has been delivered
now what i want to be able to do is have excel calculate how many of oranges how many apples how many grapes etc. there are 7 different items that i have still needs to be delivered based on a text insert "to be delivered"
Thanks let me know hope this is enough info
Hello,
I want to know formula to count cells that does not contain some values...more than one.
Hi,
I have a spreadsheet where I want to count yields on investments between various rates (i.e. >=1% and 1")-countif(p8:p29,">2").
this returns 0.00%. Please advise. Thanks!!
Please suggest formula -
If in Column A I have names (Names are repeating) & In Column B Status against name like Yes & No.
So If I want to count how many Yes are there against any particular name than how to do it. Pls help
Hello,
assuming, that you want to count "Yes" against "Peter" use the following formula:
=COUNTIFS(A:A,"Peter",B:B,"Yes")
Just replace the name in the formula with the one from your data.
Hop it helps!
Thank you so much. Incredibly helpful!
Dear World,
Good Morning :)
I have a question on countif formula ... as a example
1. G-SS102C193-4E58-14-135
2. TR036C216E53-18-140
3. G-SS101RET-18E49-23-145
i need to know the formula for count if there is " number -number "
as example numver "1", in center of full txt there is "C193-4", i need the furmula to find cells with finding number-number formula .. if you see number"3" example. there is "word-number", i could fiqiur out to use search formula .. but i need furmula for counting or searching cells with " number-number ".
Waiting for answer if anyone can help me please...
Best Regards,
Reza Peiravi.
part number call out no. Qty
nas 15
nas 15
nas 15
pvb 25
pvb 25
tvs 35
tvs 35
xl 40
xl 40
xl 40
I have callout number for each part. How to use countif formula in excel to count number of callout. Would like something like below.
part number call out no. Qty
nas 15 3
nas 15
nas 15
pvb 25 2
pvb 25
tvs 35 2
tvs 35
xl 40 3
xl 40
xl 40
Hi!
I have Col A containing "Problem Ticket Opening time", (e.g. 2017-04-05 19:20:04), Col B containing "Problem Ticket Closing time", (e.g. 2017-04-09 12:52:10) and Col C the Customer Name having the problem/ticket (e.g. Mr John Smith). Think of 3,000 rows and think that the same customer has repeated tickets. Sometimes tickets for the same customer repeat every few days (which i dont mind to count) BUT sometimes the customer (Mr Smith) calls today for a problem and calls AGAIN tomorrow (within 24hours).
This is something i want to record within a month:
E.G. Mr Smith created 5 tickets that were under 24hours gap.
I am still trying to work out the logic. HINT which could be useful: I have managed to convert all times in Col A and B in Year Days (e.g. 31/3/2017 is day number 91).
I am stuck...
I have 40 students, I wanna use COUNTIF to know how many students got from 7 to 7.9. I wrote it like this. +countif(a2:a41;">=7"&"<7.9") is it correct?
Thanks in advance!
No it should be
=COUNTIF(A2:A14,">7")-COUNTIF(A2:A14,">7.9")
This should give you the answer
=COUNTIF(a2:a41,">7")-COUNTIF(a2:a41,">7.9")
There's another function that allows multiple criteria - COUNTIFS. Try this:
=COUNTIFS(A2:A41, ">=7", A2:A41, "<=7.9")
Hi!
I have a spreadsheet with columns A and B. In column A is new results, in column B is old results. I need to count the number of occurances where the value in column A is greater than the corresponding value in the same row of column B.
I have tried using
=COUNTIF(A2:A100,">"&B2:B100)but it always returns 0 even though there are many instances of an A value being different than the corresponding B value
I also tried =COUNTIF(A2:A100,">"&B2)But that returns the number of A values greater than B2 specifically instead of the corresponding B Value of the same row.
Please Help!!!
Hi, Kate,
SUM function will solve your problem, try this:
=SUM(--(A1:A4>B1:B4))
Finish entering the formula by pressing CTRL + SHIFT + ENTER instead of just Enter.
Another option is:
=SUMPRODUCT(--(A1:A4>B1:B4))
Hi!... well i want to know that if we have Date sheet of something issuance of inventory and now we want to sort that some one code or person how many times have issued the inventory how should we formulate this data.. actually i know the way of "Filter & the way of "Find" i m trying to formulate this data that i putt name or code in any specimen cell and got detail of all issuance times .. still confused and trying to find .. could you please have any idea
thanks you .. tany
Hi! my current formula is COUNTIF(a1,"PCS") my prob is, if it has another text in the cell e.g PCS 1 jgp, it doesnt count as 1. what formula should i use when i wanted it to count as 1 regardless if it has other containing text for as long as it has PCS
Hi! my current formula is COUNTIF(a1,"PCS") my prob is, if it has another text in the formula, it doesnt count as 1. what formula should i use when i wanted it to count as 1 regardless if it has other containing text.
Hi
i want to if 20% then show 4 if 21% to 30% then show 6 if 31% to 80 % show 8 if 81% to 100% then show 10
how set this formula in excel please suggest me with example
Hi there...I have data that lists names of people and how many times they register per month. So Column A is a list of names and there could be multiple occurrences. If you are only supposed to register 2 times a month and i would like a way to identify by name those that registered more than 2 times a month and the frequency of times they registered. How do i do this?
Honestly, a pivot table would probably be the easiest way to do this.
if you r there i want to ask something
Hola
cuantas veces puedo utilizar la palabra "countif" en una formula para sumar un mismo valor en diferentes columnas, total de columnas (6)
ejemplo: =countif(b2:b100,"1/0")+countif(c2:c100,"1/0")..........
y muchas gracias por la ayuda que me puedan prestar.
atentamente
armando
hello
I need to count cells with specific color .
Is it possible?
How do I count multiple dates in one cell? Ex: Cell A1 contains: 2/19, 2/20, 2/21 I want cell B1 to count 3. I am using this formula =LEN(TRIM(A1))-LEN(SUBSTITUTE(TRIM(B1),",",""))+1 but when I delete the dates in Cell A1 the number 1 appears in cell B1.
i need a help regarding Countif as am keeping formula for one set of numbers which are duplicate.i need to get the count beside which is the newest like eg:12345 old one 1 should be beside
12345 new one in same row i need 2 beside.
12345 2
5236 1
52879 1
12345 1 I need to get here 2
Hi Ablebite Team,
For the "COUNTIF not blank" you wrote the formula as:
=Countif(C2:C12,""&"")
It is good but for the cells which contains the formula and the result of formula is: "" (showing blank); by using above formula the counter will count them as not blank, but we do not want to count them. Please help how to count non blank cells excluding those cells.
Thanks,
Regards
I wish to count the numbers in a column where the number to be counted is less than the number one row below it. Is there a way to to this?
Example:
Column F
f1 contains the countif or sumproduct or whatever formula
The range is F2:F72
the values in F2 on are similar to:
F2: 25
F3: 19
F4: 43
F5: 14
F6: 6
F7: 73
F8: 37
F9: 41
F10: 45
The total in this case would be 4 (F3: 19, F6: 6, F8: 37 and F9: 41)
Hi Ablebite Team,
For the "COUNTIF not blank" you wrote the formula as:
=Countif(C2:C12,""&"")
It is good but for the cells which contains the formula and the result of formula is: "" (showing empty); by using above formula the counter will count them as not blank, but we do not want to count them. Please help what to do.
Thanks,
Regards
I am trying to count unique text in a column A3 - A186. Why doesn't this work? =SUMPRODUCT((COUNTIF(A3:A186,A3:A186)=1)*(A3:A186""))
It looks like the same formula from above....
=SUMPRODUCT((COUNTIF(A2:I2,A2:I2)=1)*(A2:I2""))
I am using EXCEL 2010.
Hi, I am setting up a sheet for bookings of a holiday home. I have date of entry and departure in 2 separate columns, I want to set this up so that when entering a new booking it will not allow duplicates or come up with a warning, can anyone help with what formula to use?
Thanks
I want to find the duplication in colomn.
Tell me how to use countif formula.
Hi, i would like to know if there is a function for determining the specific number and location of spaces within a cell.
For example,
Cell A1 contains: X and cell B1 contains: X
Thank you
I appreciate any help you can give me. I have a list of names down in a column.Each name has an associated value in the column to the right of these names.-----I copy a list of names from the internet and paste them along with their values to a blank portion of the spreadsheet.These names and values are in columns but they are separated by columns of other information and are three columns to the right.The Downloaded names in the column also include additional names that I do not need and the names that I download may be in a different order each time I copy the spreadsheet.is there a formula to pick out the values next to the downloaded pasted names for only the list of names that I require on my spreadsheet.I have tried many different formulas but do not seem to get them to work. thanks
the question tells me to multiply a value and then add another value to it. How do I do this??
Having difficulty writing a COUNTIF dynamic function that correctly counts a criteria based on the last 20 entries. Get confused using the OFFSET function, which I understand is essential for a dynamic database. Here's the formula I thought would work. Please advise. Thanks!
=COUNT(OFFSET(AQ54:AQ488,COUNTIF(AQ54:AQ488,"<=-3")-20,0,20))
Hi Jamie,
the example is two row of data: headers top row, data second row
Hello,
I need som e help:
How to remove Columns where values are missing in >50% of rows?
Countblank didnt work for me. I have 30000rows, 300columns.
Thanks,
Jamie
Hi,
I'm try to count the newest month with tips over 100 dollars and stop the count when the tip drop below 100:
Column A July August Sept Oct Nov Dec
Sara 125 94 121 82 120 135
Working from Dec to July (newest to oldest month) the count would only be two, as the tips drop below 100 dollars in Oct....what formula can I use??
I would like to use countifs for Criteria_Range. My Criteria Ranges is also in between Dates Range. Can it is possible to use the Criteria Range in between along with Range in between particular Dates.
eg. If there are two products named Apple and Ball updated in sheet for month of Jan. The said product sold in a month of Jan. Both the products are mentioned in A column. I would like to know how much Apples and Balls sold within particular Weeks for month of Jan.
Kindly revert on mail.
I need to know how to transfer statistics from individual excel worksheets located in a folder to excel workbook put on sharepoint. I also need to know how to get the statistical data from each individual excel worksheet to total for each day of the month.
Thanks for your assistance.
I need to count the number of names in a single cell (example B14).
I don't want to do so by specific names since the worksheet needs to be applied to a large number of people. I have tried the formula =countif(B14,"*").
However when I enter two names in cell B14 Smith Jones it only counts it has 1 instead of two.
Does anyone know how to solve the issue.
Thx
This is for Dave...
=IF(LEN(TRIM(B33))=0,0,LEN(TRIM(B33))-LEN(SUBSTITUTE(B33," ",""))+1)...
hope it helps. if i understood your question correctly.
change the cell reference in the above function to your liking.
Thanks
P.S. Great Post on COUNTIF...
Thanks for the help
What is wrong with this formula? It produces a wrong value if zero.
=COUNTIF(B2:B86,"Not Done")
sounds like cells have 0 values
use this =COUNTIF($B$2:$B$86,"0")
or use two formulas in different cells:
1. =IF(COUNTIF($B$2:$B$86,"0"), "not done","done")
2. use this =COUNTIF($B$2:$B$86,"0")
IF THE Cells are blank then use this
=COUNTIF($B$2:$B$86,"")
ciao
I don't understand the example #1 countif with multiple criteria function. It says we want to count the numbers between 5 and 15. =COUNTIF(B2:B9,">5")-COUNTIF(B2:B9,">=15")
If we are looking at the range that is greater than 5 and less than 15, why is there an equal sign on 15 if it is suppose to be less than 15?
Hi,
what formula can I use to put the following criteria in one cell and get the cell highlighted if any one of the criteria is met.
a.) if criteria range of cell has more than 3 text
b.) the sum of text in the criteria range is more than 5
c.) if the text are togather in criteria range any blanks in them, it should be counted as ONLY one text and not multiple.
d.) Everytime a text is entered in the range of cell, the cell should count 160 cells in reverse (backwards) to count the number of text from the current entered text coloumn and not count all the text in the criteria range.
Hi. I really appreciates everyone participation in this platform. Can any one help me with a formula how to calculated if an amount is 1000 and it's for 4 people makes it 4000 but if it's more then 4 like 5, 6 or 7 get it from 1050 and calculate.
Hi Swetlana, Will you please help me to find the value for the below data:
107
107
105
255
255
15
21
22
I want to count all unique values considering with duplicate as a one value.
Hope you will help me.
Thanks for your tips!
Hi Svetlana, I have a column A and a column B which can have a Y (short for Yes) entered into either of them for each row, but cannot have the Y entered in both in a row. The purpose is to record the number of, size A (140 litres)or Size B (240 litres).
Once the size is recorded, I am also recording how full each of the containtes is. (100%, 75%, 50%, 25%) This is recorde with a simple Y within the relevant cells.
At first i did not seperate the container sizes so i was able to use the ifcount function to total each column using the following formuala(=COUNTIF(E4:E12,"Y")
Are you able to tell me how I can total the number of "Y" in each of the 100%, 75%, 50%, 25% colums but based on whether the container is size A (140 litres)or Size B (240 litres).
can anyone tell me how to sort data in multiple sheets ?
can it possible to sort multiple data same time in multiple sheet?
I am trying to format a row of cells. Its to track requirements for scouts. If 1 of cells E6:E10 is an "A", and if all of cells E11:E14 are an "A", and if cells E16:E17 are an "A", and if E18 or E19 are "A", E20 will read "C", if cell between E6:E19 is "A" than E20 will read "P", or " " if none do. I have been trying for 3 days and I keep getting errors. Can you assist?