In this tutorial, we will continue exploring the fascinating world of Excel Conditional Formatting. If you do not feel very comfortable in this area, you may want to look through the previous article first to revive the basics - How to use conditional formatting in Excel.

Today are going to dwell on how to use Excel formulas to format individual cells and entire rows based on the values you specify or based on another cell's value. This is often considered advanced aerobatics of Excel conditional formatting and once mastered, it will help you push the formats in your spreadsheets far beyond their common uses.

Excel's pre-defined conditional formatting rules are mainly purposed to format cells based on their own values or the values you specify. I am talking about Data Bars, Color Scales, Icon Sets and other rules available to you on the *Conditional Formatting* button click.

If you want to apply conditional formatting based on another cell or format the entire row based on a single cell's value, then you will need to use Excel formulas. So, let's see how you can make a rule using a formula and after that I will provide a number of formula examples for different tasks.

To set up a conditional formatting rule based on a formula in Excel 2019, Excel 2016, Excel 2013 and Excel 2010, carry out these steps:

- Select the cells you want to format. You can select one column, several columns or the entire table if you want to apply your conditional format to rows.
**Tip.**If you plan to add more data in the future and you want the conditional formatting rule to get applied to new entries automatically, you can either:- Convert a range of cells to a table (
*Insert tab > Table*). In this case, the conditional formatting will be automatically applied to all new rows. - Select some empty rows below your data, say 100 blank rows.

