Sep
6

Excel RANK functions with formula examples

The tutorial explains the specificities of the Excel Rank functions and shows how to do ranking in Excel based on multiple criteria, rank data by group, calculate percentile rank, and more.

When you need to determine the relative position of a number in a list of numbers, the easiest way is to sort the numbers in ascending or descending order. If for some reason sorting is not possible, a Rank formula in Excel is the perfect tool to do the job.

Excel RANK function

The RANK function in Excel returns the order (or rank) of a numeric value compared to other values in the same list. In other words, it tells you which value is the highest, the second highest, etc.

In a sorted list, the rank of a certain number would be its position. The RANK function in Excel can determine the rank starting with the largest value (as if sorted in descending order) or the smallest value (as if sorted in ascending order).

The syntax of the Excel RANK function is as follows:

RANK(number,ref,[order])

Where:

Number (required) - the value whose rank you'd like to find.

Ref (required) - a list of numeric values to rank against. It can be supplied as an array of numbers or a reference to the list of numbers.

Order (optional) - a number that specifies how to rank values:

  • If 0 or omitted, the values are ranked in descending order, i.e. from largest to smallest.
  • If 1 or any other non-zero value, the values are ranked in ascending order, i.e. from smallest to largest.

Excel RANK.EQ function

RANK.EQ is an improved version of the RANK function, introduced in Excel 2010. It has the same syntax as RANK and works with the same logic: if several values are ranked equally, the top rank of that group of values is returned (EQ stands for "equal").

RANK.EQ(number,ref,[order])

In Excel 2007 and lower versions, you should always use the RANK function. In Excel 2010, Excel 2013, and Excel 2016, you can go with either RANK or RANK.EQ. However, it'd be wise to use RANK.EQ because RANK can be discontinued at any moment.

Excel RANK.AVG function

RANK.AVG is another function to find rank in Excel that is available only in Excel 2010, Excel 2013, Excel 2016 and later.

It has the same syntax as the other two functions:

RANK.AVG(number,ref,[order])

The difference is that if more than one number has the same rank, the average rank is returned (AVG stands for "average").

4 things you should know about RANK in Excel

  1. Any Rank formula in Excel works only for numeric values: positive and negative numbers, zeros, date and time values. Non-numeric values in the ref argument are ignored.
  2. All RANK functions return the same rank for duplicate values, and skip subsequent ranking, as shown in the example below.
  3. In Excel 2010 and later versions, the RANK function has been replaced with RANK.EQ and RANK.AVG. For backward compatibility, RANK still works in all versions of Excel, but it may not be available in the future.
  4. If number is not found within ref, any Excel Rank function would return the #N/A error.

Basic Excel Rank formula (from highest to lowest)

To gain more understanding about ranking data in Excel, please have a look at this screenshot:
Rank formulas in Excel to rank numbers from highest to lowest

All three formulas rank numbers in column B in descending order (the order argument omitted):

In all versions of Excel 2003 - 2016:

=RANK($B2,$B$2:$B$7)

In Excel 2010 - 2016:

=RANK.EQ($B2,$B$2:$B$7)

=RANK.AVG($B2,$B$2:$B$7)

The difference is in how these formulas process duplicate values. As you see, the same score appears twice, in cells B5 and B6, which affects subsequent ranking:

  • The RANK and RANK.EQ formulas give a rank of 2 to both duplicate scores. The next highest score (Daniela) is ranked 4th. A rank of 3 is not given to anyone.
  • The RANK.AVG formula assigns a different rank to each duplicate behind the scenes (2 and 3 in this example), and returns the average of those ranks (2.5). Again, the 3rd rank is not assigned to anyone.

How to use RANK in Excel - formula examples

The path to excellence, they say, is paved with practice. So, to better learn how to use RANK function in Excel, alone or in combination with other functions, let's work out solutions to a few real-life tasks.

How to rank in Excel from lowest to highest

As shown in the above example, to rank numbers from highest to lowest, you use one of the Excel Rank formulas with the order argument set to 0 or omitted (default).

To have number ranked against other numbers sorted in ascending order, put 1 or any other non-zero value in the optional third argument.

For example, to rank the 100-meter sprint times of the students, you can use either of the below formulas:

=RANK(B2,$B$2:$B$7,1)

=RANK.EQ(B2,$B$2:$B$7,1)

