by If you are a regular visitor of this blog, you've probably noticed a few articles covering different aspects of Excel conditional formatting. And now we will leverage this knowledge and create spreadsheets that differentiate between weekdays and weekends, highlight public holidays and display a coming deadline or delay. In other words, we are going to apply Excel conditional formatting to dates.
If you have some basic knowledge of Excel formulas, then you are most likely familiar with some of date and time functions such as NOW, TODAY, DATE, WEEKDAY, etc. In this tutorial, we are going to take this functionality a step further to conditionally format Excel dates in the way you want.
Excel conditional formatting for dates (built-in rules)
Microsoft Excel provides 10 options to format selected cells based on the current date.
- To apply the formatting, you simply go to the Home tab > Conditional Formatting > Highlight Cell Rules and select A Date Occurring.
- Select one of the date options from the drop-down list in the left-hand part of the window, ranging from last month to next month.
- Finally, choose one of the pre-defined formats or set up your custom format by choosing different options on the Font, Border and Fill tabs. If the Excel standard palette does not suffice, you can always click the More colors… button.
- Click OK and enjoy the result! : )
However, this fast and straightforward way has two significant limitations - 1) it works for selected cells only and 2) the conditional format is always applied based on the current date.
Excel conditional formatting formulas for dates
If you want to highlight cells or entire rows based on a date in another cell, or create rules for greater time intervals (i.e. more than a month from the current date), you will have to create your own conditional formatting rule based on a formula. Below you will find a few examples of my favorite Excel conditional formats for dates.
How to highlight weekends in Excel
Regrettably, Microsoft Excel does not have a built-in calendar similar to Outlook's. Well, let's see how you can create your own automated calendar with quite little effort.
When designing your Excel calendar, you can use the =DATE(year,month,date) function to display the days of the week. Simply enter the year and the month's number somewhere in your spreadsheet and reference those cells in the formula. Of course, you could type the numbers directly in the formula, but this is not a very efficient approach because you would have to adjust the formula for each month.
The screenshot below demonstrates the DATE function in action. I used the formula =DATE($B$2,$B$1,B$4) which is copied across row 5.
Tip. If you want to display only the days of the week like you see in the image above, select the cells with the formula (row 5 in our case), right-click and choose Format Cells…> Number > Custom. From the drop-down list under Type, select either dddd or ddd to show full day names or abbreviated names, respectively.
Your Excel calendar is almost done, and you only need to change the color of weekends. Naturally, you are not going to color the cells manually. We'll have Excel format the weekends automatically by creating a conditional formatting rule based on the WEEKDAY formula.
- You start by selecting your Excel calendar where you want to shade the weekends. In our case, it is the range $B$4:$AE$10. Be sure to start the selection with the 1st date column - Colum B in this example.
- On the Home tab, click Conditional Formatting menu > New Rule.
- Create a new conditional formatting rule based on a formula as explained in the above linked guide.
- In the "Format values where this formula is true" box, enter the following WEEKDAY formula that will determine which cells are Saturdays and Sundays:
=WEEKDAY(B$5,2)>5 - Click the Format… button and set up your custom format by switching between the Font, Border and Fill tabs and playing with different formatting options. When done, click the OK button to preview the rule.
Now, let me briefly explain the WEEKDAY(serial_number,[return_type]) formula so that you can quickly adjust it for your own spreadsheets.
- The
serial_numberparameter represents the date you are trying to find. You enter a reference to your first cell with a date, B$5 in our case. - The
[return_type]parameter determines the week type (square brackets imply it is optional). You enter 2 as the return type for a week starting from Monday (1) through Sunday (7). You can find the full list of available return types here. - Finally, you write >5 to highlight only Saturdays (6) and Sundays (7).
The screenshot below demonstrates the result in Excel 2013 - the weekends are highlighted in the reddish colour.
Tips:
- If you have non-standard weekends in your company, e.g. Fridays and Saturdays, then you would need to tweak the formula so that it starts counting from Sunday (1) and highlight days 6 (Friday) and 7 (Saturday) -
WEEKDAY(B$5,1)>5. - If you are creating a horizontal (landscape) calendar, use a relative column (without $) and absolute row (with $) in a cell reference because you should lock the reference of the row - in the above example it is row 5, so we entered B$5. But if you are designing a calendar in vertical orientation, you should do the opposite, i.e. use an absolute column and relative row, e.g. $B5 as you can see in the screenshot below:
How to highlight holidays in Excel
To improve your Excel calendar further, you can shade public holidays as well. To do that, you will need to list the holidays you want to highlight in the same or some other spreadsheet.
For example, I've added the following holidays in column A ($A$14:$A$17). Of course, not all of them are real public holidays, but they will do for demonstration purposes : )
Again, you open Conditional Formatting > New Rule. In the case of holidays, you are going to use either MATCH or COUNTIF function:
=COUNTIF($A$14:$A$17,B$5)>0=MATCH(B$5,$A$14:$A$17,0)
Note. If you have chosen a different color for holidays, you need to move the public holiday rule to the top of the rules list via Conditional Formatting > Manage Rules…
The following image shows the result in Excel 2013:
Conditionally format a cell when a value is changed to a date
It's not a big problem to conditionally format a cell when a date is added to that cell or any other cell in the same row as long as no other value type is allowed. In this case, you could simply use a formula to highlight non-blanks, as described in Excel conditional formulas for blanks and non-blanks. But what if those cells already have some values, e.g. text, and you want to change the background color when text is changed to a date?
The task may sound a bit intricate, but the solution is very simple.
- First off, you need to determine the format code of your date. Here are just a few examples:
- D1: dd-mmm-yy or d-mmm-yy
- D2: dd-mmm or d-mmm
- D3: mmm-yy
- D4: mm/dd/yy or m/d/yy or m/d/yy h:mm
You can find the complete list of date codes in this article.
- Select a column where you want to change the color of cells or the entire table in case you want to highlight rows.
- And now create a conditional formatting rule using a formula similar to this one:
=CELL("format",$A2)="D1". In the formula, A is the column with dates and D1 is the date format.If your table contains dates in 2 or more formats, then use the OR operator, e.g.
=OR(cell("format", $A2)="D1", cell("format",$A2)="D2", cell("format", $A2)="D3")The screenshot below demonstrates the result of such conditional formatting rule for dates.
How to highlight rows based on a certain date in a certain column
Suppose, you have a large Excel spreadsheet that contains two date columns (B and C). You want to highlight every row that has a certain date, say 13-May-14, in column C.
To apply Excel conditional formatting to a certain date, you need to find its numerical value first. As you probably know, Microsoft Excel stores dates as sequential serial numbers, starting from January 1, 1900. So, 1-Jan-1900 is stored as 1, 2-Jan-1900 is stored as 2… and 13-May-14 as 41772.
To find the date's number, right-click the cell, select Format Cells > Number and choose the General format. Write down the number you see and click Cancel because you do not really want to change the date's format.
That was actually the major part of the work and now you only need to create a conditional formatting rule for the entire table with this very simple formula: =$C2=41772. The formula implies that your table has headers and row 2 is your first row with data.
An alternative way is to use the DATEVALUE formula that converts the date to the number format is which it is stored, e.g. =$C2=DATEVALUE("5/13/2014")
Whichever formula you use, it will have the same effect:
Conditionally format dates in Excel based on the current date
As you probably know Microsoft Excel provides the TODAY() functions for various calculations based on the current date. Here are just a few examples of how you can use it to conditionally format dates in Excel.
Example 1. Highlight dates equal to, greater than or less than today
To conditionally format cells or entire rows based on today's date, you use the TODAY function as follows:
Equal to today: =$B2=TODAY()
Greater than today: =$B2>TODAY()
Less than today: =$B2<TODAY()
The screenshot below demonstrates the above rules in action. Please note, at the moment of writing TODAY was 12-Jun-2014.
Example 2. Conditionally format dates in Excel based on several conditions
In a similar fashion, you can use the TODAY function in combination with other Excel functions to handle more complex scenarios. For example, you may want your Excel conditional formatting date formula to color the Invoice column when the Delivery Date is equal to or greater than today BUT you want the formatting to disappear when you enter the invoice number.
For this task, you would need an additional column with the following formula (where E is your Delivery column and F the Invoice column):
=IF(E2>=TODAY(),IF(F2="", 1, 0), 0)
If the delivery date is greater than or equal to the current date and there is no number in the Invoice column, the formula returns 1, otherwise it's 0.
After that you create a simple conditional formatting rule for the Invoice column with the formula =$G2=1 where G is your additional column. Of course, you will be able to hide this column later.
Example 3. Highlight upcoming dates and delays
Suppose you have a project schedule in Excel that lists tasks, their start dates and durations. What you want is to have the end date for each task calculated automatically. An additional challenge is that the formula should also consider the weekends. For example, if the starting date is 13-Jun-2014 and the number of days of work (Duration) is 2, the ending date should come as 17-Jun-2014, because 14-Jun and 15-Jun are Saturday and Sunday.
To do this, we will use the WORKDAY.INTL(start_date,days,[weekend],[holidays]) function, more precisely =WORKDAY.INTL(B2,C2,1).
In the formula, we enter 1 as the 3rd parameter since it indicates Saturday and Sunday as holidays. You can use another value if your weekends are different, say, Fri and Sat. The full list of the weekend values is available here. Optionally, you can also use the 4th parameter [holidays], which is a set of dates (range of cells) that should be excluded from the working day calendar.
And finally, you may want to highlight rows depending on how far away the deadline is. For example, the conditional formatting rules based on the following 2 formulas highlight upcoming and recent end dates, respectively:
=AND($D2-TODAY()>=0,$D2-TODAY()<=7)- highlight all rows where the End Date (column D) is within the next 7 days. This formula is really handy when it comes to tracking upcoming expiration dates or payments.=AND(TODAY()-$D2>=0,TODAY()-$D2<=7)- highlight all rows where the End Date (column D) is within the last 7 days. You can use this formula to track the latest overdue payments and other delays.
Here are a few more formula examples that can be applied to the table above:
=$D2<TODAY() - highlights all passed dates (i.e. dates less than the current date). Can be used to format expired subscriptions, overdue payments etc.
=$D2>TODAY() - highlights all future dates (i.e. dates greater than the current date). You can use it to highlight upcoming events.
Of course, there can be infinite variations of the above formulas, depending on your particular task. For instance:
=$D2-TODAY()>=6 - highlights dates that occur in 6 or more days.
=$D2=TODAY()-14 - highlights dates occurring exactly 2 weeks ago.
How to highlight dates within a date range
If you have a long list of dates in your worksheet, you may also want to highlight the cells or rows that fall within a certain date range, i.e. highlight all dates that are between two given dates.
You can fulfil this task using the TODAY() function again. You will just have to construct a little bit more elaborate formulas as demonstrated in the examples below.
Formulas to highlight past dates
- More than 30 days ago:
=TODAY()-$A2>30 - From 30 to 15 days ago, inclusive:
=AND(TODAY()-$A2>=15, TODAY()-$A2<=30) - Less than 15 days ago:
=AND(TODAY()-$A2>=1, TODAY()-$A2<15)
The current date and any future dates are not colored.
Formulas to highlight future dates
- Will occur in more than 30 days from now:
=$A2-TODAY()>30 - In 30 to 15 days, inclusive:
=AND($A2-TODAY()>=15, $A2-TODAY()<=30) - In less than 15 days:
=AND($A2-TODAY()>=1, $A2-TODAY()<15)
The current date and any past dates are not colored.
How to shade gaps and time intervals
In this last example, we are going to utilize yet another Excel date function - DATEDIF(start_date, end_date, interval). This function calculates the difference between two dates based on the specified interval. It differs from all other functions we've discussed in this tutorial in the way that it lets you ignore months or years and calculate the difference only between days or months, whichever you choose.
Don't see how this could work for you? Think about it in another way… Suppose you have a list of birthdays of your family members and friends. Would you like to know how many days there are until their next birthday? Moreover, how many days exactly are left until your wedding anniversary and other events you wouldn't want to miss? Easily!
The formula you need is this (where A is your Date column):
=DATEDIF(TODAY(), DATE((YEAR(TODAY())+1), MONTH($A2), DAY($A2)), "yd")
The "yd" interval type at the end of the formula is used to ignore years and calculate the difference between the days only. For the full list of available interval types, look here.
Tip. If you happen to forget or misplace that complex formula, you can use this simple one instead: =365-DATEDIF($A2,TODAY(),"yd"). It produces exactly the same results, just remember to replace 365 with 366 in leap years : )
And now let's create an Excel conditional formatting rule to shade different gaps in different colors. In this case, it makes more sense to utilize Excel Color Scales rather than create a separate rule for each period.
The screenshot below demonstrates the result in Excel - a gradient 3-color scale with tints from green to red through yellow.
"Days Until Next Birthday" Excel Web App
We have created this Excel Web App to show you the above formula in action. Just enter your events in 1st column and change the corresponding dates in the 2nd column to experiment with the result.
If you are curious to know how to create such interactive Excel spreadsheets, check out this article on how to make web-based Excel spreadsheets.
Hopefully, at least one of the Excel conditional formats for dates discussed in this article has proven useful to you. If you are looking for a solution to some different task, you are most welcome to post a comment. Thank you for reading!
1193 comments
Hi, Mam i want Ms excel VB formula for for date which is equal or greater then date for 3 days more. i mean when date is less then today and more 3 days.
so that i will high light for 3 days that the reminder date is passed then after 3 days that column will not highlighted.kindly reply on my email.
i have to collect rents from different shops every month.in one column i have added the last date to collect the rent and in OK column i add ok if i collect the rent.i want a conditional formatting that if due date exceeds my date column goes red and if i receive the rent and write OK in the other column my date cell goes green
i have to collect rents from different shops every month...in one column i have added the last date to collect the rent and in OK column i add ok if i collect the rent.....i want a conditional formatting that if due date exceeds my date column goes red and if i receive the rent and write OK in the other column my date cell goes green
hello. I am trying to update a number 2.5 every 30 days starting on the 1st of the month. I would also like that number to change colors from green 0-44 to yellow at 45-59 and red at 70+
so if my number starts out at 10 in 30 days starting on the 1st the number updates to 12.5 and then in 30 more days 15 etc.
Mam, I need to highlight the date which will exceed 900 days or 30 days from the mentioned date. Kindly help me.
Hi,
Please help me if you can.
A1 contains a date
A2 contains number of days (Colour 1)
A3 contains number of days (Colour 2)
A4 contains a date
Column B contains date (Jan 1 to Dec 31)
I am looking to highlight "A2" number of days in red and "A3" number of days in blue starting on the date "A1". This alternating red and green pattern must continue until the date "A4"
Hi,
I am producing a sheet at work, and need some help. I have two columns with dates. Column A is date request received, column B is date request dealt with. I want to conditionally format column B cells to take account of the following. If date if column B is greater than 10 working days after the date in column A to highlight the cell red.
It is intended to highlight those dates where we have missed our 10 working day target.
I have tried various formulas to no avail.
Thanks in advance
I am trying to build a training database and simply want the Date of Training to be compared to TODAY. If it's over 365 days then condition format the text to red.
Can anyone help with the formulae to add as a rule. I can adjust for each cell manually.
Hi,
I have a query with Date.
If a Checkbox in B2 is ticked then C2 gets today's date else "Pending".
Note: Checkbox has been added with the help of Developer tab from the Ribbon.
I have linked them with cell F2 also to have True or False value.
Re my post - it's solved -
Conditional format is
Cell Value = Cell of that the date you need
i.e.
Cell value = $B$22 < this is where I have the date 1/1/2016 < I will then be making this cell a dynamic year so that whenever I change the year in B1 the calendars will automatically populate the conditional format based on year :)
Hello,
If I have two columns of dates (column I and column J) and I want to highlight in red cells in column J only if the date in column J is past the date of the corresponding cell in column I. Other than that I want it to be white.
Please help.
Thanks!
Ok - have spent several hours now trying to conditional formatting of a date with no luck perhaps you can help :)
I'm using a dynamic calendar - you'll probably know where I'm going with this but posting for others who don't know.
The year input
Cell - B2=year # - manually input a year i.e. 2016
Cell - B3=Month # - manually input a month i.e. 1
Cell - B4=1st day of month in the first row (i.e.. Friday is Jan 1st)i.e. 6
The Calendar Grid
Top - the month and year
Cell - B5 =month(c5)
Cell - C5 =EDATE($B$3,0) < cell is merged C5 to H5 to give is uniformed look
The Days of the Week
B6 =B8 < this is copied over to column H ie.=b8,c8,d8 ending up at H8
The calendar numbers
Starting Row
-Cell-B7: =IF(WEEKDAY(C5)=1,C5,"")
-Cell-C7: =IF(B7"",B7+1,IF(WEEKDAY(C5)=2,C5,"")) < this formula copies over to H7(changing column heading as you go)
2nd row
-Cell-B8: =H8+1< this formula copies over to H7(changing column heading as you go)
3rd row - same as 2nd
4th row - same as 2nd
5th row
-Cell-B11: =IF(H10<EOMONTH(C5,0),H10+1,"")
-Cell-Cll: =IF(B11<EOMONTH(C5,0),B11+1,"") < this formula copies over to H7(changing column heading as you go)
Row 6 (last row of calendar Grid)
-Cell-B12: =IF(H11<EOMONTH(C5,0),H11+1,"")
-Cell-C12: =IF(B12<EOMONTH(C5,0),B12+1,"") Cells D to H are empty
I need to conditional format holidays i.e. Jan 1st, Dec 25th or a range of dates(1 week vacation), etc but nothing I've tried thus far works - countif, match, if, and, etc. I think the issue is that I'm using a dynamic formula to create a date (the variable) and the holiday date is a date item fixed (i.e. Jan 1, 2016 is day 42370 in excel).
Any help would be appreciated.
Thanks
Hello,
If I have two columns of dates (column A and column B) and I want to highlight column B only if the date in column A falls within the same week of column B.
Please help.
Thanks!
Hi Audra,
You can create a conditional formatting rule with this formula (where 2 is the topmost row with dates):
=WEEKNUM($A2)=WEEKNUM($B2)
Dear Madam,
My office grants 3% increment on salary every year July. I want to program in such a way that on July 1st the increment and salary should get changed to new proportion.
Please guide me
Regards
R Dharma
Please can you help me out on this.. i have many policies but the due date is my problem i can't remember all of them so plz help that i get the due at at least 10 day before.
Thanks
Please can you help me out on this..I have a conditioning formatting with colour on employees date of assumption of duty. the colours helps me to know those who are up for confirmation depending on when each assumed duty. wat formula can help me stop the colours from appearing if the date of confirmation is due and past. Please any solution
Hello,
I'm maintaining an attendance table in the following format.
01 Wed IN 01 Wed OUT
08:27 17:16
08:36 14:31
08:38 17:07
08:32 17:05
08:47 17:05
08:31 17:04
08:16 17:13
08:31 17:13
08:29 17:05
08:40 17:06
08:32 17:02
08:52 17:05
08:36 17:08
08:30 18:37
I want to apply conditional formatting for "IN" column and "OUT" column. If IN time > 8:45, the font in that cell should be RED. If OUT time < 17:00, the font in that cell should be RED.
The data in IN and OUT columns is a result of LEFT(cell, 5) and RIGHT(cell,5) from another column that records every IN and OUT entry of the staff.
I have tried conditional formatting options but I'm obviously doing something wrong. Tried formatting the cells as Time, Custom, etc.
Appreciate your help.
Thanks.
Sunny
Hi I'm trying to produce a spreadsheet that high-lights a whole line in grey when I add a date into one cell on the line to show that the info no longer needs any action. The cell is empty until I add the date after which I want the line to go grey.
Thanks
If I have an inspection date and it comes due again in 6 months,
How do I create the formula to reflect this and have the cell turn red with 30 days before the due date?
Can someone provide Me a formula? I've tried several and still get a 'False' for the answer.
I have a Weekly calendar that start on Last Wednesday the previous month; the cell 2 has dates with formulas and change each month and is merge the cell 3 has 10 box example B3,c3,d3,e3,f3,g3,h3,i3,j3,k3 with the information. I need to transfer to the daily calendar and the daily calendar start on the first of the month and the weekly calendar change every month.
Do you know what formula I can use? Thank you for you help.
Can anyone help me with this? I have an excel file with 2 worksheets(A and B). On worksheet A, i have a weekly guide for activities. On worksheet B, i have the activities and the percentage as which are completed (0% to 100% completion). On A, i want a certain cell to be colored, say gray, if the certain cell in B between 0% and 99% completed for the week, and another color if it will be 100% completed for the week or next. Thank you so much.
Hi, how do I format dates of the month to say this week, next week of this month?
Or this month i mean.. Thanks!
Does anyone know if it is possible to create a conditional formatting rule based on time?
I am creating an action tracker type tool and would like to have the cells formatted to reflect if is it coming due or overdue. I know it can be done for Dates - but in this instance it is going to be based on time.
e.g. Assigned at 1000, due at 1230 - once is past due time flag red, coming due change orange etc.
is it possible to start the colouring of the conditional formatting of the cell from the beggining
Hello,
I am hoping you could help me with a little conditional formatting problem I am having.
I have a sheet full of dates particular employees have completed training on.
I am trying to get the cells to turn green if the date is less than two years from today and red when the date entered into the sheet is older than 2 years (730 days)from today.
eg. If the date in the cell reads 01/06/2015 it would be green and if the date in the cell reads 01/06/2013 it would be red.
NOTE: Example above assumes today's date is 01/06/2016
Hi, I need your help with color coding cells within a column that contains a vlookup formula to bring in that date, I need to color code those dates that fall within a range a certain color, 0 to 6 months, 6 months to 11 months and 11 months and older. Since some of the cells have #N/A from no data found from the vlookup, these would be left non-colored. Is this something you can help me with.
Thank you,
Jacqueline
Hi
How to I create a table that when the date from the drop down list is approaching the next cell will change colour. eg, next month will make the cell turn red as it is a closer date and 3 months time will be orange and any dates further away will be green
Hello,
I am trying to figure out a way of showing if an item has been ordered more than once in a 6 month period.
I have the list of product codes in one column and the date they were ordered in an adjacent column. Is there a way of highlighting repeated product numbers within a 6 month period?
Thank you
Hello!
I have a column of different dates that appear in this format (12-Aug-15) and I would like to format these dates based on their age.
For example, I would like the cell to be green if the date in the cell is less than 180 days old, orange if the date is greater than 180 days but less than 270 days, and red if the cell date is 365 days or more.
Any help would be greatly appreciated!
Hello I have a spreadsheet where I have columns C,F,I,L,O, and R with dates. I used the this month and next month rule but want to add a rule for 60 to 90 days and 91 to 120 days. I used the following formula but it did not seem to work: In 30 to 15 days, inclusive: =AND($A2-TODAY()>=15, $A2-TODAY()<=30). I switched out the 15 for 60 and the 30 for 90. I am not sure how the $A2 applies and that is where I am getting lost. I assume it is the start of the spreadsheet date but have played out with this with no results. Can you please assist.
Thank you
For my work's tracking sheet, we highlight the cells yellow for attempts with the date listed as mm/dd/yy and no highlight when we have made contact with the date of contact as mm/dd/yyyy. I am trying to get the cells to automatically highlight when entered as mm/dd/yy. I tried the =CELL("format",$A2)="D4" formula and it did not work. Any suggestions?
Hi
I have this scenario where in column A I have the date (04/25/2016) and in column B I have the time (12:46 PM)
I am trying to find a formula where I can change the date and time when the time mentioned in the column B is 3:00 Pm or above and it should reflect the next day in the date column with 7:00 AM as the time in Column B.
Example : column A - Column B
04/25/2016 - 3:00 PM
It should change to
04/26/2017 - 7:00 AM
Is there any way I could do that ?
in conditional formatting how to highlight dates greater than 10th of every month ?
Hi Suresh,
You can create a rule with this formula, where A1 is the topmost cell with date.
=DAY($A1)>10
Hi,
I have two dates in my Excel sheet:
1. Booking date
2. Departure date
How can I highlight Departure day Red with a comment popping out if the difference between booking day and departure day is less then 7 days?
Thanks for your help in advance,
G.
So I set a cell to search for the oldest date with no issues. I am using this as a re-certification tracker for 1, 3, and 5 year and need to see how to sort and then add to the date in 1,3,and 5 year increments.
Hope someone can help with this. Any help will be greatly appreciated.
I am trying to have Excel return the word Active or Expired in a cell based on a support contract end date.
I have the end date of the contract in cell I11
In cell I13 I have used the following formula =I11<TODAY()
This returns either a TRUE or a FALSE, depending on the current date and the date that is in cell I11.
I want cell I13 to convert the TRUE or FALSE to either Expired or Active.
So if value is TRUE then I want to see the word Expired in cell I13.
If the value is FALSE then I want to see the word Active in cell I13.
Thanks again.
Never mind, got it worked out. You have a great site here. Thanks for having it available.
Hi! I use spreadsheets for work and I am trying to figure out a formula that has to do with dates.I would like to know if there is a formula i can use that can change the cell color a couple of days before the expiration date in the cell.
Thanks,
Hi Dear,
Need your help
I want col S(Fee defaulter) to be
1) Red fill
if col E(Ending date) is over and Col Q(remaining Fee is greater than zero).
2)and want light red fill
if Col E(Ending date) is today and Q(remaining Fee is greater than zero)
3)and if both the conditions are not met then want green fill
Thanks in advance
Hello! I have dates in columns A and B, and I want to highlight the cells in column B that are past dates in A. I know I can use =$B2>$A2, but is there a way to condition the whole column rather than each individual cell?
Thank you!!
Hi Jenna,
Just apply the rule to all the cells you want to highlight, e.g. A2:A100000.
Help Please! I'm trying to find a formula that work for what I'm needing. I have two due dates 10/1 & 4/1 (Column B contains 1st pmt due date), (Column C contains 2nd pmt due date). I'm trying to find a formula for Column A that will show which pmt either 1st or 2nd pmt is due next.
Hello,
I am highlighting a calendar table in excel With this calendar table, i want to highlight the dates according to our staff type of leave.
Staff has taken LL leave from lets say 29/02/2016 to 10/03/2016, SL Leave from 01/02/2016 to 28/02/2016 and taken HOL leave from 01/25/2016 - 31/01/2016. How do you highlight the calendar table according to this dates? by colouring them according to the type of there leaves.
Yellow for LL leave
Green for HOL leave
Pink for SL leave
Hope someone can help me here. Thanks
Hi, need your help badly. I work in payroll and we have to calculate the due date based on the pay end date. The rule for CRA is that if the pay end date falls within the range of:
from the 1st through the 7th day of the month;
from the 8th through the 14th day of the month;
from the 15th through the 21st day of the month;
from the 22nd through the last day of the month.
Therefore, payment due date is on the 3rd working day EXCLUDING Sat, Sun and statutory holiday dates below:
1-Jan-2016
8-Feb-2016
25-Mar-2016
28-Mar-2016
23-May-2016
1-Jul-2016
1-Aug-2016
5-Sep-2016
10-Oct-2016
11-Nov-2016
26-Dec-2016
27-Dec-2016
I will be so grateful if you can create this condition formula for us. Thank yo.
I have created a spreadsheet where I have one cell that has a date populated for ex: B4. I have another cel J4 that I want to use to confirm if I met or exceeded that deadline date. So I am trying to use conditional formatting to set it where if I had a date less than the inputted date in B4 it goes green representing that I was on time. If I was late and input a date later than B4 it goes red. And when there is no date added the cel stays white.
I also would like to have these rules apply to the entire row of J as well.
Hello,
I can't figure out how to apply conditional formatting for one cell that highlights red when a date that is entered is greater than five days from another cell. Can anyone please break a formula down for this purpose?
Thank you.
Okay, from reading other comments and answers I found that this is an appropriate formula: =AND(ABS(INT(D4-C4))>5,NOT(ISBLANK(D4))). However, is there anyway to take it a step further and have Excel ignore weekends and holidays in the calculation of the 5 days?
Hi,
I am wanting to add some formulas to my spreadsheet.
I have column L (which has a date inserted into it) and column M which will also have a date inserted manually once work is completed, BUT I want Column M to turn red if it has been 15 days after the date inserted into column L, only if a date hasn't been entered into column M.
TIA.
Hello,
I hope you can help me with this:
I have one column of data starting in H2 I need formatting to cover:
1. Dates over a year old from todays date to be Red
2. Dates from today one year in to the future to be Green
3. Dates that are less than a year old and less than a year in the future (everything between the top 2 conditions) to be Yellow.
Hi,
I need help: I'm trying to create a conditional formatting for due dates that would give color alerts. I want the colours to fill the rows. I have a column for the dates that I want to be altered to but I want the color to fill not just the due dates column cells but the rows as well.
I also want to know if it's possible to have the color removed after I've entered the required data for the row. Thank you very much for your assistance. I look forward to your response.
Hi there,
I have a problem I'm trying to solve at work- we have a spreadsheet with dates when a form is due in, and a date when the form was submitted. I want to colour code the dates of forms that missed the deadline. How can I use conditional formatting to tell me which forms were submitted late?
I hope you can help!
Thanks
Hi Elliot,
You can create a conditional formatting rule with a simple formula:
=$B2>$A2
Here B is the column with the dates when the forms are submitted, and A is the column with due dates.
Hi!
What if the due dates and start dates are different every time, will that formula do it?
Thanks!
Hello,
I have a spreadsheet with a column contained an expiration date. I would like to conditionally format this column for dates as follows: If the date entered is before the current date, then I would like the text to be red. If the date entered is more than 30 days in the future, I would like the date to be green. If the date entered is equal to or greater than today's date, but less than 30 days out, I would like the text to be orange.
Thank you for your help!
Hello Becky,
You need to create a conditional formatting rule for each color:
1) Use the following formula to make the dates that are before the current one red:
=AND($D2<TODAY(),NOT(ISBLANK($D2)))
Here D is the column with dates; the formula ignores blank cells.
2) The following formula will help you find the dates that are over 30 days in the future to change their background color to green:
=$D2-TODAY()>30
3) If the date is the same as the current date, or if it is up to 30 days in the future, you can change its background to orange with this formula:
=AND($D2-TODAY()>=0,$D2-TODAY()<=30)
HELP! I read about conditionally formatting A2 if the date = x BUT not if an entry has been entered into B2 for example. Could someone help me with a formula? I want cells shaded red in column E if the date occurs in less than 7 days from today BUT I don't want them shaded if an entry has been entered into column F in the same row.
Hello Jesamine,
You can use the following formula in your conditional formatting rule:
=AND(TODAY() - INT(E1) < 7,INT(E1)<>INT(F1))