- Convert a range of cells to a table (
- On the
*Home*tab, in the*Styles*group, click**Conditional formatting > New Rule…**

- In the
*New Formatting Rule*window, select**Use a formula to determine which cells to format**. - Enter the formula in the corresponding box.
- Click the
**Format…**button to choose your custom format.

- Switch between the
**Font**,**Border**and**Fill**tabs and play with different options such as font style, pattern color and fill effects to set up the format that works best for you. If the standard palette does not suffice, click**More colors…**and choose any RGB or HSL color to your liking. When done, click the*OK*button.

- Make sure the
**Preview**section displays the format you want and if it does, click the*OK*button to save the rule. If you are not quite happy with the format preview, click the*Format…*button again and make the edits.

Now that you know how to create and apply Excel conditional formatting based on another cell, let's move on and see how to use various Excel formulas in practice:

As you know Microsoft Excel provides a handful of ready-to-use rules to format cells with values greater than, less than or equal to the value you specify (*Conditional Formatting >Highlight Cells Rules*). However, these rules do not work if you want to conditionally format certain columns or entire rows **based on a cell's value in another column. ** In this case, you use analogous formulas:

Condition |
Formula example |

Equal to | `=$B2=10` |

Not equal to | `=$B2<>10` |

Greater than | `=$B2>10` |

Greater than or equal to | `=$B2>=10` |

Less than | `=$B2<10` |

Less than or equal to | `=$B2<=10` |

Between | `=AND($B2>5, $B2<10)` |

The screenshot below shows an example of the **Greater than formula** that highlights product names in column A if the number of items in stock (column C) is greater than 0. Please pay attention that the formula applies to column A only ($A$2:$A$8). But if you select the whole table (in our case, $A$2:$E$8), this will highlight entire rows based on the value in column C.

In a similar fashion, you can create a conditional formatting rule to compare values of two cells. For example:

`=$A2<$B2`

- format cells or rows if a value in column A is less than the corresponding value in column B.

`=$A2=$B2`

- format cells or rows if values in columns A and B are the same.

`=$A2<>$B2`

- format cells or rows if a value in column A is not the same as in column B.

As you can see in the screenshot below, these formulas work for text values as well as for numbers.

If you want to format your Excel table based on 2 or more conditions, then use either =AND or =OR function:

Condition | Formula | Description |

If both conditions are met | `=AND($B2<$C2, $C2<$D2)` |
Formats cells if the value in column B is less than in column C, and if the value in column C is less than in column D. |

If one of the conditions is met | `=OR($B2<$C2, $C2<$D2)` |
Formats cells if the value in column B is less than in column C, or if the value in column C is less than in column D. |

In the screenshot below, we use the formula `=AND($C2>0, $D2="Worldwide")`

to change the background color of rows if the number of items in stock (Column C) is greater than 0 and if the product ships worldwide (Column D). Please pay attention that the formula works with **text values** as well as with **numbers**.

Naturally, you can use two, three or more conditions in your =AND and =OR formulas.

These are the basic conditional formatting formulas you use in Excel. Now let's consider a bit more complex but far more interesting examples.

I think everyone knows how to format empty and not empty cells in Excel - you simply create a new rule of the "*Format only cells that contain"* type and choose either **Blanks** or **No Blanks**.

But what if you want to format cells in a certain column if a corresponding cell in another column is empty or not empty? In this case, you will need to utilize Excel formulas again:

**Formula for blanks**: `=$B2=""`

- format selected cells / rows if a corresponding cell in Column B is blank.

**Formula for non-blanks**: `=$B2<>""`

- format selected cells / rows if a corresponding cell in Column B is not blank.

`=if(false,"OK", "")`

, and you don't want such cells to be treated as blanks, use the following formulas instead `=isblank(A1)=true`

or `=isblank(A1)=false`

to format blank and non-blank cells, respectively.
And here is an example of how you can use the above formulas in practice. Suppose, you have a column (B) which is "*Date of Sale*" and another column (C) "*Delivery*". These 2 columns have a value only if a sale has been made and the item delivered. So, you want the entire row to turn orange when you've made a sale; and when an item is delivered, a corresponding row should turn green. To achieve this, you need to create 2 conditional formatting rules with the following formulas:

- Orange rows (a cell in column B is not empty):
`=$B2<>""`

- Green rows (cells in column B and column C are not empty):
`=AND($B2<>"", $C2<>"")`

One more thing for you to do is to move the second rule to the top and select the *Stop if true* check box next to this rule:

In this particular case, the "Stop if true" option is actually superfluous, and the rule will work with or without it. You may want to check this box just as an extra precaution, in case you add a few other rules in the future that may conflict with any of the existing ones.

If you want to format a certain column(s) when another cell in the same row contains a certain word, you can use a formula discussed in one of the previous examples (like =$D2="Worldwide"). However, this will only work for **exact match**.

For **partial match**, you will need to use either SEARCH (case insensitive) or FIND (case sensitive).

For example, to format selected cells or rows if a corresponding cell in column D contains the word "*Worldwide*", use the below formula. This formula will find all such cells, regardless of where the specified text is located in a cell, including "*Ships Worldwide*", "*Worldwide, except for…*", etc:

`=SEARCH("Worldwide", $D2)>0`

If you'd like to shade selected cells or rows if the cell's content starts with the search text, use this one:

`=SEARCH("Worldwide", $D2)>1`

If your task is to conditionally format cells with duplicate values, you can go with the pre-defined rule available under *Conditional formatting > Highlight Cells Rules > Duplicate Values…* The following article provides a detailed guidance on how to use this feature: How to automatically highlight duplicates in Excel.

However, in some cases the data looks better if you color selected columns or entire rows when a duplicate values occurs in another column. In this case, you will need to employ an Excel conditional formatting formula again, and this time we will be using the *COUNTIF* formula. As you know, this Excel function counts the number of cells within a specified range that meet a single criterion.

`=COUNTIF($A$2:$A$10,$A2)>1`

- this formula finds duplicate values in the specified range in Column A (A2:A10 in our case), including first occurrences.

If you choose to apply the rule to the entire table, the whole rows will get formatted, as you see in the screenshot below. I've decided to change a font color in this rule, just for a change : )

To ignore the first occurrence and highlight only subsequent duplicate values, use this formula: `=COUNTIF($A$2:$A2,$A2)>1`

If you'd rather highlight only duplicates on consecutive rows, you can do this in the following way. This method works for any data types: numbers, text values and dates.

- Select the column where you want to highlight duplicates,
**without the column header**. - Create a conditional formatting rule(s) using these simple formulas:

Rule 1 (blue):`=$A1=$A2`

- highlights the 2^{nd}occurrence and all subsequent occurrences, if any.

Rule 2 (green):`=$A2=$A3`

- highlights the 1^{st}occurrence.

In the above formulas, A is the column you want to check for dupes, $A1 is the column header, $A2 is the first cell with data.

**Important!** For the formulas to work correctly, it is essential that Rule 1, which highlights the 2^{nd} and all subsequent duplicate occurrences, should be the first rule in the list, especially if you are using two different colors.

If you want apply the conditional format when duplicate values occur in two or more columns, you will need to add an extra column to your table in which you concatenate the values from the key columns using a simple formula like this one `=A2&B2`

. After that you apply a rule using either variation of the COUNTIF formula for duplicates (with or without 1^{st} occurrences). Naturally, you can hide an additional column after creating the rule.

Alternatively, you can use the COUNTIFS function that supports multiple criteria in a single formula. In this case, you won't need a helper column.

In this example, to highlight duplicate rows **with 1st occurrences**, create a rule with the following formula:

`=COUNTIFS($A$2:$A$11, $A2, $B$2:$B$11, $B2)>1`

To highlight duplicate rows **without 1st occurrences**, use this formula:

`=COUNTIFS($A$2:$A2, $A2, $B$2:$B2, $B2)>1`

One of the most frequent tasks in Excel is to check 2 columns for duplicate values - i.e. find and highlight values that exist in both columns. To do this, you will need to create an Excel conditional formatting rule for each column with a combination of `=ISERROR()`

and `=MATCH()`

functions:

For Column A: `=ISERROR(MATCH(A1,$B$1:$B$10000,0))=FALSE`

For Column B: `=ISERROR(MATCH(B1,$A$1:$A$10000,0))=FALSE`

`=$A:$A`

and `=$B:$B`

. You can see an example of practical usage in the following screenshot that highlights duplicates in Columns E and F.

As you can see, Excel conditional formatting formulas cope with dupes pretty well. However, for more complex cases, I would recommend using the Duplicate Remover add-in that is especially designed to find, highlight and remove duplicates in Excel, in one sheet or between two spreadsheets.

When you work with several sets of numeric data, the *AVERAGE()* function may come in handy to format cells whose values are below or above the average in a column.

For example, you can use the formula `=$E2<AVERAGE($E$2:$E$8)`

to conditionally format the rows where the sale numbers are below the average, as shown in the screenshot below. If you are looking for the opposite, i.e. to shade the products performing above the average, replace "<" with ">" in the formula: `=$E2>AVERAGE($E$2:$E$8)`

.

If I have a set of numbers, is there a way I can use Excel conditional formatting to highlight the number in that set that is closest to zero? This is what one of our blog readers, Jessica, wanted to know. The question is very clear and straightforward, but the answer is a bit too long for the comments sections, that's why you see a solution here :)

In our example, we'll find and highlight the number that is closest to zero. If the data set contains one or more zeroes, all of them will be highlighted. If there is no 0, then the value closest to it, either positive or negative, will be highlighted.

First off, you need to enter the following formula to any empty cell in your worksheet, you will be able to hide that cell later, if needed. The formula finds the number in a given range that is closest to the number you specify and returns the absolute value of that number (absolute value is the number without its sign):

`=MIN(ABS(B2:D13-(0)))`

In the above formula, B2:D13 is your range of cells and 0 is the number for which you want to find the closest match. For example, if you are looking for a value closest to 5, the formula will change to: `=MIN(ABS(B2:D13-(5)))`

And now, you create a conditional formatting rule with the following formula, where B3 is the top-right cell in your range and $C$2 in the cell with the above array formula:

`=OR(B3=0-$C$2,B3=0+$C$2)`

Please pay attention to the use of absolute references in the address of the cell containing the array formula ($C$2), because this cell is constant. Also, you need to replace 0 with the number for which you want to highlight the closest match. For example, if we wanted to highlight the value nearest to 5, the formula would change to: `=OR(B3=5-$C$2,B3=5+$C$2)`

In case you do not want to highlight the exact match, you need a different array formula that will find the closest value but ignore the exact match.

For example, the following array formula finds the value closest to 0 in the specified range, but ignores zeroes, if any:

`=MIN(ABS(B3:C13-(0))+(10^0*(B3:C13=0)))`

Please remember to press Ctrl + Shift + Enter after you finished typing your array formula.

The conditional formatting formula is the same as in the above example:

`=OR(B3=0-$C$2,B3=0+$C$2)`

However, since our array formula in cell C2 ignores the exact match, the conditional formatting rule ignores zeroes too and highlights the value 0.003 that is the closest match.

If you want to find the value nearest to some other number in your Excel sheet, just replace "0" with the number you want both in the array and conditional formatting formulas.

I hope the conditional formatting formulas you have learned in this tutorial will help you make sense of whatever project you are working on. If you need more examples, please check out the following articles:

If your conditional formatting rule is not working as expected, though the formula is apparently correct, do not get upset! Most likely it is not because of some weird bug in Excel conditional formatting, rather due to a tiny mistake, not evident at the first sight. Please try out 6 simple troubleshooting steps below and I'm sure you will get your formula to work:

**Use absolute & relative cell addresses correctly.**It's very difficult to deduce a general rule that will work in 100 per cent of cases. But most often you would use an absolute column (with $) and relative row (without $) in your cell references, e.g.`=$A1>1`

.Please keep in mind that the formulas

`=A1=1`

,`=$A$1=1`

and`=A$1=1`

will produce different results. If you are not sure which one is correct in your case, you can try all : ) For more information, please see Relative and absolute cell references in Excel conditional formatting.**Verify the applied range.**Check whether your conditional formatting rule applies to the correct range of cells. A rule of thumb is this - select all the cells / rows you want to format but do not include column headers.**Write the formula for the top-left cell.**In conditional formatting rules, cell references are relative to the top-left most cell in the applied range. So, always write your conditional formatting formula for the 1st row with data.For example, if your data starts in row 2, you put