Please pay attention that we lock the range in the ref argument by using absolute cell references, so that it won't change when we copy the formula down the column.
Rank numbers from lowest to highest

As the result, the lowest value (fastest time) is ranked 1st and the largest value (slowest time) gets the lowest rank of 6. The equal times (B2 and B7) are given the same rank.

How to rank data in Excel uniquely

As pointed out earlier, all of the Excel Rank functions return the same rank for items of equal value. If that's not want you want, use one of the following formulas to resolve tie-break situations and give a unique rank to each number.

Unique ranking from highest to lowest

To rank the math scores of our students uniquely in descending order, use this formula:

=RANK.EQ(B2,$B$2:$B$7)+COUNTIF($B$2:B2,B2)-1

Unique ranking from highest to lowest

Unique ranking from lowest to highest

To rank the 100-meter race results in ascending order with no duplicates, use this formula:

=RANK.EQ(B2,$B$2:$B$7,1)+COUNTIF($B$2:B2,B2)-1

Unique ranking from lowest to highest

How these formulas work

As you may have noticed, the only difference between the two formulas is the order argument of the RANK.EQ function: omitted to rank values descending, 1 to rank ascending.

In both formulas, it's the COUNTIF function with the clever use of relative and absolute cell references that does the trick. In short, you use COUNTIF to find out how many occurrences of the number being ranked there are in the above cells, including the number's cell. In the topmost row where you enter the formula, the range consists of a single cell ($B$2:B2). But because you lock only the first reference ($B$2), the last relative reference (B2) changes based on the row where the formula is copied. Thus, for row 7, the range expands to $B$2:B7, and the value in B7 is compared to each of the above cells.

Consequently, for all unique values and 1st occurrences of duplicate values, COUNTIF returns 1; and you subtract 1 at the end of the formula to restore the original rank.

For 2nd occurrences of duplicate values, COUNTIF returns 2. By subtracting 1 you increment the rank by 1 point, thus preventing duplicates. If there happen to be 3 occurrences of the same value, COUNTIF()-1 would add 2 to their ranking, and so on.

Alternative solution to break Excel RANK ties

Another way to rank numbers in Excel uniquely is by adding up two COUNTIF functions:

  • The first function determines how many values are greater than or less than the number to be ranked, depending on whether you are ranking descending or ascending, respectively.
  • The second function (with the "expanding range" $B$2:B2 as in the above example) gets the number of values equal to the number.

For example, to rank numbers uniquely from highest to lowest, you'd use this formula:

=COUNTIF($B$2:$B$7,">"&$B2)+COUNTIF($B$2:B2,B2)

As shown in the screenshot below, the tie-break is successfully resolved, and a unique rank is assigned to each student:
Another way to break Excel RANK ties

Ranking in Excel based on multiple criteria

The previous example has demonstrated two working solutions for an Excel RANK tie break situation. However, it may seem unfair that equal numbers are ranked differently based solely on their position in the list. To improve your ranking, you may want to add one more criteria to be considered in case of a tie.

In our sample dataset, let's add total scores in column C and calculate rank as follows:

  • First, rank with Math Score (main criteria)
  • When there is a tie, break it with Total Score (secondary criteria)

To have it done, we will be using a regular RANK/RANK.EQ formula to find rank, and the COUNTIFS function to break a tie:

=RANK.EQ($B2,$B$2:$B$7)+COUNTIFS($B$2:$B$7,$B2,$C$2:$C$7,">"&$C2)

Compared to the above example, this rank formula is more objective: Timothy is ranked 2nd because his total score is higher than that of Julia:
Ranking data based on multiple criteria

How this formula works

The RANK part of the formula is obvious, and the COUNTIFS function does the following:

  • The first criteria_range/criteria pair ($B$2:$B$7,$B2) counts the occurrences of the value you are ranking. Please notice, we fix the range with absolute references, but do not lock the criteria's row ($B2) so that the formula checks the value in each row individually.
  • The second criteria_range/criteria pair ($C$2:$C$7,">"&$C2) finds out how many total scores are greater than the total score of the value being ranked.

Because COUNTIFS works with the AND logic, i.e. counts only cells that meet all of the specified conditions, it returns 0 for Timothy since no other student with the same Math score has a higher total score. Hence, Timothy's rank returned by RANK.EQ is unchanged. For Julia, the COUNTIFS function returns 1 because one student with the same Math score has a higher total, so her rank number is incremented by 1. If one more student had the same Math score and a total score lower than that of Timothy and Julia, his/her rank would be incremented by 2, and so on.

