by The tutorial shows how to combine VLOOKUP and IF function together to v-lookup with if condition in Excel. You will also learn how to use IF ISNA VLOOKUP formulas to replace #N/A errors with your own text, zero or blank cell.
Whilst the VLOOKUP and IF functions are useful on their own, together they deliver even more valuable experiences. This tutorial implies that you remember the syntax of the two functions well, otherwise you may want to brush up on your knowledge by following the above links.
Vlookup with If statement: return True/False, Yes/No, etc.
One of the most common scenarios when you combine If and Vlookup together is to compare the value returned by Vlookup with a sample value and return Yes / No or True / False as the result.
In most cases, the following generic formula would work nicely:
Translated in plain English, the formula instructs Excel to return True if Vlookup is true (i.e. equal to the specified value). If Vlookup is false (not equal to the specified value), the formula returns False.
Below you will a find a few real-life uses of this IF Vlookup formula.
Example 1. Look up a specific value
Let's say, you have a list of items in column A and quantity in column B. You are creating a dashboard for your users and need a formula that would check the quantity for an item in E1 and inform the user whether the item is in stock or sold out.
You pull the quantity with a regular Vlookup with exact match formula like this:
=VLOOKUP(E1,$A$2:$B$10,2,FALSE)
Then, write an IF statement that compares Vlookup's result with zero, and returns "No" if it is equal to 0, "Yes" otherwise:
=IF(VLOOKUP(E1,$A$2:$B$10,2,FALSE)=0,"No","Yes")
Instead of Yes/No, you can return TRUE/FALSE or In Stock/Sold out or any other two choices. For example:
=IF(VLOOKUP(E1,$A$2:$B$10,2)=0,"Sold out","In stock")
You can also compare the value returned by Vlookup with sample text. In this case, be sure to enclose a text string in quotation marks, like this:
=IF(VLOOKUP(E1,$A$2:$B$10,2)="sample text",TRUE,FALSE)
Example 2. Compare Vlookup result with another cell
Another typical example of Vlookup with If condition in Excel is comparing the Vlookup output with a value in another cell. For example, we can check if it's greater than or equal to a number in cell G2:
=IF(VLOOKUP(E1,$A$2:$B$10,2)>=G2,"Yes!","No")
And here is our If formula with Vlookup in action:
In a similar fashion, you can use any other logical operator together with a cell reference in your Excel If Vlookup formula.
Example 3. Vlookup values in a shorter list
To compare each cell in the target column with another list and return True or Yes if a match is found, False or No otherwise, use this generic IF ISNA VLOOKUP formula:
If Vlookup results in the #N/A error, the formula returns "No", meaning the lookup value is not found in the lookup list. If the match is found, "Yes" is returned. For example:
=IF(ISNA(VLOOKUP(A2,$D$2:$D$4,1,FALSE)),"No","Yes")
If your business logic requires the opposite results, simply swap "Yes" and "No" to reverse the formula's logic:
=IF(ISNA(VLOOKUP(A2,$D$2:$D$4,1,FALSE)),"Yes","No")
Excel If Vlookup formula to perform different calculations
Besides displaying your own text messages, If function with Vlookup can perform different calculations based on the criteria you specify.
Taking our example further, let's calculate the commission of a specific seller (F1) depending on their effectiveness: 20% commission for those who made $200 and more, 10% for everyone else.
For this, you check if the value returned by Vlookup is greater than or equal to 200, and if it is, multiply it by 20%, otherwise by 10%:
=IF(VLOOKUP(F1,$A$2:$C$10,3,FALSE )>=200, VLOOKUP(F1,$A$2:$C$10,3,FALSE)*20%, VLOOKUP(F1,$A$2:$C$10,3,FALSE)*10%)
Where A2:A10 are seller names and C2:C10 are sales.
IF ISNA VLOOKUP to hide #N/A errors
If the VLOOKUP function cannot find a specified value, it throws an #N/A error. To catch that error and replace it with your own text, embed a Vlookup formula in the logical test of the IF function, like this:
Naturally, you can type any text you like instead of "Not found".
Supposing, you have a list of seller names in one column and sales amounts in another column. Your task is to pull a number corresponding to the name the user enters in F1. If the name is not found, display a message indicating so.
With the names in A2:A10 and amounts C2:C10, the task can be fulfilled with the following If Vlookup formula:
=IF(ISNA(VLOOKUP(F1,$A$2:$C$10,3,FALSE)), "Not found", VLOOKUP(F1,$A$2:$C$10,3,FALSE))
If the name is found, a corresponding sales amount is returned:
If the lookup value is not found, the Not found message appears instead of the #N/A error:
How this formula works
The formula's logic is very simple: you use the ISNA function to check Vlookup for #N/A errors. If an error occurs, ISNA returns TRUE, otherwise FALSE. The above values go to the logical test of the IF function, which does one of the following:
- If the logical test is TRUE (#N/A error), your message is displayed.
- If the logical test is FALSE (lookup value is found), Vlookup returns a match normally.
IFNA VLOOKUP in newer Excel versions
Beginning with Excel 2013, you can use the IFNA function instead of IF ISNA to catch and handle #N/A errors:
In our example, the formula would take the following shape:
=IFNA(VLOOKUP(F1,$A$2:$C$10,3, FALSE), "Not found")
Tip. If you'd like to trap all sorts of errors, not only #N/A, use VLOOKUP in combination with the IFERROR function. More details can be found here: IFERROR VLOOKUP in Excel.
Excel Vlookup: if not found return 0
When working with numerical values, you may want to return a zero when the lookup value is not found. To have it done, use the IF ISNA VLOOKUP formula discussed above with a little modification: instead of a text message, supply 0 in the value_if_true argument of the IF function:
In our sample table, the formula would go as follows:
=IF(ISNA(VLOOKUP(F2,$A$2:$C$10,3,FALSE)), 0, VLOOKUP(F2,$A$2:$C$10,3,FALSE))
In the recent versions of Excel 2016 and 2013, you can use the IFNA Vlookup combination again:
=IFNA(VLOOKUP(I2,$A$2:$C$10,3, FALSE), 0)
Excel Vlookup: if not found return blank cell
This is one more variation of the "Vlookup if then" statement: return nothing when the lookup value is not found. To do this, instruct your formula to return an empty string ("") instead of the #N/A error:
Below are a couple of complete formula examples:
For all Excel versions:
=IF(ISNA(VLOOKUP(F2,$A$2:$C$10,3,FALSE)), "", VLOOKUP(F2,$A$2:$C$10,3,FALSE))
For Excel 2016 and Excel 2013:
=IFNA(VLOOKUP(F2,$A$2:$C$10,3, FALSE), "")
If with Index Match - left vlookup with If condition
Experienced Excel users know that the VLOOKUP function is not the only way to do vertical lookup in Excel. The INDEX MATCH combination can also be used for this purpose and it's even more powerful and versatile. The good news is that Index Match can work together with IF in exactly the same way as Vlookup.
For example, you have order numbers in column A and seller names in column B. You are looking for a formula to pull the order number for a specific seller.
Vlookup cannot be used in this case because it cannot search from right to left. Index Match will work without a hitch as long as the lookup value is found in the lookup column. If not, a #N/A error will show up. To replace the standard error notation with your own text, nest Index Match inside IF ISNA:
=IF(ISNA(INDEX(A2:A10, MATCH(F1, $B$2:$B$10, 0))), "Not found", INDEX(A2:A10, MATCH(F1, $B$2:$B$10, 0)))
In Excel 2016 and 2016, you can use IFNA instead of IF ISNA to make the formula more compact:
=IFNA(INDEX(A2:A10, MATCH(F1, $B$2:$B$10, 0)), "Not found")
In a similar manner, you can use Index Match in other If formulas.
This is how you use Vlookup and IF statement together in Excel. To have a closer look at the formulas discussed in this tutorial, you are welcome to download our sample workbook below. I thank you for reading and hope to see you on our blog next week!
Practice workbook for download
Excel IF Vlookup - formula examples (.xlsx file)
219 comments
Hi, I would like to pull in the billed fee amount from a different data set if the unique matter number and the name of the client manager matches. Accordingly, there are two conditions: 1) matter number 2) Client manager.
Your support is greatly appreciated.
Thanks in advance.
Hello Sarah!
You can find the examples and detailed instructions here: Excel INDEX MATCH with multiple criteria - formula examples
Hi sir,
I would like to ask about this formula. I hope you can help me.
I have 1st table :
Pdp Date Pdp Created Date PAID NOTICE Dates Voucher Amount Paid Balance
01-01-2021 PD20020/1220027 12-01-2021 PAID 1 15-01-2021 BP20021/0429149 30.000.000 29.400.000 600.000
01-01-2021 PD20020/1220027 12-01-2021 PAID 2 30-09-2022 BR20022/0926004 30.000.000 600.000 -
this is the raw data.. it showed that PD 1220027 already full paid and the balance was 0.
I want to make this raw data into this table :
PDP NOMINAL PAID 1 PAID 2 PAID 3 BALANCE
PD20020/1220027 30.000.000 30.000.000
can you help me to make suitable formula to find the nominal of paid 1 and paid 2 on the second table, so the balance could be 0 ?
thank you
Regrads,
Windy
Hello Windy!
Your question is beyond the scope of the advice provided in this blog. It takes more than a single formula to solve this complex problem.
You can try creating pivot table to get all the payment data in it.
If you have a specific question about how a function or formula works, I'll try my best to help.
I have a monthly time sheet for a single staff member in South Africa. Her hours are flexible and that makes the tax rate differ monthly.
Once I have her monthly figure from the hours worked I need to refer to a table provided by SARS (tax) and if her earnings are between X and Y then I choose that value.
How do I set up my excel to automatically access the table (I have retyped the rows/columns that would be relevant (base remuneration, top remuneration, tax rate). So for example:
If she earned R9287 in the month I would look at the table row where the salary falls between R9222 and R9322 and select the tax figure of R233.
I would like the system to do this for me. HELP.
Thanks.
Hello Janet!
To check that a number is within a certain interval, use approximate match. We have special tutorials on this. Please see: How to Vlookup for approximate match and Approximate match XLOOKUP.
The data you have provided is not enough to offer you a formula.
Thank you Alexander. I will give it a go and come back to you with more details if I get stuck again.
I want to check if there is a formula for returning value as 0 or blank, if the value has already been looked up.
For example, lookup value is in Column A, some are duplicated, some are not. So if I want to look up the value of "123x", I do the formula on Row1 ColB. But for Row 2, I want it to return value as zero, since its already been looked up in Row 1. Can I do that? Thanks in advance.
Col A
Row 1 123x
Row 2 123x
Row 3 123x
Row 4 124B
Hello Juli!
I can't guess what you want to get if the value you are looking for is found. To find only the first match, you can use the COUNTIF function.
=AND(COUNTIF($A$1:$A1,"123x")=1,A1="123x")
This formula will return TRUE. Copy this formula down along the column.
I understand the scenario I also need help in this situation, basically if the first lookup value has been found the other lookup value with same text or number will just result to zero
Hello Paul!
If I understand your question correctly, to get 1 or 0 instead of TRUE or FALSE, use a math operation. Read more: Change Excel string to number with mathematic operations. For example:
=--AND(COUNTIF($A$1:$A1,"123x")=1,A1="123x")
You can also find useful information in this article: How to highlight duplicate cells and rows in Excel. The formula might look like this:
=--(COUNTIF($A$1:$A1,A1)<=1)
Sir
bloew details i have getting sheet 02 dd date on sheet 01 with same dd no and same bank name
Kindly suggest the formula ?
Sheet 01 main file
DD NO DATE BANK NAME
241 08-Jan-24 Hdfc Bank Ltd
241 16-Jan-24 Surat Mercantile Co-Op Bank Ltd
241 20-Jan-24 Surat District Co-Op Bank Ltd
244 12-Jan-24 Surat District Co-Op Bank Ltd
244 24-Jan-24 Hdfc Bank Ltd
245 02-Feb-24 Hdfc Bank Ltd
245 06-Feb-24 Bank Of India
248 16-Jan-24 Hdfc Bank Ltd
248 20-Jan-24 Hdfc Bank Ltd
255 10-Jan-24 Bank Of India
255 18-Jan-24 Surat District Co-Op Bank Ltd
260 16-Jan-24 Surat District Co-Op Bank Ltd
260 18-Jan-24 Surat District Co-Op Bank Ltd
SHEET 02 RESULT FILE
DD NO DATE BANK NAME
241 ?
241 ?
241 ?
244 ?
244 ?
245 ?
245 ?
248 ?
248 ?
255 ?
255 ?
260 ?
260 ?
Hi! To find a value based on two conditions, you can use the INDEX MATCH functions and this guide: Excel INDEX MATCH with multiple criteria - formula examples.
The formula might look like this:
=INDEX('Sheet 01'!B2:B10, MATCH(1,('Sheet 01'!A2:A10=A1)*('Sheet 01'!C2:C10=C1),0))
Respcted sir ,
no results found....
please help me
This formula on Sheet 01 searches for a date which meets two criteria: Bank Name and DD No. These criteria are on Sheet 02. If this is not what you need, tell me why and describe the problem in more detail.
Sir, i have Bank DD which is same number with Same bank or Other bank. I want to create a column on which date particular Bank DD was passed in clearing. I have Bank DD number, Bank Name and Bank Clearing Date. I tried but same value (duplicate-BANK DD same number) captured so how i trust that same Bank DD number was cleared on which date ?? so that is why i writing you for help. Can i share you my excelsheet on your e-mail id? please tell me and share your e-mail id... Thank You....
Good morning,
This might not be possible and I'm struggling to search for it properly to find an answer and I hope I'm not confusing this too much, but I basically want a formula which uses the data in one cell to return a specific result, and if it doesn't match I want it to then vlookup to a specific range on a data sheet (so if the data in one cell matches it overrides the need to do the vlookup function, but if it doesn't match then it reverts to the vlookup) :
If data in Cell H12 = a certain phrase then return a specific text result.
But if the phrase doesn't match, then I want it to run through an if/or vlookup (I already have this formula and it works fine (below), but I want it to use the above condition as the primary source to return a result.
So the if/or vlookup formula I am using successfully is: =IF(OR($J$9="N",(VLOOKUP($F$16,Dropdowns!$G$4:$K$117,5,0))),"",VLOOKUP($F$16,Dropdowns!$G$4:$K$117,5,0))
But was then trying to also incorporate =IF($H$12="Service","Manager")
So if "Service" is selected from a drop down box in one cell, it returns "Manager" in the cell I want, but if a different option is selected like "Sales" or "Marketing" etc then it reverts to using the vlookup formula above to determine who the budget holder/approver would be.
Apologies, that probably all sounds a mess.
Many thanks!
Hi! If my understanding is correct, the following formula should work for you:
=IF($H$12="Service","Manager", IF(OR($J$9="N",(VLOOKUP($F$16,Dropdowns!$G$4:$K$117,5,0))),"",VLOOKUP($F$16,Dropdowns!$G$4:$K$117,5,0)))
Maybe this article will be helpful: Nested IF in Excel – formula with multiple conditions.
=IF(E4="LO",IF(L4="THW",VLOOKUP(H4,Table1,3),IF(L4="THHN",VLOOKUP(H4,Table2,3),IF(L4="SP","")))),IF(OR(E4="CO",E4="ACU"),IF(L4="THW",VLOOKUP(H4,Table1,3),IF(L4="THHN",VLOOKUP(H4,Table2,3),IF(L4="SP",""))))
SIr can you check my formula, it says Error in Value. thank you
Hi! I can't check a formula that contains unique references to your data, which I don't have.
Hi, I have a table in which multiple columns are there. I need to search key word "P1" in column J and key word "Not Mapped" in column AN. If these two are matching then I should get output from column A which is unique ID. Can you please help me with the vlookup formula.
For Ex:
ID City1 City2 City3 City4 City5 City6 City7 City8 Priority Team1 Team2 Team3 Team4 Team5 Team6 Team7 Team8 Team9 Team10 Team11 Team12 Team13 Team14 Team15 Team16 Team17 Team18 Team19 Team20 Team21 Team22 Team23 Team24 Team25 Team26 Team27 Team28 Team29 Status
66050C24 P1 Not Mapped
56050C24 P2 Mapped
56050C24 P1 Mapped
In above example only first row satisfies the condition so it should fetch ID from column A i.e. 66050C24.
Hi! You can find the examples and detailed instructions here: Excel INDEX MATCH with multiple criteria. Based on your information, the formula might look something like this:
=INDEX(A2:A100, MATCH(1,(J2:J100="P1")*(AN2:AN100="Not mapped"),0))
Thank you for your swift response, really appreciate it.
I tried it but I am getting #SPILL! error message. Can you please help.
I got the output correctly.
Issue here is I have 100+ values which satisfies (J2:J100="P1")*(AN2:AN100="Not mapped") but I am getting output is first ID from column A. My ask is to fetch all IDs from column A which satisfies the condition (J2:J100="P1")*(AN2:AN100="Not mapped").
Hi! Try to follow the recommendations from this article: How to Vlookup multiple values in Excel with criteria. The formula might look like this:
=IFERROR(INDEX($A$2:$A$100, SMALL(IF(1=((--(J2:J100="P1"))*(--(AN2:AN100="Not mapped"))), ROW($A$2:$A$100)-1,""), ROW()-1)),"")
Also, to get a list of values by condition, you can use the FILTER function as described in this guide: Excel FILTER function with formula examples. For example:
=FILTER(A2:A100,(J2:J100="P1")*(AN2:AN100="Not mapped"))
Hello,
May I know how would I search my data in multiple columns? I have a dataset which I want to identify their function.. And each data have multiple functions which listed in multiple columns.
Eg; abc, cde, efg, ghi
Functions:
metabolism: cde, efg
Oxidative: abc, efg, ghi
Catabolism: abc, cde, efg, ghi
When I did the vlookup for ' abc' resulted N/A, cde - metabolism, efg-metabolism, ghi-N/A.
My formula as below:
=VLOOKUP(A2, 'C:\Functions'! $B:$C,2,0)
How can I make it go through other columns
So that every data have their exact function? If can't found in column 1, check in the rest of the columns until meet their function.
Thank you.
Hi! I don't really understand how you could get these results with your formula. I’ll try to guess and offer you a sequential search across multiple columns using these instructions: How to do sequential VLOOKUPs in Excel
=IFERROR(VLOOKUP(A2,$B:$C,2,0),VLOOKUP(A2,$B:$D,3,0))
or
=IFERROR(INDEX(A2:A10,MATCH(A1,B2:B10,0)),INDEX(A2:A10,MATCH(A1,C2:C10,0)))
If this is not what you wanted, please describe the problem in more detail.
I have Item_Desc in Sheet1
Item 1, Item 2, Item 3
in other hand in Sheet2 I have Item_Desc, Bill_Date, Value
Item 1, 01/12/2023, 1050
Item 2, 11/12/2023, 850
Item 1, 51/12/2023, 950
Need Solution : I need in Sheet1 VlookUp Item1 of last Bill_Date from Sheet2.
Please solve my problem.
Hi! Try using the XLOOKUP function, which can do a reverse lookup from the last value to the first value:
=XLOOKUP("Item 1",A1:A10,C1:C10,,0,-1)
You can find the examples and detailed instructions here: Excel XLOOKUP function with formula examples.
I am trying to create a new reference column in a data set to say 'If cell from column B is found in the lookup table, then return text from cell B + cell E, otherwise return just the value/text from cell B' - It is working for some, but not others.
Can you help?
=IF(VLOOKUP(B11,$N$9:$N$12,1,TRUE)=B11,TEXTJOIN(" - ",,B11,E11),B11)
Hi! If the value B11 is not found, the VLOOKUP function will return an error. Use the IFERROR function to return only the B11 value in case of an error. Try this formula:
=IFERROR(TEXTJOIN(" - ",,VLOOKUP(B11,$N$9:$N$12,1,TRUE),E11),B11)
Hi,
I have a data set where in one column i have unique code, which needs to be mapped/looked-up in another tab but the data required is in multiple tables and i need to lookup that data based on the priority .
Example "qt3213e" is my unique key which can be available in more then 1 table but based on my priority is should 1st search in table 2 then table 1 and so on till it is found and return the value in front of it. How can this be done. Thanks.
Hi! You can use different VLOOKUP formulas depending on the cell value. You can use the nested IF formula or the IFS function for this purpose. For example:
=IFS(C1=1, VLOOKUP(......),C1=2, VLOOKUP( ........))
hai,
i have to vlookup and substitute the word from "COMPANY A" to "-"
can anyone help me?
how to add 2 formula in one column?
=VLOOKUP(E3,'MASTER INFO '!A2:D734,4,FALSE)
=SUBSTITUTE(A3, "COMPANY A", "-", 1)
Hi! You can't write two formulas in the same cell. I'm not quite sure what you want to look for. To replace the text in the cell, use the SUBSTITUTE formula. If that text is not found, the value will not change. You can use a reference to a range of cells, for example:
=SUBSTITUTE(A1:A10, "COMPANY A", "-", 1)
If this does not help, explain the problem in detail.
=IFS(VLOOKUP($B:$B,SMS!$B:$B,1,FALSE),"SMS",VLOOKUP($B:$B,Email!$B:$B,1,FALSE),"Email","Others")
Please help me with my problem, I have 3 worksheets, 1st Worksheet is all the data that is sent via SMS, 2nd worksheet is all data that is sent via Email, then the 3rd worksheet is the consolidated data of the clients who replied. I used vlookup to verify what mode did I use to reach that client. As of now, I individually use vlookup per client then if N/A, I manually put "Others". Thanks in advance.
A B C
No. Account Name
1 001 Asadf Akjs
Hi! Read these instructions: Excel VLOOKUP tutorial with formula examples. Try this formula:
=IFERROR(IFS(NOT(ISNA(VLOOKUP($B1,SMS!$B:$B,1,FALSE))),"SMS",NOT(ISNA(VLOOKUP($B1,Email!$B:$B,1,FALSE))),"Email"),"Others")
You can also find an explanation of the formula in this article: How to use ISNA in Excel with VLOOKUP. If both VLOOKUP functions return an error, you can use the IFERROR function to return the value "Others".
You can copy this formula down along the column.
It returns, FALSE. I appreciate your help, TYSM.
I don’t know if this is quite what I’m needing (probably far more advanced for me). I have 2 inventory sheets, Sheet1 with running totals of inventory incl column with prices. Sheet 2 is inventory taken by various sub trades. I’m trying to have sheet 2 calculate the individual costs per item taken on a specific entry. For simple example:
Sheet1 Totals Sheet 2
Item # Quantity Cost Item Quantity Job# Cost Date
1234 10 1.25. 2345 2 111 3.00. 7/18
2345 10 1.50. 1234 3. 121 3.75. 7/18
3456 10 1.75
Maybe ill answer my own thought, but I need Sheet 2 to input column D with IF A2 range is (Sheet1A2:A3)*(sheet1C2:C3) multiplied whatever the quantity is in Sheet 2 B2.
Is this even possible? I have about 150 items and would hate to have to put criteria for each individual item.
Hi! Unfortunately, I didn't quite understand the problem. Maybe this article will be useful: Excel INDEX MATCH with multiple criteria. If not, please explain in more detail, give an example of the result you want to get.
I am trying to pull data based on multiple criteria. I have tier levels numbered 1,2,3, etc. Each tier level has amount in another column. Each customer has between 1 & 7 tiers. I need to lookup which amount makes up that tier level for each customer. (ie; customer #1 is currently at tier 2, what is the amount associated with tier 2 for that customer #).
Example:
Customer # Tier Level Amount
1 1 $0
2 $1,000
3 $2,000
Thanks!! :)
Hi! If I understand your task correctly, the following tutorial should help: Excel INDEX MATCH with multiple criteria - formula examples.
Thanks! That is close, but I need to reference a different cell for the value and they are on multiple sheets as well. I am not able to paste a screenshot so hopefully you can decipher this. ;)
Sheet 1 - Column A has the customer number (each customer number has 1 row), Column I is where I need to add the formula to find the Lower Tier Amount for that customer.
A H I
Cust Lower Tier Rank Lower Tier Min
61523 - ??? (needs to return 0)
Sheet 2 - Column A has the customer number (each customer number has 1-7 rows of tier levels), Column I is the Lower Tier Amount, Column Q shows the current lower tier number (ie, tier 1, tier 2).
A I J P Q R
Cust Volume From Volume To Current Tier Lower Tier Higher Tier
61523 0 700,000 1 - 2
61523 700,000 1,000,000 0 (1) 1
61523 1,000,000 999,999,999,999,999 0 (1) 1
Thanks!!! :)
Sorry, I knew it would mess up that formatting. A H I & A I J P Q R are the columns and the data for each column is listed below it (but bunched together).
Sheet 1 - Column A - Cust, (61523) Column H - Lower Tier Rank (-), Column I - Lower Tier Min (??? this is the value I need - should return a 0). Sheet 2 - Column A - Cust, (61523), Column I - Volume From (0), Column J - Volume To (700,000), Column P - Current Tier (1), Column Q - Lower Tier (-), Column R - Higher Tier (2).
Hi! If I understand correctly, you have two criteria that are written in Sheet1!A2 and Sheet1!H2. Look for them on Sheet2. Use worksheet references in the formula. Read more: Excel reference to another sheet or workbook (external reference).
On sheet one Column I is the amount for the tier that is in Q (this is the value I need returned on sheet 2). Sheet one has; Customer # in column A, and their tier level number on column Q.
On sheet 2, Column A has the customer number. Column H has the tier level number.
I need sheet 2, column I to tell me what the amount is on sheet 1 that matches both the customer number and the tier number.
Sorry, I wish I could add screenshots. :)
That is exactly what I needed! Thank you so much for all your help!! :)
If I understand correctly, study this manual carefully: Excel INDEX MATCH with multiple criteria. Try a formula like this:
=INDEX(Sheet2!I2:I100, MATCH(1,(Sheet1!A2=Sheet2!A2:A100)*(Sheet1!Q2=Sheet2!H2:H100),0))
Hello
i have 12 seet of 12 month and i want to make one master seet all seet have pary name and its payble amount , for exampale , we have to do 2000 payment to abcd party in jan. And 3000 in feb. How can i make master seet to seet all month payment in row, i want formula that put jan paybale ammount in jan cell ,not in diffrent month cell .
So please help me with make this master seet
Thank you.
Hello! Unfortunately, this information is not enough to recommend a formula to you. I don't really understand how your data is organized. I hope this instruction will be helpful: INDEX MATCH MATCH in Excel for two-dimensional lookup.
I have two Columns:
Column A Column B
OLF2-09-AI-001 1"-AI-130486-BAE3-IS50
OLF2-09-AI-003 1/2"-AI-130586-A7A
OLF2-09-AI-005 12"-AI-137584-AR3-IH25
OLF2-09-BH-001 1"-BH-130486-A7A
OLF2-09-BH-001 12"-BH-135846-A7A
OLF2-09-BH-001 8"-BH-135874-A7A
OLF2-09-BH-001 14"-BH-132145-A7A
OLF2-09-GR-001 1"-GR1358100-AS3-IC
OLF2-09-GR-001 1"-GR-130004-A7A
OLF2-09-GR-001 1"-GR-130005-A7A
OLF2-09-GR-001 1"-GR-1300001-A7A
OLF2-09-NHD-004 1"-GR-136666-A7A
I want to get result as value in column B against similar value of column A with largest number with " sign.
Hi! From your description, I can't understand what result you want to get. To search for the largest number, extract it from the text using the LEFT function and SEARCH function
Try this formula:
=LEFT(B1,SEARCH("""",B1)-1)
Hi I am hoping to use excel to drive an advice action
Column 2 = drop down list
Column 3 = will return a text based action based on the response in Column 2
For example:
drop down = yes => Talk to Mel
drop down = no => leave blank
drop down = not sure => Talk to Sam
drop down = [any other choice] => Further information required
Hi!
Here is the article that may be helpful to you: How to make a dependent (cascading) drop-down list in Excel
Hi, I have cell A1 Apples and Cell A2 Lemons on Sheet 2. Cell B1 and 2 is qty, now i have Cell A3 Apples & Lemons and Cell B3 qty. On my next Sheet
I have Cell A1 Apples and Cell A2 Lemons. I want to vlookup the second sheet and count the qty over to Sheet 1, prob is i have Cell A3 with Apples and Lemons, but need to split count to sheet 1 ex: Apples and Lemons in Cell A3 qty is 4, now this must count to sheet 1 as apples 2 and lemons 2 and or apples =4 and lemons =4, either one of the 2 solutions will work as i have a database working with machinery. On my excel apples will be a machine (DD211) and lemons will be (DD2710) they use the same parts therefore sometimes I get 1 order for both machines, I still need separated data as to what was ordered for each, So it should be order 1 for DD2710 and DD211, 50 parts, on sheet 2 it must show DD211 1 order Cell A1 and cell A2 DD2710 1 order or it could shou DD211 25 parts Cell A1 and 25 Parts DD2710 cell A2, Hope i explained enough detail
Thank you
Hi!
The VLOOKUP function cannot search for a match over a part of the text in a cell. Also, your problem is very confusing and cannot be solved by a single formula. If you have a specific question about the operation of a function or formula, I will try to answer it.