`=A$2=10`

to highlight cells with values equal to 10 in**all the rows**. A common mistake is to always use a reference to the first row (e.g.`=A$1=10`

). Please remember, you reference row 1 in the formula only if your table does not have headers and your data really starts in row 1. The most obvious indication of this case is when the rule is working, but formats values not in the rows it should.**Check the rule you created.**Double-check the rule in the Conditional Formatting Rules Manager. Sometimes, for no reason at all, Microsoft Excel distorts the rule you have just created. So, if the rule is not working, go to*Conditional Formatting > Manage Rules*and check both the formula and the range it applies to. If you have copied the formula from the web or some other external source, make sure the**straight quotes**are used.**Adjust cell references when copying the rule.**If you copy Excel conditional formatting using Format Painter, don't forget to adjust all cell references in the formula.**Split complex formulas into simple elements.**If you use a complex Excel formula that includes several different functions, split it into simple elements and verify each function individually.

And finally, if you've tried all the steps but your conditional formatting rule is still not working correctly, drop me a line in comments and we will try to fathom it out together :)

In my next article we are going to look into the capabilities of Excel conditional formatting for dates. See you next week and thanks for reading!

Excel formulas
CSV
Excel functions
Print
Financial functions
Vlookup
Merge data in Excel
SumIf
CountIf
Excel Compare
If statement
Excel Charts
Pivot Table
Conditional formatting
Excel formatting
Excel duplicates
Excel date
Excel tips
Excel macro
Outlook
Google Sheets
Outlook duplicates
Outlook templates

Category: Excel Tips and How-to

## 1,207 responses to "Excel formulas for conditional formatting based on another cell value"

I want to conditionally format cells which has value less than Normal Range Males More than 13.6; Females More Than 11

SN WN EN Sex Hb.

1 3755 11098 M 16.5

2 3756 11140 M 14.6

3 3757 11153 M 14.7

4 3758 10005 M 12

5 3759 10166 F 9

6 3760 10197 M 16.6

7 3761 11149 M 12.7

8 3762 0 F 10.2

9 3763 10112 M 16.6

10 3764 11123 M 13.6

11 3765 10040 M 13.8

12 3766 10195 F 10

13 3767 11082 M 11.6

14 3768 10117 M 13.9

15 3769 10171 M 16

16 3770 10025 M 14

17 3771 11127 M 15.4

I tried your formulas. It did not work. I don't know what mistake I am making.

Hi. I am trying to change the color of an empty cell in the first column of my table if columns f2 and w2 have the same value and if column e2 has the number 4390001 in it. I want the empty column to highlight red. I can get it to do it, but it is not highlighting in the right cell. It is one off on some and others it highlights a bunch without reason. This is the formula I have gotten to. =W2:W21617=F2:F21617=(E2:E21617="4390001") Please help!

Hi

I want to find a date in column L8: L3500 that corresponds to the value in E3 picked from column D8: D3500 (found by formula = MIN (D8: D3500). Which formula do I use? Thanks in advance for your help.

Hi,

I have a sheet which is adding up data using sumif. The default is 0, due to no data to add. As data is added, I'd like to be able to differentiate the 0 as nothing matches from the data adds to 0. I thought this may be possible with conditional formatting, but am unable to work this out. Is there a way?

Thanks.

I am trying to sort out a conditional formatting issue using multiple cells, The current formula I have entered is (=$X$2="SS4 1") which works exactly how I want it to on Cell X2, however I want the rule applied to multiple cells and anyway I have tried it doesn't work. I want it to apply to the following range of cells, ($X$2:$FK$2="SS4 1") I have tried entering like that and it doesn't work I'v tried entering like this (=$X$2+$AA$2+$AD$2+$AG$2+$AJ$2+$AM$2+$AP$2+$AS$2+$AV$2+$AY$2+$BB$2+$BE$2+$BH$2+$BK$2+$BN$2+$BQ$2+$BT$2+$BW$2+$BZ$2+$CC$2+$CF$2+$CI$2+$CL$2+$CO$2+$CR$2+$CU$2+$CX$2+$DA$2+$DD$2+$DG$2="SS4 1") and ive tried entering like this (=$X$2,$AA$2,$AD$2,$AG$2,$AJ$2,$AM$2,$AP$2,$AS$2="SS4 1") obviously I have not selected all cells in the last two examples but just wanted to show how I was entering it using + or , and still nothing. Please help.

I need to make a formula using less than or greater than ?????

EG. 1-30 minutes = full rate ( make the cell green)

31 to 40 minutes = -10%(subtract)(make the cell amber)

41 to 50 minutes = -25%(subtract) make the cell purple)

