by In this tutorial, we will continue exploring the fascinating world of Excel Conditional Formatting. If you do not feel very comfortable in this area, you may want to look through the previous article first to revive the basics - How to use conditional formatting in Excel.
Today are going to dwell on how to use Excel formulas to format individual cells and entire rows based on the values you specify or based on another cell's value. This is often considered advanced aerobatics of Excel conditional formatting and once mastered, it will help you push the formats in your spreadsheets far beyond their common uses.
Excel conditional formatting based on another cell value
Excel's predefined conditional formatting, such as Data Bars, Color Scales and Icon Sets, are mainly purposed to format cells based on their own values. If you want to apply conditional formatting based on another cell or format an entire row based on a single cell's value, then you will need to use formulas.
So, let's see how you can make a rule using a formula and after discuss formula examples for specific tasks.
How to create a conditional formatting rule based on formula
To set up a conditional formatting rule based on a formula in any version of Excel 2010 through Excel 365, carry out these steps:
- Select the cells you want to format. You can select one column, several columns or the entire table if you want to apply your conditional format to rows.
Tip. If you plan to add more data in the future and you want the conditional formatting rule to get applied to new entries automatically, you can either:
- Convert a range of cells to a table (Insert tab > Table). In this case, the conditional formatting will be automatically applied to all new rows.
- Select some empty rows below your data, say 100 blank rows.
- On the Home tab, in the Styles group, click Conditional formatting > New Rule…
- In the New Formatting Rule window, select Use a formula to determine which cells to format.
- Enter the formula in the corresponding box.
- Click the Format… button to choose your custom format.
- Switch between the Font, Border and Fill tabs and play with different options such as font style, pattern color and fill effects to set up the format that works best for you. If the standard palette does not suffice, click More colors… and choose any RGB or HSL color to your liking. When done, click the OK button.
- Make sure the Preview section displays the format you want and if it does, click the OK button to save the rule. If you are not quite happy with the format preview, click the Format… button again and make the edits.
Tip. Whenever you need to edit a conditional formatting formula, press F2 and then move to the needed place within the formula using the arrow keys. If you try arrowing without pressing F2, a range will be inserted into the formula rather than just moving the insertion pointer. To add a certain cell reference to the formula, press F2 a second time and then click that cell.
Excel conditional formatting formula examples
Now that you know how to create and apply Excel conditional formatting based on another cell, let's move on and see how to use various Excel formulas in practice.
Tip. For your Excel conditional formatting formula to work correctly, please always follow these simple rules.
Formulas to compare values (numbers and text)
As you know Microsoft Excel provides a handful of ready-to-use rules to format cells with values greater than, less than or equal to the value you specify (Conditional Formatting >Highlight Cells Rules). However, these rules do not work if you want to conditionally format certain columns or entire rows based on a cell's value in another column. In this case, you use analogous formulas:
| Condition | Formula example |
|---|---|
| Equal to | =$B2=10 |
| Not equal to | =$B2<>10 |
| Greater than | =$B2>10 |
| Greater than or equal to | =$B2>=10 |
| Less than | =$B2<10 |
| Less than or equal to | =$B2<=10 |
| Between | =AND($B2>5, $B2<10) |
The screenshot below shows an example of the Greater than formula that highlights product names in column A if the number of items in stock (column C) is greater than 0. Please pay attention that the formula applies to column A only ($A$2:$A$8). But if you select the whole table (in our case, $A$2:$E$8), this will highlight entire rows based on the value in column C.
In a similar fashion, you can create a conditional formatting rule to compare values of two cells. For example:
=$A2<$B2 - format cells or rows if a value in column A is less than the corresponding value in column B.
=$A2=$B2 - format cells or rows if values in columns A and B are the same.
=$A2<>$B2 - format cells or rows if a value in column A is not the same as in column B.
As you can see in the screenshot below, these formulas work for text values as well as for numbers.
AND and OR formulas
If you want to format your Excel table based on 2 or more conditions, then use either =AND or =OR function:
| Condition | Formula | Description |
|---|---|---|
| If both conditions are met | =AND($B2<$C2, $C2<$D2) |
Formats cells if the value in column B is less than in column C, and if the value in column C is less than in column D. |
| If one of the conditions is met | =OR($B2<$C2, $C2<$D2) |
Formats cells if the value in column B is less than in column C, or if the value in column C is less than in column D. |
In the screenshot below, we use the formula =AND($C2>0, $D2="Worldwide") to change the background color of rows if the number of items in stock (Column C) is greater than 0 and if the product ships worldwide (Column D). Please pay attention that the formula works with text values as well as with numbers.
Naturally, you can use two, three or more conditions in your AND and OR formulas. To see how this works in practice, watch Video: Conditional formatting based on another cell.
These are the basic conditional formatting formulas you use in Excel. Now let's consider a bit more complex but far more interesting examples.
Conditional formatting for empty and non-empty cells
I think everyone knows how to format empty and not empty cells in Excel - you simply create a new rule of the "Format only cells that contain" type and choose either Blanks or No Blanks.
But what if you want to format cells in a certain column if a corresponding cell in another column is empty or not empty? In this case, you will need to utilize Excel formulas again:
Formula for blanks: =$B2="" - format selected cells / rows if a corresponding cell in Column B is blank.
Formula for non-blanks: =$B2<>"" - format selected cells / rows if a corresponding cell in Column B is not blank.
Note. The formulas above will work for cells that are "visually" empty or not empty. If you use some Excel function that returns an empty string, e.g. =if(false,"OK", ""), and you don't want such cells to be treated as blanks, use the following formulas instead =isblank(A1)=true or =isblank(A1)=false to format blank and non-blank cells, respectively.
And here is an example of how you can use the above formulas in practice. Suppose, you have a column (B) which is "Date of Sale" and another column (C) "Delivery". These 2 columns have a value only if a sale has been made and the item delivered. So, you want the entire row to turn orange when you've made a sale; and when an item is delivered, a corresponding row should turn green. To achieve this, you need to create 2 conditional formatting rules with the following formulas:
- Orange rows (a cell in column B is not empty):
=$B2<>"" - Green rows (cells in column B and column C are not empty):
=AND($B2<>"", $C2<>"")
One more thing for you to do is to move the second rule to the top and select the Stop if true check box next to this rule:
In this particular case, the "Stop if true" option is actually superfluous, and the rule will work with or without it. You may want to check this box just as an extra precaution, in case you add a few other rules in the future that may conflict with any of the existing ones.
For more information, please see Excel conditional formatting for blank cells.
Excel formulas to work with text values
If you want to format a certain column(s) when another cell in the same row contains a certain word, you can use a formula discussed in one of the previous examples (like =$D2="Worldwide"). However, this will only work for exact match.
For partial match, you will need to use either SEARCH (case insensitive) or FIND (case sensitive).
For example, to format selected cells or rows if a corresponding cell in column D contains the word "Worldwide", use the below formula. This formula will find all such cells, regardless of where the specified text is located in a cell, including "Ships Worldwide", "Worldwide, except for…", etc:
=SEARCH("Worldwide", $D2)>0
If you'd like to shade selected cells or rows if the cell's content starts with the search text, use this one:
=SEARCH("Worldwide", $D2)>1
Excel formulas to highlight duplicates
If your task is to conditionally format cells with duplicate values, you can go with the pre-defined rule available under Conditional formatting > Highlight Cells Rules > Duplicate Values… The following article provides a detailed guidance on how to use this feature: How to automatically highlight duplicates in Excel.
However, in some cases the data looks better if you color selected columns or entire rows when a duplicate values occurs in another column. In this case, you will need to employ an Excel conditional formatting formula again, and this time we will be using the COUNTIF formula. As you know, this Excel function counts the number of cells within a specified range that meet a single criterion.
Highlight duplicates including 1st occurrences
=COUNTIF($A$2:$A$10,$A2)>1 - this formula finds duplicate values in the specified range in Column A (A2:A10 in our case), including first occurrences.
If you choose to apply the rule to the entire table, the whole rows will get formatted, as you see in the screenshot below. I've decided to change a font color in this rule, just for a change : )
Highlight duplicates without 1st occurrences
To ignore the first occurrence and highlight only subsequent duplicate values, use this formula: =COUNTIF($A$2:$A2,$A2)>1
Highlight consecutive duplicates in Excel
If you'd rather highlight only duplicates on consecutive rows, you can do this in the following way. This method works for any data types: numbers, text values and dates.
- Select the column where you want to highlight duplicates, without the column header.
- Create a conditional formatting rule(s) using these simple formulas:
Rule 1 (blue):=$A1=$A2- highlights the 2nd occurrence and all subsequent occurrences, if any.
Rule 2 (green):=$A2=$A3- highlights the 1st occurrence.
In the above formulas, A is the column you want to check for dupes, $A1 is the column header, $A2 is the first cell with data.
Important! For the formulas to work correctly, it is essential that Rule 1, which highlights the 2nd and all subsequent duplicate occurrences, should be the first rule in the list, especially if you are using two different colors.
Highlight duplicate rows
If you want apply the conditional format when duplicate values occur in two or more columns, you will need to add an extra column to your table in which you concatenate the values from the key columns using a simple formula like this one =A2&B2. After that you apply a rule using either variation of the COUNTIF formula for duplicates (with or without 1st occurrences). Naturally, you can hide an additional column after creating the rule.
Alternatively, you can use the COUNTIFS function that supports multiple criteria in a single formula. In this case, you won't need a helper column.
In this example, to highlight duplicate rows with 1st occurrences, create a rule with the following formula:
=COUNTIFS($A$2:$A$11, $A2, $B$2:$B$11, $B2)>1
To highlight duplicate rows without 1st occurrences, use this formula:
=COUNTIFS($A$2:$A2, $A2, $B$2:$B2, $B2)>1
Compare 2 columns for duplicates
One of the most frequent tasks in Excel is to check 2 columns for duplicate values - i.e. find and highlight values that exist in both columns. To do this, you will need to create an Excel conditional formatting rule for each column with a combination of =ISERROR() and =MATCH() functions:
For Column A: =ISERROR(MATCH(A1,$B$1:$B$10000,0))=FALSE
For Column B: =ISERROR(MATCH(B1,$A$1:$A$10000,0))=FALSE
Note. For such conditional formulas to work correctly, it's very important that you apply the rules to the entire columns, e.g. =$A:$A and =$B:$B.
You can see an example of practical usage in the following screenshot that highlights duplicates in Columns E and F.
As you can see, Excel conditional formatting formulas cope with dupes pretty well. However, for more complex cases, I would recommend using the Duplicate Remover add-in that is especially designed to find, highlight and remove duplicates in Excel, in one sheet or between two spreadsheets.
Formulas to highlight values above or below average
When you work with several sets of numeric data, the AVERAGE() function may come in handy to format cells whose values are below or above the average in a column.
For example, you can use the formula =$E2<AVERAGE($E$2:$E$8) to conditionally format the rows where the sale numbers are below the average, as shown in the screenshot below. If you are looking for the opposite, i.e. to shade the products performing above the average, replace "<" with ">" in the formula: =$E2>AVERAGE($E$2:$E$8).
How to highlight the nearest value in Excel
If I have a set of numbers, is there a way I can use Excel conditional formatting to highlight the number in that set that is closest to zero? This is what one of our blog readers, Jessica, wanted to know. The question is very clear and straightforward, but the answer is a bit too long for the comments sections, that's why you see a solution here :)
Example 1. Find the nearest value, including exact match
In our example, we'll find and highlight the number that is closest to zero. If the data set contains one or more zeroes, all of them will be highlighted. If there is no 0, then the value closest to it, either positive or negative, will be highlighted.
First off, you need to enter the following formula to any empty cell in your worksheet, you will be able to hide that cell later, if needed. The formula finds the number in a given range that is closest to the number you specify and returns the absolute value of that number (absolute value is the number without its sign):
=MIN(ABS(B2:D13-(0)))
In the above formula, B2:D13 is your range of cells and 0 is the number for which you want to find the closest match. For example, if you are looking for a value closest to 5, the formula will change to: =MIN(ABS(B2:D13-(5)))
Note. This is an array formula, so you need to press Ctrl + Shift + Enter instead of a simple Enter stroke to complete it.
And now, you create a conditional formatting rule with the following formula, where B3 is the top-right cell in your range and $C$2 in the cell with the above array formula:
=OR(B3=0-$C$2,B3=0+$C$2)
Please pay attention to the use of absolute references in the address of the cell containing the array formula ($C$2), because this cell is constant. Also, you need to replace 0 with the number for which you want to highlight the closest match. For example, if we wanted to highlight the value nearest to 5, the formula would change to: =OR(B3=5-$C$2,B3=5+$C$2)
Example 2. Highlight a value closest to the given value, but NOT exact match
In case you do not want to highlight the exact match, you need a different array formula that will find the closest value but ignore the exact match.
For example, the following array formula finds the value closest to 0 in the specified range, but ignores zeroes, if any:
=MIN(ABS(B3:C13-(0))+(10^0*(B3:C13=0)))
Please remember to press Ctrl + Shift + Enter after you finished typing your array formula.
The conditional formatting formula is the same as in the above example:
=OR(B3=0-$C$2,B3=0+$C$2)
However, since our array formula in cell C2 ignores the exact match, the conditional formatting rule ignores zeroes too and highlights the value 0.003 that is the closest match.
If you want to find the value nearest to some other number in your Excel sheet, just replace "0" with the number you want both in the array and conditional formatting formulas.
I hope the conditional formatting formulas you have learned in this tutorial will help you make sense of whatever project you are working on. If you need more examples, please check out the following articles:
Why isn't my Excel conditional formatting working correctly?
If your conditional formatting rule is not working as expected, though the formula is apparently correct, do not get upset! Most likely it is not because of some weird bug in Excel conditional formatting, rather due to a tiny mistake, not evident at the first sight. Please try out 6 simple troubleshooting steps below and I'm sure you will get your formula to work:
- Use absolute & relative cell addresses correctly. It's very difficult to deduce a general rule that will work in 100 per cent of cases. But most often you would use an absolute column (with $) and relative row (without $) in your cell references, e.g.
=$A1>1.Please keep in mind that the formulas
=A1=1,=$A$1=1and=A$1=1will produce different results. If you are not sure which one is correct in your case, you can try all : ) For more information, please see Relative and absolute cell references in Excel conditional formatting. - Verify the applied range. Check whether your conditional formatting rule applies to the correct range of cells. A rule of thumb is this - select all the cells / rows you want to format but do not include column headers.
- Write the formula for the top-left cell. In conditional formatting rules, cell references are relative to the top-left most cell in the applied range. So, always write your conditional formatting formula for the 1st row with data.
For example, if your data starts in row 2, you put
=A$2=10to highlight cells with values equal to 10 in all the rows. A common mistake is to always use a reference to the first row (e.g.=A$1=10). Please remember, you reference row 1 in the formula only if your table does not have headers and your data really starts in row 1. The most obvious indication of this case is when the rule is working, but formats values not in the rows it should. - Check the rule you created. Double-check the rule in the Conditional Formatting Rules Manager. Sometimes, for no reason at all, Microsoft Excel distorts the rule you have just created. So, if the rule is not working, go to Conditional Formatting > Manage Rules and check both the formula and the range it applies to. If you have copied the formula from the web or some other external source, make sure the straight quotes are used.
- Adjust cell references when copying the rule. If you copy Excel conditional formatting using Format Painter, don't forget to adjust all cell references in the formula.
- Split complex formulas into simple elements. If you use a complex Excel formula that includes several different functions, split it into simple elements and verify each function individually.
And finally, if you've tried all the steps but your conditional formatting rule is still not working correctly, drop me a line in comments and we will try to fathom it out together :)
In my next article we are going to look into the capabilities of Excel conditional formatting for dates. See you next week and thanks for reading!
1636 comments
Hi, I've setup a training spreadsheet and added conditional formatting so that the cell turns red if the expiry date has passed (but only if the cell contains a value.
=IF((AND(K11<TODAY(),K11"")),TRUE,FALSE)
Trying to setup an additional rule that turns it yellow if that expiry date comes within 2 months of the current date but not sure on the details of the formula. i thought something like this maybe but its not working.
=IF((AND(K11<TODAY+60(),K11"")),TRUE,FALSE)
Any help would be greatly appreciated.
Thanks
Hi Steven,
The formula is correct except that parentheses should be after TODAY(), not after 60. Please try this one:
=IF(AND(K11<TODAY()+60, K11<>""),TRUE,FALSE)
I am trying to figure how to format the first cell in each row so that it will change to a color when all the cells are populated within that row (columns A-R). Some of the cells have text, some have numbers, and some have both. I am wanting to do this so that I know which rows are complete, without having to scroll back and forth and visualizing each one.
Each month the number of rows I have varies, so it may be 90 one month, it may be 130 another. The first row is a title/header row. The first column is populated with names. Any ideas?
Thanks!
Hello Christine,
Select the column A (from A2 till the end) and create a conditional formatting rule using this formula:
=COUNTBLANK($B2:$R2)=0
hi,
i have this check list with a checkbox, and i need to know how i can make the question status cell to display a text(done, pending) while changing the cell color (red to green),when i select one of the checkbox answer.
ex. do you have a list of traces on PCB? []yes []no []n/a [question status]
I am using MS Excel 2010. I want to use conditional formatting for B8 to B21 ( Format only Top-Green and Bottom-Red ranked values ) excluding 0.
Hi,
Greetings.
in condition formatting check the cell value, if it is true assigned zero in another cell how?
Please kindly send the formula
Thanks
Ali Ahammad.
please help me
I have this problem ( I create a conditional formatting to cell $I$2 (((cell value - less than - =$H$2-$H$2*10% )))
is there away to create a conditional formatting to all cell below depend on the right cell like this
(((cell value - less than - =$H$3-$H$3*10% ))) to cell $I$3
(((cell value - less than - =$H$4-$H$4*10% ))) to cell $I$4
(((cell value - less than - =$H$5-$H$5*10% ))) to cell $I$5
This is a great list of conditional formatting uses! I have one I would like to see if you can tackle. I would like to highlight a range of values (item numbers) for a list of specific item numbers that qualify. The list may be small or it may be quite large. Would I need to do an OR function for each of the items in the list or is there a simpler way to get this done? Thanks!
GREAT columb. More insightful than the videos. Thanks.
conditional formatting for cell B1- if cell A1=Optimize and B1 is greater than 0, red (or whatever)
A1 B1
Optimize 1
Use this Formula
=AND($B1>0, $A1="Optimize")
Select B1 Column.
sorry for the double post. it changed.
Hi there..
Been stuck with my project already.
I have a value in column A.
And i need to apply a 3-color scale on column B depending on the value of column A.
Condition:
If column A=<1 - column B turns red
if column A=<the half of A - column B turns yellow
if column A= the value of A - column B turns dirty white
i think this is simple but im getting invalid formula.
why's that? this is what i've been doing
on column B3, i enter this
=$A$3=$A$3
Hi there..
Been stuck with my project already.
I have a value in column A.
And i need to apply a 3-color scale on column B depending on the value of column A.
Condition:
If column A=<1 - column B turns red
if column A= the value of A - column B turns dirty white
i think this is simple but im getting invalid formula.
why's that? this is what i've been doing
on column B3, i enter this
=$A$3=<1
=$A$3=$A$3
Hi,
I am in desperate need of some help with something if possible.
I am trying to conditionally format cells in a column (E, range 3-96) to:
-turn black if the cell next to it in column D is blank and the cell in column E is also blank.
-turn orange if the cell next to it in column D is blank but the cell in column E contains a time.
Any ideas?
Thanks in advance!
I would like to change my text value in column E and F based on the text entered into any cell in column F.
For example: If I enter in any cell in column F "BBL" I would like the "BBL" in column F to be red as well as any text I enter in column E but only in that specific row. I would like this formatting to work for the entire spreadsheet.
Hi there..
Been stuck with my project already.
I have a value in column A.
And i need to apply a 3-color scale on column B depending on the value of column A.
Condition:
If column A=<1 - column B turns red
if column A=the value of column A - column B turns dirty white
i think this is simple but im getting invalid formula.
why's that? this is what i've been doing
on column B3, i enter this
=$A$3=<1
=$A$3=$A$3
Hi, I want to conditional formating rows based off of what is in two different columns
Column1 Column2
1 NG
2 NG
1 OK
3 NG
2 NG
4 OK
I have it set up right now that if its OK it hightlights the row gray and if NG it shows orange. I want to make it that if another entry is entered and it is OK but the first time it is NG it will change the row to gray. So for the example the first row 1 is orange because of NG but when you add in the second 1 with OK it will change the first row 1 to gray also.
Thanks for the help!!
I want to use the conditional formatting to color a column of cells based on "yes" or "no" in another cell. I tried walking through the steps above and got nothing. I also tried formatting it as a table and using the COUNTIF equation. I got it to work on a test cell but when I tried to duplicate it with the entire column I got nothing.
Hi Svetlana, I'm having a problem trying to find if the numbers in a column are in a sequence or not.
I want to highlight a cell whenever the it is not equal to the cell above it + 1.
So:
2
3
4
2 <-- HIGHLIGHT
5 <-- HIGHLIGHT
6
8 <-- HIGHLIGHT
Thank you for your help
hi
tanx for your most useful tips
I have a question
I wanna write formula that says if you search a number in column b by Crtl+f
and it finds it the near column (column a) type ok and it change the color of it automatically...
is it possible anyway?
Hello,
I am trying to run down a large list full of one's and zero's. If it is zero, then the corresponding row, 2 rows to the left, value I do not care about. If it is a one, I then want to essentially add it to a mixing pot with all of the other values that have 1 corresponding with them, then find the max value of all of them. HELP!?
Hi Will,
I understand that you have a list of 0s and 1s but I'm not sure I understand the task. Can you please try to describe it in the following way:
-if cell A1 is 0, then do what?
- if Cell A1 is 1, then do what?
Hello,
I have a problem of replacing a cell value if th background color of the cell is Yellow: for example
Column A B
1 2
1 2
I would like in a new sheet to put in (column A) 1 or 2 depends on the Yellow color in A1 and B1,
so if A1 is highlighted in Yellow then put in the new sheet A1 code 1 if not then put 2
How I do that?
Hello,
I'm currently using 2 sheets to keep track of client information. sheet 1 (client info) has columns listed as A1-SSN, B1-Lastname, C1-Firstname, D1-Phone#, and E1-paid (which is blank since the service occurs before payment) and each column has about 100 entries of the information. Now in sheet 2 (payments) I have the same columns listed in the 1st row and a vlookup formula in all the cells so that when I enter the SSN number in A2, the rest of the 2 row fills in with the names, numbers, etc. My question is how do I make it that when I enter 'yes' under the payment column (E2), my sheet 1 with also fill in 'yes' in column E for the right client?
Thank you for any help you can give
Hello!
Simple request. I have had trouble finding the proper way to do this. I want to be able to enter a name in a cell on Sheet 1 of the MS Excel Workbook (2010) and have that same name (or data) repeated in a corresponding cell on another Sheet in the same workbook as I enter it in the one place. Basically I need names of associates to appear in multiple places, but only want to enter it once. Any tips?
Good day!
Hope you can help, as I tried everything and nothing works:
I have two columns (Sales in 2013 in one columns, and sales in 2014 in another column - this is made depending on customer). Now I have to figure out, from a glance, which customer bought more in 2014, which less
Column A B C
Sales in 2013 Sales in 2014
Purchaser 1 2131442,93 1783657,38
Purchaser 2 295638,22 2609,31
Purchaser 3 1733348,19 865579,68
Purchaser 4 1472991,01 418399,35
Purchaser 5 1490602,99 120403,99
Purchaser 6 2927921,82 2729046,74
Purchaser 7 452169,39 392953,53
THank you for your help.
I would like to create a conditional formatting rule for the following:
Cell C2: If cell C1=36 then the text in C2 would be 3x/8 weeks, 2x/6 weeks (36)
Once that is completed, I'd like to create additional conditional formatting rules for the same cell.
Is that possible?
Hi Npratt,
I'm not sure I exactly understand the condition. Assuming that you want to put the text 3x/8 weeks in cell C2 if C1 euqals 36, otherwise - 2x/6 weeks (36), here is the formula for cell C2:
=IF(C1=36, "3x/8 weeks", "2x/6 weeks (36)")
I am trying to highlight entire row based on a cell value
Wxample: I want my formula to highlight entire row where cell value = MH000038, when I am giving the below formula excel is not considering the zeros it is removing
Rule created = $C2=MH000038
Excel converting it to =$C2=MH38 so no cells are highlighting
any help will be appreciated.
Hi Suma,
Simply enclose the cell value in quotes so that Excel interprets it as a text string, like this:
=$C2="MH000038"
Hi ,
I have a question, in my case 1 particular cell say A1 is done with a conditional color formatting so that the color of the cell changes with the value input in it. What I want is that the same cell color should be done for another cell say A2.
Could you please advise.Thanks
can somebody help to solve this for me please? In excel 2013 I have a column where I have put some values.
e.g. In D1 cell and I want to give conditional formatting to E1 cell that it becomes red in background if the value in D1 is less then 50% and it becomes Yellow in background if the value in D1 is greater then 49% and it becomes Green in background if the value is equal to 100%.
Note: E Column I want to keep empty for the specific color as explained above.
Thank you in advance for your support. Regards,
I want to color red a particular set of data if it contains data which is in a particular column using conditional formatting. what formulae should i use. i am not able to give an array in the formulae
Hi Svetlana,
I need help searching a range of cells for information that may be contained in another spreadsheet. I have two spreadsheets which contain information for hundreds of entities, one for 2013-2014 members and another for 2014-2015 members. What I would like to do is identify new members by searching the Tax IDs in both sheets. If the Tax ID is found on both sheets, I would like it to do nothing. If a new Tax ID is identified on the 2014-2015 sheet, I would like it to highlight red.
Thank you in advance!
Jen
hi
I need to conditionally format a cell based on the conditional formatting of three other cells.
for example
A1 is Green
A2 is Green
A3 is Red
so I want A4 to show as Amber
Is this possible and if so how do I do it?
Thanks in advance
Amber
Hi Svetlana.
My problem would not appear to be too difficult but I cannot find a way to make this work.
I am working on a rota for staff. In cell 1 I have a time 8:00:00 which is the start time. In cell 2 I have a finish time of 16:00:00 which i want to highlight in red using conditional formatting if the start time is = to 8:00:00. I'm sure this is easy but I'm stumped!
Hi,
How can i make a calender in excel using formula (except using visual basic)?
Hi Svetlana,
I am trying to enter a formula that will color a row based on the values on two sheets matching. If I have a series of telephone numbers on one sheet and I have sheet with phone numbers on a second sheet, I want to highlight the row on the first sheet that has a matching phone number. I want to do this for the complete sheet.
So far I have managed to highlight the matching cells on sheet 1 using the following formula:
=COUNTIF('Sheet 2'!$D$2:$D$71,D2)
with a format to color the cell yellow applied.
That will obviously only highlight a cell if a matching number is found on sheet 2. I need to be able to color the row.
Thanks
Hi,
Pls help me with this.
Sheet 1 has to be a summary sheet that shows the consolidated values of # of open positions at onsite/offshore and for a particular month in sheet 2.
Sheet1 resultant table should be something like this
Status Dec-14 Jan-15 Feb-15
ON|OFF ON|OFF ON|OFF
Open 1 2 2 4 0 2
Selected 0 2 1 1 2 3
Identified 1 0 0 1 0 0
Sheet2 values will be like this
Name Status Location Start date
X Open ONSITE JAn-15
Y Open Offshore FEB-15
Z Selected Offshore Dec-14
XX Identified Onsite Dec-14
YY Selected Offshore Feb-15
Pls help me
Hi, I am a bit desperate here... I have searched everywhere but I can't find a solution to my problem. I really hope you can help me! So here it is:
My issue is with the conditional formatting using a formula. To summarize, I want G3 to be highlighted if F3 is more than or equal to 0 and also G3 is smaller than 90% of F3.
This is the formula I have entered in the conditional formatting but it doesn't work:
="AND($F3>=0, $G3<$F3*0.9)"
Thanks for your help in advance :)
Nevermind! I Figured it out. It should have looked like this:
=AND($F3>=0, $G3<($F3*0.9))
I am such a noob :P
sorry, formatting went wrong, hope you can read it
for every space there should be a tab.
Hi, thanks for the helpful posts. Though I am struggling with the following:
I want to color column B depending on column A. And result columns (say E to X) should be dependent on B (it's like a matrix of column B). My guess is I mix up relative and absolute cell-links. Or I don't get how to copy the rule for a cell to others, i.e. I can create the rule for a single cell, but not the full column.
A B ... E F G .... X
Positive 44 =B1 =B2 =B3 ....
Positive 43 =B13 =B14 =B15 ....
Negative 40
Positive 50
Uncertain 42
Positive 49
Negative 20
.... ...
Very greatfull for any tips or solutions.
I'm using Excel 2013. I have not found a solution to this problem. I have a spreadsheet with 100 rows. The values in column P are numbers that are independent of each other. They range in value from 1.00 to 60.00. The values in column O range from 0.00 up to the value in column P for that row. I want to have each cell in column O in my worksheet use a red-yellow-green color scale conditional format, where the low value is zero, the middle value is one-half the value in column P for that row, and the high value is the value in column P for that row. I can create this conditional format for any one row easy enough. I can't find any way to copy it to the other 99 rows because the cell references in the color scale conditional format need to be absolute. It would be a lot of manual work to create this conditional format for each row one at a time. Is there a lower-effort mechanism available to do this?
in my worksheet, i have two columns, one is alphabet (column B) and the other one is numeric (Column C).
my condition is:
if column B is L, then column C should be 1
if column B is V, then column C should be 2
if column B is T, then column C should be 3
I WANT TO SATISFY THIS THREE CONDITIONS IN A SINGLE FORMULA, IS IT POSSIBLE?
PLS GUIDE ME
Oops the table didn't appear as it should be...
Hello,
I have a workbook in excel and I want to know what article/type/value which is clicked or typed frequently in excel. But, I don't know how. can you help me?
Thanks :)
Hello,
I have a workbook in excel and I want to know what article/type/value which is clicked or typed frequently in excel. But, I don't know how. can you help me?
Thanks :)
Hi,
I want to format a column of cells to fill in depending on when a specified date in another column has passed. For example I input the date into column "b" and then Seven days after that date has passed, I want Columns D,E,F to fill green. I am having trouble creating a formula depending on a date, any help offered would be appreciated.
Thanks!
Hi,
I want to format a column of percentages, dependent on the column of percentages to the left of them.
Highlight in green if the value is between 2% and -2%
Highlight in amber if the value is between 2% and 4%, and -2% and -4%
Highlight in red if the value is above 4%, or below -4%
I'm sure this is easy, but i cannot get my head round it. I think it could be to do with how the rules are ordered in the manage rules section, but not sure.
Thanks.
Oops the table didn't appear as supposed;
Output 1 Output 2 Addition to column B
260,1 201,123 b2
262,1 242,105 y4-NH3+2
330,2 250,618 y4+2
338,1 269,161 y2
351,1 306,134 y5-H2O+2
372,1 306,625 y5-NH3+2
372,8 315,139 y5+2
416,1 320,197 a3
418,1 330,181 b3-H2O
348,192 b3
370,655 y6-H2O+2
371,147 y6-NH3+2
372,170 y3
379,660 y6+2
417,213 a4-NH3
427,197 y7-H2O+2
427,689 y7-NH3+2
434,240 a4
436,202 y7+2
444,224 b4-H2O
Hi there,
I'm trying to compare column A with a table, for example column B and if there is a match the match should be colored. Column B contains a output that had several decimals. The match does not need to be exact, ideally I would like to scan for a range of about +/-0.5 of column B. Does anyone have a suggestion how to approach this?
ColumnA ColumnB ColumnC
Output1 Output2 Addition to column B
260,1 201,123 b2
262,1 242,105 y4-NH3+2
330,2 250,618 y4+2
338,1 269,161 y2
351,1 306,134 y5-H2O+2
372,1 306,625 y5-NH3+2
372,8 315,139 y5+2
416,1 320,197 a3
418,1 330,181 b3-H2O
348,192 b3
370,655 y6-H2O+2
371,147 y6-NH3+2
372,170 y3
379,660 y6+2
417,213 a4-NH3
427,197 y7-H2O+2
427,689 y7-NH3+2
434,240 a4
436,202 y7+2
444,224 b4-H2O
For example 330.2 matches 330,181 (with addition b3-H2O)and so they should be filled in with red. 372.1 matches with 372,170 and thus y3, the should be colored orange etc.
Look forward to any help,
Thanks, regards,
G
Output 1 Output 2 Addition to column B
260,1 201,123 b2
262,1 242,105 y4-NH3+2
330,2 250,618 y4+2
338,1 269,161 y2
351,1 306,134 y5-H2O+2
372,1 306,625 y5-NH3+2
372,8 315,139 y5+2
416,1 320,197 a3
418,1 330,181 b3-H2O
348,192 b3
370,655 y6-H2O+2
371,147 y6-NH3+2
372,170 y3
379,660 y6+2
417,213 a4-NH3
427,197 y7-H2O+2
427,689 y7-NH3+2
434,240 a4
436,202 y7+2
444,224 b4-H2O
Hmm the table didn't come out as it supposed to..
Output 1 Output 2 Addition to column B
260,1 201,123 b2
262,1 242,105 y4-NH3+2
330,2 250,618 y4+2
338,1 269,161 y2
351,1 306,134 y5-H2O+2
372,1 306,625 y5-NH3+2
372,8 315,139 y5+2
416,1 320,197 a3
418,1 330,181 b3-H2O
348,192 b3
370,655 y6-H2O+2
371,147 y6-NH3+2
372,170 y3
379,660 y6+2
417,213 a4-NH3
427,197 y7-H2O+2
427,689 y7-NH3+2
434,240 a4
436,202 y7+2
444,224 b4-H2O
Oops the table didn't appear as it should be..
Is it possible to give a colum like "stable" or "ascending" the directional icons?
Like if stays "stable" then must be ↔ and for "ascending" ↑.
I i want use now the directional icons, i must give a number. I want in text.
I solved this problem with using VLookup
Please help me, I have a spreadsheet,eg A1:P245, I would like to be able to do is delete/clear any cells that contains a particular text.
For example the cells may contain the following data
P1abc P1gvh p2erg P3fgh sro34 sro56 srj67
How do I clear the cell that start with P
How do i clear the cells that contains ro
Thanks you.
I have text from a drop down list (NO and YES) in Cell B2 that I want to use as the basis for conditional formatting elsewhere in the spreadsheet (to color a number of cells in a certain row red), but the formula (=$b2="YES") does not seem to recognize the text - if I insert the text manually rather than use the drop down list it works just fine. Any suggestions?
Thank you.
Hi..
I want to change a entire row color for a cell value of the row... If i have 'fail' in a certain cell (D1) then i want to highlight row 1. How can I do that?
Hi Nazmul,
Simply select all the rows you want to highlight and create a rule with this formula:
=$D1="fail"
Hi Svetlana,
Thanks a lot..it works..
Hi Svetlana,
I am trying to do conditional formatting of email addresses to quickly identify addresses from gmail, hotmail, and yahoo. After a lot of looking online, I found a formula I could use:
=NOT(ISERR(SEARCH(Sheet2!$A1:$A3,A1)))
(Sheet 2 A1 - A3 are: A1= gmail.com, A2= hotmail.com, A3 = yahoo.com)
However, when I put this in my conditional formatting - it only highlights those addresses with gmail in them and ignores the rest. I'm not sure what I am doing wrong. Any ideas?
-Michael
Hi Michael,
The point is that you have an array formula and array formulas can't be used in conditional formatting rules. In your case, the formula turns into =NOT(ISERR(SEARCH(Sheet2!$A1,A1))) and highlights only gmail addresses.
You can pick the domain name in a row and use the MATCH function to find matches in your lookup table using the following formula:
=MATCH(IFERROR(RIGHT(A1,LEN(A1)-FIND("@",A1)),""),Sheet2!$A$1:$A$3,0)>=1
You rock my world. Remind to me buy you a beer if we ever meet. :)
How do I conditionally format a table so that in column J when the word "Complete" is entered it highlights rows C to J in green?