*In this short tutorial, you will learn how to quickly calculate a simple moving average in Excel, what functions to use to get moving average for the last N days, weeks, months or years, and how to add a moving average trendline to an Excel chart.*

In a couple of recent articles, we have taken a close look at calculating average in Excel. If you've been following our blog, you already know how to calculate a normal average and what functions to use to find weighted average. In today's tutorial, we will discuss two basic techniques to calculate moving average in Excel.

Generally speaking, **moving average** (also referred to as *rolling average*, *running average* or *moving mean*) can be defined as a series of averages for different subsets of the same data set.

It is frequently used in statistics, seasonally-adjusted economic and weather forecasting to understand underlying trends. In stock trading, moving average is an indicator that shows the average value of a security over a given period of time. In business, it's a common practice to calculate a moving average of sales for the last 3 months to determine the recent trend.

For example, the moving average of three-month temperatures can be calculated by taking the average of temperatures from January to March, then the average of temperatures from February to April, then of March to May, and so on.

There exist different types of moving average such as simple (also known as arithmetic), exponential, variable, triangular, and weighted. In this tutorial, we will be looking into the most commonly used **simple moving average**.

Overall, there are two ways to get a simple moving average in Excel - by using formulas and trendline options. The following examples demonstrate both techniques.

A simple moving average can be calculated in no time with the AVERAGE function. Supposing you have a list of average monthly temperatures in column B, and you want to find a moving average for 3 months (as shown in the image above).

Write a usual AVERAGE formula for the first 3 values and input it in the row corresponding to the 3^{rd} value from the top (cell C4 in this example), and then copy the formula down to other cells in the column:

`=AVERAGE(B2:B4)`

You can fix the column with an absolute reference (like $B2) if you want to, but be sure to use **relative row references** (without the $ sign) so that the formula adjusts properly for other cells.

Remembering that an average is computed by adding up values and then dividing the sum by the number of values to be averaged, you can verify the result by using the SUM formula:

`=SUM(B2:B4)/3`

Supposing you have a list of data, e.g. sale figures or stock quotes, and you want to know the average of the last 3 months at any point of time. For this, you need a formula that will recalculate the average as soon as you enter a value for the next month. What Excel function is capable of doing this? The good old AVERAGE in combination with OFFSET and COUNT.

=AVERAGE(OFFSET(*first cell*, COUNT(*entire range*)-*N*,0,*N*,1))

Where *N* is the number of the last days / weeks / months/ years to include in the average.

Not sure how to use this moving average formula in your Excel worksheets? The following example will make things clearer.

Assuming that the values to average are in column B beginning in row 2, the formula would be as follows:

`=AVERAGE(OFFSET(B2,COUNT(B2:B100)-3,0,3,1))`

And now, let's try to understand what this Excel moving average formula is actually doing.

- The COUNT function COUNT(B2:B100) counts how many values are already entered in column B. We start counting in B2 because row 1 is the column header.
- The OFFSET function takes cell B2 (the 1
^{st}argument) as the starting point, and offsets the count (the value returned by the COUNT function) by moving 3 rows up (-3 in the 2^{nd}argument). As the result, it returns the sum of values in a range consisting of 3 rows (3 in the 4^{th}argument) and 1 column (1 in the last argument), which is the latest 3 months that we want. - Finally, the returned sum is passed to the AVERAGE function to calculate the moving average.

Tip. If you are working with continuously updatable worksheets where new rows are likely to be added in the future, be sure to supply a sufficient number of rows to the COUNT function to accommodate potential new entries. It's not a problem if you include more rows than actually needed as long as you have the first cell right, the COUNT function will discard all empty rows anyway.

As you probably noticed, the table in this example contains data for only 12 months, and yet the range B2:B100 is supplied to COUNT, just to be on the save side :)

If you want to calculate a moving average for the last N days, months, years, etc. in the same row, you can adjust the Offset formula in this way:

=AVERAGE(OFFSET(*first cell*,0,COUNT(*range*)*-N*,1,*N*,))

Supposing B2 is the first number in the row, and you want to include the last 3 numbers in the average, the formula takes the following shape:

`=AVERAGE(OFFSET(B2,0,COUNT(B2:N2)-3,1,3))`

If you have already created a chart for your data, adding a moving average trendline for that chart is a matter of seconds. For this, we are going to use **Excel Trendline** feature and the detailed steps follow below.

For this example, I've created a 2-D column chart (*Insert tab* > *Charts group*) for our sales data:

And now, we want to "visualize" the moving average for 3 months.

- In Excel 2013, select the chart, go to the
*Design tab*>*Chart Layouts*group, and click*Add Chart Element*>*Trendline*>*More Trendline Options*…

In Excel 2010 and Excel 2007, go to

*Layout*>*Trendline*>*More Trendline Options*.Tip. If you do not need to specify the details such as the moving average interval or names, you can click

*Design*>*Add Chart Element*>*Trendline*>*Moving Average*for the immediate result. - The
*Format Trendline*pane will open on the right-hand side of your worksheet in Excel 2013, and the corresponding dialog box will pop up in Excel 2010 and 2007.On the

*Format Trendline*pane, you click the Trendline Options icon, select the**Moving Average**option and specify the moving average interval in the**Period**box:

- Close the Trendline pane and you will find the moving average trendline added to your chart:

To refine your chat, you can switch to the *Fill & Line* or *Effects* tab on the *Format Trendline* pane and play with different options such as line type, color, width, etc.

For powerful data analysis, you may want to add a few moving average trendlines with different time intervals to see how the trend evolves. The following screenshot shows the 2-month (green) and 3-month (brick red) moving average trendlines:

Well, that's all about calculating moving average in Excel. The sample worksheet with the moving average formulas and trendline is available for download - Moving Average spreadsheet. I thank you for reading and look forward to seeing you next week!

Table of contents