51+minutes = -100% (subtract) make the cell red

I'm looking to highlight dates that are before today (using the "TODAY()" function) but only where the "Status" column is NOT "Complete".

So in column G I have all the end dates of our projects, starting in row 3 (G3) and in column E I have the status of each project, again starting in row 3 (E3). The statuses in column E are:

Complete

In Progress

Not Started

Cancelled

Overdue

On Hold

"BLANK"

What I need is for column G to have highlighted all dates that are before todays date "<TODAY()" but will not highlight when column E displays "Complete". However it needs to be highlighted when column E displays any other value.

What would be the best formula for this?

Dear Sir

I have 2 column Ordered Qty and Received Qty for this i wANT TO SEE IN ONE COLUM i want to get answer Received or Pending kindly help me

Hi Ronald

I believe you are looking for this: =IF(B22>=1,"Received","Pending")

Where "B22" will be the cell (value) under Qty Received.

However, you can also use:

=IF(B22>=A22,"Received","Pending") Where "B22" is the Qty Ordered, "A22" is Qty Received. If number of items received is less than the amount ordered, it will stay on pending, until updated to reflect all items received.

Hi

I have copy-pasted a data from another program to Excel. The cell value shows number only, but the format of this cell contains the category of Custom formatting.

i.e The cell value is 5, but the display is 5 Dr ( Debit value in accounting).Format of this cell shows "0.00"Dr".

Similarly some other cells contain Cr (Credit value in accounting),Format of this cell shows "0.00"Cr".

My question is if I want to sort or apply conditional formatting to these values which contains Cr and Dr value, what is the method?

I need help setting conditional formatting in a column, where if any of the values equals to "A", "B" or "C" colour the cell green. I've tried the following that didn't work.

Cell Value/Formula = OR ("A","B", "C")

Cell Value/Formula = OR ($G:$G="A",$G:$G="B", $G:$G="C")

Any help would be greatly appreciated.

I want to validate one sheet contains all the information exactly like the second sheet, and when they done the area is highlighted.

hi

i have excel calendar. column (A) have date and Column (B) days and colomn (C) notes. when change the month or year dates and days changes but in coloumn (C) entered notes still remain. pls help how i can clear that notes when i change the month or year. pls

Hi,

I'm trying to highlight rows where the date is greater than 6 months and using this formula that I googled.

=$G2<=EDATE(TODAY(),-6)

It works well and highlights the rows that I need it to, but then it is also highlighting the row if column G is blank. How do I stop it doing this?

I've tried adding the format cells that only contain Blank, but then the rest of the row is still highlighted.

Are you able to give me any suggestions?

I'm making a March Madness pool sheet. I would like it to be fully automated, other than updating round by round winner & losers. I have a source sheet (Teams tab) with all teams in tournament in column B cells 4-67, and corresponding columns C, D, E, F, G, H cells 4-67 to assign round 1, 2, 3, 4, 5, 6 results. I have a destination sheet (Participants tab) with all participants names, picks and final four teams. I have everything figured out except: How can I conditionally format Participants tab cells for final four picks to change format when that team loses, based on entry in one of the rounds columns for said team in Teams tab changes state?

Hello Svetlana Cheusheva!

There is a great example for your expertise on Conditional Formatting sorted data!

Hopefully its a simple overlooked solution for a large number of readers that can create more new traffic on your site with your response.

The formula for formatting is written for the top-left cell and works great through the range but as soon as the data is sorted A-Z or Z-A, the conditional formatting for the rest of the range acts irrationally. Formatting of the rows are changed to the incorrect condition.

(Sheet description is summarized below).

Is this an example of troubleshooting step #3 "Write the formula for the top-left cell."?

If so, how is formula conditional formatting achieved with data that will be frequently sorted?

Please contact (via your preference) if there is a solution for this. Feel free to use this obstacle as new feed for your page for your audience with your solution. Hopefully it is beneficial for your goals.

Thank you

Pablo Vazquez

PROJECT DESCRIPTION:

Project names are listed on column A.

Corresponding dates of the projects are listed on columns B through D (Start date 1, Start date 2, and End Date 3).

Presentation dates of each project are listed on column F.

Rows are conditionally formatted based on the condition if a given date on Column F falls within which start date and end date from column B through D.

For example: If Project 1A (cell A1) with a presentation date of 1/31/2020 (cell F1) falls between Start date 1 (B1) and End date 1 (D1); therefore Row 1 highlighted green.

If Project 1A (cell A1) with a presentation date of 2/28/2020 (cell F1) falls between Start date 2 (C1) and End date 1 (D1); therefore Row 1 highlighted orange.

Once sorted A-Z by project names/numbers or start dates or presentation dates, the rows that are supposed to be highlighted green are either not highlighted or highlighted orange. Vice-versa with rows supposed to be highlighted green.

Hi,

Found do I apply a conditional format for the difference between 2 numbers.

I want to Highlight if the difference is less than 10 or less than 5.

EG

A1 is 10 less than A2 show as red, if it is 5 less than show as green.

A1 100 A2 120

thanks,

Glenn

Hello Glenn!

You'll need to set the conditional formatting rule for cell A1 with the following formula applied:

=$A$2 - $A$1<10

And choose red as a color to fill the cell with.

Then add one more rule to the same cell with another formula:

=$A$2 - $A$1<5

Green will be the color for this condition.

I hope this is exactly what you need.

I want F2 to be formatted based on a check cell C2 and then H2 and I2. In basic terms, If "(F2(value) + H2(value) + I2(value)) = C2(value)" is true, cell should be formatted. If false format wouldn't apply and there is already a rule for if F2 and C2 aren't equal.

