Comments on: How to conditionally format dates and time in Excel with formulas and inbuilt rules

See how to apply Excel conditional formatting to dates. Learn how to use formulas to highlight weekends and holidays, format cells when a value is changed to a date, shade upcoming dates and delays, conditionally format dates based on the current date, and more. Continue reading →

Comments page 6. Total comments: 758

  1. Good Afternoon,

    I have a company training matrix which i would like to format. The majority of our training expires in 3 years.
    The date we insert on the matrix is when the training will expire eg. 28/8/19.
    Could you please advise how to format this that 1 year prior to expiry date cell will change from white to another colour and 6 months prior to expiry cell will change colour again?

    Many Thanks,
    Felicity

    1. Hi Felicity,

      You can create two rules with the following formulas:
      1. For the red color:
      =TODAY() >= DATE(YEAR($A1), MONTH($A1) - 6, DAY($A1))
      2. For the yellow color:
      =TODAY() >= DATE(YEAR($A1) - 1, MONTH($A1), DAY($A1))
      Make sure that the rules are in the following order: red, yellow.

  2. Hello Mam,

    I need a help in condition formatting. and amount should be in blue colour if cell value exceed 30 and within 61.

  3. I have been trying feverishly to create a conditional format formula for an approaching deadline, as well as a deadline which has been met and/or expired. I have utilized many different formulas, but all to no avail, as I cannot accomplish what I have set out to do with the formulas:

    1. Format an alert, in the form of a red-colored cell for the deadline that has expired (and/or is past due)- when the date arrives (e.g., say the deadline is 9/3/2016.. on that day, I want the cell to turn red),

    2. Format an alert in the form of an golden-colored cell for 48 hours prior to the deadline (I want the cell to turn gold when the 48 hours before the deadline date arrives, using only weekdays),

    3. Format the deadline in the form of adding 9 days to the date entered into another cell, & the second deadline alert for 48 hours (weekdays only) before the final deadline (which is the 9 days after the initial set date)

    I came across this formula: =IF(A3>> http://www.journalofaccountancy.com/issues/2005/mar/programexceltoalertyoutoadeadline.html

    Can anyone please help me? This is really and truly, driving me batty man! I have been working on this project for 4 days now!

    -Crystal

    1. OH MY GOODNESS CRYSTAL! I need this too! Any chance you were able to figure it out since you posted online in Sept?

      1. Hi Crystal and Aly,

        I do not fully understand condition 3. As for the first 2 conditions, you can create the conditional formatting rules with the following formulas, where A2 is the top-most deadline cell:

        1. Red: =$A2<=TODAY()

        2. Golden: =AND($A2>=WORKDAY(TODAY(), -2), $A2<TODAY())

        Important note! For the rules to work correctly, the golden rule should be the 1st in the list of rules.

  4. Hello,

    If I have two columns of dates (column A and column B) and I want to highlight column B only if the date in column A falls within the same week of column B.

    Please help.

    Thanks!

    1. Hi Audra,

      You can create a conditional formatting rule with this formula (where 2 is the topmost row with dates):
      =WEEKNUM($A2)=WEEKNUM($B2)

  5. Hi, how do I format dates of the month to say this week, next week of this month?

    1. Or this month i mean.. Thanks!

  6. in conditional formatting how to highlight dates greater than 10th of every month ?

    1. Hi Suresh,

      You can create a rule with this formula, where A1 is the topmost cell with date.
      =DAY($A1)>10

  7. Hope someone can help with this. Any help will be greatly appreciated.

    I am trying to have Excel return the word Active or Expired in a cell based on a support contract end date.

    I have the end date of the contract in cell I11

    In cell I13 I have used the following formula =I11<TODAY()

    This returns either a TRUE or a FALSE, depending on the current date and the date that is in cell I11.

    I want cell I13 to convert the TRUE or FALSE to either Expired or Active.

    So if value is TRUE then I want to see the word Expired in cell I13.

    If the value is FALSE then I want to see the word Active in cell I13.

    Thanks again.

    1. Never mind, got it worked out. You have a great site here. Thanks for having it available.

  8. Hello! I have dates in columns A and B, and I want to highlight the cells in column B that are past dates in A. I know I can use =$B2>$A2, but is there a way to condition the whole column rather than each individual cell?

    Thank you!!

    1. Hi Jenna,

      Just apply the rule to all the cells you want to highlight, e.g. A2:A100000.

  9. Hello,

    I can't figure out how to apply conditional formatting for one cell that highlights red when a date that is entered is greater than five days from another cell. Can anyone please break a formula down for this purpose?

    Thank you.

    1. Okay, from reading other comments and answers I found that this is an appropriate formula: =AND(ABS(INT(D4-C4))>5,NOT(ISBLANK(D4))). However, is there anyway to take it a step further and have Excel ignore weekends and holidays in the calculation of the 5 days?

  10. Hi there,
    I have a problem I'm trying to solve at work- we have a spreadsheet with dates when a form is due in, and a date when the form was submitted. I want to colour code the dates of forms that missed the deadline. How can I use conditional formatting to tell me which forms were submitted late?
    I hope you can help!
    Thanks

    1. Hi Elliot,

      You can create a conditional formatting rule with a simple formula:
      =$B2>$A2

      Here B is the column with the dates when the forms are submitted, and A is the column with due dates.

      1. Hi!
        What if the due dates and start dates are different every time, will that formula do it?
        Thanks!

  11. Hello,
    I have a spreadsheet with a column contained an expiration date. I would like to conditionally format this column for dates as follows: If the date entered is before the current date, then I would like the text to be red. If the date entered is more than 30 days in the future, I would like the date to be green. If the date entered is equal to or greater than today's date, but less than 30 days out, I would like the text to be orange.

    Thank you for your help!

    1. Hello Becky,

      You need to create a conditional formatting rule for each color:
      1) Use the following formula to make the dates that are before the current one red:
      =AND($D2<TODAY(),NOT(ISBLANK($D2)))
      Here D is the column with dates; the formula ignores blank cells.
      2) The following formula will help you find the dates that are over 30 days in the future to change their background color to green:
      =$D2-TODAY()>30
      3) If the date is the same as the current date, or if it is up to 30 days in the future, you can change its background to orange with this formula:
      =AND($D2-TODAY()>=0,$D2-TODAY()<=30)

  12. HELP! I read about conditionally formatting A2 if the date = x BUT not if an entry has been entered into B2 for example. Could someone help me with a formula? I want cells shaded red in column E if the date occurs in less than 7 days from today BUT I don't want them shaded if an entry has been entered into column F in the same row.

    1. Hello Jesamine,

      You can use the following formula in your conditional formatting rule:
      =AND(TODAY() - INT(E1) < 7,INT(E1)<>INT(F1))

  13. Hi, I have a training spreadsheet which shows a date in cells to show when training was completed. I would like a formula which changes these cells to a colour when they are due for renewal in 3 years time. Some cells are blank which shows training hasn't been completed, so these cells will need to be the same colour as above. Thank you for your help.

  14. Can you help me? I want to use conditional formatting where the cell is to be green if that date (from another cell) is under 14 days and will input the 14th day. Then the cell is colored red if over 14 days.

    Example: 1/7/16 IN ANOTHER CELL(in green) 1/21/16
    12/15/16 (in red) (blank)

    1. Hello Beve,

      You can create two rules with the following formulas:
      1) Apply green color if the date in cell B2 is not more than 14 days away from the date in cell A2:
      =AND(ABS(INT(B2-A2))<=14,NOT(ISBLANK(B2)))
      2) Apply red if the date in cell C2 is over 14 days away from the date in A2:
      =AND(ABS(INT(C2-A2))>14,NOT(ISBLANK(C2)))
      These rules ignore blanks.

  15. Is it possible to condition a single cell to change colors based on its entered date vs. the current date? As an example using a cell with a Due Date, I want the cell to stay "green" up to 3-days before it is due. At the 3-day mark turn "yellow". After the 3rd day and it passes its original due date it turns "red".

    Any assistance would be much appreciated-JM

    1. Hello James,

      You can create three separate conditional formatting rules using the formulas below:
      - One rule will apply green color when there are more than 3 days left:
      =C2-B2>3

      One rule is for turning cells yellow if there are 3 days left to the due date:
      =C2-B2=3

      The third rule will highlight the cells red when there are fewer than 3 days to the due date and 3 days after it:
      =AND(C2-B2<3,C2-B2>-3)

      Here C2 is the due date, and B2 is the cell with the current date.

  16. HI,

    I WANT TO CALCULATE HOW MANY DAYS THERE ARE UNTIL THE NEXT RENEWAL FOR THEIR VISA. AM CREATING A EMPLOYEE DATABASE.
    =DATEDIF(TODAY(),DATE((YEAR(TODAY())+1),MONTH($A2),DAY($A2)),"yd")

    I TRIED THIS AND WORKING FINE. BUT I NEED IT FOR 2-4 YEARS CALCULATION.

  17. Please suggest how to highlight 2nd and 4th Sat and all Sunday in a month as weekend using conditional formatting.

    1. Hello Mali,

      You can create separate rules to highlight certain days of the week. You can use the following formula for the rule that highlights Sundays:
      =WEEKDAY(A2)=1

      You can use the following formula to highlight the second Saturday each month:
      =(DATE(YEAR(A2),MONTH(A2),1)+(7-WEEKDAY(DATE(YEAR(A2),MONTH(A2),1)))+7)=A2

      Here is the formula for highlighting every 4th Saturday:
      =(DATE(YEAR(A2),MONTH(A2),1)+(7-WEEKDAY(DATE(YEAR(A2),MONTH(A2),1)))+21)=A2

  18. I am trying to color code a date in a column if the date in the column is < or = to the date in the column before it.

    Example if the date in Column G is <or= to date in Column F color the cell green.

    Every formula I have tried so far has not give me the results I am looking for.

    =IF(f<=g,TRUE,FALSE) =IFdate(G<=F,true, false) =if date g<=f

    I am using exel version 2013 and use a formula to determine which cells to format under the new formatting rules.

    Any assistance would be greatly appreciate. Thank you,

    1. Hello Bonny,

      You can use the following simple formula for your conditional formatting rule:
      =F2<=G2

      If there are blanks in the range, you can ignore them by using this formula instead:
      =AND(NOT(ISBLANK(G2)),F2<=G2)

  19. Hi Svetlana,

    we have created sheet for Service report tracker to my team, so if some one log a complaint today that compliant it should show one colour if still the complaint not fixed it in 15 days it has to go to different colour and if the compliant call has closed it has to go to the different colour Can you tell me the formula I should use?

    1. Hi Peter,

      You need to create two conditional formatting rules and choose to use the formulas below. Say, if your dates are in column A, and a note that the complaint is fixed is in column B, then use one rule to highlight all dates in column A red if more than 15 days passed and if the cell in column B is blank:
      =AND(TODAY()-A2>15,ISBLANK(B2),NOT(ISBLANK(A2)))

      Create the second rule to highlight cells in column A green if there is anything entered in column B:
      =AND(NOT(ISBLANK(B2)),NOT(ISBLANK(A2)))

  20. Hi, i am trying to format - highlight a rows based on date in the corresponding cell in that row, so every day would the row would have a different color.
    For example i have a table :
    A1 - Task column, B1- Date, C3 - Start time, D4 - End time and etc.
    so it might be several tasks different rows following one after another for 11/25/2015
    so i it can be only two colors but need to highlight all rows for that day in one color and let say - next day 11/26/2015 i have more tasks to be highlighted in another color.
    I would really appreciate your help, thanks

    1. Hello Andrey,

      You can alternate row colors when the date changes, please see the solution described here:
      https://www.ablebits.com/office-addins-blog/alternate-row-colors-excel/#value-based

      If you want to use more colors, you can create conditional formatting rules for as many colors as you want to use with the formulas below. Say, if you want to use 3 colors, you would need to create three rules with the following formulas and assign each one a color:
      =MOD($B2,3)=2
      =MOD($B2,3)=1
      =MOD($B2,3)=0

  21. Hi I am trying to show various cells at different stages from an expiration date! So if Colum E is 31/12/2015. i would like blank cells within L-S to show once they are say L is 15 days past this and M 3mths past this and N is 6 mths past this etc? Is this possible??
    Thanks in advance?

    1. Hello Gareth,

      If we understand your task correctly, you can create conditional formatting rules with formulas for each of the cells you want to highlight, e.g. for M4 the formula would be:
      =E4-D4<=90
      Here E4 is the cell with the expiration date and D4 is the cell with the current date. If
      You can add another rule for N4 the same way:
      =E4-D4<=180

  22. Hi Svetlana,

    I have a member roster where dues expire at the end of the year. They are entered as 2015/12/31 in column S beginning in row 3.

    I need two formulas. Because the member's name is far to the left in column A, I want to (1) change the cell fill color of the member name if the expiration date is in the current year and (2) if the expiration date is in the previous year or earlier. I want to apply the formula to all rows of members, more than 500 names.

    Would you help me? How could I do that with conditional formatting?

    Many thanks and looking forward to your help.

    1. Hello Joe,

      You need to create two conditional formatting rules with the option to "Use a formula to determine which cells to format", and apply the rules to column A.

      One rule should look for years that are earlier than the current:
      =YEAR(S3)<YEAR(TODAY())
      The second rule should find the current year:
      =YEAR(S3)=YEAR(TODAY())

  23. Hello Swetlena,

    Is there any way in which I can use Red & Green coloue together in one column to reflect the expiry date.

    The green colour fades more towards the red colour as the expiry date approaches?

    Regards,
    Akhil

    1. Hello Akhil,

      You can select the range with dates and create a conditional formatting rule with the "2-Color Scale" format style. Select green color for the minimum value and red for the maximum value, choose to use formula for the maximum value and refer to the cell with the expiry date, e.g. =$B$11.

  24. Hi Miss Svetlana,

    I have a problem on my report. My Boss want to see the my data and highlighted using conditional formatting for the clients have no record or data for past six months and my report was format by month. I hope you can help on this.

    Thank you.

    1. Hello Adrian,

      When you create a conditional formatting rule, choose to "Use a formula to determine which cells to format" and try the following formula:
      =A2>EOMONTH(TODAY()-210,0)+1

  25. I have a problem with conditional formatting "greater than value".
    I'm trying to create a new rule wherein the values are results of time difference and of "if" formula.
    This is how it goes. =if((7:05 AM-7:00 AM)>0,(7:05 AM-7:00 AM),"0:00) but the formula bar contains =if((K11-M11)>0,M11-K11,"0:00")
    The answer should be 0:05 mins and I tried conditional formatting it.
    The conditional formatting rule is like this;"Cell Value>0:00","AaBbCc"(this are formatted in red font color),Applies to cells from "=$O$11:$O$16".
    The answer in from the formula bar should turn red(0:05) and it did, except the problem is it turned all the other cells answers (0:00) into red.

    1. Hello,

      You can use a simple formula =M11-K11 first and set the cell format to time -> 13:30. This way you will see minutes in the format you need. Then create a conditional formatting rule based on the following formula:
      =MINUTE(M3-K3)>4
      It will highlight all values that are over 4 minutes.

  26. Hi Svetlana
    If training dates are entered within a range of cells for the current month (if we are in Oct, then all dates will be October dates), and all cells are formatted so that dates entered are red and look like dd/mm/yyyy, how can I conditionally format the red dates for October to change to black 5 days into the new month so that any new November dates entered at the start of the month remain red, while the rest change?
    Essentially, we need a gap between the end of the month and when the previous month's dates change so that we can send reports of previous month's activities.
    Would really appreciate your help with this.
    Thanks :)

    1. Hello Lynette,

      Please try to create a new conditional formatting rule, choose to "Use a formula to determine which cells to format" and enter the following formula:
      =OR(MONTH(A2)=1, A2<=EOMONTH($A$2,0)+5)

      Please replace column A with the column where you have the dates.

      Click "Format" to change the found dates to black font and click Ok.

  27. Hi, I have random dates of the year in a column now I want to highlight the higher/last date of each month but not able to find any condition need help.

    Ex-
    8-Feb-15
    9-Feb-15
    10-Feb-15
    20-Apr-15 (Highlight this)
    1-Mar-15
    2-Mar-15
    10-Mar-15 (Highlight this)
    17-Apr-15
    18-Apr-15
    1-May-15
    5-May-15
    6-May-15
    8-May-15
    9-May-15 (Highlight this)
    10-Jan-15
    11-Jan-15
    24-Jan-15
    25-Jan-15
    26-Jan-15 (Highlight this)
    8-Feb-15
    11-Feb-15
    24-Feb-15
    25-Feb-15 (Highlight this)

    1. Hello Bhardwaj,

      You need to create a conditional formatting rule, choose to "Use a formula to determine which cells to format" and enter the following formula:

      =IF(C2<>"",LOOKUP(2,1/(C2-DAY(C2)=C$2:C$100-DAY(C$2:C$100)),C$2:C$100)=C2,FALSE)

      Here C2:C100 is the range with your dates.

      Select format for the cells and click Ok.

  28. I need to calculate the days between a start date (A1) and today but to stop calculating when an end date is entered in cell (A2) so (A3) will show how many days have passed but when I open the file after the end date I don't want the calculation to continue going forward.

    1. Hello Dale,

      Please try one of the following formulas in A3 to calculate the number of days between the start date and today, or between the start day and the end date if it is entered in cell A2:
      =IF(A2="";TODAY()-A1; A2-A1)
      Or
      =IF(ISBLANK(A2); TODAY()-A1;A2-A1)

  29. HI,
    HOw to print the current date in a cell based upon the change in the color of the cell?

    1. Hello Pruthi,
      If we understand your task correctly, you can use the following VBA code that one of our developers wrote for you:
      - Open your Excel file;
      - Press Alt+F11 on your keyboard;
      - Double-click the sheet name in the list and paste the code below, but change the reference to your data range and the cell with the necessary color:
      Private Sub CommandButton1_Click()
      Dim color
      Dim i As Integer
      Range("J2").Select
      color = Selection.Interior.color
      Range("F2:F11").Select
      For i = 2 To 11
      Range("F" & i).Select
      If Selection.Interior.color = color Then
      Selection.Value = Date
      End If
      Range("G" & i).Select
      If Selection.Interior.color = color Then
      Selection.Value = Date
      End If
      Next i
      End Sub

      - Click Run

  30. Hi Svetlana,

    I want to use conditional formatting to show (via color highlighting) if a date entered into a cell is within the current calendar year (at any time the spreadsheet is opened). Can you tell me the formula I should use?

    Thanks!

    1. Hi Kevin,

      You can create an Excel conditional formatting rule based on a formula similar to this:

      =YEAR(TODAY())=YEAR($A1)

      Where A1 is the cell containing your date.

  31. Hi I am a total loss here

    I have a column (D5) with Certificate Test/Start dates (YYYY/MM/DD) I then have a column (E5) with months eg. 3,6,12,24 etc, these indicate the months before the certificate needs to be "retested".

    These month values are variables so I can't hardcode a value like Cell Value less than =NOW()-365 (This is for a year validity certificate) and =NOW()-(E5*30.5) meaning month x days, this doesn't work or I am just screwing up the format.

    I want to do a conditional format on D5 that uses E5 to flag D5 as RED (expired), YELLOW (30 days before expiry) and GREEN (still valid)

    Can anyone please help :(

    1. Hi Nick,

      You can use the following formula to calculate the expiry dates:
      =DATE(YEAR($D5), MONTH($D5)+$E5, DAY($D5))

      And than you can create 3 rules with the following formulas based on the expiry date (say in column G):

      Red:=$G5-TODAY()>30

      Yellow:=AND($G5>TODAY(),$G5-TODAY()<=30)

      Green: =$G5-TODAY()>30

      If you don't want an additional column with expiry dates, you can replace G5 in the conditional formatting formulas with the Date function, e.g.:

      Green: =DATE(YEAR($D5), MONTH($D5)+$E5, DAY($D5))-TODAY()>30

  32. Hi,

    I have a date, order #, and arrival date columns

    is there a way to highlight the arrival date column if it is empty after 24 hours from the respective order date?

    For Example:
    order # 3 is placed on 10/04/15 and arrival date is not mentioned until 10/06/15 then it should be highlighted in a different color on 10/05/15

    1. Hello Lijina,

      Supposing that the order date is in column A and arrival date is in column B, and row 2 is the topmost row with dates, select the arrival date column (B) beginning with row 2, and create a rule with the following formula:

      =AND(TODAY()-($A2+1)>0, $B2="", $A2<>"")

  33. Hello,
    I want to highlight an entire row in which only one cell (H2) contains a date. I would like my whole row to be highlighted red when the date in this cell(H5)is two days away from today (coming up in 2 days).

    Thank you very much

    1. H2 again sorry, not H5

      1. Hello Nicolas,

        Select the entire rows that you want to highlight beginning with your first row with dates, e.g. A2:I100. And create a rule with one of the following formulas:

        Date in H2 is exactly two days away from today:
        =$H2-TODAY()=2

        Date in H2 is 1 or 2 days away from today:
        =AND($H2-TODAY()>0, $H2-TODAY()<=2)

  34. Hi,

    I am trying to format cells so that if one date is entered it will be yellow, if two dates are entered it will become orange and if three dates are entered it will become green. Dates (Uk style! :)) will be all listed in the same cell either:
    - dd/mm/yy (yellow)
    - dd/mm/yy, dd/mm/yy (orange)
    - dd/mm/yy, dd/mm/yy, dd/mm/yy (green)
    Do you know if this is possible please and do you have any tips on achieving this?
    Many thanks in advance!

    1. Hi Georgie,

      Because two or more dates entered in the same cell turn into a usual text string, you can write formulas based on how many commas a certain cell contains, if any.

      For example, if your dates reside in column A beginning in row 2, you can use the following formulas:

      Green (3 dates): =SEARCH(",*,", $A2)
      Orange (2 dates): =SEARCH(",", $A2)
      Yellow (1 date): =$A2<>""

      Please note, the rules order is important, so make sure the green rule is the first in the list of rule, and the yellow rule is the last.

  35. I have a date column to identify when individuals leave. I would like the color to change from green being >90 days out, <90 days out- yellow, and <30 days out red. How do I accomplish this?

  36. how to calculate number of days less than 1 month from column with dates. I couldn't find a formula for this. Is it so simple as it is not here?

    1. Hi Monica,

      If you want to highlight the past dates within 1 month from today's date, you can create a rule with the following formula:
      =TODAY()-$A2<=30

      If you are looking for something different, please clarify.

  37. Just needed some help with conditional formatting. I have two columns both with dates - Column A and B. I want to highlight only the dates in B which Date occur 10 days after the date of Column A

    1. Hi Alwin,

      You can create a rule with the formula =$B2-$A2=10 (row 2 is supposed to be the first row with data.

      1. Thanks for your reply
        while I am using this formula it is showing TRUE/FALSE. Actually I need to highlight that column with a specific color and also need to see the date.

        1. To highlight the column, you need to create a conditional formatting rule with the above formulas. You can find the detailed steps to create a rule in this tutorial.

          1. Hi Svetlana Cheusheva,
            Still I am unable to do this. Please help me to highlight the column B
            Column A Column B
            01-04-2015 11-04-2015
            02-04-2015 17-04-2015
            03-04-2015 23-04-2015
            04-04-2015 09-04-2015
            05-04-2015 15-04-2015
            06-04-2015 21-04-2015
            07-04-2015 27-04-2015
            08-04-2015 13-04-2015
            09-04-2015 19-04-2015
            10-04-2015 25-04-2015
            11-04-2015 01-05-2015
            12-04-2015 17-04-2015
            13-04-2015 23-04-2015
            14-04-2015 29-04-2015
            15-04-2015 05-05-2015
            16-04-2015 21-04-2015

        2. I need to highlight the Column B.

  38. HI,
    I have been trying to figure out a formula that changes the color of the cell to red if the date in the cell is <=10 days away from today's date. i.e if the date in the cell reads 07/12/2015 and I opened the spreed sheet today 07/22/2015 the date on that cell should be highlighted in red.

    1. Hi Manny,

      You can create a rule with the following formula, where A2 is the top-most cell with your dates:
      =TODAY()-$A2>=10

  39. Ok think I have a mission imposable here, I need to do an “if, than conditional formatting”. So column “A” is the item “B” is the Due date and “C” is the delivery date. So I need the date in Column “B” to be Green if “C” is blank and “B” is greater than 120 days out, Yellow if “C” is blank and “B” is 60-120 days out and Red if “C” is blank and “B” is less than 60 days out. Is this even possible?

    1. Hi Chris,

      Of course, it's possible. If my understanding is correct, "greater than 120 days out" means more than 120 days from the current date. If so, you can create 3 rules based on the following formulas (assuming that row 2 is your top-most row with data):

      Green: =AND($C2="", $B2-TODAY()>120)
      Yellow: =AND($C2="", $B2-TODAY()>=60, $B2-TODAY()<=120)
      Red: =AND($C2="", $B2-TODAY()<60)

  40. I want cells to turn red if date is within 30 days of maturity date, turn green if within 15 days and turn yellow if within 3 days.

    For Ex if Maturity date is 07-Apr-2016, I need that cell to be red if date(current) is 07-Mar-2016 and so on.

    Please advise formulae to be used for above.

    1. Hi Nick,

      Assuming that the Maturity date is in cell A1, you can create 3 rules based on the following formulas:

      Red: =AND($A$1-TODAY()<=30, $A$1-TODAY()>15)
      Green: =AND($A$1-TODAY()<=15, $A$1-TODAY()>3)
      Yellow: =AND($A$1-TODAY()<=3, $A$1-TODAY()>0)

  41. Hi,

    I have a large spreadsheet with a column containing dates, and need to have a column next to this one which names which year the date falls into.

    Eg, if a date is between 01/08/12 and 31/07/13 the 2nd column needs to say "year 1", 01/08/13 - 31/07/14 is "year 2" and so on.

    I'm sure this should be fairly simple I just cant work it out!!

    1. Hi Roy,

      You don't need conditional formatting in this case. Use a nested IF function similar to this:
      =IF(AND(A1>=DATEVALUE("1-Aug-2012"), A1<=DATEVALUE("31-Jul-2013")), "year1", IF(A1<=DATEVALUE("31-Jul-2014"), "year2", ""))

      1. Hi Svetlana,

        That's brilliant, I suspected I was doing something fundamentally wrong!

        Thanks for your help!
        Roy

  42. and that is using todays date as the expire date.

    1. Hi Stacey,

      Select the cells in column C that you want to color, begining in C3, and create a rule with the formula =$C3<=TODAY()

  43. I am trying to do the following:

    Track dates and identify if the date in the cell is

    Less than 14 days ago
    More than 14 days ago
    More than 30 days ago

    I have tried all possible combinations I can find, but cannot come up with an exact formula.

    Thank you

    1. Hello Leslie,

      Try the following formulas where A2 is your first row with data.

      Less than 14 days ago: =AND(TODAY()-$A2>0, TODAY()-$A2<14)
      From 30 to 14 days ago, inclusive: =AND(TODAY()-$A2>=14, TODAY()-$A2<=30)
      More than 30 days ago: =TODAY()-$A2>30

  44. :) Thanks a Ton. have bookmarked your site. :)
    1 Facebook like from me in return. thanks again.
    2 removed ad filtering addons from the site.
    Best wishes.

  45. another question:

    how to know if two dates fall in the same month?
    thanks again :)

    1. Using the MONTH function :)

      For example, =MONTH(A1)=MONTH(B1) will display TRUE if the dates fall in the same month, FALSE otherwise.

  46. Thanks for such a quick reply. btw: what should be the format of the cell in which i want the results. i am also now looking into the link being suggested.
    thanks again

  47. hi
    11/1/2013 0:00 is present in cell C3
    11/2/2013 0:00 is present in cell C2

    formatting of both is "mm/dd/yyyy h:mm"

    how can i find the difference/number of days between these two dates.

    Thanks in advance.
    eagerly waiting.

  48. I am trying to figure a formula for when how long it is taking cars to go through detail process from when they arrive. What I need is something that would turn the row
    Green for today plus 5 day
    yellow for 6-10
    red for 11+

    I have tried several and cannot get it to change the right color.

    Please and Thank you

    1. Hi Megan,

      Supposing that your dates are in column A beginning in row 2, you can use the following formulas:

      Green: =AND($A2-TODAY()>=0, $A2-TODAY()<=5)

      Yellow: =AND($A2-TODAY()>=6, $A2-TODAY()<=10)

      Red: =$A2-TODAY()>=11

  49. Good day, Svetlana,

    I've glanced through your forum to see if I could find a place where you've already answered, but saw one similar still blank. So I'll ask again for both of us!

    I have dated certifications that are due every year. However, for inspection, I can't put in the due date and use the common TODAY function that most people use to get 90/60/30 days out from being due. Mine has to incorporate the last completion date counting down to when it is due again next year. I'm looking for a formula that will use today's date, reference the column with last completion dates, and tell me when they are 90-61/60-31/30-1/0-past due. If you could help me and suggest which one of the new rule choices to select and enter it into, I would much appreciate it!

    Have a Great Evening!
    ~HLA

    1. Good time of day! :)

      Supposing the last completion dates are in column A, you can create rules with the following formulas:

      90-61: =AND($A2-TODAY()>60, $A2-TODAY()<=90)

      60-31: =AND($A2-TODAY()>30, $A2-TODAY()<=60)

      30-1: =AND($A2-TODAY()>0, $A2-TODAY()<=30)

      0-past due: =TODAY()-$A2>=0

      1. Svetlana, hello!

        I must thank you, Lady. I very much appreciate your expertise, and wish you a wonderful day!

  50. Hi!

    I've got to create a spreadsheet and I'm totally overwhelmed!

    I need to have future dates assigned to particular cells and I need to have those cells become highlighted a month before this date. Does that make sense and what would be the best way to do that?
    Best,
    M

    1. Hi Margarita,

      Supposing that your future dates are in column A and begin in cell A2, you can use the following formula:

      =AND($A2-TODAY()>0, $A2-TODAY()<=30)

Post a comment



Thanks for your comment! Please note that all comments are pre-moderated, and off-topic ones may be deleted.
For faster help, please keep your question clear and concise. While we can't guarantee a reply to every question, we'll do our best to respond :)