Excel logical operators: equal to, not equal to, greater than, less than

Many tasks you perform in Excel involve comparing data in different cells. For this, Microsoft Excel provides six logical operators, which are also called comparison operators. This tutorial aims to help you understand the insight of Excel logical operators and write the most efficient formulas for your data analysis.

Excel logical operators - overview

A logical operator is used in Excel to compare two values. Logical operators are sometimes called Boolean operators because the result of the comparison in any given case can only be either TRUE or FALSE.

Six logical operators are available in Excel. The following table explains what each of them does and illustrates the theory with formula examples.

Condition Operator Formula Example Description
Equal to = =A1=B1 The formula returns TRUE if a value in cell A1 is equal to the values in cell B1; FALSE otherwise.
Not equal to <> =A1<>B1 The formula returns TRUE if a value in cell A1 is not equal to the value in cell B1; FALSE otherwise.
Greater than > =A1>B1 The formula returns TRUE if a value in cell A1 is greater than a value in cell B1; otherwise it returns FALSE.
Less than < =A1<B1 The formula returns TRUE if a value in cell A1 is less than in cell B1; FALSE otherwise.
Greater than or equal to >= =A1>=B1 The formula returns TRUE if a value in cell A1 is greater than or equal to the values in cell B1; FALSE otherwise.
Less than or equal to <= =A1<=B1 The formula returns TRUE if a value in cell A1 is less than or equal to the values in cell B1; FALSE otherwise.

The screenshot below demonstrates the results returned by Equal to, Not equal to, Greater than and Less than logical operators:
Using Equal to, Not equal to, Greater than and Less than in Excel

It may seem that the above table covers it all and there's nothing more to talk about. But in fact, each logical operator has its own specificities and knowing them can help you harness the real power of Excel formulas.

Using "Equal to" logical operator in Excel

The Equal to logical operator (=) can be used to compare all data types - numbers, dates, text values, Booleans, as well as the results returned by other Excel formulas. For example:

=A1=B1 Returns TRUE if the values in cells A1 and B1 are the same, FALSE otherwise.
=A1="oranges" Returns TRUE if cells A1 contain the word "oranges", FALSE otherwise.
=A1=TRUE Returns TRUE if cells A1 contain the Boolean value TRUE, otherwise it returns FALSE.
=A1=(B1/2) Returns TRUE if a number in cell A1 is equal to the quotient of the division of B1 by 2, FALSE otherwise.

Example 1. Using the "Equal to" operator with dates

You might be surprised to know that the Equal to logical operator cannot compare dates as easily as numbers. For example, if the cells A1 and A2 contain the date "12/1/2014", the formula =A1=A2 will return TRUE exactly as it should.

However, if you try either =A1=12/1/2014 or =A1="12/1/2014" you will get FALSE as the result. A bit unexpected, eh?

The point is that Excel stores dates as numbers beginning with 1-Jan-1900, which is stored as 1. The date 12/1/2014 is stored as 41974. In the above formulas, Microsoft Excel interprets "12/1/2014" as a usual text string, and since "12/1/2014" is not equal to 41974, it returns FALSE.

To get the correct result, you must always wrap a date in the DATEVALUE function, like this =A1=DATEVALUE("12/1/2014")
Using Excel's equal to operator with dates

Note. The DATEVALUE function needs to be used with other logical operator as well, as demonstrated in the examples that follow.

The same approach should be applied when you use Excel's equal to operator in the logical test of the IF function. You can find more info as well as a few formula examples in this tutorial: Using Excel IF function with dates.

Example 2. Using the "Equal to" operator with text values

Using Excel's Equal to operator with text values does not require any extra twists. The only thing you should keep in mind is that the Equal to logical operator in Excel is case-insensitive, meaning that case differences are ignored when comparing text values.

For example, if cell A1 contains the word "oranges" and cell B1 contains "Oranges", the formula =A1=B1 will return TRUE.

If you want to compare text values taking in to account their case differences, you should use the EXACT function instead of the Equal to operator. The syntax of the EXACT function is as simple as:

EXACT(text1, text2)