Hi,

I have coded column starting from cell A3:A56 with one or more text for each cell from another column starting from the cell B6:B71. I have changed the background color for each of the cells with a distinctive color and the same text for each cell in the column B6:B71. I would like to match any of the cell in the column A3:A56 that contains the same text in column B6:B71 with its color. At the moment the cells from the column A3:A56 have no background color(white). What sort of conditional rule should I apply in column A3:A56 that can use the color of the cell that contains the same text from column B6:B71

Unfortunately, it is technically impossible for Excel to use colors as formula components or conditions. This can be achived with the help of VBA only.

As a workaround, you may use the conditions you set for the conditional formatting as the conditions for your formula. That should work.

Please check out this article, I beloeve you'll find this information helpful

I have a column that each cell uses a formula to produce a value. I would like to apply conditional formatting to those cells based on the vale produced by that formula. Pretty simple really, =IF(A1+B1)>0.

But what I am finding is that even if the product of that formula is 0 it still conditionally highlights it because there is something in that cell, a formula. I know I have successfully done this a thousand times before however now it is just fighting with me. Is there a setting or something that I can change so that the conditional formatting 'looks' at the cell value rather then the enclosed formula?

Hello Robert!

Please specify which conditional formatting type you are using exactly - Data Bats, Color Scales or something else? It'll help me understand the situation better and recommend you some solution. Thank you.

I can't use in cell conditional function AND. It doesn't work inside "tables". WHy?

Hello anybody.....

I am trying to format a spreadsheet for a lot of people that I manage travel arrangements for, I need the cell to change colour on the date I input in to the cell (date of travel) and then change back to no colour 14 days from the inputted date...

For instance ...John travels to Albania so I enter 20/03/2020 in the cell and it turns red. After 14 days has passed I want that cell to revert back to clear again until the next time I enter a date for travel.

I have tried several formulas but it is frying my brain trying to get it to work.

I am handling every country in the world and over 300 people so any help would be appreciated.

Thanks

Hello Mark!

Please first select the entire column you'll be filling with travel dates, then go to

Conditional Formatting- > New Rule -> Use a formula to determine which cells to format and put the following formula:

=TODAY()-$A1<14

Thank will do the trick for you.

I need to copy the conditional formatting range as F2:AA2 to have at the below row the range as F3:AA3 and so on

I am trying to copy a "Conditional Formatting" Cell. The line I am copying has the "Conditional Formatting" of "If N$4$>F$4$ then turn cell yellow". When I copy it to the next line it is "If N$4$>F$5$ then turn cell yellow". I want it to be "IF N$5$>F$5$ then turn the cell yellow". Is it possible to copy and get this result?

Hello Doug!

If I understand your task correctly, please try the following formula conditional formatting:

=N4>F4

Read more about Relative and absolute cell references in Excel conditional formatting rules on our blog

I hope it’ll be helpful.

Hi ,

I have number of series of numbers like 1,2,3,9,-1,-3,-10 in a row then drastical changes like 1, 9,-10 should be highlighted in my row how to do it

Hello Pavan!

I’m sorry but your task is not entirely clear to me.

For me to be able to help you better, please describe your task in more detail. It’ll help me understand it better and find a solution for you. Thank you.

I have an excel worksheet I have a formula: =IF(G22="Y","CORROSION",""). What I need to do is add to this formula I need it to show that: IF (G22="Y" AND H22="X", "CLEANED"). I have tried several different ways of writing it but all I get is an error. The first formula works I just want to expand on it, is that possible?

Hello Jesse,

Please try the following formula:

=IF(AND(G22="Y",H22="X"),"CLEANED","")

You can learn more about Excel IF statement with multiple AND/OR conditions in this article on our blog.

Hope this is what you need.

I want to conditionally format all cells in column A based on corresponding values in column B.

For example, format cell a1 if cell b1>10 or b110 or cell b2<-10, and so on.

I want to create one rule to format all cells in column A based on the above logic.

Please advise best solution. Thanks.

I have 2 columns in my spreadsheet that are dates. Then, I have a third column (G) whose formula calculates the time between those two columns: =IFERROR(DATEDIF(E64,V64, "D"),DATEDIF(V64,E64, "D")). The condition i want applied If the dates from E is less than column V, then i want the column G cell to be RED. I would like the condition to apply all of column G, but its dependent on its own unique row's dates. Is there a way to get a condition to be dynamic like the drag down principle for equations?

Hello Sara!

To apply conditional formatting to an entire row or column, review this guide. Hope I understood your problem correctly.

Hello Svetlana,

I have the following question, I would like to create a formula in order to change the values in one of the columns (to be decreasing by 1) if the values in another column are increasing by one and if a different data is inserted to highlight it. For instance if in column A, that numbers start with 1 and increase progressively up to 30 in the other to start with 8654 and decrease with 1, tried with if and it partially worked out, still it does not register the deviations from the condition given. Thanks a lot :)

Hi,

I need to help to highlight the values.

I have data set in Column B1 to B10. If I enter value in column A1, then excel should highlight to tell the entered value is between particular cells.

B1=449.25

B2=445.25

B3=438.29

B4=435.27

B5=427.28

B6=425.29

B7=420.3

B8=415.31

B9=410.29

If I enter the value in A1 as 417.25, the cells B7 & B8 should highlight. Please help on this.

Hello!

Using conditional formatting, you can select all the cells in a column that are larger than some value. A second rule can be created for all cells that are smaller. For each rule, set its own color.

Hi Alexander! I'd like to show a red RAG status in a separate cell, based on the values quoted within five other cells, where none, or only one, of the five cells has a value of "4".

Hello Paul!

You can also use the formula to conditionally format a cell:

=SUM(--(B1=4),--(B2=4),--(B3=4),--(B4=4),--(B5=4)) > 1

I hope this will help

Hello

I have 8 different sheets in one workbook.

Each sheet is named as " raw,process,issues,closed"

example: When a product number 72 has completed its production, we will paste the details in "closed" sheet

