by Microsoft Excel provides several functions purposed for counting different kinds of cells, such as blanks or non-blanks, with number, date or text values, containing specific words or character, etc.
In this article, we will focus on the Excel COUNTIF function that is purposed for counting cells with the condition you specify. First, we will briefly cover the syntax and general usage, and then I provide a number of examples and warn about possible quirks when using this function with multiple criteria and specific types of cells.
In essence, COUNTIF formulas are identical in all Excel versions, so you can use the examples from this tutorial in Excel 365, 2021, 2019, 2016, 2013, 2010 and 2007.
COUNTIF function in Excel - syntax and usage
Excel COUNTIF function is used for counting cells within a specified range that meet a certain criterion, or condition.
For example, you can write a COUNTIF formula to find out how many cells in your worksheet contain a number greater than or less than the number you specify. Another typical use of COUNTIF in Excel is for counting cells with a specific word or starting with a particular letter(s).
The syntax of the COUNTIF function is very simple:
As you see, there are only 2 arguments, both of which are required:
- range - defines one or several cells to count. You put the range in a formula like you usually do in Excel, e.g. A1:A20.
- criteria - defines the condition that tells the function which cells to count. It can be a number, text string, cell reference or expression. For instance, you can use the criteria like these: "10", A2, ">=10", "some text".
And here is the simplest example of Excel COUNTIF function. What you see in the image below is the list of the best tennis players for the last 14 years. The formula =COUNTIF(C2:C15,"Roger Federer") counts how many times Roger Federer's name is on the list:
Note. A criterion is case insensitive, meaning that if you type "roger federer" as the criteria in the above formula, this will produce the same result.
Excel COUNTIF function examples
As you have just seen, the syntax of the COUNTIF function is very simple. However, it allows for many possible variations of the criteria, including wildcard characters, the values of other cells, and even other Excel functions. This diversity makes the COUNTIF function really powerful and fit for many tasks, as you will see in the examples that follow.
COUNTIF formula for text and numbers (exact match)
In fact, we discussed the COUNTIF function that counts text values matching a specified criterion exactly a moment ago. Let me remind you that formula for cells containing an exact string of text: =COUNTIF(C2:C15,"Roger Federer"). So, you enter:
- A range as the first parameter;
- A comma as the delimiter;
- A word or several words enclosed in quotes as the criteria.
Instead of typing text, you can use a reference to any cell containing that word or words and get absolutely the same results, e.g. =COUNTIF(C1:C9,C7).
Similarly, COUNTIF formulas work for numbers. As shown in the screenshot below, the below formula perfectly counts cells with quantity 5 in Column D:
=COUNTIF(D2:D9, 5)
In this article, you will find a few more formulas to count cells that contain any text, specific characters or only filtered cells.
COUNTIF formulas with wildcard characters (partial match)
In case your Excel data include several variations of the keyword(s) you want to count, then you can use a wildcard character to count all the cells containing a certain word, phrase or letters as part of the cell's contents.
Suppose, you have a list of tasks assigned to different persons, and you want to know the number of tasks assigned to Danny Brown. Because Danny's name is written in several different ways, we enter "*Brown*" as the search criteria =COUNTIF(D2:D10, "*Brown*").
An asterisk (*) is used to find cells with any sequence of leading and trailing characters, as illustrated in the above example. If you need to match any single character, enter a question mark (?) instead, as demonstrated below.
Tip. It is also possible to use wildcards with cell references with the help of the concatenation operator (&). For example, instead of supplying "*Brown*" directly in the formula, you can type it in some cell, say F1, and use the following formula to count cells containing "Brown": =COUNTIF(D2:D10, "*"&F1&"*")
Count cells beginning or ending with certain characters
You can use either wildcard character, asterisk (*) or question mark (?), with the criterion depending on which exactly result you want to achieve.
If you want to know the number of cells that start or end with certain text no matter how many other characters a cell contains, use these formulas:
=COUNTIF(C2:C10,"Mr*") - count cells that begin with "Mr".
=COUNTIF(C2:C10,"*ed") - count cells that end with the letters "ed".
The image below demonstrates the second formula in action:
If you are looking for a count of cells that start or end with certain letters and contain the exact number of characters, you use the Excel COUNTIF function with the question mark character (?) in the criteria:
=COUNTIF(D2:D9,"??own") - counts the number of cells ending with the letters "own" and having exactly 5 characters in cells D2 through D9, including spaces.
=COUNTIF(D2:D9,"Mr??????") - counts the number of cells starting with the letters "Mr" and having exactly 8 characters in cells D2 through D9, including spaces.
Tip. To find the number of cells containing an actual question mark or asterisk, type a tilde (~) before the ? or * character in the formula. For example, =COUNTIF(D2:D9,"*~?*") will count all cells containing the question mark in the range D2:D9.
Excel COUNTIF for blank and non-blank cells
These formula examples demonstrate how you can use the COUNTIF function in Excel to count the number of empty or non-empty cells in a specified range.
COUNTIF not blank
In some Excel COUNTIF tutorials and other online resources, you may come across formulas for counting non-blank cells in Excel similar to this one:
=COUNTIF(A1:A10,"*")
But the fact is, the above formula counts only cells containing any text values including empty strings, meaning that cells with dates and numbers will be treated as blank cells and not included in the count!
If you need a universal COUNTIF formula for counting all non-blank cells in a specified range, here you go:
Or
This formula works correctly with all value types - text, dates and numbers - as you can see in the screenshot below.
COUNTIF blank
If you want the opposite, i.e. count blank cells in a certain range, you should adhere to the same approach - use a formula with a wildcard character for text values and with the "" criteria to count all empty cells.
Formula to count cells not containing any text:
Since an asterisk (*) matches any sequence of text characters, the formula counts cells not equal to *, i.e. not containing any text in the specified range.
Universal COUNTIF formula for blanks (all value types):
The above formula correctly handles numbers, dates and text values. For example, here's how you can get the number of empty cells in the range C2:C11:
=COUNTIF(C2:C11,"")
Please be aware that Microsoft Excel has another function for counting blank cells, COUNTBLANK. For instance, the following formulas will produce exactly the same results as the COUNTIF formulas you see in the screenshot above:
Count blanks:
=COUNTBLANK(C2:C11)
Count non-blanks:
=ROWS(C2:C11)*COLUMNS(C2:C11)-COUNTBLANK(C2:C11)
Also, please keep in mind that both COUNTIF and COUNTBLANK count cells with empty strings that only look blank. If you do not want to treat such cells as blanks, use "=" for criteria. For example:
=COUNTIF(C2:C11,"=")
For more information about counting blanks and not blanks in Excel, please see:
COUNTIF greater than, less than or equal to
To count cells with values greater than, less than or equal to the number you specify, you simply add a corresponding operator to the criteria, as shown in the table below.
Please pay attention that in COUNTIF formulas, an operator with a number are always enclosed in quotes.
| Criteria | Formula Example | Description |
|---|---|---|
| Count if greater than | =COUNTIF(A2:A10,">5") | Count cells where value is greater than 5. |
| Count if less than | =COUNTIF(A2:A10,"<5") | Count cells with values less than 5. |
| Count if equal to | =COUNTIF(A2:A10,"=5") | Count cells where value is equal to 5. |
| Count if not equal to | =COUNTIF(A2:A10,"<>5") | Count cells where value is not equal to 5. |
| Count if greater than or equal to | =COUNTIF(C2:C8,">=5") | Count cells where value is greater than or equal to 5. |
| Count if less than or equal to | =COUNTIF(C2:C8,"<=5") | Count cells where value is less than or equal to 5. |
You can also use all of the above formulas to count cells based on another cell value, you will just need to replace the number in the criteria with a cell reference.
Note. In case of a cell reference, you have to enclose the operator in quotes and add an ampersand (&) before the cell reference. For example, to count cells in the range D2:D9 with values greater than a value in cell D3, you use this formula =COUNTIF(D2:D9,">"&D3):
If you want to count cells that contain an actual operator as part of the cell's contents, i.e. the characters ">", "<" or "=", then use a wildcard character with the operator in the criteria. Such criteria will be treated as a text string rather than a numeric expression. For example, the formula =COUNTIF(D2:D9,"*>5*") will count all cells in the range D2:D9 with contents like this "Delivery >5 days" or ">5 available".
Using Excel COUNTIF function with dates
If you want to count cells with dates that are greater than, less than or equal to the date you specify or date in another cell, you proceed in the already familiar way using formulas similar to the ones we discussed a moment ago. All of the above formulas work for dates as well as for numbers. Let me give you just a few examples:
| Criteria | Formula Example | Description |
|---|---|---|
| Count dates equal to the specified date. | =COUNTIF(B2:B10,"6/1/2014") | Counts the number of cells in the range B2:B10 with the date 1-Jun-2014. |
| Count dates greater than or equal to another date. | =COUNTIF(B2:B10,">=6/1/2014") | Count the number of cells in the range B2:B10 with a date greater than or equal to 6/1/2014. |
| Count dates greater than or equal to a date in another cell, minus x days. | =COUNTIF(B2:B10,">="&B2-"7") | Count the number of cells in the range B2:B10 with a date greater than or equal to the date in B2 minus 7 days. |
Apart from these common usages, you can utilize the COUNTIF function in conjunction with specific Excel Date and Time functions such as TODAY() to count cells based on the current date.
| Criteria | Formula Example |
|---|---|
| Count dates equal to the current date. | =COUNTIF(A2:A10,TODAY()) |
| Count dates prior to the current date, i.e. less than today. | =COUNTIF(A2:A10,"<"&TODAY()) |
| Count dates after the current date, i.e. greater than today. | =COUNTIF(A2:A10,">"&TODAY()) |
| Count dates that are due in a week. | =COUNTIF(A2:A10,"="&TODAY()+7) |
| Count dates in a specific date range. | =COUNTIF(B2:B10, ">=6/1/2014")-COUNTIF(B2:B10, ">6/7/2014") |
Here is an example of using such formulas on real data (at the moment of writing today was 25-Jun-2014):
Excel COUNTIF with multiple criteria
In fact, Excel COUNTIF function is not exactly designed to count cells with multiple criteria. In most cases, you'd use its plural counterpart, the COUNTIFS function to count cells that match two or more criteria (AND logic). However, some tasks can be solved by combining two or more COUNTIF functions in one formula.
Count values between two numbers
One of the most common applications of Excel COUNTIF function with 2 criteria is counting numbers within a specific range, i.e. less than X but greater than Y. For example, you can use the following formula to count cells in the range B2:B9 where a value is greater than 5 and less than 15.
=COUNTIF(B2:B9,">5")-COUNTIF(B2:B9,">=15")
How this formula works:
Here, we use two separate COUNTIF functions - the first one finds out how many values are greater than 5 and the other one gets a count of values greater than or equal to 15. Then, you subtract the latter from the former and get the desired result.
Count cells with multiple OR criteria
In situations when you want to get several different items in a range, add 2 or more COUNTIF functions together. Supposing, you have a shopping list and you want to find out how many soft drinks are included. To have it done, use a formula similar to this:
=COUNTIF(B2:B13,"Lemonade")+COUNTIF(B2:B13,"*juice")
Please pay attention that we've included the wildcard character (*) in the second criterion, it is used to count all kinds of juice on the list.
In the same manner, you can write a COUNTIF formula with several conditions. Here is an example of the COUNTIF formula with multiple OR conditions that counts lemonade, juice and ice cream:
=COUNTIF(B2:B13,"Lemonade") + COUNTIF(B2:B13,"*juice") + COUNTIF(B2:B13,"Ice cream")
For other ways to count cells with OR logic, please see this tutorial: Excel COUNTIF and COUNTIFS with OR conditions.
Using COUNTIF function to find duplicates and unique values
Another possible usage of the COUNTIF function in Excel is for finding duplicates in one column, between two columns, or in a row.
Example 1. Find and count duplicates in 1 column
For example, this simple formula =COUNTIF(B2:B10,B2)>1 will spot all duplicate entries in the range B2:B10 while another function =COUNTIF(B2:B10,TRUE) will tell you how many dupes are there:
Example 2. Count duplicates between two columns
If you have two separate lists, say lists of names in columns B and C, and you want to know how many names appear in both columns, you can use Excel COUNTIF in combination with the SUMPRODUCT function to count duplicates:
=SUMPRODUCT((COUNTIF(B2:B1000,C2:C1000)>0)*(C2:C1000<>""))
We can even take a step further and count how many unique names there are in Column C, i.e. names that do NOT appear in Column B:
=SUMPRODUCT((COUNTIF(B2:B1000,C2:C1000)=0)*(C2:C1000<>""))
Tip. If you want to highlight duplicate cells or entire rows containing duplicate entries, you can create conditional formatting rules based on the COUNTIF formulas, as demonstrated in this tutorial - Excel conditional formatting formulas to highlight duplicates.
Example 3. Count duplicates and unique values in a row
If you want to count duplicates or unique values in a certain row rather than a column, use one of the below formulas. These formulas might be helpful, say, to analyze the lottery draw history.
Count duplicates in a row:
=SUMPRODUCT((COUNTIF(A2:I2,A2:I2)>1)*(A2:I2<>""))
Count unique values in a row:
=SUMPRODUCT((COUNTIF(A2:I2,A2:I2)=1)*(A2:I2<>""))
Excel COUNTIF - frequently asked questions and issues
I hope these examples have helped you to get a feel for the Excel COUNTIF function. If you've tried any of the above formulas on your data and were not able to get them to work or are having a problem with the formula you created, please look through the following 5 most common issues. There is a good chance that you will find the answer or a helpful tip there.
1. COUNTIF on a non-contiguous range of cells
Question: How can I use COUNTIF in Excel on a non-contiguous range or a selection of cells?
Answer: Excel COUNTIF does not work on non-adjacent ranges, nor does its syntax allow specifying several individual cells as the first parameter. Instead, you can use a combination of several COUNTIF functions:
Wrong: =COUNTIF(A2,B3,C4,">0")
Right: =COUNTIF(A2,">0") + COUNTIF(B3,">0") + COUNTIF(C4,">0")
An alternative way is using the INDIRECT function to create an array of ranges. For example, both of the below formulas produce the same result you see in the screenshot:
=SUM(COUNTIF(INDIRECT({"B2:B8","D2:C8"}),"=0"))
=COUNTIF($B2:$B8,0) + COUNTIF($C2:$C8,0)
2. Ampersand and quotes in COUNTIF formulas
Question: When do I need to use an ampersand in a COUNTIF formula?
Answer: It is probably the trickiest part of the COUNTIF function, which I personally find very confusing. Though if you give it some thought, you'll see the reasoning behind it - an ampersand and quotes are needed to construct a text string for the argument. So, you can adhere to these rules:
If you use a number or a cell reference in the exact match criteria, you need neither ampersand nor quotes. For example:
=COUNTIF(A1:A10,10)
or
=COUNTIF(A1:A10,C1)
If your criteria includes text, wildcard character or logical operator with a number, enclose it in quotes. For example:
=COUNTIF(A2:A10,"lemons")
or
=COUNTIF(A2:A10,"*") or =COUNTIF(A2:A10,">5")
In case your criteria is an expression with a cell reference or another Excel function, you have to use the quotes ("") to start a text string and ampersand (&) to concatenate and finish the string off. For example:
=COUNTIF(A2:A10,">"&D2)
or
=COUNTIF(A2:A10,"<="&TODAY())
If you are in doubt whether an ampersand is needed or not, try out both ways. In most cases an ampersand works just fine, e.g. both of the below formulas work equally well.
=COUNTIF(C2:C8,"<=5")
and
=COUNTIF(C2:C8,"<="&5)
3. COUNTIF for formatted (color coded) cells
Question: How do I count cells by fill or font color rather than by values?
Answer: Regrettably, the syntax of the Excel COUNTIF function does not allow using formats as the condition. The only possible way to count or sum cells based on their color is using a macro, or more precisely an Excel User-Defined function. You can find the code working for cells colored manually as well as for conditionally formatted cells in this article - How to count and sum Excel cells by fill and font color.
4. #NAME? error in the COUNTIF formula
Issue: My COUNTIF formula throws a #NAME? error. How can I get it fixed?
Answer: Most likely, you have supplied an incorrect range to the formula. Please check out point 1 above.
5. Excel COUNTIF formula not working
Issue: My COUNTIF formula is not working! What have I done wrong?
Answer: If you have written a formula which is seemingly correct but it does not work or produces a wrong result, start by checking the most obvious things such as a range, conditions, cell references, use of ampersand and quotes.
Be very careful with using spaces in a COUNTIF formula. When creating one of the formulas for this article I was on the verge of pulling my hair out because the correct formula (I knew with certainty it was right!) wouldn't work. As it turned out, the problem was in a measly space somewhere in between, argh... For instance, look at this formula:
=COUNTIF(B2:B13," Lemonade").
At first sight, there is nothing wrong about it, except for an extra space after the opening quotation mark. Microsoft Excel will swallow the formula just fine without an error message, warning or any other indication, assuming you really want to count cells containing the word 'Lemonade' and a leading space.
If you use the COUNTIF function with multiple criteria, split the formula into several pieces and verify each function individually.
And this is all for today. In the next article, we will explore several ways to count cells in Excel with multiple conditions. Hope to see you next week and thanks for reading!
575 comments
I am trying to create a formula in Column C is a list of names, Column K is a list of numbers over dates i.e. 401 over through to -480 until due, i need a formula to count the amount of names from Column C that has how many of Column K over 0=Zero so >0, can anybody help me?
Hi! I hope you have studied the recommendations in the tutorial above. If I understand your task correctly, it contains answers to your question. If you have multiple conditions to count values, use these instructions: How to use Excel COUNTIFS and COUNTIF with multiple criteria. It's hard for me to offer you a formula since I don't really understand what a “list of numbers over dates” is.
HELP
"=IF(BK8=0,0,=IF(BK8>(CEILING(BK8,5)-0.25),(CEILING(BK8,5)-0.25)+5,(CEILING(BK8,5)-0.25)))" doesn't seem to work.
situtation:
1. if BK8 is 0 then BL8 will show 0 but if BK8 has value then BL8 will round off to 4.75 or 9.75
Hi! For nested IF, do not use “=” sign inside the formula.
=IF(BK8=0,0, IF(BK8>(CEILING(BK8,5)-0.25), (CEILING(BK8,5)-0.25)+5,(CEILING(BK8,5)-0.25)))
Wanting a count of how many times "Lemonade" was sold in the last 5 years. =COUNTIF(A9:A31,">"&DATE(YEAR(TODAY())-5,MONTH(TODAY()),DAY(TODAY()))) gives the total number of sales in the five years. =COUNTIF(B9:B31,B2) gives the Lemonade count when "Lemonade" is in cell B2. Have not been able to combine the counts together.
Hello James!
To count the number of values for multiple conditions, use the COUNTIFS function. You can find the examples and detailed instructions here: How to use Excel COUNTIFS and COUNTIF with multiple criteria. For example:
=COUNTIFS(A9:A31,">"&DATE(YEAR(TODAY())-5,MONTH(TODAY()),DAY(TODAY())),B9:B31,B2)
Found it. Should be COUNTIFS - =COUNTIFS(A9:A31,">"&DATE(YEAR(TODAY())-5,MONTH(TODAY()),DAY(TODAY())),B9:B31,"="&B2)
I want to highlight the unique value once(present in a sheet) please help me in this/
Hi! You can find the examples and detailed instructions here: How to highlight unique and distinct values.
Hello. I have three different team members. A,b,c. Each one has a due date. I need a formula that counts if today date falls within 7 days of due date & by employee.
Please
Hello Chris!
I think you may find this instruction helpful: Get number of days between today and another date.
I can offer this formula:
=IF(AND(A1="A",(TODAY()-B1)<7),"Yes","No")
If this is not what you wanted, please describe the problem in more detail.
Hi, I have a question.
How to use Countif to calculate how many cases are closed each day in October 2024 in "Sheet 1"? Sheet 1's column A lists dates in sequencial order (such as 10/1/2024, 10/2/2024,......10/30/2024, etc). Souce of the data are listed in another workbook: column "Closed Date" lists the closed date if a case is closed (e.g. 10/1/2024 if it is closed on 10/1/2024); if it is not completed, "closed date" column shows blank.
Can the source of data workbook be closed or has to be opened all the time in order to make the formula works?
Hello Eva!
When you create a link in Excel to a different book, the other book does not have to be open. If the source book is closed, then you will need to add the full path to the external link.
Read more: Excel reference to another workbook.
Hello!
I have an excel file that I need to count a specific range of minutes.
1. Greater than 0:46
2. Less than 0:45
3. 0:00
Is there a formula that I can count less than 0:45 but won't count the 0:00 as well?
Thank you!
Hi! To calculate values for multiple conditions, use COUNTIFS formula. Look for the example formulas here: How to use Excel COUNTIFS and COUNTIF with multiple criteria. To set the time value, you can use TIME function.
Based on your information, the formula might look something like this:
=COUNTIFS(A1:A10,"<"&TIME(0,45,0),A1:A10,"<>0")
Hi, for the countif within a date range, is it possible instead of having the actual dates in the formula that the formula could reference a cell that contains a date?
I have =COUNTIF(U8:U17,">=D19")-COUNTIF(U8:U17,"<=F19") where my start date is in D and end date is in column E but it is coming up as zero but there are 10 dates in column U that actually meet this criteria.
Hi! In the COUNTIF formula, you can use a reference to a date cell.
You can see an example of this in the section above: Using Excel COUNTIF function with dates.
=COUNTIF(U8:U17,">="&D19)
Sorry my mistake, it's column F that has the end dates, but what I have isn't working. I tried:
=COUNTIF(U8:U17,"="&F19)
and
=COUNTIF(U8:U17,">="&D19)-COUNTIF(U8:U17,">="&F19) (flip-flopped the signs)
It still comes up at zero and not 10. Just wondered what I am missing.
It did it again. Basically look at the second formula and the first i tried was with the > and < signs reversed.
Hi! The first condition is greater than the start date. The second condition is less than the end date.
=COUNTIF(U8:U17,">="&D19)-COUNTIF(U8:U17,"<="&F19)
You can also use the COUNTIFS formula to count by two conditions. Read more: Excel COUNTIFS and COUNTIF with multiple AND / OR criteria.
=COUNTIFS(U8:U17,">="&D19,U8:U17,"<="&F19)
Ah Countifs. Thank you! I tested that and that is doing exactly what I need. Thank you!
=COUNTIF(U8:U17,"="&F19)
Sorry it cut that off of my first reply
formula for date (sample June 1, 2024 to June 7, 2024) counting the criteria of murder data
=COUNTIFS('8 FOCUS CRIME RESPONSE'!B2:B,">="&B2,'8 FOCUS CRIME RESPONSE'!B2:B"<="&C2, '8 FOCUS CRIME RESPONSE'!J2:J,A3)
This is what I have come up with but it is not working I cannot find anything that closely resembles what I am trying to do and the COUNTIF explanation sheet is not giving me much guidance. I am trying to add up dollar amounts in column "O" if they are task assignments and between dates of 1/1/23 and 12/31/23.
=COUNTIFS(O2:O1077,AND(D2:D1077,"Task",E2:E1077,">=1/1/23"))-COUNTIFS(O2:O1077,AND(D2:D1077,"Task",E2:E1077,">=12/31/23"))
Hi! If I understand your task correctly, this guide may be helpful: How to use SUMIFS in Excel (AND logic). See Example 2 - Using Excel SUMIFS with dates.
Based on your information, the formula might look something like this:
=SUMIFS(O2:O1077,D2:D1077,"Task",E2:E1077,">=1/1/23",E2:E1077,"<=12/31/23")
Tried it another way with no luck.
=SUMIFS(O2:O1077,(D2:D1077,"Task",E2:E1077,">=1/1/23"))-SUMIFS(O2:O1077,(D2:D1077,"Task",E2:E1077,">=12/31/23"))
Good morning,
I have a sheet and I am trying to count if multiple criteria are met. First criteria is has to match a specific word and second criteria is has to be including and after date 1/1/24 which is contained in a different column. Here is what I have but it is not working and I have changed the sign between the two sets and no matter what I change it to it does not come out correct. Please if you could tell me what I need to fix.
=COUNTIF(D900:D1077,"Task")+COUNTIF(E900:E1077,">=1/1/24")
Hello! If you want to calculate values on two criteria, use the COUNTIFS function. Try to use the recommendations described in this article: How to use Excel COUNTIFS and COUNTIF with multiple criteria
For example:
=COUNTIFS(D900:D1077,"Task",E900:E1077,">=1/1/24")
If I may, how can I take it a step further. I want to use this function and if these criteria are met then total up the dollar amounts that would correspond to the counted items in column O
=COUNTIFS($D2:D1077,"Task",$E2:E1077,">=1/1/23")-COUNTIFS($D2:D1077,"Task",$E2:E1077,">=12/31/23")
Hi! To sum values by multiple conditions, use the SUMIFS function and these instructions: Excel SUMIFS and SUMIF with multiple criteria – formula examples.
The formula might look like this:
=SUMIFS(O2:O1077,$D2:D1077,"Task",$E2:E1077,">=1/1/23")
Thank you again.
hi, good day to you. I am looking at the daily closing prices of a stock and would like to find out how many days (say) within a 20-day period that the price closed higher versus the day before. For instance, column A2:A21 are the dates and B2:B21 are the closing prices. Say if the price dropped every single day (vs. the day-before) except for One day where the price ticked higher (and subsequently continued to drop again), the Count would be ONE (1). That is, only One episode over the 20-day period, the price actually 'ticked higher'.
Could kindly guide me please how best I could approach this problem?
Thanks very much and wishing you & your loved ones bliss & health.
Sincerely.
Hi! Please try the following formula:
=SUMPRODUCT(--(B3:B21-B2:B20>0))
For more information, please visit: Excel SUMPRODUCT function with multiple criteria.
I need to determine time in position based off <6 Months, <1 year, <2 years, 3 years. Can I use a countif for that?
Jeremy 2/20/2012
Chris 7/11/2022
Lucas 4/26/2010
John 7/8/2020
Tyler 11/5/2018
Daniel 4/17/2023
Jeremy 4/29/2019
Johnny 9/9/2019
Josh 7/10/2017
David 7/18/2022
Hi! Read the section above carefully: Using Excel COUNTIF function with dates. For example, this counts dates more than 3 years from the current date:
=COUNTIF(B1:B10,"<"&(TODAY()+365*3))
Hello,
My issue is creating a count function for 3 criteria. My workbook has 12 columns of information and I am trying to create counting functions meeting filter options. For example, if I want to see how many individuals I have with a specific class license (column a) [what I am looking for] from a specific department (column b) [filter option], and years of service greater than 5 years [filter option], how would I construct that function?
Hi! You can find the examples and detailed instructions here: How to use Excel COUNTIFS and COUNTIF with multiple criteria.
I have a spreadsheet with a column of number of units per order and a column of dates. There are multiple entries per date. I want to sum how many units were produced on each date.
1 06/01/23
1 06/01/23
4 06/01/23
1 06/01/23
1 06/02/23
3 06/02/23
4 06/03/23
1 06/04/23
5 06/04/23
2 06/05/23
Continues. How do I get an output that summaries similar to:
06/01/23 = 6
06/02/23 = 4
06/03/23 = 4
06/04/23 = 6
06/05/23 = 2
Additionally, I would like to use the master data tab as the source and have the output on a separate tab.
Have been trying to figure out how to get a sum of unique numbers (Column C) from the following example:
Column C
List of over 2000 Phone Numbers
Column D
Dates (example rows 2-52 are one date, rows 53 - 105 a different date and so on)
Column F
Date lookup value.
What I'm trying to figure out is the unique sum of numbers in column C with a date in column D that matches the date in Column F Row 2.
Hi! If I understand your task correctly, the following tutorial should help: Count unique values with criteria. For example:
=IFERROR(ROWS(UNIQUE(FILTER(C2:C1000,D2:D1000=F2))), 0)
I've tried that but I get back "That function isn't valid" and then it highlights the word FILTER. I'm using excel 2016.
Hi! Your version of Excel does not have FILTER and UNIQUE functions. I can recommend using the Excel Filter to get Phone Numbers for a specific date. Then, to count the unique Phone Numbers, use these recommendations: Count unique and distinct values in Excel with formula or pivot table.
I have a question.
A2:A15 contain some dates. I want to count how many dates in this range falls between each specific date range.
C2:C9 contain a list of start dates
D2:D9 contain a list of end dates
This formula works (as you described above):
=COUNTIF($A$2:$A$15,">"&C2)-COUNTIF($A$2:$A$15,">"&D2)
But why does this formula not work? Considering that excel reads the datevalue?
=COUNTIF($A$2:$A$15,AND(">"&C2,"<"&D2)
Hi! Your formula returns the correct result.
Oh I noticed that I should use COUNTIFS. Thank you!
I'm using the below to try to count the number of entries within November in a spreadsheet based on the date input into column A:
=COUNTIF(Sheet1!A:A,">=01/11/2023"&"<=30/11/2023")
There are 3 entries when i look manually but this produces the number 1 which is wrong. What is wrong with my formula?
Hi! If you want to count values that match two criteria, use the COUNTIFS function as described in this manual: Excel COUNTIFS and COUNTIF with multiple AND / OR criteria. For example:
=COUNTIFS(Sheet1!A:A,">=01/11/2023",Sheet1!A:A,"<=30/11/2023")
Hi I need to count the number of dates that is in the past. However the dates to be counted is in every second column. A will be the test date, B will be the expiry date, C will be another test date and D the expiry date for C. Thus I need to count the dates expired in A, C, E, G ect. Help would be greatly appreciated.
Hi! The COUNTIF function count values by condition in only one column. Therefore, write a specific COUNTIF function for each column.
If I understand your task correctly, try the following formula:
=COUNTIF(B2:B10,"<"&TODAY()) + COUNTIF(D2:D10,"<"&TODAY())
Your concern is appreciated,
What does the "@" sign in the format cells mean?
I know that "#" stands for a number
I know that "$" stands for a Currency
But also what sign or symbol is used for a text format?
Hi! @ is placeholder for text. For example, the following format will display text values in red:
0;0;0;[Red]@
Prefix for text: "Delivered in "@
You can learn more about text format in this article: Excel format for number, text, scientific notation, accounting, etc.
Thank you!