Alternative solutions to rank numbers with multiple criteria

Instead of the RANK or RANK.EQ function, you could use COUNTIF to check the main criteria, and COUNTIFS or SUMPRODUCT to resolve a tie break:

=COUNTIF($B$2:$B$7,">"&$B2)+COUNTIFS($B$2:$B$7,$B2,$C$2:$C$7,">"&$C2)+1

=COUNTIF($B$2:$B$7,">"&B2)+SUMPRODUCT(--($C$2:$C$7=C2),--($B$2:$B$7>B2))+1

The result of these formulas are exactly the same as shown above.

How to calculate percentile rank in Excel

In statistics, a percentile (or centile) is the value below which a certain percentage of values in a given dataset falls. For example, if 70% of students are equal to or below your test score, your percentile rank is 70.

To get percentile rank in Excel, use the RANK or RANK.EQ function with a non-zero order argument to rank numbers from smallest to largest, and then divide the rank by the count of numbers. So, the generic Excel Percentile Rank formula goes as follows:

RANK.EQ(topmost_cell,range,1)/COUNT(range)

To calculate the percentile rank of our students, the formula takes the following shape:

=RANK.EQ(B2,$B$2:$B$7,1)/COUNT($B$2:$B$7)

To have the results displayed correctly, be sure to set the Percentage format to the formula cells:
Calculating percentile rank in Excel

How to rank numbers in non-adjacent cells

In situations when you need to rank non-contiguous cells, supply those cells directly in the ref argument of your Excel Rank formula in the form of a reference union, locking the references with the $ sign. For example:

=RANK(B2,($B$2,$B$4,$B$6))

To prevent errors in non-ranked cells, wrap RANK in the IFERROR function, like this:

=IFERROR(RANK(B2,($B$2,$B$4,$B$6)), "")

Please notice that a duplicate number is also given a rank, though cell B5 is not included in the formula:
Ranking numbers in non-adjacent cells

If you need to rank multiple non-contiguous cells, the above formula may become too long. In this case, a more elegant solution would be defining a named range, and referencing that name in the formula:

=IFERROR(RANK(B2,range), "")

Ranking numbers in non-contiguous cells based on a named range.

How to rank in Excel by group

When working with entries organized into some kind of data structure, data may belong to various groups, and you might want to rank numbers within each group individually. The Excel RANK function cannot resolve this challenge, so we are going to use a more complex SUMPRODUCT formula:

Rank by group in descending order:

=SUMPRODUCT((A2=$A$2:$A$7)*(C2<$C$2:$C$7))+1

Rank by group in ascending order:

=SUMPRODUCT((A2=$A$2:$A$7)*(C2>$C$2:$C$7))+1

Where:

  • A2:A7 are groups assigned to numbers.
  • C2:C7 are numbers to be ranked.

In this example, we use the first formula to rank numbers in each group from largest to smallest:
Ranking data by group

How this formula works

Essentially, the formula evaluates 2 conditions:

  • First, you check the group (A2=$A$2:$A$7). This part returns an array of TRUE and FALSE based on whether a range element belongs to the same group as A2.
  • Second, you check the score. To rank values from largest to smallest (descending order), use the condition (C2<$C$2:$C$11), which returns TRUE for the cells greater than or equal to C2, FALSE otherwise.

Since in Microsoft Excel terms, TRUE = 1 and FALSE = 0, multiplying the two arrays gives an array of 1's and 0's, where 1 is returned only for the rows in which both conditions are met.

Then, SUMPRODUCT adds up the elements of the 1's and 0's array, hence returning 0 for the largest number in each group. And you add 1 to the result to start ranking with 1.

The formula that ranks numbers within groups from smallest to largest (ascending order) works with the same logic. The difference is that SUMPRODUCT returns 0 for the smallest number in a particular group, since no number in that group meets the 2nd condition (C2>$C$2:$C$7). Again, you replace zero rank with the 1st rank by adding 1 to the formula result.

Instead of SUMPRODUCT, you can use the SUM function to add up the array elements. But this would require using an array formula, completed via Ctrl + Shift + Enter. For example:

=SUM((A2=$A$2:$A$7)*(C2<$C$2:$C$7))+1

How to rank positive and negative numbers separately

If your list of numbers contains both positive and negative values, the Excel RANK function will rank them all in no time. But what if you'd like to have positive and negative numbers ranked separately?

With numbers in cells A2 to A10, use one of the following formulas to get individual ranking for positive and negative values:

Rank positive numbers descending:

=IF($A2>0,COUNTIF($A$2:$A$10,">"&A2)+1,"")

Rank positive numbers ascending:

=IF($A2>0,COUNTIF($A$2:$A$10,">0")-COUNTIF($A$2:$A$10,">"&$A2),"")

Rank negative numbers descending:

=IF($A2<0,COUNTIF($A$2:$A$10,"<0")-COUNTIF($A$2:$A$10,"<"&$A2),"")

Rank negative numbers ascending:

=IF($A2<0,COUNTIF($A$2:$A$10,"<"&$A2)+1,"")

The results will look something similar to this:
Ranking positive and negative numbers separately

How these formulas work

To begin with, let's break down the formula that ranks positive numbers in descending order:

  • In the logical test of the IF function, you check whether the number is greater than zero.
  • If the number is greater than 0, the COUNTIF function returns the count of values higher than the number being ranked.

    In this example, A2 contains the 2nd highest positive number, for which COUNTIF returns 1, meaning there is just one number greater than it. In order to start our ranking with 1, not 0, we add 1 to the formula result, so it returns a rank of 2 for A2.

  • If the number is greater than 0, the formula returns an empty string ("").

The formula that ranks positive numbers in ascending order works a bit differently:

If the number is greater than 0, the first COUNTIF gets the total count of positive numbers in the data set, and the second COUNTIF finds out how many values are higher than that number. Then, you subtract the latter from the former, and get the desired rank. In this example, there are 5 positive values, 1 of which is greater than A2. So, you subtract 1 from 5, thus getting a rank of 4 for A2.

Formulas to rank negative numbers are based on a similar logic.

Note. All of the above formulas ignore zero values because 0 belongs neither to the set of positive nor to the set of negative numbers. To include zeros in your ranking, replace >0 and <0 with >=0 and <=0, respectively, where the formula logic requires.

For example, to rank positive numbers and zeros from largest to smallest, use this formula: =IF($A2>=0,COUNTIF($A$2:$A$10,">"&A2)+1,"")

How to rank data in Excel ignoring zero values

As you already know, a RANK formula is Excel handles all numbers: positive, negative and zeros. But in some cases, we just want to rank cells with data ignoring 0 values. On the web, you can find a few possible solutions for this task, but the Excel RANK IF formula, methinks, is the most universal one:

Rank numbers descending ignoring zero:

=IF($B2=0,"",IF($B2>0,RANK($B2,$B$2:$B$10), RANK($B2,$B$2:$B$10)-COUNTIF($B$2:$B$10,0)))

Rank numbers ascending ignoring zero:

=IF($B2=0,"",IF($B2>0,RANK($B2,$B$2:$B$10,1) - COUNTIF($B$2:$B$10,0), RANK($B2,$B$2:$B$10,1)))

Where B2:B10 is the range of numbers to be ranked.

The best thing about this formula is that it works beautifully both for positive and negative numbers, leaving zero values out of ranking:
Rank numbers in Excel ignoring zero values

How this formula works

At first sight, the formula may seem a bit tricky. Upon a closer look, the logic is very simple.

Here's how the Excel RANK IF formula ranks numbers from largest to smallest ignoring zeros:

  • The first IF checks whether the number is 0, and if it is, returns an empty string:

    IF($B2=0,"", …)

  • If the number is not zero, the second IF checks whether it's greater than 0, and if it is, a regular RANK / RANK.EQ function calculates its rank:

    IF($B2>0,RANK($B2,$B$2:$B$10),…)

  • If the number is less than 0, you adjust ranking by the zero count. In this example, there are 4 positive numbers and 2 zeros. So, for the largest negative number in B10, an Excel RANK formula would return 7. But we skip zeros, and therefore we need to adjust the rank by 2 points. For this, we subtract the number of zeros from the rank:

    RANK($B2,$B$2:$B$10)-COUNTIF($B$2:$B$10,0))

Yep, it's that easy! The formula to ranks numbers from smallest to largest ignoring zeroes works in a similar manner, and it could be a good brain exercise to deduce its logic :)