I would like to apply conditional formatting or find duplicates if

I entered the same number in coloumn A of sheet1 or sheet2 or sheet3, it should highlight with any color.

If range A2:A30 has 2 data validation, "selected, not selected". I want respective B Column to be N/A, if respective A column is "not selected", by using conditional formatting, is it possible?

Hello!

Conditional formatting may not prevent a cell from being edited. You can use Data Validation tool. For example, for cell B2, you can write the rule

=A2="not selected"

After that you can copy this cell down along the column B.

Please help me make a formula for my data, scenario is this:

Where column B2 is the Release Date and column B5 is the 1st Amort Date.

f the release date (B2) Range from 1 - 25 of the month the 1st Amort Date (B5) should be the 10th of the following Month,

then if the release date (B2) Range from 26 - 31 of the month the 1st Amort Date (B5) should be the 5th of the following Next Month.

Example: B2 - July 15, 2020

B5 - August 10, 2020

then

B2 - July 26, 2020

B5 - September 5, 2020

Hello!

If I understand your task correctly, the following formula should work for you:

=IF(DAY(B2)<26,DATE(YEAR(B2),MONTH(B2)+1,10), DATE(YEAR(B2),MONTH(B2)+2,5))

I hope it’ll be helpful.

How to show a text in a cell that is adjacent to the one that is formatted?

Eg: I have a C.formatted cell in A1 that says, =A1>100 format red color. which it works. But I like to see the adjacent cell(B1) to turn RED bacground and yellow text saying "OVER BUDGET"

When conditional format activated in A1, B1 turns on with Red background and yellow Text.

is it possible without using macros a simple way? and it can be copied to the columns

Thank you in advance

When conditional format activated in A1, B1 turns on with Red background and yellow Text saying "OVER BUDGET"

is it possible without using macros a simple way? and it can be copied to the columns

Thank you in advance

I am trying to format a group of cells to a specific color (ie 2 cells side by side with a first and last name) based on a third cells value ( ie Days) which represents what shift they are on.

Suggestions?

Great info! Thank you for sharing!!

I have aaplied conditional formatting to the following situation:

1. Column K has a percentage value derived by applying formula

=(DATEDIF(O3,TODAY(),"d")+1)/(DATEDIF(O3,P3,"d")+1) with data from other cells.

2. Column L is to be updated manually.

I want to change the colour of column L with reference to the percentage value in the cell being greater than, less than or equal to Column K. Conditional formatting works well in first and second data cell of column L but starts faltering thereafter.

I have tried the same logic in other columns and cells but in vain.

Please help.

Thanks

Naveen Arora

Hello!

Unfortunately, without seeing your data it hard to give you advice.

What formula did you use for conditional formatting? What data is in column L?

Can anyone help me?

IF(ISBLANK(S10),””,(H10*S10)+(V10*W10))?

The formula is in cell X10.

I’m getting the #Value! error in all my empty cells in the x column, as V10 & W10 values may not have any input sometimes. How can I fix this to reflect that?😩

Hello!

You get the #Value error! if V10 & W10 contains text or space. If the cell is empty, there is no error. You can handle this error with the IFERROR function -

=IF(ISBLANK(S10),"",(H10*S10)+IFERROR((V10*W10),0))

I hope it’ll be helpful.

Hello Alexander, thank you so much this worked like a charm. Out of 30 cells maybe 10 cells will require the formula using the v10*w10 calculations, so when I dragged the formula down it would give me that value error. Thank you sooooo very much!

The above formulas all return TRUE or FALSE, so they work perfectly as a trigger for conditional formatting.

I have two column A&B Column A have given some number Like,1,2,3,4,5,6,7,8,9

and Column B have given some number like,1,3,5 according to Column B highlight

the Column using the conditional Formulae.

I need you pls sir,

Thanks&Regards

Niru Kumar

Hello!

I’m not sure I got you right since the description you provided is not entirely clear.

Explain the phrase "Column B have given some number like,1,3,5 according to Column B highlight".

Write an example of the source data and the result you want to get.

Good day,

I must admit it is a gift to stumble on this article, but however my challenges was not addressed. I have a work sheet with just a single column. I need a formula that will highlight the row above the cell if the cell contains a specific text. For example if A2 contains "great" A1 should be highlighted. Thank you so much while i await your response.

Hello!

See how you can quickly shade the entire row based on a numeric or text value of a single cell in this article.

Awesome!!!

Many thanks

On sheet 1I have data in columns A1 to A80 , B1 to B80 and D1 to D80. When I enter a value into columns, not all of them, C1 to C80 I would like the entire row to appear on sheet 2, is this possible?

Hello!

In cell A1 on sheet 2, enter the formula

=IF(Sheet1!C1<>"",Sheet1!A1,"")

Enter similar formulas in B1 and D1

Hi there

I'm trying to set rules within a column, to highlight specific cells in that column if they are greater than, equal to or less than the figure in the cell next to it. Can you help?

Any help would be appreciated.

FYI - I am only a basic excel user - apologies.

Hello!

Highlight the columns you want and use something like this conditional formatting formula:

=$A1>$B1

I hope it’ll be helpful.

I have two rows with benchmarks as below, wherein i need conditional formatting as Results for all categories that are 4% or more above in GREEN

results 4% or more below the applicable benchmarks are shaded yellow. I need to compare Row 2 with Row 1: for e.g.: 73% is 4% above benchmark of 69% and should be formatted in Green color.

Row1 : 73% 76% 63% 69% 87% 64%

Row2 : 69% 76% 71% 63% 83% 59%

Hello!

I hope you have studied the recommendations in the tutorial above. It contains answers to your question.

Try the following conditional formatting formula:

=(A1-A2)>=4%

I know there is a way to set up a code that will automatically add the color code in a column throughout my excel sheet. I just don't know how to do it. Can anyone help?

Example

Color Color Code

Grey TS21

Hello!

Custom colors can be added using the Format Cells - More colors - Custom menu. This can be done in conditional formatting when creating a condition.

Hello to all

i need this formula please

