by The tutorial explains the syntax of the Google Sheets VLOOKUP function and shows how to use Vlookup formulas for solving real-life tasks.
When working with interrelated data, one of the most common challenges is finding information across multiple sheets. You often perform such tasks in everyday life, for example when scanning a flight schedule board for your flight number to get the departing time and status. Google Sheets VLOOKUP works in a similar way - looks up and retrieves matching data from another table on the same sheet or from a different sheet.
A widespread opinion is that VLOOKUP is one of the most difficult and obscure functions. But that's not true! In fact, it's easy to do VLOOKUP in Google Sheets, and in a moment you will make sure of it.
Google Sheets VLOOKUP - syntax and usage
The VLOOKUP function in Google Sheets is designed to perform a vertical lookup - search for a key value (unique identifier) down the first column in a specified range and return a value in the same row from another column.
The syntax for the Google Sheets VLOOKUP function is as follows:
The first 3 arguments are required, the last one is optional:
Search_key - is the value to search for (lookup value or unique identifier). For example, you can search for the word "apple", number 10, or the value in cell A2.
Range - two or more columns of data for the search. The Google Sheets VLOOKUP function always searches in the first column of range.
Index - the column number in range from which a matching value (value in the same row as search_key) should be returned.
The first column in range has index 1. If index is less than 1, a Vlookup formula returns the #VALUE! error. If it's greater than the number of columns in range, VLOOKUP returns the #REF! error.
Is_sorted - indicates whether the lookup column is sorted (TRUE) or not (FALSE). In most cases, FALSE is recommended.
- If is_sorted is TRUE or omitted (default), the first column of range must be sorted in ascending order, i.e. from A to Z or from smallest to largest.
In this case a Vlookup formula returns an approximate match. More precisely, it searches for exact match first. If an exact match is not found, the formula searches for the closest match that is less than or equal to search_key. If all values in the lookup column are greater than the search key, an #N/A error is returned.
- If is_sorted is set to FALSE, no sorting is required. In this case, a Vlookup formula searches for exact match. If the lookup column contains 2 or more values exactly equal to search_key, the 1st value found is returned.
At first sight, the syntax may seem a bit complicated, but the below Google Sheet Vlookup formula example will make things easier to understand.
Supposing you have two tables: main table and lookup table like shown in the screenshot below. The tables have a common column (Order ID) that is a unique identifier. You aim to pull the status of each order from the lookup table to the main table.
Now, how do you use Google Sheets Vlookup to accomplish the task? To begin with, let's define the arguments for our Vlookup formula:
- Search_key - Order ID (A3), the value to be searched for in the first column of the Lookup table.
- Range - the Lookup table ($F$3:$G$14). Please pay attention that we lock the range by using absolute cell references since we plan to copy the formula to multiple cells.
- Index - 2 because the Status column from which we want to return a match is the 2nd column in range.
- Is_sorted - FALSE because our search column (F) is not sorted.
Putting all the arguments together, we get this formula:
=VLOOKUP(A3,$F$3:$G$14,2,false)
Enter it in the first cell (D3) of the main table, copy down the column, and you will get a result similar to this:
Is the Vlookup formula still difficult for you to comprehend? Then look at it this way:
As you already understood, the Google Sheets VLOOKUP function is a thing with nuances. Remembering these five simple facts will keep you out of trouble and help you avoid most common Vlookup errors.
5 things to know about Google Sheets VLOOKUP
How to use VLOOKUP in Google Sheets - formula examples
Now that you have a basic idea of how Google Sheets Vlookup works, it's time to try your hand in making a few formulas on your own. To make the below Vlookup examples easier to follow, you can open the sample Vlookup Google sheet.
How to Vlookup from a different sheet
In real-life spreadsheets, the main table and Lookup table often reside on different sheets. To refer your Vlookup formula to another sheet within the same spreadsheet, put the worksheet name followed by an exclamation mark (!) before the range reference. For example:
=VLOOKUP(A2,Sheet4!$A$2:$B$13,2,false)
The formula will search for the value in A2 in the range A2:A13 on Sheet4, and return a matching value from column B (2nd column in range).
If the sheet name includes spaces or non-alphabetical characters, be sure to enclose it in single quotation marks. For example:
=VLOOKUP(A2,'Lookup table'!$A$2:$B$13,2,false)
Tip. Instead of typing a reference to another sheet manually, you can have Google Sheets insert it for you automatically. For this, start typing your Vlookup formula and when it comes to the range argument, switch to the lookup sheet and select the range using a mouse. This will add a range reference to the formula, and you will only have to change a relative reference (default) to an absolute reference. To do this, either type the $ sign before the column letter and row number, or select the reference and press F4 to toggle between different reference types.
Google Sheets Vlookup with wildcard characters
In situations when you do not know the entire lookup value (search_key), but you do know a part of it, you can do a lookup with the following wildcard characters:
- Question mark (?) to match any single character, and
- Asterisk (*) to match any sequence of characters.
Let's say you want to retrieve information about a specific order from the table below. You cannot recall the order Id in full, but you remember that the first character is "A". So, you use an asterisk (*) to fill in the missing part, like this:
=VLOOKUP("a*",$A$2:$C$13,2,false)
Better yet, you can enter the known part of the search key in some cell and concatenate that cell with "*" to create a more versatile Vlookup formula:
To pull the item: =VLOOKUP($F$1&"*",$A$2:$C$13,2,false)
To pull the amount: =VLOOKUP($F$1&"*",$A$2:$C$13,3,false)
Tip. If you need to search for an actual question mark or asterisk character, put a tilde (~) before the character, e.g. "~*".
Google Sheets Index Match formula for left Vlookup
One of the most significant limitations of the VLOOKUP function (both in Excel and Google Sheets) is that it cannot look at its left. That is, if the search column is not the first column in the lookup table, Google Sheets Vlookup will fail. In such situations, use a more powerful and more durable Index Match formula:
For example, to look up the A3 value (search_key) in G3:G14 (lookup_range) and return a match from F3:F14 (return_range), use this formula:
=INDEX($F$3:$F$14, MATCH (A3, $G$3:$G$14, 0))
The following screenshot shows this Index Match formula in action:
Another advantage of the Index Match formula compared to Vlookup is that it is immune to structural changes you make in the sheets since it references the return column directly. In particular, inserting or deleting a column in the lookup table breaks a Vlookup formula because the "hard-coded" index number becomes invalid, while the Index Match formula remains safe and sound.
For more information about INDEX MATCH, please see Why INDEX MATCH is a better alternative to VLOOKUP. Though the above tutorial targets Excel, INDEX MATCH in Google Sheets works exactly the same way, except for different names of the arguments.
Case-sensitive Vlookup in Google Sheets
In cases when the text case matters, use INDEX MATCH in combination with the TRUE and EXACT functions to make a case-sensitive Google Sheets Vlookup array formula:
Assuming the search key is in cell A3, the lookup range is G3:G14 and the return range is F3:F14, the formula goes as follows:
=ArrayFormula(INDEX($F$3:$F$14, MATCH (TRUE,EXACT($G$3:$G$14, A3),0)))
As shown in the screenshot below, the formula has no problem with distinguishing uppercase and lowercase characters such as A-1001 and a-1001:
Tip. Pressing Ctrl + Shift + Enter while editing a formula inserts the ARRAYFORMULA function at the beginning of the formula automatically.
Vlookup formulas are the most common but not the only way to look up in Google Sheets. The next and the final section of this tutorial demonstrates an alternative.
Merge Sheets: formula-free alternative for Google Sheets Vlookup
If you are looking for a visual formula-free way to do Google spreadsheet Vlookup, consider using the Merge Sheets add-on. You can get it for free from the Google Sheets add-ons store:
Once the add-on is added to your Google Sheets, you can find it under the Extensions tab:
With the Merge Sheets add-on in place, you are ready to give it a field test. The source data is already familiar to you: we will be pulling information from the Status column based on the Order ID:
- Select any cell with data within the Main sheet and click Extensions > Merge Sheets > Start.
In most cases, the add-on will pick up the entire table for you automatically. If it doesn't, either click the Auto select button or select the range in your main sheet manually, and then click Next:
- Select the range in the Lookup sheet. The range does not necessarily have to be the same size as the range in the main sheet. In this example, the lookup table has 2 more rows than the main table.
- Select one or more key columns (unique identifiers) to compare. Since we are comparing the sheets by Order ID, we select only this column:
- Under Lookup columns, select the column(s) in the Lookup sheet from which you want to retrieve data. Under Main columns, choose the corresponding columns in the Main sheet into which you want to copy the data.
In this example, we are pulling information from the Status column on the Lookup sheet into the Status column on the Main sheet:
- Optionally, select one or more additional actions. Most often, you'd want to Add non-matching rows to the end of the main table, i.e. copy the rows that exist only in the lookup table to the end of the main table. And Update your main table right where it is:
Click Merge, allow the Merge Sheets add-on a moment for processing, and you are good to go!
Video: How to use Merge Sheets to vlookup without formulas
Vlookup multiple matches an easy way!
Filter & Extract Data is another Google Sheets tool for advanced lookup. The add-on can return all matches, not just the first one as the VLOOKUP function does. Moreover, it can evaluate multiple conditions, look up in any direction, and return all or the specified number of matches as values or formulas.
Remembering that a picture is worth a thousand words, let's see how the add-on works on real-life data. Supposing, some orders in our sample table contain several items, and you wish to retrieve all the items of a specific order. A Vlookup formula is unable to do this, while a more powerful QUERY function can. The problem is this function requires knowledge of the query language or at least SQL syntax. Have no desire to spend days studying this? Install the Filter & Extract Data add-on and get a flawless formula in seconds!
In your Google Sheet, click Extensions > Filter & Extract Data > Start, and define the lookup criteria:
- Select the range with your data (A1:D15).
- Specify how many matches to return (all in our case).
- Choose which columns to return the data from (Item, Amount and Status).
- Set one or more conditions. We want to pull the information about the order number input in F2, so we configure just one condition: Order ID = F2.
- Select the top-left cell for the result.
- Click Preview result to make sure you will get exactly what you are looking for.
- If all is good, click either Insert formula or Paste result.
For this example, we chose to return matches as formulas. So, you can now type any order number in F2, and the formula shown in the screenshot below will recalculate automatically:
To learn more about the add-on, visit the Filter & Extract Data home page or get it now from the Google Workspace Marketplace:
Video: How to vlookup multiple matches using the add-on
That's how you can do Google Sheets lookup. I thank you for reading and hope to see you on our blog next week!
Latest comments
I am trying to get information related to specific people in column D to copy the information from column 19 to a new sheet, is the Vlookup the right google function? My boss works in excel but I only have google sheets
You’re on the right track
If you want to pull information from column 19 (which would be column S) based on a match in column D, VLOOKUP can work like this:
=VLOOKUP("Person's Name", Sheet1!D:S, 16, FALSE)
"Person's Name" — the name you're looking for.
Sheet1!D:S — the range where column D is the first column.
16 — because column S is 16 columns to the right of D.
FALSE — for an exact match.
Hello,
How do I search for a single value in multiple columns and return info in different columns? For example, I need to find the value of Tab A's cell D5 in either Tab B's column B and return the value in Tab B's column C. If not found in Tab B's column B, look in Tab B's column H and return the value in Tab B's column I. If still not found, return value of 'Not Found.'
Thanks in advance!
Michelle
Hello Michelle,
I believe you need to build a nested IF formula that will use VLOOKUP to look for the values one by one.
Hello, I get a list emailed to me that I just figures out how to split into different cells. The list I get sent has an invoice number and amount but is completely out of order from the original list I send to them. Is there a way to compare the two if I put all in cells?
Hello Amber,
You will find different ways of comparing data in Google Sheets in this article.
Hello. I need to determine what formula to use and how. I have various words in two cells. If there are specific words in those two cells, they need to produce a number which references a cell. Whatever two words are found in those two cells, I want the formula to grab a specific number from another cell. For example, I found a formula that comes close to what I want to do, but I need it do the answer in one cell depending which words are found in the orginal two cells. =QUERY(C7:M7,"SELECT K WHERE C contains 'sugar' And D contains 'milk'",1) and my other one =QUERY(C7:O7,"SELECT O WHERE C contains 'sugar' And F contains 'butter'",1)
Hello leona,
I'd recommend you to use the SWITCH function instead. To look for both words, also incorporate the AND function as described here.
Hello,
I have this formula: =if(isna(vlookup($A1,'Student Schedules'!$A$1:$H,2,False))," ",vlookup($A1,'Student Schedules'!$A$1:$H,2,False)) and it works great. But is it possible to add something that would make it so when it pulls that information into Column B it will think sort all columns by what is in B and place them in alphabetical order?
Any help would be appreciated!
Hello Connie,
First I'd suggest wrapping this IF formula to ARRAYFORMULA and changing your $A1 reference to the entire column. This way this one formula will return the entire column of the results that can be sorted.
Then wrap this formula in SORT function.
Hi,
As I look at the above examples in vlookup of two google sheets, I haven't seen the same as what I want my google sheet to be happen.
I have a "Form Responses", the most important for this sheet is the Mem_ID, Month and Amount.
In my other sheet "Sinking Fund 2023", in Members Contribution, I am creating the formula under "Jan1st, Jan2nd, etc." and to be looked up from Form Responses.
If MemID_2022-0001 has a response for Jan1st, the amount should be added in Jan1st column and if it is Jan2nd this should be automatic added in Sinking Fund 2023 google sheet.
Any one knows how to do the formula. This also needs the importrange function since we are using 2 google sheets.
Below are the links of my google sheet.
Deposit and Payments
https://docs.google.com/spreadsheets/d/124atlHALikF_sUt7JhV7WvpZwH7MokTDgdWckip_vPE/edit#gid=1642645643
Sinking Fund 2023
https://docs.google.com/spreadsheets/d/1L6XoVKF6VlwV6Ia7cDj4Ta5cz3nXDuhjoSi0Nwjhy5E/edit#gid=1548046258
Thanks in advance
Hi Richard,
You need to use QUERY function for this task. Put the following formula into E4 of Members Contribution, Sinking Fund 2023:
=QUERY({IMPORTRANGE("LINK_TO_Deposit_&_Payments_FILE","Form Responses!$I$1:$L")},"select sum(Col4) where (Col1='"&$B4&"' and Col2='"&$E$3&"') label sum(Col4) ''" ,0)
For it to work, don't forget to replace LINK_TO_Deposit_&_Payments_FILE with the link to that file and connect the IMPORTRANGE to it as well. Here's a tutorial on the IMPORTRANGE just in case.
Multiple Vlookup matches looks great but the add-on required that I give you the ability to delete my sheets. That is a non-starter and shouldn't be necessary
Hi!
Multiple Vlookup matches creates a new dataset in the location of your choice according to your requirements. It does not require any data to be deleted. It is possible that the range where you want to put the data is not empty.
I have to look up multiple employees numbers several times a week, however; it's usually the same employees. I would like to use sheet 2 for listing the employee number, last name, first name, then use this list as a lookup on sheet 1 by typing the last name and first name, with the employee number auto-populating the first column. How would I write this formula? Thank you.
I have shared a sample spreadsheet. I hope I did it correctly. Thank you for any assistance you can give me.
Hello!
To search for a value by multiple criteria, use INDEX MATCH. For more information, please visit: Google Sheets INDEX MATCH with multiple criteria.
=index(Numbers!C2:C4,match(C2&D2,Numbers!$A$2:$A$4&Numbers!$B$2:$B$4,0),1)
Hope this is what you need.
I want to use "vlookup" and "value by colour" at the same time in a Formula on different sheet. How can i make it?
Hello Ashik,
You may want to check these special functions out: CELLCOLOR & VALUESBYCOLORALL. They are part of our Function by Color add-on, and you can use them in your own formulas.
I am trying to pull the email from a list where the info is written: last name, first name.
And on my search cell is: first name, last name.
Can I do that with Vlookup? or what formula can I use? Do the names have to be written precisely in the same order? Thank you
Hello Vanessa,
Yes, formulas in Google Sheets work with complete matches unless you use regular expressions or wildcard characters. But if you refer to a cell as a sample, the formula will be looking for that exact record with words in that exact order.
To quickly bring those names in the same order, you can split them by comma & space to columns, change columns places, and merge them back by comma and space.
I'm not able to vlookup from one sheet to another Google sheet what to do
Hello Ishita,
To vlookup from another spreadsheet, you need to add IMPORTRANGE to your formula. Svetlana has provided an example here:
https://www.ablebits.com/office-addins-blog/vlookup-google-sheets-example/#comment-321671
I'm trying to see how I can workout the Vlookup function and IF statement with my spreadsheet
I Want column "C" from the "Summary" Sheet pulling data "General" Sheet
This is my initial formula =VLOOKUP(A4,General!B2:M13,4)
Im trying to search that matches the Column "Summary A" on column "General B"
When it matches, I want this to get the VA on column " General D" only if column "General E" has a check or TRUE value.
https://docs.google.com/spreadsheets/d/1XgRyASr8alEB0AT36KbYNDj1XVb7kTM1sdvTOmWy10k/edit#gid=134747200
Hello Guenahel,
If I understand your task correctly, try this formula in C3 and copy it down the column:
=IF(General!E2=TRUE,IFERROR(VLOOKUP(A3,General!$B$2:$M$13,3),"no matches"),"")
To understand how this formula works in order to build similar formulas for other columns, please visit these tutorials:
Google Sheets IF function
IFERROR + VLOOKUP
I'm trying to Search Column C but for the results of searching, Column C to include Column D in the displayed result.
///-----------------------------------------------------------------------------------------------//
/// Column A | Column B | Column C | Column D //
1// Search_"Cool" | |Cool Statemnt | Cooler Statmnt //
2// Cool Statemnt| Cooler Statmnt| | //
///----------------------------------------------------------------------------------------------//
The formula I am using is =ArrayFormula(IFERROR(VLOOKUP($A$1,$C$1:$D$79,{1,2}), "NOT FOUND"))
The problem I'm running into is that regardless of what I search, I can only get two results from Column C, and its matches Column D for results. Though I have 75 Column C, word phrases I'm only getting $C$67 or $C$1. Of course NOT FOUND shows.
Thoughts and thanks in advance!
Charlie
PS, I gave access to the email stated below.
Hello Charlie,
Thank you for sharing your spreadsheet right away.
Your VLOOKUP on the "Sayings" sheet doesn't work because it looks for the exact match: cells that contain only the word from A2. To look up for cells that contain this word, you need to build VLOOKUP with wildcard characters. I've entered the example to A5.
Also, VLOOKUP returns only the first matching record. To lookup for multiple matches, you will need to use the method described in this part of the tutorial.
Hello,
I'm trying to run a weekly Pick'em type game for a group of people and I run it so whoever got the max points for the week gets awarded them 1 playoff bracket. I would like to sum these playoff bracket so people can know how many they get. Currently, each week is separated into separate sheets and then the total playoff brackets is summed in a separate summary standing sheet with this code:
=IFERROR(VLOOKUP(B3,'Week 1'!B$4:D$43,3,FALSE),0)
Is there a way to automatically add new sheets to this so it sums the playoff bracket total? Or do I have manually add it every week like this?
=SUM(IFERROR(VLOOKUP(B3,'Week 1'!B$4:D$43,3,FALSE),0),IFERROR(VLOOKUP(B3,'Week 2'!B$4:D$43,3,FALSE),0))
Thank you and have a great day!
Hello William,
I'm afraid there's no formula to add a new sheet with another formula automatically. You need to create the sheet and the formula manually, or try macros or even Google Apps Script for the task.
Hi, I want to ask you, I have two tabs in one google sheet. I want to make if the item in the first tab match with the second one , then it shows " 〇 " and if it's not it shows " × ". How can I do that? Thank you. I hope you can answer me. Have a good day !
Hi Sarah,
It looks like the IF function is exactly what you need. There's also a special tool that helps you build IF formulas correctly.
So i want to use vlookup in multiple sheets with in a single spreadsheet in google sheet. I want to use a data validation drop down to switch search range (array). The Data validation Dropdown contains names of N number of sheets present in a spreadsheet. So when I change drop done selection the range in the vlookup changes accordingly. Is it possible?
=Vlookup(A1,searh_range,2,0)
In this formula how can I have search_range change according to the selection I make from drop-down list.
Hello Refi,
If I understand your task correctly, you need to embed your VLOOKUP into the IF function. The IF function will check what's in the drop-down and return the VLOOKUP with the required search range.
When using this for a Google Sheet that is active for form responses, is there a way to fill the cells with the VLOOKUP value upon submission? Also, is there a way to remove the #N/A for the column for cells that are currently unpopulated?
Hello Daniel,
You can remove #N/A using the trick from this blog post.
As for VLOOKUP for future form responses, as responses are inserted as entire new rows, you can either copy the formula manually or use Apps Scripts. Here's an overview of Google Apps Script with a lot of helpful content and links:
https://developers.google.com/apps-script/overview
Hello,
Thanks for the post - I've spent hours trying to figure out how to get the info I need. Still no luck.
I have a spreadsheet with multiple lines that contain order info (RAW). I want the formulae to specifically look for a customer name, and then the word "fruit" and bring me the info "Small" / "Large" or nothing when there is no fruit add on
=QUERY('RAW'!F:M,"SELECT M WHERE (lower(M) contains 'seasonal fruit add-on') AND ((lower(F) = lower('"&E2&"')))")
Please help :) Thank you!
Hello Dani,
The QUERY formula simply returns the contents of your table.
If you want to have special words for all cases when your criteria are met, please try using the IF function instead.
Hi want to use Vlookup and take data to a slide presentation from an excel sheet - can I do that ?
Hi Varsha,
Since Excel and Google Slides are completely different platforms, there's no way to connect them.
The only thing I can suggest is to convert your Excel file into Google Sheets. You can import your Excel file to Sheets via File > Import > Upload > Select a file from your device.
My Query is that - If want to write Yes / No in E Cell if Name in D cell is present in list from A Column. Can you please help with this
Please refer the sheet - https://docs.google.com/spreadsheets/d/1iaemtTWh1JoC-8wucvoTRwhmmXj6VqxB9LuHgrJ1jmw/edit?usp=sharing
Hello Jitendra,
Here's a formula for you to try:
=Arrayformula(IF(COUNTIF($A$2:$A$21,$D$2:$D$21)>0,"Yes","No"))
To understand how it works and build such formulas, I highly encourage you to learn how these functions work:
ArrayFormula function
IF function
COUNTIF function
Hi, the post is awesome, but it took me hours to find out what can be the reason of none of the formulas working for me.
Since I use the hungarian version og Google sheet, I should use hungarian formulas, with semicolon as separating parameters insted of commas. (Google sheet specific formulas should used in english. For example: IMPORTRANGE)
Maybe it will help for others also who using the google sheet not english version.
All the best:
Laszlo
Hi László,
You're right, your spreadsheet locale dictates the delimiters that should be used in all your formulas. I've added this info to our article on possible VLOOKUP errors as the first thing to check. Thank you very much! :)