Where text 1 and text2 are the values you want to compare. If the values are exactly the same, including case, Excel returns TRUE; otherwise, it returns FALSE. You can also use the EXACT function in IF formulas when you need a case-sensitive comparison of text values, as shown in the below screenshot:
Using the EXACT function for case-sensitive comparison of text values

Note. If you want to compare the length of two text values, you can use the LEN function instead, for example =LEN(A2)=LEN(B2) or =LEN(A2)>=LEN(B2).

Example 3. Comparing Boolean values and numbers

There is a widespread opinion that in Microsoft Excel the Boolean value of TRUE always equates to 1 and FALSE to 0. However, this is only partially true, and the key word here is "always" or more precisely "not always" : )

When writing an 'equal to' logical expression that compares a Boolean value and a number, you need to specifically point out for Excel that a non-numeric Boolean value should be treated as a number. You can do this by adding the double minus sign in front of a Boolean value or a cell reference, e. g. =A2=--TRUE or =A2=--B2.

The 1st minus sign, which is technically called the unary operator, coerces TRUE/FALSE to -1/0, respectively, and the second unary negates the values turning them into +1 and 0. This will probably be easier to understand looking at the following screenshot:
Comparing Boolean values and numbers

Note. You should add the double unary operator before a Boolean when using other logical operators such as not equal to, greater than or less than to correctly compare a numeric and Boolean values.

When using logical operators in complex formulas, you might also need to add the double unary before each logical expression that returns TRUE or FALSE as the result. Here's an example of such a formula: SUMPRODUCT and SUMIFS in Excel.

Using "Not equal to" logical operator in Excel

You use Excel's Not equal to operator (<>) when you want to make sure that a cell's value is not equal to a specified value. The use of the Not equal to operator is very similar to the use of Equal to that we discussed a moment ago.

The results returned by the Not equal to operator are analogous to the results produced by the Excel NOT function that reverses the value of its argument. The following table provides a few formula examples.

Not equal to operator NOT function Description
=A1<>B1 =NOT(A1=B1) Returns TRUE if the values in cells A1 and B1 are not the same, FALSE otherwise.
=A1<>"oranges" =NOT(A1="oranges") Returns TRUE if cell A1 contains any value other than "oranges", FALSE if it contains "oranges" or "ORANGES" or "Oranges", etc.
=A1<>TRUE =NOT(A1=TRUE) Returns TRUE if cell A1 contains any value other than TRUE, FALSE otherwise.
=A1<>(B1/2) =NOT(A1=B1/2) Returns TRUE if a number in cell A1 is not equal to the quotient of the division of B1 by 2, FALSE otherwise.
=A1<>DATEVALUE("12/1/2014") =NOT(A1=DATEVALUE("12/1/2014")) Returns TRUE if A1 contains any value other than the date of 1-Dec-2014, regardless of the date format, FALSE otherwise.

Greater than, less than, greater than or equal to, less than or equal to

You use these logical operators in Excel to check how one number compares to another. Microsoft Excel provides 4 comparison operates whose names are self-explanatory:

  • Greater than (>)
  • Greater than or equal to (>=)
  • Less than (<)
  • Less than or equal to (<=)

Most often, Excel comparison operators are used with numbers, date and time values. For example:

=A1>20 Returns TRUE if a number in cell A1 is greater than 20, FALSE otherwise.
=A1>=(B1/2) Returns TRUE if a number in cell A1 is greater than or equal to the quotient of the division of B1 by 2, FALSE otherwise.
=A1<DATEVALUE("12/1/2014") Returns TRUE if a date in cell A1 is less than 1-Dec-2014, FALSE otherwise.
=A1<=SUM(B1:D1) Returns TRUE if a number in cell A1 is less than or equal to the sum of values in cells B1:D1, FALSE otherwise.

Using Excel comparison operators with text values

In theory, you can also use the greater than, greater than or equal to operators as well as their less than counterparts with text values. For example, if cell A1 contains "apples" and B1 contains "bananas", guess what the formula =A1>B1 will return? Congratulations to those who've staked on FALSE : )

When comparing text values, Microsoft Excel ignores their case and compares the values symbol by symbol, "a" being considered the lowest text value and "z" - the highest text value.

So, when comparing the values of "apples" (A1) and "bananas" (B1), Excel starts with their first letters "a" and "b", respectively, and since "b" is greater than "a", the formula =A1>B1 returns FALSE.