i have a table of data about the weather for my country citiesand each city in a sheet sorted by the date

and the last sheet i program it to be refresh and updated once i open the file and it contains all the cities (each city in one row)

now i need the formula which is easier 1-for EXample .... (D) is the date line so if the Date is the same between D10 in sheet 1 and D2 in the last sheet copy E1 from the last sheet to the sheet 1 in E10 .

2- check the date in sheet1 and date in the last sheet for rwo 2 if it is the same copy row 2 to sheet 1 in the last row or the first empty row which meen the last row.

Hello!

Unfortunately, without seeing your data it is difficult to give you any advice. If you need to conditionally fill in the value of cell E10 on Sheet1, then you can use the formula

=IF(Sheet1!D10=Sheet100!D2,Sheet100!E1,"")

If you need to replace an existing value in E10 with a new value, you need to use a VBA macro.

Your second question is not completely clear to me. If you explain in more detail, I will try to help.

Hello

I want in Google Sheets if the value of a cell is less than the value of the last 24 hours(I use to import data from a website on this cell and this cell is variable), the color of the target cell should be red, and inverse if it was more, the color of the target cell should be green.

I do not know what its computational formula is!

Hello Dear,

can anyone help me below my query?

actually i have my one excel file i jus give below small example ,

i have to Colum A&B …

once i enter any value in Colum A (like mention in Below "A" ) then Colum "B" Should change automatically with some action value, like i have mention in below.?

Example :- If i enter "Colum A" (C-030) "Colum B" should be change "P1-C030" (without - after C)

A B

C-030 P1-C030

B-129 P1-B129

Thanks, Regards,

Khan

Hello!

Please use the following formula:

="P1-"&SUBSTITUTE(A1,"-","",1)

Replace "-" with nothing using the SUBSTITUTE function.

I hope it’ll be helpful.

Dear Alexander.

many thanks lot its working well.

i don't have words you to said...thanks you very much.

god bless..

br,

regards,

Dear Mr. Alexander

have a good day!

Can you please help me more regarding the above formula.

below is the table i have, there is five(5) Colom as below & two(2) rows.

actually i have two(2) warehouses- which name is (P1 & OP )

I have assigned the formula which you help me.

if you can see the below table i have Colom "A" name is storage("WH"& "OP") .

what i want in my sheet once i enter in Colom "A" in first (1) Row- WH, so Colom "D" should be show as P1-F171 & Colom "E" should disappeared & once i enter in Row(2) as OP so Colom "E" with OP-F172 Should show and Colom D should disappeared.

we need to combind the formola i hope...i think.. please support..

i hope you have understand my question

A B C D E

Storage Location Qty WH-1 Open Yard

WH F-171 62 P1-F171 --

OP F-172 62 --- OP-F172

regards,

Hello!

If I got you right, the formula below will help you with your task:

=IF(A1="WH","P1-F171",IF(A1="OP","OP-F172","" ) )

I hope it’ll be helpful.

thanks for your support..

above formula very help me to combined the formula with (if+ SUBSTITUTE)

below is the formula i have combined it

=IF($B$15="WH","P1-"&SUBSTITUTE(C15,"-","",1),IF($B$15="OY","OP-"&SUBSTITUTE(C15,"-","",1)))

thank you

Please help: value is any alphanumeric combination in Excel

If A & B have no values: display as Red

If A & B both have values: display as Red

If A only has value: display as Green

If B only has value: display as Grey

Needed for a 3D component!

Any help would be greatly appreciated.

Many thanks in advance

Best regards

Hello!

Use formulas for conditional formatting:

=AND(ISBLANK(A1),ISBLANK(B1))

=AND(NOT(ISBLANK(A1)),NOT(ISBLANK(B1)))

=AND(NOT(ISBLANK(A1)),ISBLANK(B1))

=AND(NOT(ISBLANK(A1)),ISBLANK(B1))

I hope I answered your question.

I have my specifications for a finished product where the top row has the minimum and the lower row the maximum.

Then I have actual values of each parameter that was observed on a daily basis when each batch was sampled and analysed.

Let me show an example below:

Date Product Parameter (%)

Moisture Protein

Specification Minimum 11.5 20

Maximum 12.5 24

02.12.2020 Broiler Starter 10 19

03.12.2020 Broiler starter 11.8 25

04.12.2020 Broiler Starter 12 20

04.12.2020 Broiler Starter 13 24.7

Please show me which formula I can use to highlight a red colour on an actual result that is below the minimum specification or above the maximum spec and green on a value that is greater or equal to the minimum or less or equal to the maximum specification.

Thank you.

In my workbook I need to show that the date in column s is either equal to or 120 days before column c and if column s is more than 120 days before then I need it it to show up in red fill. It needs to start on the second row on in the spreadsheet. Can you help!

Hello!

Please check out the following article on our blog, it’ll be sure to help you with your task: How to conditionally format dates and time in Excel.

Hope this is what you need.

I'm going insane, when i insert conditional formatting based on the value of another cell the formula works in some cells and not others for no reason I'm not sure why.

=$BE2BD2

Hello!

I’m sorry but your task is not entirely clear to me. For me to be able to help you better, please describe your task in more detail. Please specify what formula you used and what problem or error occurred.

It’ll help me understand it better and find a solution for you.

Hi

I have conditional formatted data with "=$D2>$E2" for range "=$E:$E"

However excel has filled cells that do not correspond to the formulae?

What have I done wrong?

I need the E column to be filled if greater than the D column.

Hello!

If you are formatting the entire column $E:$E, then the condition must start at the first cell. Use the formula

=$D1>$E1

Hope this is what you need.

Hi

The first cell is the title for the row which is why row 2 is used.

Hi,

Then do not use the entire column =$E:$E in the link, but specify =$E2:$E2000

Formula — =$D2>$E2

I hope I answered your question.

Hi Alexander

Thank you, changing the entire column to a specific range seems to have worked.

Is there a reason why this messed up the Conditional Formatting?

Hello!

