by Many tasks you perform in Excel involve comparing data in different cells. For this, Microsoft Excel provides six logical operators, which are also called comparison operators. This tutorial aims to help you understand the insight of Excel logical operators and write the most efficient formulas for your data analysis.
Excel logical operators - overview
A logical operator is used in Excel to compare two values. Logical operators are sometimes called Boolean operators because the result of the comparison in any given case can only be either TRUE or FALSE.
Six logical operators are available in Excel. The following table explains what each of them does and illustrates the theory with formula examples.
| Condition | Operator | Formula Example | Description |
| Equal to | = | =A1=B1 | The formula returns TRUE if a value in cell A1 is equal to the values in cell B1; FALSE otherwise. |
| Not equal to | <> | =A1<>B1 | The formula returns TRUE if a value in cell A1 is not equal to the value in cell B1; FALSE otherwise. |
| Greater than | > | =A1>B1 | The formula returns TRUE if a value in cell A1 is greater than a value in cell B1; otherwise it returns FALSE. |
| Less than | < | =A1<B1 | The formula returns TRUE if a value in cell A1 is less than in cell B1; FALSE otherwise. |
| Greater than or equal to | >= | =A1>=B1 | The formula returns TRUE if a value in cell A1 is greater than or equal to the values in cell B1; FALSE otherwise. |
| Less than or equal to | <= | =A1<=B1 | The formula returns TRUE if a value in cell A1 is less than or equal to the values in cell B1; FALSE otherwise. |
The screenshot below demonstrates the results returned by Equal to, Not equal to, Greater than and Less than logical operators:
It may seem that the above table covers it all and there's nothing more to talk about. But in fact, each logical operator has its own specificities and knowing them can help you harness the real power of Excel formulas.
Using "Equal to" logical operator in Excel
The Equal to logical operator (=) can be used to compare all data types - numbers, dates, text values, Booleans, as well as the results returned by other Excel formulas. For example:
| =A1=B1 | Returns TRUE if the values in cells A1 and B1 are the same, FALSE otherwise. |
| =A1="oranges" | Returns TRUE if cells A1 contain the word "oranges", FALSE otherwise. |
| =A1=TRUE | Returns TRUE if cells A1 contain the Boolean value TRUE, otherwise it returns FALSE. |
| =A1=(B1/2) | Returns TRUE if a number in cell A1 is equal to the quotient of the division of B1 by 2, FALSE otherwise. |
Example 1. Using the "Equal to" operator with dates
You might be surprised to know that the Equal to logical operator cannot compare dates as easily as numbers. For example, if the cells A1 and A2 contain the date "12/1/2014", the formula =A1=A2 will return TRUE exactly as it should.
However, if you try either =A1=12/1/2014 or =A1="12/1/2014" you will get FALSE as the result. A bit unexpected, eh?
The point is that Excel stores dates as numbers beginning with 1-Jan-1900, which is stored as 1. The date 12/1/2014 is stored as 41974. In the above formulas, Microsoft Excel interprets "12/1/2014" as a usual text string, and since "12/1/2014" is not equal to 41974, it returns FALSE.
To get the correct result, you must always wrap a date in the DATEVALUE function, like this =A1=DATEVALUE("12/1/2014")
Note. The DATEVALUE function needs to be used with other logical operator as well, as demonstrated in the examples that follow.
The same approach should be applied when you use Excel's equal to operator in the logical test of the IF function. You can find more info as well as a few formula examples in this tutorial: Using Excel IF function with dates.
Example 2. Using the "Equal to" operator with text values
Using Excel's Equal to operator with text values does not require any extra twists. The only thing you should keep in mind is that the Equal to logical operator in Excel is case-insensitive, meaning that case differences are ignored when comparing text values.
For example, if cell A1 contains the word "oranges" and cell B1 contains "Oranges", the formula =A1=B1 will return TRUE.
If you want to compare text values taking in to account their case differences, you should use the EXACT function instead of the Equal to operator. The syntax of the EXACT function is as simple as:
Where text 1 and text2 are the values you want to compare. If the values are exactly the same, including case, Excel returns TRUE; otherwise, it returns FALSE. You can also use the EXACT function in IF formulas when you need a case-sensitive comparison of text values, as shown in the below screenshot:
Note. If you want to compare the length of two text values, you can use the LEN function instead, for example =LEN(A2)=LEN(B2) or =LEN(A2)>=LEN(B2).
Example 3. Comparing Boolean values and numbers
There is a widespread opinion that in Microsoft Excel the Boolean value of TRUE always equates to 1 and FALSE to 0. However, this is only partially true, and the key word here is "always" or more precisely "not always" : )
When writing an 'equal to' logical expression that compares a Boolean value and a number, you need to specifically point out for Excel that a non-numeric Boolean value should be treated as a number. You can do this by adding the double minus sign in front of a Boolean value or a cell reference, e. g. =A2=--TRUE or =A2=--B2.
The 1st minus sign, which is technically called the unary operator, coerces TRUE/FALSE to -1/0, respectively, and the second unary negates the values turning them into +1 and 0. This will probably be easier to understand looking at the following screenshot:
Note. You should add the double unary operator before a Boolean when using other logical operators such as not equal to, greater than or less than to correctly compare a numeric and Boolean values.
When using logical operators in complex formulas, you might also need to add the double unary before each logical expression that returns TRUE or FALSE as the result. Here's an example of such a formula: SUMPRODUCT and SUMIFS in Excel.
Using "Not equal to" logical operator in Excel
You use Excel's Not equal to operator (<>) when you want to make sure that a cell's value is not equal to a specified value. The use of the Not equal to operator is very similar to the use of Equal to that we discussed a moment ago.
The results returned by the Not equal to operator are analogous to the results produced by the Excel NOT function that reverses the value of its argument. The following table provides a few formula examples.
| Not equal to operator | NOT function | Description |
| =A1<>B1 | =NOT(A1=B1) | Returns TRUE if the values in cells A1 and B1 are not the same, FALSE otherwise. |
| =A1<>"oranges" | =NOT(A1="oranges") | Returns TRUE if cell A1 contains any value other than "oranges", FALSE if it contains "oranges" or "ORANGES" or "Oranges", etc. |
| =A1<>TRUE | =NOT(A1=TRUE) | Returns TRUE if cell A1 contains any value other than TRUE, FALSE otherwise. |
| =A1<>(B1/2) | =NOT(A1=B1/2) | Returns TRUE if a number in cell A1 is not equal to the quotient of the division of B1 by 2, FALSE otherwise. |
| =A1<>DATEVALUE("12/1/2014") | =NOT(A1=DATEVALUE("12/1/2014")) | Returns TRUE if A1 contains any value other than the date of 1-Dec-2014, regardless of the date format, FALSE otherwise. |
Greater than, less than, greater than or equal to, less than or equal to
You use these logical operators in Excel to check how one number compares to another. Microsoft Excel provides 4 comparison operates whose names are self-explanatory:
- Greater than (>)
- Greater than or equal to (>=)
- Less than (<)
- Less than or equal to (<=)
Most often, Excel comparison operators are used with numbers, date and time values. For example:
| =A1>20 | Returns TRUE if a number in cell A1 is greater than 20, FALSE otherwise. |
| =A1>=(B1/2) | Returns TRUE if a number in cell A1 is greater than or equal to the quotient of the division of B1 by 2, FALSE otherwise. |
| =A1<DATEVALUE("12/1/2014") | Returns TRUE if a date in cell A1 is less than 1-Dec-2014, FALSE otherwise. |
| =A1<=SUM(B1:D1) | Returns TRUE if a number in cell A1 is less than or equal to the sum of values in cells B1:D1, FALSE otherwise. |
Using Excel comparison operators with text values
In theory, you can also use the greater than, greater than or equal to operators as well as their less than counterparts with text values. For example, if cell A1 contains "apples" and B1 contains "bananas", guess what the formula =A1>B1 will return? Congratulations to those who've staked on FALSE : )
When comparing text values, Microsoft Excel ignores their case and compares the values symbol by symbol, "a" being considered the lowest text value and "z" - the highest text value.
So, when comparing the values of "apples" (A1) and "bananas" (B1), Excel starts with their first letters "a" and "b", respectively, and since "b" is greater than "a", the formula =A1>B1 returns FALSE.
If the first letters are the same, then the 2nd letters are compared, if they happen to be identical too, then Excel gets to the 3rd, 4th letters and so on. For example, if A1 contained "apples" and B1 contained "agave", the formula =A1>B1 would return TRUE because "p" is greater than "g".
At first sight, the use of comparison operators with text values seems to have very little practical sense, but you never know what you might need in the future, so probably this knowledge will prove helpful to someone.
Common uses of logical operators in Excel
In real work, Excel logical operators are rarely used on their own. Agree, the Boolean values TRUE and FALSE they return, though very true (excuse the pun), are not very meaningful. To get more sensible results, you can use logical operators as part of Excel functions or conditional formatting rules, as demonstrated in the below examples.
1. Using logical operators in arguments of Excel functions
When it comes to logical operators, Excel is very permissive and allows using them in parameters of many functions. One of the most common uses is found in Excel IF function where the comparison operators can help to construct a logical test, and the IF formula will return an appropriate result depending on whether the test evaluates to TRUE or FALSE. For example:
=IF(A1>=B1, "OK", "Not OK")
This simple IF formula returns OK if a value in cell A1 is greater than or equal to a value in cell B1, "Not OK" otherwise.
And here's another example:
=IF(A1<>B1, SUM(A1:C1), "")
The formula compares the values in cells A1 and B1, and if A1 is not equal to B1, the sum of values in cells A1:C1 is returned, an empty string otherwise.
Excel logical operators are also widely used in special IF functions such as SUMIF, COUNTIF, AVERAGEIF and their plural counterparts that return a result based on a certain condition or multiple conditions.
You can find a wealth of formula examples in the following tutorials:
2. Using Excel logical operators in mathematical calculations
Of course, Excel functions are very powerful, but you don't always have to use them to achieve the desired result. For example, the results returned by the following two formulas are identical:
IF function: =IF(B2>C2, B2*10, B2*5)
Formula with logical operators: =(B2>C2)*(B2*10)+(B2<=C2)*(B2*5)
I guess the IF formula is easier to interpret, right? It tells Excel to multiply a value in cell B2 by 10 if B2 is greater than C2, otherwise the value in B1 is multiplied by 5.
Now, let's analyze what the 2nd formula with the greater than and less than or equal to logical operators does. It helps to know that in mathematical calculations Excel does equate the Boolean value TRUE to 1, and FALSE to 0. Keeping this in mind, let's see what each of the logical expressions actually returns.
If a value in cell B2 is greater than a value in C2, then the expression B2>C2 is TRUE, and consequently equal to 1. On the other hand, B2<=C2 is FALSE and equal to 0. So, given that B2>C2, our formula undergoes the following transformation:
Since any number multiplied by zero gives zero, we can cast away the second part of the formula after the plus sign. And because any number multiplied by 1 is that number, our complex formula turns into a simple =B2*10 that returns the product of multiplying B2 by 10, which is exactly what the above IF formula does : )
Obviously, if a value in cell B2 is less than in C2, then the expression B2>C2 evaluates to FALSE (0) and B2<=C2 to TRUE (1), meaning that the reverse of the described above will occur.
3. Logical operators in Excel conditional formatting
Another common use of logical operators is found in Excel Conditional Formatting that lets you quickly highlight the most important information in a spreadsheet.
For example, the following simple rules highlight selected cells or entire rows in your worksheet depending on a value in column A:
Less than (orange): =A1<5
Greater than (green): =A1>20
For the detailed-step-by-step instructions and rule examples, please see the following articles:
As you see, the use of logical operators in Excel is intuitive and easy. In the next article, we are going to learn the nuts and bolts of Excel logical functions that allow performing more than one comparison in a formula. Please stay tuned and thank you for reading!
1250 comments
Trying again...
IF cell A=Apples and cell B10 but 20 but <30, then return cell C=500.
IF cell A=Grapes and cell B10 but 20 but <30, then return cell C=300.
IF Cell A=Apples and cell B10 but 20 but <30, then return cell C=500. IF cell A=Grapes and cell B10 but 20 but <30, then return cell C=300.
I don't know why I'm not able to publish my complete question. there is more to the above logic that I'm looking to add.
For some reason, it didn't post my complete question.
IF Cell A=Apples and cell B10 but 20 but <30, then return cell C=500. IF cell A=Grapes and cell B10 but 20 but <30, then return cell C=300.
I meant,
IF Cell A=Apples and cell B10 but 20 but <30, then return cell C=500.
IF cell A=Grapes and cell B10 but 20 but <30, then return cell C=300.
Hello, looking for formula for the below logical statement,
IF cell A=Apples and cell B10 but 20 but <30, then return cell C=500.
IF cell A=Grapes and cell B10 but 20 but <30, then return cell C=300.
Appreciate your help!!
cell A1=K, cell A2=L, Cell A3=K
Cell B1=10-Feb-2016, Cell B2=02-Feb-2016, cell B3=15-Feb-2016.
I need equation at cell A4 to show the maximum date relevant to item K (In column A) from the dates in column B, which is 15-Feb-2016.
Please advise me which formula should I use.
Thank you in advance.
iN ONE CELL"32*34*36" ,WANT TO MULTIPLY IN ANOTHER CELL WITHOUT RETYPING .iS IT POSSIBLE?
***HELP!!***
I need a formula for the following. It's kind of a multi-step process:
1. If A1=A2 and B1=B2, then return value TRUE.
2. If A1=A2 and B1B2, then return value FALSE.
3. But if A1A2, then disregard formula/leave blank.
I meant to say:
1. If A1=A2 and B1=B2, then return value TRUE.
2. If A1=A2 and B1 doesn't equal B2, then return FALSE.
3. But if A1 doesn't equal A2, then disregard formula/leave blank.
Hi Cameron,
Try the following formula:
=IF(AND(A1=A2, B1=B2), TRUE, IF(AND(A1=A2, B1<>B2), FALSE, ""))
I know it's confusing, but I ONLY want the B values to equal each other if the A values are equal... If the A values aren't equal, then I want the B values to forget that command and revert to only like values...Here's an example of what I mean:
A1:A7 all have the same value. If B1=B2=B3...=B7 then great! If B1:B7 DON'T have equal values, then I need an error notice. After A1:A7, there is another group of DIFFERENT like-values...A8:A15. For all of these, I need B8=B9=B10...=B15. If they don't, I need an error. Hope that helps.
Cameron,
My previous formula works for 2 cells only (A1 and A2). To compare groups of 7 cells, try the following one:
=IF(AND(COUNTIF($A$1:$A$7, $A1)=7, COUNTIF($B$1:$B$7, $B1)=7), TRUE, IF(AND(COUNTIF($A$1:$A$7, $A1)=7, COUNTIF($B$1:$B$7, $B1)<>7), FALSE, ""))
If cells A1:A7 have the same values and B1:B7 have the same values, the formula returns TRUE.
If cells A1:A7 have the same values but B1:B7 have different values, the formula returns FALSE. You can change this to any error message you want.
Otherwise, the formula returns an empty string.
Hi Svetlana!
Thank you so much for your quick replies. When I tried to enter this last formula, it gave me a notice for a circular reference? I clicked ok, and the formula returned a zero. Any ideas what this means/how to fix?
Secondly, I have an even more complex question for you (if that wasn't already hard enough). What if my first group is A1:A7 but the next grouping is A8:A18? What if it isn't always groups of 7, but it varies group size randomly down column A? Is there any way I can enter a formula to predict this, and always have the corresponding B values equal? (Where B1:B7 are equal and then B8:B18 would be equal, etc.) Again, I just need the formula to return True or False for these groupings. Thanks!!
If one date is greater than another date I need a return value of true and a count of the difference. Example if 02/01/2016 thru 02/06/2016 equals 5 days then true if not false. Also how many day greater or less? I will need the formula to continue throughout the year.
hi,
i want the cell to compare a number with another cell and copy the cell with greater value
I am struggling with this simple task .. can you pls help ?
I have an excel sheet with over 20,000 products with weight in decimals. I am trying to do this :
if weight is greater than 0.00 and/equal 1.0 then "0-1 lbs"
If weight is greater than 1.10 and/equal 2.00 then "1 and 2 lbs"
I am using =IF(AND(A2>0,A2<1),"0-1 lbs","") but this is not working for decimals
examples :
Weight (lbs)
0.10
0.01
0.02
0.03
0.04
0.05
0.06
0.07
0.08
0.09
0.10
0.11
0.12
0.13
Hi Vinay,
Try this one:
=IF(AND(A2>1.1,A2<=2),"1 and 2 lbs", IF(A2>0,"0-1 lbs",""))
Hello I have a weird request. So here is what I can tell you about this problem we have a system that if we reach 10.00 that is 100% if it falls below that then it is greater than 100% if it is greater than 10.00 then it would be lower than 100%. Is there a formula to do in excel that can figure this out or not really?
Hi there, need some help with between formula below is the formula I am trying to create
=if(r38 is between 0.5 and 8.5,U42,if(r38>9,0,if(r38 is between 9 and 14.5,v42,if(r38>14.5,0,if(r38 is between 15 and 18.5,w42,if(r38>18,0,if(r38=18.5 +,X42
Thank you,
the formula type out wrong...
it's
=IF(B18011200;40%*B1)
Hi Celeste,
Our blog engine often mangles formulas in comments, sorry for that.
Try the following formula:
=IF(B1>=1201; 40%*B1, IF(B1>=801; 30%*B1; 20%*B1))
It worked! Thank you Svetlana!!!
I need a help guyz..for eg when x>20 should proceed with a formula or when x<20 takes the other.please help me to create a formula buddies
What formulas you want to see when one of the conditions is met? Also, is 'x' in 'x>20' is a cell reference? Give us more details, so we would be able to help you out.
Hi Svetlana!
I need to automatically calculate, with a formula, for discounts in cell B1:
20% discount: less than $800 orders;
30% discount: orders from $801 to $1,200; and
40% discount: orders over $ 1,201.
I've used:
=IF(B18011200;40%*B1)
and I get the 20% and 40% discount calculation, but the 30% calculation is wrong. Can you correct it for me?
Thanks!
I want to multiply 2 cells, A11 and L11, but if the product is <=0 I want to enter Cell A11.
Hi Marlone ,
Try the following formula:
=IF(A1*L11<=0, A11, A1*L11)
Hello Svetlana could You please help
In cell H-4 I have an amt. 139629.11
In cell I-4 I need if formula showing down the column when copied
if the amt in h4 is same 00 if its grater show the difference if its less show the difference.
I am just an amateur mathematician but I do not know how to bit it
something is missing there
Thanks for Your help in advance. Jozef
Hi Svetlana!
In cell A1 I have the total sum of the order.
I need to automatically calculate, with a formula, for discounts in cell B1:
20% discount: less than $800 orders;
30% discount: orders from $801 to $1,200; and
40% discount: orders over $ 1,201.
Can you please help me?
Thanks!
I wanted to align my stock price bandwise with and if & and formulas please suggest
suppose Cell E Contains following and i wanted priceband 0-2, 2.1-5, 5.1-8, 8.1-12, 12.1-18 & 25+
100000
99990
299900
387666
789000
900000
1015000
1815000
1215000
1315000
2500000
Hi, I'm stuck and looking for help please.
I need to take a range of cells with dollar values and compare them to one cell with another dollar value. The range of cells which has the least dollar amount I need to show up as highlighted in a different colour. For example:
A1 = $100
Compare values in A2-A10, if A6 has the least (cheapest) value ($99) then this cell is highlighted in a stand out colour
Any help is greatly appreciated.
how I calculate in excel , If I dont need amount less than 1500 in a coloum.
Problem with conditional formatting using greater/lower than:
how do I skip a blank cell and compare with the previous cell?
Example: A1= 5, B1= blank, C1= 2
I need to know if C1 is greater/lower than B1, but if B1 is blank then I want to skip B1 and instead get result for C1 greater/lower than A1. What formula do I use to do this?
Thanks in advance!
Hi Niksua,
You can create 2 conditional formatting rules with the following formulas:
If B1 is not blank, highlight C1 when it's greater than B1:
=AND($B1<>"", $C1>$B1)
If B1 is blank, highlight C1 when it's greater than A1:
=AND($B1="", $C1>$A1)
bonus calculation suppose B4*0.0833 but not greater than 583
what is the formula than
Looking for how to return a value for a number that falls within certain ranges. For example:
If H10 is greater than 750, return 1
If H10 is between 650 and 749, return 2
If H10 is between 550 and 649, return 3
If H10 is less than 550, return 4.
So that if in cell H10 a number is entered, then in cell H11 a value of 1, 2, 3 or 4 will be displayed.
Any help would be appreciated. Thanks!
IF(H10=>750,1,IF(H10=>650,2,IF(H10=>550,3,4)
Suppose A1=A+B+C+D & A2=B+A+D+C , i apply =exact(A1=A2) but result is "False".
In Excel any other function for this. Reply me as early as possible.
Thank you...
Hello Bhanu,
EXACT is the right function for this task. Just note, the correct syntax is =EXACT(A1,A2)
You can test it in the following way. Enter some values in another column, say column C, and then type the following formulas:
In cell A1: =C1+C2+C3+C4
In cell A2: =C2+C1+C4+C3
Then enter the formula =EXACT(A1,A2) in some cell, and it will return TRUE.
say for example i have 2 colums with a lot of numbers they are not by each other how do I put all the numbers which are equal to each other in excel
AMAZINGLY CLEAR EXPLANATION, THANK YOU!!
I've only used the double unary operator trick several times over my 20 years of daily Excel use because no one has ever able to effectively explain what the two negative symbols did.
Now I can add this to my repertoire and actually KNOW what it does. PRICELESS!
I'm going crazy on this..
I need to create a conditional formatting meeting several criteria.
If a1>0 and = d1 OR b1>0 and = c1
Hi Mauriccio,
Try creating a conditional formatting rule with the following formula:
=OR(AND($A1>0, $A1=$D1), AND($B1>0, $B1=$C1))
Hi Svetlana, regarding to operator larger or smaller, I would like to know is there any operator to interpret data as below:
for example I have:
account code listed on column A: 1, 2, 3, 10, 20, 30, 100, 200, 300
Amount listed on column B: 1000, 2000, 3000, 4000, 5000, 60000, 7000, 8000, 9000
I want to use sumifs statement to summarize the amount when the account code is under 1XX (e.g. the sum of account codes 1, 10 and 100), in this case I don't think sumifs criteria using larger or smaller operator can sort out the account codes that I want....Do you have any idea on this?
Many thanks.
no worries, got it
okay about to give up. I need the number entered in one cell (which is D18 on my SS) to decide what range and assign the appropriate value. for example if the number is 1-8 then 3 would display in cell G18, if 9-16 than 6, if 17-25 than 9, if 26-34 than 12, 35 plus would be 15
previous post was incorrect
IF((C7>72700,9,"0"),IF(C7>227425208012143916<208012,2,"0"))
Need help with this formula
Vehicle and odometer readings
If cell C7 is 72700 or higher it is vehicle 9
227425 or higher 5
208012 or higher 21
143916 or higher 2
Hi!
You need to use nested IF functions and the correct syntax is as follows:
=IF(C7>=227425, 5, IF(C7>=208012, 21, IF(C7>=143916, 2, IF(C7>=72700, 9, 0))))
Hello,
Thank you for your prompt response. I very much appreciate it!
IF((C7>72700,9,"0"),IF(C7>227425208012143916<208012,2,"0"))
Need help with this formula
Vehicle and odometer readings
If cell C7 is 72700 or higher it is vehicle 9
227425 or higher 5
208012 or higher 21
143916 or higher 2
I need to create a function based on a decimal place
ex. 7.341, if the the decimal value is greater or lesser than .4, the value of "7" would be unknown lets say, if the number has a decimal point equal to .4 or greater the value of "7" stays the same, if the number has a decimal point of .39 or less than, we will subtract 1 from the "7". How do I put this into a function especially since the value is dependent on decimal points.
Hi Justyna,
If my understanding of the task is correct, one of the following formulas should work a treat (where A1 is the decimal number).
Return a decimal number:
=IF(A1-TRUNC(A1,0)>=0.4, A1, A1-1)
Return an integer:
=IF(A1-TRUNC(A1,0)>=0.4, TRUNC(A1,0), TRUNC(A1,0)-1)
I have to select multiply based on below conditions
If"value"600, then O.D+600
"value" cell is diameter of pipe
result of "then" statement is " width of trench"
required to bury that pipe.
the "width of trench" varies with pipe diameter.
can u help me write formulae for above
input"value" IS DIAMETER
output"Width"
I'm trying to create a formula to automatically compare two scores and return whether the game was a win, loss, or tie for the team in question. I understand how to handle just wins and losses [for instance, =IF(BS10>BR11,"W","L")], but the possibility of a tie complicates things. I've tried using the IF formula with the if true value set to "T" and the if false value as the equation above, but it is invalid. Is there a way to do this?
Hi Jake,
I think you can use the following nested IF's:
=IF(BS10>BR11,"W", IF(BS10<BR11, "L", "T"))
Hi,
can you help me our please
if G3 is greater than H3 I want to have these 2 cells to be subtracted as G3-H3, if G3 is lesser than H3 I want to have these 2 cells to be subtracted as H3-G3
i had used the below formula but error occurred so can you help me please
=IF(G3>H3),"G3-H3",IF(G3>H3),"H3-G3"
Many Thanks Svetlana,
in need:
L9 = 3000 if k9=(100% to 120%)
L9=4000 IF K9 =(121%-130%)
L9=5000 IF K9 greater than 131%
J8= 0% IF E8=(0% TO 50%)
J8= 10% IF E8=(51% TO 60%)
J8= 15% IF E8=(61% TO 80%)
J8= 20% IF E8=(greater than 81%)
Best Regards
Majed
How would you type an IF statement for a cell that is equal to 50 , 500, or 550 to be multiplied by formula x but for all other values to be multiplied by formula y.
Hi Taquana,
You can use a formula similar to this:
=IF(OR(A1=50, A1=500, A1=550), A1*x, Z1*y)
Hi Svetlana,
i need value in H2 = E2 when it< or = the value in G2
if this value greater than the value in G2 then the value in H2=the value in G2
THANKS,
Hi Majed,
Here's the formula for H2:
=IF(E2<=G2, E2, G2)
Many Thanks Svetlana,
in need:
L9 = 3000 if k9=(100% to 120%)
L9=4000 IF K9 =(121%-130%)
L9=5000 IF K9 greater than 131%
J8= 0% IF E8=(0% TO 50%)
J8= 10% IF E8=(51% TO 60%)
J8= 15% IF E8=(61% TO 80%)
J8= 20% IF E8=(greater than 81%)
Best Regards
Majed
Hi
I wonder if you could help me please, I need to set up a formula which will allow me to charge based upon numbers;
i.e
100 or less = £35
101 to 200 = £45
201 to 300 = £55
301 to 400 = £65
401 to 700 = £75
701 to 1000 = £100
Many Thanks,
Hello Susan,
You can use the following nested IF functions:
=IF(A1>700,100, IF(A1>400,75, IF(A1>300,65, IF(A1>200,55, IF(A1>100,45,35)))))
Hi Svetlana,
Happy Holidays! I would like to know if you would be able to help me with my request no. 248, above. I appreciate it very much!
Sincerely,
Lorena
Happy holidays to you too, Lorena!
You can use the following nested IF functions (where A1 is total points):
=IF(A1>359, "A", IF(A1>319, "B", IF(A1>279, "C", IF(A1>239, "D", "F"))))
You can find the detailed explanation of the formula's syntax and logic in this tutorial:
https://www.ablebits.com/office-addins-blog/nested-if-excel-multiple-conditions/
Thank you so much, Svetlana! I am looking forward to trying this.
Sincerely,
Lorena
Please help.
This is my problem:
start time 08:00 am End time 19:00 pm
Start time 18:30 pm End time 22:00 pm
If the shift starts after 18:00 or ends after 18:00 a night allowance of R15,00 is payed.
How do I do this function.
this is what I have come up with ,but what I need is c2(start time) or d2(end time)is greater than 18:00 then the allowance needs to be paid.
=IF(C2>0,75;G2+15;G2)
Hi Lance,
If C2 and D2 are time values, you can use a formula similar to this one:
=IF(OR(C2>TIME(18;0;0); D2>TIME(18;0;0)); G2+15; G2)
Hi Elexed.Can you put this formula
=$G8+MIN(IF($F8<5,5000,IF($F8<10,7500,IF($F8<15,10000,IF($F8<20,12500,IF($F8<25,15000,IF($F8<30,17500,20000)))))),ROUND(IF($F8<5,0.2,IF($F8<10,0.3,IF($F8<15,0.4,IF($F8<20,0.5,IF($F8<25,0.6,IF($F8<30,0.7,0.8))))))*G8,0))
I need these condition:
1. If b=0 = a/2
2. if b<=0, a<=0 = 0
3. if b<=0 = 0
I use these 2 formula :
=IF(E1=0,"",IF(D1<=0,"")))
=IF(E1=0,D1/2,0),elseif(E1<=0&D1=0,0)
but when b<=0, a<=0 this is not working. that I want to mean- if both b&a cell negative or <=0 it is not working. Is it possible for those 3 condition apply in excel.
Please Help me.
Dider-E-Elahi
Hi,
I am trying to use IF/AND to look at two cells that each could contain either "TRUE", "FALSE" or 'blank'. and return either "G" if both are TRUE ... "A" if one cell is "TRUE" and the other either "FALSE" or 'blank' ... "R" if neither contain "TRUE" or both are "FALSE" or 'bank'etc..
I have tried this formula
=IF(AND(Sheet2!B11="TRUE", Sheet2!B14="TRUE"),"G", IF(AND(Sheet2!B11="TRUE", Sheet2!B14="FALSE"),"A", IF(AND(Sheet2!B11="", Sheet2!B14="TRUE"),"A", IF(AND(Sheet2!B11="", Sheet2!B14=""),"R", IF(AND(Sheet2!B11="TRUE", Sheet2!B14=""),"A", IF(AND(Sheet2!B11="", Sheet2!B14="FALSE"),"R", IF(AND(Sheet2!B11="FALSE", Sheet2!B14="FALSE"),"R", IF(AND(Sheet2!B11="FALSE", Sheet2!B14=""),"R", IF(AND(Sheet2!B11="FALSE", Sheet2!B14="TRUE"),"R")))))))))
But the only permutation that returns a result is if they are both blank.. the rest return "FALSE"
Please help
Hi!Kindly affix one formula in proposed salary column which may taken into account tenure in Hospital, present salary & auto increase & %age of present salary as per given policy schedule & pick the figure which is lower side & then apply the same amount as Marginal Increase in salary. In short i want to implement the policy schedule for proposed increase in salary.
1 A-0412 2/1/2014 29D.10M,1Y 34,225 (34,225)
2 A-0416 1/27/2015 3D.11M,0Y 33,472 (33,472)
3 A-0431 1/1/2007 29D.11M,8Y 38,824 (38,824)
Range of Years Worked Maximum Limit of Increase in Salary
Below 5 Lower of 5,000 or 20 % of present salary
5-10 Lower of 7,500 or 30 % of present salary
10-15 Lower of 10,000 or 40 % of present salary
15-20 Lower of 12,500 or 50 % of present salary
20-25 Lower of 15,000 or 60 % of present salary
25-30 Lower of 17,500 or 70 % of present salary
30-35 Lower of 20,000 or 80 % of present salary
Hello,
I have a bunch of numbers that are updating in column B (around 100 rows of percentages and their symbol in column A) every fifteen minutes. I want to display only the ones that are less than -5% or greater than 5% with their symbol. Is there a way to do this and display it in a new list so it only shows these values in a condensed list?
Hi Svetlana
Now it my issue is resolved, You are "GENIUS", Thanks a lot, Have a Great Happy Life and Happy New Year, God Bless You.
I really appreciate and thank you again.
Asad
Hi Svetlana
I mean to say, for example if I receive 10 items in "QTY RECEIVED" in Col-A and issue 11 items in "QTY ISSUED" in Col-B then your formula is showing -1 in "QTY BALANCE" in Col-F, I want that is should also show "error" in stead of -1.
Thanks
Asad
Hi Asad,
Here you go:
=IF(AND($B2<=$A2, SUM($C2:$E2)=$B2), $A2-$B2, "error")
Hi
How to check greater than 30 but less than 60 in a cell. Imagine value is in Cell A1.
Hi Ihsan,
You need to use an AND statement like this: AND(A1>30, A1<60)
For example, =IF(AND(A1>30, A1<60), "OK", "Not OK")