If the first letters are the same, then the 2nd letters are compared, if they happen to be identical too, then Excel gets to the 3rd, 4th letters and so on. For example, if A1 contained "apples" and B1 contained "agave", the formula =A1>B1 would return TRUE because "p" is greater than "g".
Using Excel comparison operators with text values

At first sight, the use of comparison operators with text values seems to have very little practical sense, but you never know what you might need in the future, so probably this knowledge will prove helpful to someone.

Common uses of logical operators in Excel

In real work, Excel logical operators are rarely used on their own. Agree, the Boolean values TRUE and FALSE they return, though very true (excuse the pun), are not very meaningful. To get more sensible results, you can use logical operators as part of Excel functions or conditional formatting rules, as demonstrated in the below examples.

1. Using logical operators in arguments of Excel functions

When it comes to logical operators, Excel is very permissive and allows using them in parameters of many functions. One of the most common uses is found in Excel IF function where the comparison operators can help to construct a logical test, and the IF formula will return an appropriate result depending on whether the test evaluates to TRUE or FALSE. For example:

=IF(A1>=B1, "OK", "Not OK")

This simple IF formula returns OK if a value in cell A1 is greater than or equal to a value in cell B1, "Not OK" otherwise.

And here's another example:

=IF(A1<>B1, SUM(A1:C1), "")

The formula compares the values in cells A1 and B1, and if A1 is not equal to B1, the sum of values in cells A1:C1 is returned, an empty string otherwise.

Excel logical operators are also widely used in special IF functions such as SUMIF, COUNTIF, AVERAGEIF and their plural counterparts that return a result based on a certain condition or multiple conditions.

You can find a wealth of formula examples in the following tutorials:

2. Using Excel logical operators in mathematical calculations

Of course, Excel functions are very powerful, but you don't always have to use them to achieve the desired result. For example, the results returned by the following two formulas are identical:

IF function: =IF(B2>C2, B2*10, B2*5)

Formula with logical operators: =(B2>C2)*(B2*10)+(B2<=C2)*(B2*5)
Using Excel logical operators in mathematical calculations

I guess the IF formula is easier to interpret, right? It tells Excel to multiply a value in cell B2 by 10 if B2 is greater than C2, otherwise the value in B1 is multiplied by 5.

Now, let's analyze what the 2nd formula with the greater than and less than or equal to logical operators does. It helps to know that in mathematical calculations Excel does equate the Boolean value TRUE to 1, and FALSE to 0. Keeping this in mind, let's see what each of the logical expressions actually returns.

If a value in cell B2 is greater than a value in C2, then the expression B2>C2 is TRUE, and consequently equal to 1. On the other hand, B2<=C2 is FALSE and equal to 0. So, given that B2>C2, our formula undergoes the following transformation:
Formula with logical operators

Since any number multiplied by zero gives zero, we can cast away the second part of the formula after the plus sign. And because any number multiplied by 1 is that number, our complex formula turns into a simple =B2*10 that returns the product of multiplying B2 by 10, which is exactly what the above IF formula does : )

Obviously, if a value in cell B2 is less than in C2, then the expression B2>C2 evaluates to FALSE (0) and B2<=C2 to TRUE (1), meaning that the reverse of the described above will occur.

3. Logical operators in Excel conditional formatting

Another common use of logical operators is found in Excel Conditional Formatting that lets you quickly highlight the most important information in a spreadsheet.

For example, the following simple rules highlight selected cells or entire rows in your worksheet depending on a value in column A:

Less than (orange): =A1<5

Greater than (green): =A1>20
Using logical operator in Excel conditional formatting

For the detailed-step-by-step instructions and rule examples, please see the following articles:

As you see, the use of logical operators in Excel is intuitive and easy. In the next article, we are going to learn the nuts and bolts of Excel logical functions that allow performing more than one comparison in a formula. Please stay tuned and thank you for reading!

Table of contents