If you select the entire column E for conditional formatting, then the format is applied to all cells starting with E1. The formatting rule should be written on the first cell of this range. You formatted cell E1 with the data in cell E2. Cell E2 was formatted based on the value of E3. Etc.

I applied the same conditional formatting formula to another Excel S/S with a larger data selection and Excel has filled extra cells that should not have been as were not greater than the formula cell. What else is not working as I now have the correct formula to put on the conditional formatting but this yields incorrect results?

I HAVE A TABLE IN EXCELL I WILL FINDE CELLS WHIT COLOER FILL SPECIFIED AND VALUE ROW AND COLUMN HEDER THAT CELLS WRITE ON CELLS ONATHER WITH VBA CODE IS SOME ONE HELPE ME FOR

I have a calander which vlookups leave types from another tab. Although it inserts the whole leave name such as 'Recreational Leave'. I would like it to change the result to a shorter name and change colour. I have set up conditional formatting as follows:

Equal to "Recreational Leave"

Formatted the background to blue as well as in the number tab I have selected custom and written "REC".

The conditional formatting has changed the cell to blue but it hasn't changed the word to REC.

I have tried typing Recreational Leave into the cell to see if it the formula causing the error but it still doesn't change the word to REC. In another cell I have a drop down list (1-12) and have used conditional formatting to change the number from 1 to JAN, 2 to FEB etc by using the technique mentioned above and it worked fine.

Hello!

With conditional formatting, you can show Jan instead of 1. To do this, you need to change the cell format. The cell will write 1, but it will show Jan. Conditional formatting does not change the value in the cell. Therefore, you can change the color, but you cannot replace 'Recreational Leave' with REC.

I have a set of up to 12 5-digit random numbers in a column starting at B3.

For each random number, the 5 digits are entered in columns starting at B3, and the individual digits are entered into a row starting at C3. So for B3=13579, C3=1, E3=3, G3=5, I3=7 & K3=9.

When I enter a 1, 2, 3, 4 or 5 digit number into the row starting at C2, I want the conditional formatting to highlight a cell when a match is made. So for the example above, 13579, if I entered G2=5 & I2=7, I expect G3 & I3 to highlight.

I created the rule in C3 for the 1 (one) digit, =AND($C$2=1,$C3=$C$2), and used “copy” “paste special” “format” to copy the formatting down to the remaining 11 columns. The conditional formula works great for C3 & C4, but the copied format in C5-C14 is =AND($C$2=1,$C4=$C$2). The $C4 never increments! But, the formatting rule indicates it applies to C3-C14.

I cannot figure out the correct way to "copy." All help would be appreciated. This is for playing Kakura so I need 100+ “tables” that I don’t want to write a conditional formula for each cell!!

I can send the spreadsheet if a visual would help.

Thanks

Hello!

If you want to create conditional formatting for cells C3:C14, then first select this range, and then create formatting with the rule

=AND($C$2=1,$C3=$C$2)

No need to copy conditional formatting.

I hope I answered your question. If something is still unclear, please feel free to ask.

I am trying to use formulas and conditional formatting to have a spreadsheet automatically populate names based off of another name in separate column.

For instance, If I am assigned a task and my name is in column B, I want column G to automatically populate my supervisor/manager's name. I have multiple personnel in this spreadsheet, but once I figure out the formula, I can change the names. I keep having to look up supervisors in a directory, so I would love if my spreadsheet did it automatically for repeat entries!

Oh, also, if multiple personnel have the same supervisor, I am assuming I can have it look up multiple names by separating with a comma and quotes around the names using OR?

Hello!

If column N contains the names of employees, and column M contains their supervisors, then you can use this VLOOKUP formula in column G:

=VLOOKUP($B2, $M$2:$N$100, 2, FALSE)

You can learn more about VLOOKUP function in this article on our blog.

I hope this will help, otherwise please do not hesitate to contact me anytime.

HI SIR,

I AM TRYING TO DO CONDITIONAL FORMATTING FOR HIGHLIGHTING A ROW WHEN CELL VALUE (CELL 'L') EQUAL TO ZERO,I WANT TO APPLY IT TO ALL WORK SHEET HOW CAN I DO THAT

Hello!

In your Excel spreadsheet, select the cells you want to format. If this is the entire worksheet, then select it entirely, and then create a formatting rule.

I am trying to create a conditioning format formula that highlights a row when a due date reaches within 5 days of the current date. I am using excel 365.

Hello!

Please have a look at this article - Conditionally format dates in Excel based on the current date.

I hope this will help

Hi

I have conditional formatted data to "fill with a colour" :

"=$D2>$E2" for range "specify =$E2:$E2000

Formula — =$D2>$E2"

I need the E column to be filled if greater than the D column which worked for spreadsheet one however I applied the same conditional formatting formula to another Excel S/S with a larger data selection and Excel has filled extra cells that should not have been filled or correspond to the formula and were not greater than the formula cell.

What else is not working

Hi,

If column E is greater than D, then you need to apply the conditional formatting formula

=$E2>$D2

This formula can only be applied to these columns.

Where did you apply it and what is S/S - I do not understand.

Hi, maybe you can help me with

I have one row with the predefined conditional formatting scale colors (this row contains numbers)

A row above contains text, and I want it to have the same colors as the numbers row.

How I can do that without using VBA?

Regards,

Hello!

I recommend creating another conditional formatting rule. Select the range to format, starting with the first line of text. For example, line 10 contains text, line 11 contains numbers. Select the $10:$17 row range.

Write down the conditional formatting formula, for example =$E11>100. If E11 contains the number 150, then line 10 will be filled in, and so on.

I hope I answered your question.

Thank you very much - one thing - the numbers in the number row, each is colored with different color - and I want the text line the same - if the number cell changes the color then the text cell above also changes the color :)

Hello!

You create two conditional formatting rules. The first one already exists for a row with numbers. The second rule for the row above is in the way I suggested.

Hii,

i want information to set conditional format. if B2<A2 THEN B2 get automatically and aslo apply for that entire row. if value B2=A2 then no changes. How to apply it for full Coloum ? pleaes help

Hi,

Please check out this article to learn how to change the row color based on a cell's value.