How to calculate rank in Excel by absolute value

When dealing with a list of positive and negative values, there may be a need to rank numbers by their absolute values ignoring the sign.

The task can be fulfilled with one of the bellow formulas, at the heart of which is the ABS function that returns the absolute value of a number:

Rank ABS descending:

=SUMPRODUCT((ABS(A2)<=ABS(A$2:A$7)) * (A$2:A$7<>"")) - SUMPRODUCT((ABS(A2)=ABS($A$2:$A$7)) * (A$2:A$7<>""))+1

Rank ABS ascending:

=SUMPRODUCT((ABS(A2)>=ABS(A$2:A$7)) * (A$2:A$7<>"")) - SUMPRODUCT((ABS(A2)=ABS($A$2:$A$7)) * (A$2:A$7<>""))+1

As the result, negative numbers are ranked as if they were positive numbers:
Find rank in Excel by absolute value

How to get N largest or smallest values

If you wish to get an actual N number of the largest or smallest values rather than their ranking, use the LARGE or SMALL function, respectively.

For example, we can get the top 3 scores of our students with this formula:

=LARGE($B$2:$B$7, $D3)

Where B2:B7 is the list of scores and D3 is the desired rank.

Additionally, you can retrieve the students' names by using the INDEX MATCH formula (provided there are no duplicate scores in the top 3):

=INDEX($A$2:$A$7,MATCH(E3,$B$2:$B$7,0))

Use the LARGE function to get the top 3 values in the list

Similarly, you can use the SMALL function to pull the bottom 3 values:

=SMALL($B$2:$B$7, $D3)

Use the SMALL function to get the bottom 3 values

That's how you do ranking in Excel. To better understand and probably reverse-engineer the formulas discussed in this tutorial, you are welcome to download our Sample Rank Excel workbook.

I thank you for reading and hope to see you on our blog next week!

You may also be interested in:

2 Responses to "Excel RANK functions with formula examples"

  1. Sebastian says:

    Dears,
    In RANK.EQ function why rank 2 is skipping to Rank 3 on re applying marks. Could you help me please.

    Best regards,

  2. sujan says:

    -0.19
    0.18
    0.10
    -0.04
    -0.08
    -0.04
    -2.22
    -0.67
    -0.36
    -0.05
    -1.32
    -1.36
    -0.48
    -1.15
    0.65
    0.04
    0.38
    -0.38
    0.19
    0.38
    0.01
    0.38
    -0.68
    -0.05
    0.40
    0.35
    -0.41
    -0.30
    -0.02
    -0.49
    0.99
    0.10
    1.23
    0.89
    1.21
    -1.44
    -1.58
    -1.38
    0.10
    1.00
    -1.93
    1.23
    1.37
    -1.45
    -0.99
    -2.05
    -1.63
    -1.79

    How to rank this in excel?

Post a comment



Unfortunately, due to the volume of comments received we cannot guarantee that we will be able to give you a timely response. When posting a question, please be very clear and concise. We thank you for understanding!
Excel add-ins and Outlook tools - Ablebits.com
Ultimate Suite for Excel Professionals
 
 
60+ professional tools for Excel 2016-2007 to do your daily work
Incredible product, even better tech support…AbleBits totally delivers!
Deborah Bryant
Anyone who works with Excel is sure to find their work made easier
Jackie Lee
The best spent money on software I've ever spent!
Patrick Raugh
Ablebits is a fantastic product - easy to use and so efficient.
Debra Celmer
Excel is at its best now
Annie C.
I don't know how to thank you enough for your Excel add-ins
Jennifer Morningstar
Anybody who experiences it, is bound to love it!
Kumar Nepa
AbleBits suite has really helped me when I was in a crunch!
Nelda Fink
I have enjoyed every bit of it and time am using it
Christian Onyekachi Nwosu
It's the best $100 we've ever spent!
Mike Cavanagh
I love the program, and I can't imagine using Excel without it!
Robert Madsen
One word… WOW!
Dave Brown
Love the products!
David Johnston
It is like having an expert at my shoulder helping me…
Linda Shakespeare
Your software really helps make my job easier
Jeannie C.
Thanks for a terrific product that is worth every single cent!
Dianne Young
I love your product
Brad Gibson
Awesome!!!
Sheila Blanchard