1250 comments

  1. Hi Svetlana

    can you please help me about find out formula against my Question No. 246, I will really appreciate.

    Thanks

    asad

    • Hi Asad,

      If my understanding of your task is correct, the following formula should do a trick:

      =IF(SUM($C2:$E2)=$B2, $A2-$B2, "error")

      • Hi Svetlana

        Thanks a lot for your help, it is almost done, formula is working except a little more help, if value of column A and B does not match then it should also show error.

        Thank you again.

        Asad

        • Hi Asad,

          My understanding was that A and B can be different values, because we calculate their difference. Please clarify what you mean by "A and B does not match".

  2. Hi

    I need a formula when, whereby the value ranges from -0.03 to 0.03, it should appear as True. And if there are other values, it should appear as False. Please help with this. Thank You.

  3. Hello,
    I'm working on a spreadsheet for grades in my class. I have a column that includes the total points earned by each student. I would like to set up a rule that would give an output if the total points are within a particular range. For example, if the total points are between 360 and 400, the output would be an "A," If the points are between 320-359, the output would be a "B" etc. I was able to make it work with an IF(AND but once I added a third condition, it wouldn't work. I'm also not sure how to format the rule when I want the cell I'm referencing to be in between a set of numbers. For example 319<Cell<360. What do you recommend?

    This is my grading scale in case it helps.
    A 400-360
    B 359-320
    C 319-280
    D 279-240
    F 239-0

    Thanks for your help!!

  4. I am trying to find a formula that will take a (24 hour) time in one cell, compare it to a (24 hour) time in a different cell and if the second cell is greater than "13:00:00", enter "13" in a separate cell.

    From my information:
    if 24:00:00 (in cell e9) is greater than 13:00:00 (in cell f9), then cell h9 will equal "13".

  5. Hi Svetlana

    I am making inventory sheet and facing problem about calculation the Balance QTY. let me explain here; I have made total 6 columns;

    Col A - 10 QTY. Received
    Col B - 7 QTY. Issued
    Col C - 4 QTY. Installed
    Col D - 1 QTY. Returned
    Col E - 1 QTY. DEAD
    Col F - QTY. Balance

    I have purchased 10 items and issued 7, that means 3 items should be shown in balance, but my inventory record justifying total 6 items of column C,D and E. So it should show error in column F until I find 1 missing item? Because I have issued total 7 and if total items of C,D and E matches with column B then 3 items should show in column F Balance.

    I will really appreciate for your help.

    Thanks

    Asad

  6. i want compare Column F2 & E2 for 10% difference and display it fg in windings3 in column C hoow can this be achieved?

    This is what i have at the moment.

    =IF(F2=E2*0,9,F2<=E2*1,1),"fg","i"))

    • =IF(F2=E2*0,9,F2<=E2*1,1),"fg","i"))

  7. Hi Svetlana,

    I'm trying to calculate the following:
    If cell A is greater than or equal to cell B, and cell C is greater than or equal 930, cell F will pay x amount.

    Thanks in advance for your help.

    Al

    • Hi Al,

      You can use a formula similar to this:
      =IF(AND(A1>=B1, C1>=930), 10, "")

      Where 10 is x amount.

  8. Hi Svetlana

    I am making inventory sheet and facing problem about calculation the Balance QTY. let me explain here; I have made total 6 columns;

    Col A - 10 QTY. Received
    Col B - 7 QTY. Issued
    Col C - 4 QTY. Installed
    Col D - 1 QTY. Returned
    Col E - 1 QTY. DEAD
    Col F - QTY. Balance

    I have purchased 10 items and issued 7, that means 3 items should be shown in balance, but my inventory record justifying total 6 items of column C,D and E. So it should show error in column F until I find 1 missing item? Because I have issued total 7 and if total items of C,D and E matches with column B then 3 items should show in column F Balance.

    I will really appreciate for your help.

    Thanks

    Asad

  9. Ok, I have multiple formulas going on.

    Cells A:A I input different numbers from 0 to 38.

    Cell ak1 =0, al1 = 1, am1 = 3 etc.

    Under each cell example (ak2, I have =countif (a1:a120,ak1) giving me the results of how many times ak1 (0) appears in column a1:a120.

    Each of these results in different amounts. I would like to sort the greatest amounts to the lesser amounts displaying the number in ak1 not ak2 thru cells b2:b39

    For example if 9 shows up 7 times and is the most I want 9 to show in cell b2 and then then next lesser number to appear in b3, etc.

  10. =IF(G10>=0=1000=1000=6000=9000,"EXCELLENT")

  11. Hi I need to compare Data in 2 sheets on a daily basis. I have a list of products names (in Alphabetical order) in Row A that have best before dates (CODE LIFE) in row I. I need to know if the best before date changes at all by + or - 5days. However the products in row A may not always be in the same order or even there as we may have sold out of the product under that BBD or Sent more product! today I may have 3 lines of Product A but tomorrow I may only have 2?? could you help please??

  12. HELP!! I need help on a formula
    If D15 is less than 21, but greater 101, then c5+c6+c7+c8*d15

    thanks in advance!!

    • Hi Christa,

      No number can be less than 21, but greater than 101 :) Do you mean greater than 21 and less than 101?

  13. I need help on a formula

    If J3 is less than 65 then A
    If J3 is equal to 65 then B
    If J3 is greater than 65 then C

    Thanks

    • Hi!

      You can use the following nested IF's:

      =IF(J3<65, "A", IF(J3=65, "B", "C"))

  14. i need help on this its about paye(pay as you earn)
    want to work this out
    if B11 is greater than 25000 it must subtract 25000 from it and the remainder multiply by 30% and add 750, if less than 25000 but greater than 20000 it must subtruct 20000 and multiply the remainder with 15% and if its 20000 below it must do nothing

  15. 0.75 <= x < 1.25
    please some body explain it to me

    • Hello Mehmood,

      In Excel formulas, you express this condition using the following AND statement: AND(A1>=0.75, A1<1.25)

  16. hallo

    i have token system
    how to use which formula for token calculate.

    value is
    150-600 is 1
    601-1000 is 2
    1001-2000 is 3
    2001-3000 is 4
    3001-4000 is 5
    40001-Above 6

    Please reply fast.

  17. Need to clarify the above question again

    i have to calculate c21*d21 to f21, if f21 value is equals to or less than "20" then f21 should show as "20" (20 is the minimum value) if the result is greater than "20" then the actual value should show in F21

  18. Hi Svetlana Cheushev,

    I have to calculate c21*d21 to f21, if f21 value is = 20 then f21 should show the actual value in F21

    can you help please.

  19. my previous post doesn't show everything I typed:

    I would like to have a well report a p value asterisk according to the following criteria:
    >0.05 "ns"
    less than or equal to 0.05 but greater than 0.01 "*"
    less than or equal to 0.01 but greater than 0.001 "**"
    anything <=0.0001 "***"
    Can anyone help?

  20. I would like to have a well report a p value asterisk according to the following criteria:
    >0.05 "ns"
    0.01 "*"
    0.001 "**"
    anything <=0.0001 "***"

    Can anyone help me write this function? Thanks!

  21. Hi i would like help with my formula
    If value1 is lower than 30 and value2 is lower than 30 equals 24,
    if not value1 is greater than 30 and value2 is greater than 30 equals 22,
    if not value1 is greater than 60 and value2 is greater than 60 equals 20.

    What i want is to check the size of something and give a range according to 2 measures, i mean if size is 24x28 the value is 24; if size is 24 x 40 the value is 22; if value is 60x24 the value is 20. It all depends on both sizes.

  22. Want to put age groups against age collected in a column. Was using if(A1>=20&A1<=25,"20-25","OKAY","NOT IN AGE LIMIT"). but not getting answer. Wanted to use nested if for more options.

  23. what is the wrong in the below formal

    =IF(G65,G610,2)

  24. I need to combine these 3 formulas into one
    1. A = less than or Equal to 5
    1. IF(AND(A15, A110,2, "0")

    thanks for your help

    • Hi Hebah,

      I think you are looking for a nested IF formula like this:
      =IF(A1<=5, 1, IF(A1<10, 1.5, 2))

      The formula does the following:

      If A1<=5, return 1
      If A1>5 and <10, return 1.5
      If A1>=10, return 2

  25. I have three categories
    First on = 1
    Second one = 1.5
    Thread one = 2
    How I can do if function to get the below result
    = if (cell Nuber on 5 and <10 ,1.5,If cell Nuber on <10,2)

  26. I have three categories
    First on = 1
    Second one = 1.5
    Thread one = 2
    How I can do IF function to get the below result
    = if (C15 and <10 ),(1.5),If (C1 <10),(2)

  27. Apols Svetlana, seem to have deleted some of the text by accident before sending last comment. It should read:
    The formula i am trying returns the Medium scores as FALSE, which is: =IF(BU10>15,"High",IF(BU10>7<16,"Medium",IF(BU1015,"High",IF(BU107,"Medium",IF(BU10<8,"Low"))) it won't recognise the any of the Low scores.

    Kind regards,

    Terry

  28. Hi Svetlana,

    On a spreadsheet I am trying to give a word label to ranges of values in the previous cell. The formula i am trying is:=IF(BU10>15,"High",IF(BU10>7<16,"Medium",IF(BU1015,"High",IF(BU107,"Medium",IF(BU10<8,"Low"))) it won't recognise the any of the Low scores.

    Can you advise?

    Kind regards,

    Terry

  29. How do I solve with a formula when I input cell A1 any value ranged from 1000 to 7150 then cell A2 is equal to formula (A1/1000)*3.5, otherwise A2 should displays as 0?
    Thank you!

  30. How can you use the "unique" conditional formatting function ONLY when the cell is greater than zero or ""? Thanks

  31. Hi. My problem is this
    I need the sum of cell:
    A1: where when I type 1 it would have a value of 20, 2 would have a value of 25, and 3 would have a value of 60

    B1: where whatever value i would put would be multiplied by 60

    thanks very much

  32. hi,
    i just wanted to know that how can i compare from 3 row with each other with the percentage eg:A col contain 2.2,B col contain 2.25 and c col contain 2.23
    now which is greater by 5% can anybody help on this

  33. I am attempting to find imbalances amongst sum formulas. Some of the cells contain errors (#N/A) that I want to ignore. How do I do that?

    =IF((AND(J20,M20,P20)),"","X") is my current formaula but returns #N/A because of the errors. What should I change?

    Thanks

  34. Below formula will show me the latest date if A1 and B1 matches, if no match it show FALSE. I want the cell to be empty.

    =IF(A1=B1;MAX(F8:F100))

    • Sorry wrong cell count F8-F100,

      Anyway I got the correct formula!

      =IF(A1=B1;MAX(B2:B100);"")

      This will make sure C1 is empty when A1 and B1 is matching

  35. Hi,

    I have 3 cells, A1 Total ordered (numbers) and B1 received orders (numbers), C1 should tell me the date when A1 and B1 matches.
    Is that possible?

    Or even better if possible:
    Total ordered A1 is counting dates typed in the column A2-A100. Same with received orders B1, counting dates from B2-B100.
    C1 could find the latest date from B2-B100 and then in formula make sure A1 and B1 matches to show the latest date from B2-B100, if no match then empty.
    That would make sure that today date is not late due to typing of the dates in the A and B column.

  36. how can i program a value that when i encode A instead of 1... so that when it will be summed up, it will still count as 1 and not 0?

  37. Hello,

    I need some help for an IF function to display the logical test for a number which is "greater than or equal to 1 and less than or equal to 30".
    Could you please suggest what I can put for this in the logical test?

    Twinkle

  38. Hi Svetlana, thank you for your help. I have two more questions:

    1)I need to have the following If statement return a blank value (a cell that is truly blank and doesn’t say “blank”) if it is false

    =IF(C10>I10, "YES")

    2)Using conditional formatting, is there a way to have two rules in one cell. For example, say I have a formula in C1 that can return a value of either “YES” or “NO”. If in cell D1 I want the cell to be highlighted green if the value in C1 is “NO” and red if the value was “YES”. How can I accomplish this?

    Thanks

  39. Need your help... not sure what formula i need to have to get the time interval between 2 time duration in minutes. also i need to have a message box error informing me that time interval should be atleast 5 minutes...

    =IFERROR(F22-E22)*1440

    • Hi Jay,

      You can use a formula similar to this:
      =IF((F22-E22)*1440>5, (F22-E22)*1440, "less than 5 min")

      This won't display a message box, but insert the text "less than 5 min" in the cell if the time difference is less than 5 minutes.

  40. If I am trying to compare the following data...how would I write out the IF statement?

    If B7 is the same as B22 than it needs to equal d22?

  41. Hi, I need a formula for this:

    =IF(A1="YES”, B1+C1*0.93)

    So what I am looking for is if column A says "YES" then the value from the formula B1 + C1 * .93 will show in the cell I put this formula in.

    • Hi Adam,

      Your formula is correct. If it does not work as you expected, then please give an example - what values you have in B1 and C1 and what is the expected result.

    • =IF(A1="YES", B1+C1*0.93, ())

  42. I need to creaate a formula that calculates an amount based on the following:
    If amount =1,000,000 multiply by 70%, but if it is between 1,000,001 and 1,499,000 multiply by 80%, but if it is greater than 1,500,000 multiply by 90%, if it less than 1,000,000 make it = 0. Can you help?

  43. =IF(AND(A1>=80,A1=91,A1=101,A1=111,A1<=121),"SOUTH",))))

    already got it

  44. hi svetlana,

    i have a table of customer sales and want to grade them according to month spend, A, B, C and D. what formula would i need to define as per below;
    A = greater than 80,000
    B = greater than 41,000 and less than 80,000
    C = greater than 25,000 and less than 41,000
    D = less than 25,000 and greater than 0

    thanks in advance and look forward to you reply.

    daniel.

  45. hello i need help,
    for example,
    If A1 is equal to 80 up to 90 = EAST
    if 91-100 = NORTH
    if 101 -110 = SOUTH
    if 111-121 = WEST

    how can i make this in a if statement

  46. =COUNTIF('15 PP YR '!D5:NG5,"f")+IF(B3="FT">480,B3="PT">300)

    Here is what I have attempted. '15 PP YR'is a sheet, D5:NG5-adds up a row, if F. and then not sure which formula to use for if FT = full time the max is 480 turn red if above 480, then for PT = part time the max is 300 then turn red. Thanks for any help you can provide.

    • I haven't gotten any assistance on my question, is there anything else you need. Thanks for any help, you can provide.

  47. hi please help me to create a formula-

    i want that the value should be count when the cell values is divide by 5 or grater than or equal by 5.

    For ex:- in 2 cell value is 2 0r 3 then sum should be 0 as per my condition (not divide not grater or equal to 5)

    if value 5 or 6 then sum should be 10. (both of divide by 5 and 2nd remains 1 but should not count in sum.)

    Ex2:- in three cell value is 5, 4, 7 then sum should be 10 (not count 4, value less from 5 & not divide 5)
    or
    if value is 15, 22, 34 then sum should be 65. (remains 0, 2, 4 which not counted.)

    or tell me formula for value of %.

  48. I need a assistance with a formula. In column a1 will be either FT OR PT, column b1 totals from sheet1 and needs to include if less than 300 if "PT" then RED OR if greater than 480 if "FT" then RED. How would I write that formula? Thanks for any help.

  49. Hi,
    I need help whit this:

    IF A2=1, how to autocomplete B2=0 and C2=0

    I need to type 1 in first column and the next two columns autocomplet whit 0(zero)

    Thank you!

    • *in B2 =IF(A2=1,0,())
      *in B3 =IF(A2=1,0,())

  50. Start Week Close Week Week No
    24-Oct-15 30-Oct-15 84
    31-Oct-15 6-Nov-15 85
    7-Nov-15 13-Nov-15 86
    14-Nov-15 20-Nov-15 87
    21-Nov-15 27-Nov-15 88
    28-Nov-15 4-Dec-15 89
    5-Dec-15 11-Dec-15 90
    12-Dec-15 18-Dec-15 91
    19-Dec-15 25-Dec-15 92
    26-Dec-15 1-Jan-16 93
    2-Jan-16 8-Jan-16 94
    9-Jan-16 15-Jan-16 95
    16-Jan-16 22-Jan-16 96
    23-Jan-16 29-Jan-16 97
    30-Jan-16 5-Feb-16 98

    Could you please help me to provide IF(AND) formula for assigning week no
    For eg 20-Dec-2105 which is week 92

Post a comment



Thank you for your comment!
When posting a question, please be very clear and concise. This will help us provide a quick and relevant solution to
your query. We cannot guarantee that we will answer every question, but we'll do our best :)