by In this tutorial, we will continue exploring the fascinating world of Excel Conditional Formatting. If you do not feel very comfortable in this area, you may want to look through the previous article first to revive the basics - How to use conditional formatting in Excel.
Today are going to dwell on how to use Excel formulas to format individual cells and entire rows based on the values you specify or based on another cell's value. This is often considered advanced aerobatics of Excel conditional formatting and once mastered, it will help you push the formats in your spreadsheets far beyond their common uses.
Excel conditional formatting based on another cell value
Excel's predefined conditional formatting, such as Data Bars, Color Scales and Icon Sets, are mainly purposed to format cells based on their own values. If you want to apply conditional formatting based on another cell or format an entire row based on a single cell's value, then you will need to use formulas.
So, let's see how you can make a rule using a formula and after discuss formula examples for specific tasks.
How to create a conditional formatting rule based on formula
To set up a conditional formatting rule based on a formula in any version of Excel 2010 through Excel 365, carry out these steps:
- Select the cells you want to format. You can select one column, several columns or the entire table if you want to apply your conditional format to rows.
Tip. If you plan to add more data in the future and you want the conditional formatting rule to get applied to new entries automatically, you can either:
- Convert a range of cells to a table (Insert tab > Table). In this case, the conditional formatting will be automatically applied to all new rows.
- Select some empty rows below your data, say 100 blank rows.
- On the Home tab, in the Styles group, click Conditional formatting > New Rule…
- In the New Formatting Rule window, select Use a formula to determine which cells to format.
- Enter the formula in the corresponding box.
- Click the Format… button to choose your custom format.
- Switch between the Font, Border and Fill tabs and play with different options such as font style, pattern color and fill effects to set up the format that works best for you. If the standard palette does not suffice, click More colors… and choose any RGB or HSL color to your liking. When done, click the OK button.
- Make sure the Preview section displays the format you want and if it does, click the OK button to save the rule. If you are not quite happy with the format preview, click the Format… button again and make the edits.
Tip. Whenever you need to edit a conditional formatting formula, press F2 and then move to the needed place within the formula using the arrow keys. If you try arrowing without pressing F2, a range will be inserted into the formula rather than just moving the insertion pointer. To add a certain cell reference to the formula, press F2 a second time and then click that cell.
Excel conditional formatting formula examples
Now that you know how to create and apply Excel conditional formatting based on another cell, let's move on and see how to use various Excel formulas in practice.
Tip. For your Excel conditional formatting formula to work correctly, please always follow these simple rules.
Formulas to compare values (numbers and text)
As you know Microsoft Excel provides a handful of ready-to-use rules to format cells with values greater than, less than or equal to the value you specify (Conditional Formatting >Highlight Cells Rules). However, these rules do not work if you want to conditionally format certain columns or entire rows based on a cell's value in another column. In this case, you use analogous formulas:
| Condition | Formula example |
|---|---|
| Equal to | =$B2=10 |
| Not equal to | =$B2<>10 |
| Greater than | =$B2>10 |
| Greater than or equal to | =$B2>=10 |
| Less than | =$B2<10 |
| Less than or equal to | =$B2<=10 |
| Between | =AND($B2>5, $B2<10) |
The screenshot below shows an example of the Greater than formula that highlights product names in column A if the number of items in stock (column C) is greater than 0. Please pay attention that the formula applies to column A only ($A$2:$A$8). But if you select the whole table (in our case, $A$2:$E$8), this will highlight entire rows based on the value in column C.
In a similar fashion, you can create a conditional formatting rule to compare values of two cells. For example:
=$A2<$B2 - format cells or rows if a value in column A is less than the corresponding value in column B.
=$A2=$B2 - format cells or rows if values in columns A and B are the same.
=$A2<>$B2 - format cells or rows if a value in column A is not the same as in column B.
As you can see in the screenshot below, these formulas work for text values as well as for numbers.
AND and OR formulas
If you want to format your Excel table based on 2 or more conditions, then use either =AND or =OR function:
| Condition | Formula | Description |
|---|---|---|
| If both conditions are met | =AND($B2<$C2, $C2<$D2) |
Formats cells if the value in column B is less than in column C, and if the value in column C is less than in column D. |
| If one of the conditions is met | =OR($B2<$C2, $C2<$D2) |
Formats cells if the value in column B is less than in column C, or if the value in column C is less than in column D. |
In the screenshot below, we use the formula =AND($C2>0, $D2="Worldwide") to change the background color of rows if the number of items in stock (Column C) is greater than 0 and if the product ships worldwide (Column D). Please pay attention that the formula works with text values as well as with numbers.
Naturally, you can use two, three or more conditions in your AND and OR formulas. To see how this works in practice, watch Video: Conditional formatting based on another cell.
These are the basic conditional formatting formulas you use in Excel. Now let's consider a bit more complex but far more interesting examples.
Conditional formatting for empty and non-empty cells
I think everyone knows how to format empty and not empty cells in Excel - you simply create a new rule of the "Format only cells that contain" type and choose either Blanks or No Blanks.
But what if you want to format cells in a certain column if a corresponding cell in another column is empty or not empty? In this case, you will need to utilize Excel formulas again:
Formula for blanks: =$B2="" - format selected cells / rows if a corresponding cell in Column B is blank.
Formula for non-blanks: =$B2<>"" - format selected cells / rows if a corresponding cell in Column B is not blank.
Note. The formulas above will work for cells that are "visually" empty or not empty. If you use some Excel function that returns an empty string, e.g. =if(false,"OK", ""), and you don't want such cells to be treated as blanks, use the following formulas instead =isblank(A1)=true or =isblank(A1)=false to format blank and non-blank cells, respectively.
And here is an example of how you can use the above formulas in practice. Suppose, you have a column (B) which is "Date of Sale" and another column (C) "Delivery". These 2 columns have a value only if a sale has been made and the item delivered. So, you want the entire row to turn orange when you've made a sale; and when an item is delivered, a corresponding row should turn green. To achieve this, you need to create 2 conditional formatting rules with the following formulas:
- Orange rows (a cell in column B is not empty):
=$B2<>"" - Green rows (cells in column B and column C are not empty):
=AND($B2<>"", $C2<>"")
One more thing for you to do is to move the second rule to the top and select the Stop if true check box next to this rule:
In this particular case, the "Stop if true" option is actually superfluous, and the rule will work with or without it. You may want to check this box just as an extra precaution, in case you add a few other rules in the future that may conflict with any of the existing ones.
For more information, please see Excel conditional formatting for blank cells.
Excel formulas to work with text values
If you want to format a certain column(s) when another cell in the same row contains a certain word, you can use a formula discussed in one of the previous examples (like =$D2="Worldwide"). However, this will only work for exact match.
For partial match, you will need to use either SEARCH (case insensitive) or FIND (case sensitive).
For example, to format selected cells or rows if a corresponding cell in column D contains the word "Worldwide", use the below formula. This formula will find all such cells, regardless of where the specified text is located in a cell, including "Ships Worldwide", "Worldwide, except for…", etc:
=SEARCH("Worldwide", $D2)>0
If you'd like to shade selected cells or rows if the cell's content starts with the search text, use this one:
=SEARCH("Worldwide", $D2)>1
Excel formulas to highlight duplicates
If your task is to conditionally format cells with duplicate values, you can go with the pre-defined rule available under Conditional formatting > Highlight Cells Rules > Duplicate Values… The following article provides a detailed guidance on how to use this feature: How to automatically highlight duplicates in Excel.
However, in some cases the data looks better if you color selected columns or entire rows when a duplicate values occurs in another column. In this case, you will need to employ an Excel conditional formatting formula again, and this time we will be using the COUNTIF formula. As you know, this Excel function counts the number of cells within a specified range that meet a single criterion.
Highlight duplicates including 1st occurrences
=COUNTIF($A$2:$A$10,$A2)>1 - this formula finds duplicate values in the specified range in Column A (A2:A10 in our case), including first occurrences.
If you choose to apply the rule to the entire table, the whole rows will get formatted, as you see in the screenshot below. I've decided to change a font color in this rule, just for a change : )
Highlight duplicates without 1st occurrences
To ignore the first occurrence and highlight only subsequent duplicate values, use this formula: =COUNTIF($A$2:$A2,$A2)>1
Highlight consecutive duplicates in Excel
If you'd rather highlight only duplicates on consecutive rows, you can do this in the following way. This method works for any data types: numbers, text values and dates.
- Select the column where you want to highlight duplicates, without the column header.
- Create a conditional formatting rule(s) using these simple formulas:
Rule 1 (blue):=$A1=$A2- highlights the 2nd occurrence and all subsequent occurrences, if any.
Rule 2 (green):=$A2=$A3- highlights the 1st occurrence.
In the above formulas, A is the column you want to check for dupes, $A1 is the column header, $A2 is the first cell with data.
Important! For the formulas to work correctly, it is essential that Rule 1, which highlights the 2nd and all subsequent duplicate occurrences, should be the first rule in the list, especially if you are using two different colors.
Highlight duplicate rows
If you want apply the conditional format when duplicate values occur in two or more columns, you will need to add an extra column to your table in which you concatenate the values from the key columns using a simple formula like this one =A2&B2. After that you apply a rule using either variation of the COUNTIF formula for duplicates (with or without 1st occurrences). Naturally, you can hide an additional column after creating the rule.
Alternatively, you can use the COUNTIFS function that supports multiple criteria in a single formula. In this case, you won't need a helper column.
In this example, to highlight duplicate rows with 1st occurrences, create a rule with the following formula:
=COUNTIFS($A$2:$A$11, $A2, $B$2:$B$11, $B2)>1
To highlight duplicate rows without 1st occurrences, use this formula:
=COUNTIFS($A$2:$A2, $A2, $B$2:$B2, $B2)>1
Compare 2 columns for duplicates
One of the most frequent tasks in Excel is to check 2 columns for duplicate values - i.e. find and highlight values that exist in both columns. To do this, you will need to create an Excel conditional formatting rule for each column with a combination of =ISERROR() and =MATCH() functions:
For Column A: =ISERROR(MATCH(A1,$B$1:$B$10000,0))=FALSE
For Column B: =ISERROR(MATCH(B1,$A$1:$A$10000,0))=FALSE
Note. For such conditional formulas to work correctly, it's very important that you apply the rules to the entire columns, e.g. =$A:$A and =$B:$B.
You can see an example of practical usage in the following screenshot that highlights duplicates in Columns E and F.
As you can see, Excel conditional formatting formulas cope with dupes pretty well. However, for more complex cases, I would recommend using the Duplicate Remover add-in that is especially designed to find, highlight and remove duplicates in Excel, in one sheet or between two spreadsheets.
Formulas to highlight values above or below average
When you work with several sets of numeric data, the AVERAGE() function may come in handy to format cells whose values are below or above the average in a column.
For example, you can use the formula =$E2<AVERAGE($E$2:$E$8) to conditionally format the rows where the sale numbers are below the average, as shown in the screenshot below. If you are looking for the opposite, i.e. to shade the products performing above the average, replace "<" with ">" in the formula: =$E2>AVERAGE($E$2:$E$8).
How to highlight the nearest value in Excel
If I have a set of numbers, is there a way I can use Excel conditional formatting to highlight the number in that set that is closest to zero? This is what one of our blog readers, Jessica, wanted to know. The question is very clear and straightforward, but the answer is a bit too long for the comments sections, that's why you see a solution here :)
Example 1. Find the nearest value, including exact match
In our example, we'll find and highlight the number that is closest to zero. If the data set contains one or more zeroes, all of them will be highlighted. If there is no 0, then the value closest to it, either positive or negative, will be highlighted.
First off, you need to enter the following formula to any empty cell in your worksheet, you will be able to hide that cell later, if needed. The formula finds the number in a given range that is closest to the number you specify and returns the absolute value of that number (absolute value is the number without its sign):
=MIN(ABS(B2:D13-(0)))
In the above formula, B2:D13 is your range of cells and 0 is the number for which you want to find the closest match. For example, if you are looking for a value closest to 5, the formula will change to: =MIN(ABS(B2:D13-(5)))
Note. This is an array formula, so you need to press Ctrl + Shift + Enter instead of a simple Enter stroke to complete it.
And now, you create a conditional formatting rule with the following formula, where B3 is the top-right cell in your range and $C$2 in the cell with the above array formula:
=OR(B3=0-$C$2,B3=0+$C$2)
Please pay attention to the use of absolute references in the address of the cell containing the array formula ($C$2), because this cell is constant. Also, you need to replace 0 with the number for which you want to highlight the closest match. For example, if we wanted to highlight the value nearest to 5, the formula would change to: =OR(B3=5-$C$2,B3=5+$C$2)
Example 2. Highlight a value closest to the given value, but NOT exact match
In case you do not want to highlight the exact match, you need a different array formula that will find the closest value but ignore the exact match.
For example, the following array formula finds the value closest to 0 in the specified range, but ignores zeroes, if any:
=MIN(ABS(B3:C13-(0))+(10^0*(B3:C13=0)))
Please remember to press Ctrl + Shift + Enter after you finished typing your array formula.
The conditional formatting formula is the same as in the above example:
=OR(B3=0-$C$2,B3=0+$C$2)
However, since our array formula in cell C2 ignores the exact match, the conditional formatting rule ignores zeroes too and highlights the value 0.003 that is the closest match.
If you want to find the value nearest to some other number in your Excel sheet, just replace "0" with the number you want both in the array and conditional formatting formulas.
I hope the conditional formatting formulas you have learned in this tutorial will help you make sense of whatever project you are working on. If you need more examples, please check out the following articles:
Why isn't my Excel conditional formatting working correctly?
If your conditional formatting rule is not working as expected, though the formula is apparently correct, do not get upset! Most likely it is not because of some weird bug in Excel conditional formatting, rather due to a tiny mistake, not evident at the first sight. Please try out 6 simple troubleshooting steps below and I'm sure you will get your formula to work:
- Use absolute & relative cell addresses correctly. It's very difficult to deduce a general rule that will work in 100 per cent of cases. But most often you would use an absolute column (with $) and relative row (without $) in your cell references, e.g.
=$A1>1.Please keep in mind that the formulas
=A1=1,=$A$1=1and=A$1=1will produce different results. If you are not sure which one is correct in your case, you can try all : ) For more information, please see Relative and absolute cell references in Excel conditional formatting. - Verify the applied range. Check whether your conditional formatting rule applies to the correct range of cells. A rule of thumb is this - select all the cells / rows you want to format but do not include column headers.
- Write the formula for the top-left cell. In conditional formatting rules, cell references are relative to the top-left most cell in the applied range. So, always write your conditional formatting formula for the 1st row with data.
For example, if your data starts in row 2, you put
=A$2=10to highlight cells with values equal to 10 in all the rows. A common mistake is to always use a reference to the first row (e.g.=A$1=10). Please remember, you reference row 1 in the formula only if your table does not have headers and your data really starts in row 1. The most obvious indication of this case is when the rule is working, but formats values not in the rows it should. - Check the rule you created. Double-check the rule in the Conditional Formatting Rules Manager. Sometimes, for no reason at all, Microsoft Excel distorts the rule you have just created. So, if the rule is not working, go to Conditional Formatting > Manage Rules and check both the formula and the range it applies to. If you have copied the formula from the web or some other external source, make sure the straight quotes are used.
- Adjust cell references when copying the rule. If you copy Excel conditional formatting using Format Painter, don't forget to adjust all cell references in the formula.
- Split complex formulas into simple elements. If you use a complex Excel formula that includes several different functions, split it into simple elements and verify each function individually.
And finally, if you've tried all the steps but your conditional formatting rule is still not working correctly, drop me a line in comments and we will try to fathom it out together :)
In my next article we are going to look into the capabilities of Excel conditional formatting for dates. See you next week and thanks for reading!
1643 comments
I have a table that I would like to apply conditional formatting to one row (lets call it column G). Column G contains the number of days away from start date (can also be a negative number if start date has passed). Another column (Column H) contains a percentage ranging from 0% to 100%, indicating the percentage of the task completed. I would like Column G to have conditional formatting that colors the cell as follows:
Red - if Column G is less than 0 and Column H is less than 100%
Yellow - if Column G is between 0 and 7 and Column H is less than 100%
Green - if Column H is 100%
Any help you can provide would be greatly appreciated!
I have a drop down with the word CXL in it. How do I make other cells that I want to turn red when this is selected. The selected cells will contain diffrent data and can be anything from words to numbers.
Sir,
I am trying to format my datasheet on the criteria based on only three types of values in an entire table (a range of cells). If one cell contains "A1" then it should be green background. If other cell contains "B1" then all cells that contains B1 should be color as yellow. And lastly, if other cells contains "C1" then it should be Red of all cells that containts C1.
Please Help
I am trying to conditionally format a data set based on a specific cell. I have data from A3:G78 and I want to highlight rows if AA3 is not blank. I have tried including the cell in the data, I've tried "=isblank($AA$3)=false", "=$AA$3""". Nothing seems to work. Any suggestions?
Hi, I have some data in excel and this data is alpha numerical ( GST TIN) how Can I used conditional formatting for strikethrough for only 15 alpa numerical digit because GST TIN is only 15 digit.
Was curious as to how would you go about finding duplicates in two different columns, then highlighting those matches based on a 3rd column's data, ex: I want to match two lists of sites, and find the duplicates once those are found I want to highlight sites on one of the columns based on a value on a 3rd column, thanks! Great post by the way.
I have different data arranged in the same data array that runs from A1 to BQ158 on multiple sheets. I would like to highlight cells on Sheet 2 if the value on Sheet 1 is greater than a set number (e.g., 30). For example, I want Cell C100 on Sheet 2 to be highlighted if the value in C100 on Sheet 1 is greater than 30. I need all cells from A1 to BQ158 to be checked in a similar fashion across 5 different sheets. Is there a way to quickly do this so that each cell is checked with the same corresponding cell on another page. Thanks
There are at least a third of the sales in a row painted yellow.
Sir, in excel sheet one row contains 50 columns. I wand to check the cells with numbers greater than zero. Kindly send a formula. Also I need suggestion to check all rows in that sheet.
Sir, send me a formula for conditional formatting for Blank and No Blank cells.
Hi. I am trying to set a the background colour behind a pivot table. I have found a thread which used conditional formatting [Cell Value] [equal to] [=""""] and then selecting the colour... but I can't get it to work, is there another way to have a background colour on my dashboard which ensures that the colour remains when the pivot table is filtered
I am trying to create a conditional formating for a report I generate for my team to compare 2 different cells and highlight when the two values are different by +/- 20%. I am not sure if this is possible based on everything I am finding though. Any recommendations or suggestions on the formula or where to look?
Apologies for the duplication. There was an omission in the earlier post. this is the correct version. Thank you. I am working on a particular cell, say B11 that is to return or retain entered value based on conditions in cells F5 (Kings and Queens) and B7 (Low, Medium and High. when I enter a figure in this cell (B11) between 90 and 20 which are grades say 98, it must return 90 and 20 when I enter any figure below 20, say 17 when F5=Queens and B7=High. But when I enter 77, it returns 77. If F5=Queens and B7= Medium, I want to enter a figure in this cell between 60 and 15. If I enter 12, it must return 15 and if 65, must enter 60 in B11, but if I enter 48, it retains 48. Lastly, if F5=Kings and B7= Low, Medium or High, it must enter 20 no matter the figure I enter in B11. Can I use a single formula for each condition or combined into a single formula? I don't want to use a vba. Thank you
I am working on a particular cell, say B11 that is to return or retain entered value based on conditions in cells F5 (Kings and Queens) and B7 (Low, Medium and High. when I enter a figure in this cell (B11) between 90 and 20 which are grades say 98, it must return 90 and 20 when I enter any figure below 17 when F5=Queens and B7=High. But when I enter 77, it returns 77. If F5=Queens and B7= Medium, I want to enter a figure in this cell between 60 and 15. If I enter 12, it must return 15 and if 65, must enter 60 in B11, but if I enter 48, it retains 48. Lastly, if F5=Kings and B7= Low, Medium or High, it must enter 20 no matter the figure I enter in B11. Can I use a single formula for each condition or combined into a single formula? I don't want to use a vba. Thank you
Anyone? I would like to know if what i have in mind is possible
I have a names on column A
then b2:ab2 contains the dates for the whole month
I would like to automatically highlight days of the week based on names on column A
Example: if a3="Raymond", then highlight cells on row 3 which falls under thursdays and fridays based on cells b2:ab2(they contain the dates. ex Mar01, Mar02, Mar03...)
Select Cell F21
In conditional formatting, click on new rule.
Select "use a formula to determine which cells to format"
=$F$21>(0.02*$B$21)
Format with the Format button
Click OK
I am trying to format a cell to return 0 if the number is less than 10 and return the exact number if equal or greater than 10. How do I go about it?
=if(a1<10,0,a1)
but that formula should be in another cell, ie: enter this in cell b1
I'm trying to conditional format a cell based on the value of another cell. For example, Cell C2 is 50. I want C3 to show Q if greater than or equal to 50 and U if not. I thought I could use =IF(C2>=50, Q, U) but it doesn't work. What am I missing?
You're just missing the "".
If you want to enter a text from your formula, you should always have "".
=if(c2>=50,"Q","U")
I am trying to create the following conditional format: =IF(G5=100%,"COMPLETE") so when the % value reaches 100%, the cell will change to complete?
Hello to every one!
hope so you are good. I am not so so much good in excel but i have some issue.any expert who can help me will be highly appreciable.i tried my best to clear my point
I have two workbook. in first workbook the name of sheet "sheet1". now data is as below: three columns a b and c
a b c
f01 0 1
f02 8 9
f03 7 0
f04 10 6
f05 5 5
f06 3 0
f07 8 7
f08 0 0
f09 8 6
f10 0 0
upto to f50.... i:e a column have values upto f1 to f50. colm ba nd c have numeric values which are may be zero.
the second work book have data as below:they have only two column a and b:
a b
f05 ?
f04 ?
f08 ?
f10 ?
f15 ?
f16 ?
f20 ?
1.now i want formula on question mark ins second workbook which is that it get value from fist workbook which is greater then zero(remember c column in first workbook is 1 and b is zero so it also should pick it...i:e greater then 0)matches the exact a column.
2.And the second condition is which i m facing problem that value and also very important which is the formula picks all the values (a column only) from first work book which have only value greater then zero weather in column b or column c except it shouldn't get the value which contain both the 0.
i know these are basically two different scenarios. it is possible that both scenarios work in one formula?? if yes then it will be good for me but if not then help in second scenario.
waiting for your kind response.
Advance Thank you!
a please tell me is there any option in conditional formatting or elsewhere to insert or add a circle while value is true..........
I am trying to create a conditional format based on a date calculated from a date in a different cell
so lets say i need a patient to get a test on a specific date prior to the date in B1 06/08/2019. the date of test cell D1 is formulated (=B1-7*20) then in cell E1 has “done” typed cell D1 turns green. But if the date in cell D1 has passed and “done” is not typed in E1 then the cell turns red.
I am just having a heck of a time because the conditional formatting doesn’t recognize the formula in D1 as a date thus it wont change.
Hi,
How to use If(isblank) formula when the cell i am linking has an existing formula? The result is always #value since the excel reads it not blank although the value is zero or blank since it has an existing formula. Anyone who can understand this situation? =). You're response will be so much appreciated! Thanks.
Hi,
I am using excel 2007, I'm trying to use conditional formatting using the below formula. Basically, I want to highlight column A if the other column has negative values.But is not working. It worked on excel 2016. Appreciate your help for any suggestion.
=IFS($E7<0,TRUE,$F7<0,TRUE,$G7<0,TRUE,$H7<0,TRUE,$I7<0,TRUE,$J7<0,TRUE,$K7<0,TRUE,$L7<0,TRUE,$M7<0,TRUE,$N7<0,TRUE,$O7<0,TRUE,$P7<0,TRUE,$Q7<0,TRUE,$R7<0,TRUE,$S7<0,TRUE,$D7<0,TRUE,$T7<0,TRUE,TRUE,FALSE)
Thank you so much.
Hi,
I am trying to highlight cell F21 if the amount in this cell is greater or less than 0.02 of the amount in cell B21. Can you help?
Select Cell F21
In conditional formatting, click on new rule.
Select "use a formula to determine which cells to format"
=$F$21>(0.02*$B$21)
Format with the Format button
Click OK
Hi
I wanted to know if I could use conditional formatting based on a predefined table in excel. The conditional formatting should be able to identify the text in that table, find the text in the defined sheet, and format it to a specific color based on the table's formatting.
Hi Excel Wizards ,
I am looking for help with creating a formula
I am trying to format a cell to say PASS & also format the cell to change colour to green based on this answer.
The cell I am trying to format has to read multiple text values based in a different row any ideas how to go about this or help would be greatly appreciated.
Regards
Seamus
Hi
I have two columns with the conditional format of one cell based on the cell further along the row. I would like to know if they are less equal to or more than. I can do this for one cell. However, when I copy and it down it still references the original cell. How do I make it so that it changes the reference cell?
I have 2 columns, A and B. Column A should always be less than Column B. Can you please help me out?
Hi.
How do I automatically offset cell values between columns?
Hi
I really appreciate your site and clear layouts.
Can you come to my rescue please.
I would like to use conditional formatting and highlight lowest value in col as below
A6.6
A7.7
A3.6
A4.0
I would like A3.6 to be highlighted as it is the lowest value. I've experimented because there is both text and number in the same col but no luck.
Thanks in anticipation
Alex
Hi please help.
I have three columns, ID, Date and Code.
I want to highlight the rows that have the ID and Date the same and the Code on that date is only T. If on the same date there is a code that is T and T, I do want to highlight it. If on the same date there is a code that is C and T, I do want to highlight it. Thank you.
I urgently need help to calculate and "bonus" on a commission structure.
This is what I need for example:
If the SUM of A1+B2 = between 1 & 9, then A1 needs to be multiplied by a certain % however if the SUM of A1 + B2 = between 10 & 19, then A1 needs to be multiplied by a different % and so on.
I have a sliding scale of 6 percentages.
0-149999 | 0%
150000-199999 | 1,25%
200000-299999 | 1,50%
300000-399999 | etc...
400000-799999
800000 +
I hope this makes sense and hopefully someone can help
I urgently need help to calculate and "bonus" on a commission structure.
This is what I need for example:
If the SUM of A1+B2 = between 1 & 9, then A1 needs to be multiplied by a certain % however if the SUM of A1 + B2 = between 10 & 19, then A1 needs to be multiplied by a different % and so on.
I have a sliding scale of 6 percentages.
0-149999 | 0%
150000-199999 | 1,25%
200000-299999 | 1,50%
300000-399999 | etc...
400000-799999
800000 +
I hope this makes sense and hopefully someone can help
I would use a nested formula.
I would put all of my SUM Values in Column C, The Lowest Number of each range in Column D, and the corresponding percentages in Column E.
Then, for each calculation, I would put the following formula into Column F.
=IF($C1>=$D$6,$C1*E6,IF($C1>=$D$5,$C1*$E5,IF($C1>=$D$4,$C1*$E4,IF(...
Continue Nesting until all sections are considered.
I hope this helps.
Thank you very much for the help in the topic "Excel formulas to work with text values"
hi i have some sales value and contribution % of sales value and i want to highlight those articles which are contributing 80% of my total sales value how can i do it?
I want conditional formatting to apply in the following instance.
I want the blank cells in the Range B2:D10 to be highlighted red if the corresponding Cell in Column A contains a value. And if Column A does not contain a value, I want no conditional formatting in the Range B2:D10
Is this possible?
Hello,
I have a spreadsheet I'm writing for a complaints database. Responses are meant to be issued within 10 working days.
I would like the row to highlight if:
the response deadline (auto-populated date, calculated from complaint date, in cell I3) has passed, AND no response has been made (J3- entered manually as the date of response). I have the whole table, minus headings, selected to format to a shade of pink, and in my conditional formatting formula (which I believe I sourced from somewhere online!) I have:
=AND($I3<TODAY(),$J3"")
this works in as much as it highlights the row, but it highlights it whether or not J3 is blank. I have fiddled with the absolute references but that just results in nothing being highlighted at all, even when it should be.
Please could someone explain to me what the () after today, and the after J3 do to affect the formula, and how I can manipulate it to highlight only if both conditions are met?
What is also bizarre is that I have rewritten this formula from scratch within the formula box (at the same position in the rules order), and it doesn't do anything, even if both conditions are met. I feel like my version of excel is a bit temperamental and does whatever it feels like!
I can take screenshots to show what I mean if that's helpful.
Thanks in advance :)
Bel
Hello,
I was wondering if you'd be able to help me. I am trying to use a conditional formatting for two criteria, anything that has tomorrow's date and is a duplicate.
My spreadsheet has other days from October, but since tomorrow is October 11th, I want the conditional formatting to show me any duplicate numbers for October 11th only and highlight those duplicates for October 11th.
I appreciate any help you can offer me!
Hi Guys,
I'm trying to create a rule in which If the Column starts with the number "13", to then make all numbers in the adjacent row negative. Is there such a way to do this?
Thank you.
How can I use Conditional Formatting, when valve change in A1, B1 change the color.
Is there any formula in this regard?
Hai,
During 37th week of 2018 [September], the first week of Hijri-1440 falls/starts.
How to arrive at Hijri [Islamic] week number equivalent to Gregorian week number.
Appreciate your valuable guidance, thanks,
Conditional Formatting Problem: I have made 8 Rules to color code certain words. 6 of the 8 Rules work great, but 2 do not. I have deleted the 2 Rules & reentered, but still no luck. HELP!
PLEASE FIND THE REQUIREMENT BELOW TO WRITE A FORMULA IN EXCEL,
IF THE AGE IS BETWEEN 1-35, PRINT 1000,
IF THE AGE IS BETWEEN 36-40, PRINT 2000,
IF THE AGE IS BETWEEN 41-45, PRINT 3000,
IF THE AGE IS BETWEEN 46-50, PRINT 4000
Cell L18 Cell L19
AGE VALUE
1 - 35 1000
36 - 40 2000
41 - 45 3000
46 - 50 4000
=IF(L18<36,"1000",IF(L18<41,"2000",IF(L18<46,"3000",IF(L18<51,"4000",""))))
Arif:
I think you are looking for something like this:
=IF(B55<=35,1000,IF(B55<=40,2000,IF(B55<=45,3000,IF(B55<=50,4000,"Out of Range"))))
Where the value being tested is in B55.
The "Out of Range" is needed to supply a display message if the value is above 50.
i hava two coloum in excel sheet A and B.
the value is different in both coloum.
i need a conditional formatting formula to change color of col B when col A value is lower then col B.
Single cell color change but when i select the coloum it is not working
please help..........
thank you.
How can I use conditional formatting in a single column?
For instance, using column A entering text in A1, then when text is entered in A2 and hit enter, A1 will have a strikethrough and A2 will not. Enter text in A3, A2 will strikethrough and A3 will not, so on and so forth.
I appreciate any help.
I have an Excel workbook with two sheets. I need to make column D in Sheet 2 format to fill the background a color if Sheet 1 has the exact same number in Column C. What is the function I type into Conditional Formatting New Rule on Sheet 2? Please and thank you!
Hello, Svetlana
I'm having some problems using "OR" function. What I need is something like this:
=OR($D1 = "TEXT 1" , SEARCH("TEXT 2",$D1) > 0)
"Translating" what I'm trying to do is "I want TRUE when either the D column has the exact value 'TEXT 1' or has 'TEXT 2' written with not necessarily exact match"
The problem I'm facing here is that if I add the SEARCH function, it only matches the result of the SEARCH function. If I remove it, it matches the "TEXT 1" one.
Am I missing something here? I'm a programmer and have to say Excel functions have a really terrible syntax. I'm sure it is a very simple issue, but I can't solve it.
Thanks in advance
Hi,
I Have a question regarding conditional formatting. I know how to apply a rule that if the value is under a certain amount, the cell value will equal this amount. I now want to apply a rule that if a cell is between a range, the value s equal to a certain formula. Example; if value is between 10000 and 20000, the result is 10000 plus 90% of the portion in excess to 10000.
Help?
hello
please I want the A1 and B1 to automatically give me an answer in cell C1
A1 20 + B1 20 = C1 40
please how do I format the cells
I really need your help
Emmanuel:
If I understand your question you need to enter this formula in C1:
=A1+B1