Comments on: How to use IF function in Excel: examples for text, numbers, dates, blanks

IF is one of the most popular and useful functions in Excel. Generally, you use an IF statement to test a condition and to return one value if the condition is met, and another value if the condition is not met. Continue reading →

Comments page 25. Total comments: 2999

  1. Hi,

    How would I write the formula to get the following:

    If A1 IS BETWEN 1 & 3 then "q1" however if between 4 & 6 then Q2, If between 7 & 9 then q3...

    Thanks!

    Mishaal

    1. Hi Michelle,

      You can use a nested IF formula similar to this, beginning with the largest values:

      =IF(AND(A1>=7, A1<=9), "q3", IF(A1>=4, "q2", IF(A1>=1, "q1", "")))

      If there is no upper-bound limit, it can be simplified it to:

      =IF(A1>=7, "q3", IF(A1>=4, "q2", IF(A1>=1, "q1", "")))

  2. Hi,
    i shall appreciate if you could please guide me as to how I can use IF function formula while making general journal (Accounts) to auto post entries into respective ledgers(account heads/expense heads) ?
    I look forward for a positive response.

    Thank you,

    Danish Abbasi

    1. Hi Danish,

      Please try to explain the task from another viewpoint. In what columns do you have data, and where do you want to auto post data and based on exactly what conditions?

  3. Hi Svetlana,

    Could you please help me with my question below?
    I'm collecting in 1 sheet customers feedbacks from 7 different languages (sheets).
    So in the same colomn A, I have the answers "Yes, Oui, Ja, Si, No, Non, Nein...." or "Non, No, Nain...".
    The formula works fine for 1 language "=IF(A2="SI",1,0)" but do not know how to add the others..I would need number 1 to appear if it's an answers "Yes, Ja, Si, oui.. and a 0 if it's a "Non, No, Nain...".
    Any idea how can I compile all of this in one formula please?
    That would be much appreciated if you could help with this.

    Thanks a lot,

    Erin

    1. Hi Erin,

      You can add multiple OR conditions in your logical test, like this:

      =IF(OR(A2="SI", A2="Yes", A2="Ja"), 1, 0)"

      1. Hi, what if the cells are multi-word strings and I want to have anything that contains, (e.g.) 'blue', 'green' or 'purple' return 'cool' and everything else 'warm'.
        For example:
        light blue (cool)
        burnt orange (warm)
        forest green (cool)
        etc.
        thanks

  4. = IF(A10,A1, IF(A20,A2,IF(A30,A3,"BAD")))

    BAD is mean all 3 cells are blank

    1. Hi!

      Sorry, I am not sure I can follow you. Can you explain the conditions (logical tests), please?

  5. if i5 is less then D5 value is zero and if D5 is greater then I5 value is D5 is show

    1. =IF(I5<D5, 0, D5)

      The formula will return 0 if I5<D5, and the value in D5 if I5>=D5. If you are looking for something different, please clarify.

  6. I am doing an excel on monthly growth of values based on employees. Issue is some people start during the month and some quit. So I have some people with no value at the beginning of the month and other with no value at the end. I do not want those to show up as values.

    A B C D
    1 1/1/15 2/1/15 Growth Percentage
    2 225,749 248,324 200,471 88.8%
    3 420,284 420,284 0%
    4 48,744 -48,744 0%

    For D2, I did =IF(OR(A2="",B2=""),,(B2-A2)/ABS(A2)) which gives me the percentage of growth through the month and returns 0% if either is blank. Can I make column D actually be blank instead of showing 0%? Or, I want to show a total average growth at the bottom of column D without being penalized for all the 0%. If D5 was going to be the "average" cell, could I do =AVERAGE(D2:D4) but somehow tell it to not include the cells which have a value of 0%? Some people have a negative percentage and I need to include those.

    1. Well that table got all messed up after submitting it. Column A is 1/1/15's value, column B is 2/1/15's value, column C is the growth from 1/1 to 2/1 and column D is the percentage that they grew (or dropped) over the month.

      1. Hi Doug,

        I would add "" to value_if_true to return an empty string if either A2 or B2 is blank.

        =IF(OR(A2="",B2=""),"",(B2-A2)/ABS(A2))

  7. I want to write a formula where if the value in a particular cell is less then 18 I want the cell to indicate the cost is $48 but if the value is greater than 18 then I want the value to be $48 plus the value greater than 18 (or the value +30)

    if A10 < 18 then = $48.00 but if A10 < 18 then = (A10 + 30)

    Can this be done?

    1. Figured it out, thanks =IF(E225>19,E225+30,"$48.00")

  8. I want to test the value of a portion of a cell. For example: The cell says Approved: 12345 where 12345 is a changing order number, the list has Declined and Refunded transactions as well. Is there a way to test only for the word Approved without consideration of the remaining data within the field?

    1. Hello Krystalya,

      You have to use ISNUMBER and SEARCH function for partial match, like this:

      =IF(ISNUMBER(SEARCH("approved",A2)), "yes", "no")

      Where A2 says "says Approved: 12345".

      Please check out "Example 3. IF formula for text values with partial match" in this tutorial for full details.

  9. Hello,
    I have a workbook with multiple sheets. In column A, of sheet 1, is a list of names. I have been able to get those names to populate on sheet 2 and three using ;
    =IF(INDIRECT("Sheet1!A" & ROWS($1:1))="","",INDIRECT("Sheet1!A" & ROWS($1:1)))
    This works well to a point. What I would like to happen is when a name is deleted from column A, sheet 1, I would like the data in sheets 2 and three in the corresponding row to be deleted as well. i.e. if row 17 (A-L) on sheet 1 is deleted, then row 17 A-L) on sheets 2 and 3 will be deleted.
    Thanks

    1. There was a simple fix. Just group the sheets together. Adjust as nessasary. And then un group.

  10. Hi Svelana,
    How are you today. I appreciate the time you're taking to help me with my problem. I'm sure all these individual questions can be burdensome. My question is:

    I have the first 80 cells numbered 1-80 in sequence. I have this in every row as well, and then after that I have 20 columns each with a number 1-80. I wanna highlight one of the 1st 1-80 if one of the 20 cells has a number that matches it. Is this possible?

    Thank you,

    1. Hi Eddie,

      Sorry, I am not sure I fully understand your data structure. If you could post your sample workbook on our forum, our support team will do their best to help.

  11. I need a formula for:
    If A1=1, then B1:B4=1, otherwise B1:B4=0. If A5=1, then B5:B8=1, otherwise B5:B8=0.
    I can also do:
    If A1=1, then A2:A4=1, otherwise A2:A4=0. If A5=1, then A6:A8=1, otherwise A6:A8=0.

    When I try to copy this formula down to record 10,000 I am getting a loop error. Excel is returning:
    A1
    1
    0
    0
    0
    1
    0
    0
    0
    How can I fix this??

    1. Hi Brianna,

      Try entering the following formula in cells B1 through B4, and A2 through A4:

      =IF($A$1=1, 1, 0)

      And this one in cells B5 through B8, and A6 through A8:
      =IF($A$5=1, 1, 0)

  12. Hi I want to use this formula with =If condition
    =RIGHT(A2,LEN(A2)-FIND(" ",A2,12))
    i tried many time but it not fits in.
    =if(A2<len(9),"Write your full name,RIGHT(A2,LEN(A2)-FIND(" ",A2,12)))
    why this is not working????
    Please guide me

    1. Hi Nadeem,

      Sorry, I cannot understand what your RIGHT formula does. Can you explain in words?

      Anyway, the IF function may look similar to this:

      =IF(LEN(A2)<9,"Write your full name", RIGHT())

      It returns "Write your full name" when A2 contains less than 9 characters. Otherwise, what is it supposed to return?

  13. I am trying to run an IF formula this is what I was trying to do =IF(A1>0,[A1=B1],[A1=0])
    Basically if cell A1 is greater than zero I want the cell to be replaced with the data from cell B1, however if cell A1 is not greater than zero I want the cell to equal zero.
    Can someone please help?!!!

    1. Hi Mel,

      You don't want square brackets in IF formulas:

      =IF(A1>0, B1, 0)

  14. Hello Rupesh,

    You need a nested IF formula like this:

    =IF(A2>90, 4, IF(A2>=80, 3, IF(A2>=70,2,1)))

    1. Hi. I’m trying to figure out how to do two different calculations in a cell. Using the IF function.

      It involves 3 different cells
      If cell C3 has a number greater than 0, I multiply C3 by C1 plus the total in cell B2 to get a running total in the second row . Easy enough. My problem comes when I want to put in a 0 in C3 and then the cell has to multiply the running total by .5 (cutting the total in half).
      I’m not sure how to put both in one cell. I would appreciate any help.

      Thank you.

      P.S. this is to keep score in a dart game called Shanghai ?

  15. i need help, i have data which i need to analyse, in a cell i have entered data for males and females with the figures of household size, e.g male 2 and female 3, so i need a formula to find the total of males and females separately.

  16. I need to use IF function on below case;

    If one item is available from a column, then Yes or else No. Please advise the fuction.

    1. Hi Jay,

      Here is an example:

      =IF(A1="item you want", "yes", "no")

  17. HI,

    I WANT TO CREATE IN EXCEL 2007 Which shows that in a selected cell (specifically Column K in spreadsheet in each cell downwards)if I will type a Value on it(numbers. 1-9) it will correspond to a word. say for example 1 means okay, 2 means not yet and etc. some sort of shortcut techniques in typing for that word. what kind of Formula should I use? Please let me know.

    Thanks Svetlana!

    1. Hi JAS,

      You can use nested IF functions, like this:

      =IF(A1=1, "ok", IF(A1=2, "not yet", IF(A1=3, "smth else", "")))

      Excel 2007 allows adding up to 64 nested IF in one formula.

      1. Great, thanks a lot!

  18. I created a quiz and used data validation. I want to get 1 mark for the answer of 42 otherwise 0. I used if(A4="42", 1,0).it give me 0. am I using wrong syntax

    1. Hi Istkar,

      You don't need to enclose numbers in double quotes unless you want them to be treated as text strings. Once you remove "", your formula will work great:
      =IF(A4=42,1,0)

  19. can you help with the below:
    i am creating a sheet for associates in my company. 1 tab has all details of the associate that a company database should have. column 'F' has the designation of the associate and column "A" has names
    what i want to do (in another tab in the same excel). wherever column "F" has designation as manager the cell in the new tab should show me the name of that associate.
    eg: if cell value f4=manager then value in new cell (in new tab) should be name as in A4.

    i want the same to be applied to every cell.

    1. Hi Ankit,

      Hopefully, this is what you are looking for:
      =IF(F4="manager", A4, "")

  20. How many times i can add IF in one formula.

    1. In Excel 2013, Excel 2010 and Excel 2010, you can add up to 64 nested IF functions. In older versions of Excel, you can use a maximum of 7 IFs in one formula.

  21. I've two columns A & B, out of this i want to check against A column name if B column is not blank then it should show complete else Partial, for more understanding see below example

    C-A C-B Output
    A ABC12 Complete
    A 105 Complete
    A 13 Complete
    B 213 Partial
    B ABC12 Partial
    B Partial

    1. Hi Rajendra,

      I am afraid our blog engine has made a mess of your data :( I understand about B column being non-blank. But exactly what shall we check against A column?

  22. If somebody can please help me.
    Mentioned below is my problem
    I have a time format and I am trying to put an If formula which should give me a yes or no if its greater than or equal to a specific time

    FOR EXAMPLE:
    If (04:07:47)is greater than or equal to (04:00:00)then YES else NO

    1. Hi Raymond,

      If both times are entered in some cells, then you can use a simple IF formula like this:

      =IF(A2>=B2, "yes", "no")

      Where B2 is 04:00:00.

      If you want to specify one of the values directly in the formula, then you will need the TIMEVALUE function is addition to IF:

      =IF(A2>=TIMEVALUE("4:00:00"), "yes", "no")

  23. Thank you Svetlana! To take this one step further and I tried couldn't get it to work

    =IF(A1="put",C1-B1,IF(A1="call",B1-C1,"")) then take answer of this and calculate the difference between the answer and D1 *100* E1

    1. This is more in line with what I was thinking all wrapped up in one formula - =IF(A1="put",C1-B1,IF(A1="call",B1-C1,"")) --- This is the first operation

      IF cell O25 is a positive number subtract U25 or IF cell O25 is a negative number add U25 --- This is the second operation

      How would you write them separate and within on formula sequence?

      Thank you again!

      1. Hi Jason,

        Please specify if these are AND or OR conditions?

        For example, if A1="put" and O25 is a positive number, then what do we do?

        If A1="put" and O25 is a negative number, then... ?

        And the same for A1="call", please.

        1. What I believe I'm trying to do is calculate the positive or negative variance (on a non absolute basis)

          My apologies, so I have your formula =IF(A1="put",C1-B1,IF(A1="call",B1-C1,"")) ... in column "U"

          And in column "V" I'm trying to calculate the actual difference between cell O25 and U25(i.e. Add if a number is negative, Subtract if a number is positive)say if U25 Is positive and O25 in positive then O25-U25 or if U31 is negative and O31 is positive then U31+O31

          I was also would like to combine this formula with your =IF(A1="put",C1-B1,IF(A1="call",B1-C1,""))

          1. Let me check if my understanding is correct. If values in both columns U and O are positive, then O25-U25. If a value in either column or in both columns are negative, then U325+O25. If so, I would suggest that you keep the formula in column U as is and put the following one in column V (it is actually for cell V25, but you can easily adjust the references:
            =IF(AND(U25>0, O25>0), O25-U25, U25+O25)

            Also, please note that the formula equates zero to negative numbers. If you want to treat 0 as a positive number, then change the logical test to AND(U25>=0, O25>=0)

            If I misunderstand something, please correct me.

            1. Nope you made my nonsense into sense;-) So in that last formula =IF(AND(U25>0, O25>0), O25-U25, U25+O25)... how would I make any negative result display 0 and any positive result show the full value of the calculation?

  24. HOW TO MULTIPLY ONE VALUE OF A CELL BY THE PERCENT OF ANOTHER CELL

    1. Hi Thello,

      For example like this:
      =A1*(A1*10%)

      If you are looking for something different, please provide a bit more details.

  25. Hi Svetlana how would you write this all in the same cell ... (If Cell A1 says “PUT” then Subtract cell B1 from C1 OR If Cell A1 says “CALL” then Subtract C1 from B1)

    1. Hi Jason,

      You need a nested IF like this:
      =IF(A1="put",C1-B1,IF(A1="call",B1-C1,""))

  26. Hi,
    I'm trying to get my formula to say if I5=Y or N/A then 0 value, if not then 1 value. I'm using this: If(I5="Y""N/A",0,1) but I'm getting the value 0 no matter what's in I5. I5 is either Y, N, or N/A, and I only want it to populate when there's an "N". I thought the problem was that "N" and "N/A" both contain "N", but I typed in "fill" to test and still 0 value. Please help. Thanks!

    1. Hi Felicia,

      Since you have 2 conditions, you should include the OR statement in your formula, like this:

      =IF(OR(I5="Y", I5="N/A"), 0, 1)

  27. How could we change the color of the Cell if the logical_test is true or false?
    Thank you.

  28. Hi,

    in column A user will be entering date. In column B the month will get updated automatically with =Month(A1) function.
    Now I want if the cell of A column is blank, then in column B will be showing "-" & the moment user enter the date it will return the month.

    What would be the formula in excel... pl surrgest

    1. Hi!

      I believe this is what you are looking for:

      =IF(A1="", "-", MONTH(A1))

  29. =if(A1=12," ","12"),if(A1=8,"16"),if(A1=16,"8")

    can anyone fix it... it will a very helpfull for me...

    thank you very much

  30. Hello everyone,
    I'm looking for a formula that looks at date ranges - so if the date of the line item is between 'date 1' and 'date 2' then display the line item in on a separate sheet.
    Similarly if the date of the line item is NOT within 'date 1' and 'date 2' then display the line item on another sheet.

    Any assistance would be greatly appreciated!

    1. Hi Lorna,

      You need two different formulas like these:

      1. If between 2 dates:

      =IF(AND("line item date">date1, "line item date"<date2), "line item", "")

      2. If outside the date range (not within 2 dates):

      =IF(OR("line item date"<date1, "line item date">date2), "line item", "")

      If you can provide more details about your date structure (in what columns are dates and where are line items), I think we will get the real formula.

  31. Hello,
    I ave a situation, i whish you can help me with: i need to work on a formula with the if funtion. i have to mark a range of values, for example: all the values are in the cell "B2"

    range: 1 - 100
    markA: 1 - 20 ( "a" )
    markB: 21 - 35 ( "b" )
    markC: 36 - 50 ( "c" )
    markD: 51 - 89 ( "d" )
    markE: 90 - 100 ( "e" )

    i have try the next formula:
    =(IF(B2=21,B2=40,B2=71,B291,"VFEL"))

    but it says the is a error, can you help out ?

    thanks

    1. Hi Ussiels,

      I am not sure I exactly understand the task, but it looks very similar to this one that can be solved using nested IFs.

      Is this what you are looking for?

  32. I request to you i make a time , using if statement =if(A110,"A-10")

    1. I request to you i make a time sheet , using if statement =if((A110,"sum(A1-10))

  33. i am working on aproject. I need help with
    f2 contains both words and numbers. How do i display the text and numbers in 2 separate cells?

    1. got it

  34. =IF(I10-K10, IF(I10="",N10-K10, IF(ISBLANK(N10),"2")))
    the first one will be formula then the other if blank of i10 IS BLANK USE FOR N10 THEN IF N10 IS BLANK IT SHOULD BE EQUAL TO "2" THANKS
    hi how to comine this formula thanks

    1. SORI ITS N10.. THANKS

  35. Hello!
    Thank you for this guide. It's very helpful. I do have one question though, I am trying to copy a date on a cell. Say, date is in A1 and a restriction is in B1. My formula goes like this - =IF(B1="0","",A1). C1 should have be a copy of the date in A1 right? Wrong. Mine shows 420417. It shows numbers T_T not the date. Please help. Thank you in advance.

    1. Sorry about this one. After a few trial and error, I managed to get it :D. Here's how I did it...

      Make sure that the cell you are copying is in a proper format. Don't let it automate to DATE, CURRENCY and etc. Then, before you create a statement, say =IF(X=A,"","B"), make sure you CLEAR FORMAT that cell. Good luck to you guys :D Thanks again.

  36. Hello Svetlana,
    Your site is very helpful!
    Could you kindly help me with below:
    I need a formula where if the cell in particular row contain values from a table, then return value "trade", otherwise "unknown". The list contains over 100 values, therefore the ISNUMBER(SEARCH) function cannot be used.

    "Table" example:
    11 trade
    12 trade
    13 trade
    14 trade
    15 trade
    186 trade
    ...

    List example:
    13 trade
    13,14 trade
    15,2222 trade
    2882,2213 unknown
    14,11,75,2882,2213 unknown

    1. 14,11,75,2882,2213 trade

  37. HELLO,
    i need a formula to show that if my first cell is greater than the average then to show me 0 otherwise to show the difference between the first cell and the average(some cells are 0) ,so i was trying =IF(D3>D$291;TRUE=0;FALSE=D3-D291) but doesn't work .THANK YOU IN ADVANCE!!!

    1. Hello Sofia,

      Just enter the following formula:
      =IF(D3>D$291; 0; D3-D$291)

  38. i am trying to set up an IF function where it searches a cell for a word that has the letters UCI if true gives the result 2.2 if false gives 2.8. i have done this but doesnt seem to work :(
    =IF(ISNUMBER(SEARCH(E3="UCI")),"2.2","2.8")

    please help

    1. Hello James,
      =IF(ISNUMBER(SEARCH("UCI",E3)),"2.2","2.8")

  39. Hi, i want an output with two conditions. That is if A1=I OR II OR III and if B1<=5 then the output in C1 should reflect as 'yes' otherwise it should be 'no'.
    I typed as =if(and(A1="I", A1="II", A1="III",B1<=5),"yes","no").This is not working.
    Kindly let me know the error or is this formula totally wrong? Thanks in advance.

    1. Aengus, thank you for your help.

      Shiva, you can also use the formula below (the result will be same):
      =IF(AND(OR(A1="I", A1="II", A1="III"),B1<>"", B1<=5),"yes","no")

      1. Thank you Alexander. The result was correct. Elated to learn new techniques.
        Cheers.

    2. Here you go
      =IF(OR(A1="I",A1="II",A1="III"),IF(AND(B1<=5),"YES","NO"))

      1. Thank you Aengus. The formula worked wonderfully well.Delighted.
        Cheers.

  40. Hi. I want to extract a number from a cell(B2) at an exact time. I have two times on my sheet, one is the start time of an event and the other is the actual time right now. When there is a differance of 2 minutes between both times, then i want to extract the number in cell(B2) and i want the value to remain there.
    My sheet is connected to a website and the sheet is updated every second, so the value in cell B2 is constantly changing.
    Is this possible???

    1. Hello Aengus,

      I am sorry, but there is no way to fulfill your task using formulas. Since you want the value to remain in the cell, a VBA macro is needed for this task. You can look for it on http://www.mrexcel.com or http://www.excelforum.com.

      1. Hi,
        I have a two workbooks 1)Masterlist and 2)Saleslist

        Master list have columns description, unit and unit price. Fixed number of rows.
        Sales list have columns description, unit, unit price, saleqty and amount. Rows increases on ever sales.

        It will be wonderful some body can help with the code to fill the cell unit price in the workbook Saleslist when I enter matching description of the item as in Masterlist.

  41. Thanks for posting If Function in a very easily manner.

    can you tell me the function to extract text from cell

    Eg: Paid to Sub cont Rafiq/against balance payment.
    Paid Sub cont Shafeeque/against part payment.

    In this I want to extract only from the text sub cont to /.

    1. I am sorry, your task is not very clear. For us to be able to assist you better, please post a small sample workbook with your data and the expected result on our forums. Our support team will look into your task and try to help.

  42. Hi,

    I have a master sheet and individual sheets (with the details) for a survey.

    I want to be able to populate the individual sheets with simply putting a Y or N on the master sheet. Is this possible?

    ie A clients details and their consent to receiving marketing, research & volunteering are on the master sheet. Can I then automatically populate the individual sheets from the master?

    Thanks
    Debra

    1. Hello Debra,
      You can enter the formula like the one below to the cells on your individual sheets:
      =if(MasterSheet!$A$2="y", MasterSheet!$C$2, "")

      That means that if cell A2 is in the master sheet contains "Y", copy data from MasterSheet!$C$2.

  43. Hello,

    I'm having trouble making a formula that will return a date or a value. i.e. I'm making a time off request form, and sometimes the cell will have a single date (2/11/15) and sometimes it will have multiple dates (2/11/15 to 2/12/15). I can get the single date to fill by formatting my formula cell to "date," but I cannot get the range to show up. I want the exact input from the cell to show up regardless of being a date or "text" as the multiple dates would be considered.

    My formula that I'm using is =IF(A7,A7,"").

    I've tried using a variety of arguments in front of the second A7, but I still haven't gotten the results I want. I don't want to format the original cell to text if I can avoid it.

    1. I found my answer. Thank you.

      =IF(ISBLANK(A7),"",A7)

      This does exactly what I need.

  44. Hi, I am trying to work out a formula that says:

    Work out the average of F5:F11 IF B5:B11 contains data

    Is there any chance you could help?

    Many Thanks
    Rachel

    1. Hi Rachel,

      =IF(COUNTA(B5:B11)=7,AVERAGE(F5:F11),"")

  45. Hi there, i am trying to figure out a formula for not leaving cells blank. For instance, if B2 has the word "debit card" the C2 cannot be left blank. If B2 contains the word "cash" then C2 can be left blank.

    Does such a formula exist?

    Many thanks
    Lara

  46. I tried using the If formula for my data but I just could not get it to work.

    Example:
    I have set a target for John and if he meet the target the cell will display the Rebate (10%) percentage, if not it will display 0%.
    Rebate: 10&
    QTD: 17,275
    Target: 12,500

    How do i go about setting the formula for this?

    Thanks so much!

    1. >cell will display the Rebate
      =IF(E2>=12500, "10%", "0%")

      Where E2 is the cell with a target for John.

  47. Hi ,

    I am using nested IF for age
    =IF(M7<39,"Cohort C",IF(AND(39<=M7,M7<48),"Cohort B","Cohort A"))

    however the age i am using DATEIF formula as below :
    =DATEDIF(K7,TODAY(),"Y") & " Years, " & DATEDIF(K7,TODAY(),"YM") & " Months, " & DATEDIF(K7,TODAY(),"MD") & " Days"

    which result as i.e 35 years , 2 months, 1 days

    How can i specify the date as above format in the nested IF statement ?

    1. Hi Luxmi,

      It's difficult to give any advice without seeing the real data. It will be helpful if you can give more details about the value in cell M7 and other cells the formula refers to.

      1. sorry it is actually M7 = Age . However , for this scenario the age is purely calculated by the year only.

        How if i use below formula to calculate the (M7 cell) age & use this M7 cell to do nested if statement :
        =DATEDIF(K7,TODAY(),"Y") & " Years, " & DATEDIF(K7,TODAY(),"YM") & " Months, " & DATEDIF(K7,TODAY(),"MD") & " Days"

        which result as i.e 35 years , 2 months, 1 days

        how can i specify the age using this format ?
        =IF(M7<39 years, 00 Month 00 Day,"Cohort C",IF(AND(39 Years 00 Month 00 Day<=M7,M7<48 years 00 Months 00 Days),"Cohort B","Cohort A"))

        1. Hello Luxmi,

          Please specify the age in the same way as you calculate data in cell M7, i.e. using this formula:
          =IF(DATEDIF(K7,TODAY(),"Y") < 39,"Cohort C", IF(DATEDIF(K7,TODAY(),"Y") < 48,"Cohort B","Cohort A"))

  48. Using an IF statement, can more than one action be included if the condition is met? For example, if A1=x then (B1 = "true" and C1=y) else (B1 = "false" and C1=z)

    1. Hi Nancy,

      There is no way to do this in a single formula because a formula can return the result only in a cell where it is entered.

      You can simply use two formulas:

      For B1: =IF(A1="x", true, false)
      For C1: =IF(A1="x", "y", "z")

      If you need to change a lot of cells, then a VBA macro will be a better solution.

  49. Hi just wanna ask help on this.I'm confused on how to exactly put many functions in the formula. The legend are the following:

    "B" - 74 below
    "D" - 75-79
    "AP" - 80-84
    "P" - 85-89
    "A" - 90 up

    For example:I actually tried to enter =IF(E16<75,"B","D")=IF(E16=80<85,"D","AP")=IF(E16=.....ETC...

    pls help me...

    1. Hi Michelle,

      You need to use a nested IF function like this:

      =IF(E16>=90, "A", IF(E16>=85, "P", IF(E16>=80, "AP", IF(E16>=75, "D", "B"))))

  50. I want to figure out a way in column A1 to column A1000 is equal to the word "Done" then enter the current date in the coresponding column B1 to column B1000

    1) Enter Done in A1 and B1 gets automatically updated with date and time
    2) Enter In Progress in A2 and B2 get nothing updated
    3) Enter Done in A3 and B3 gets automatically updated with data and time
    4) and so on....

    Status Timestamp for Completion
    A1 Done B1 02/06/2015 5:17:33 PM
    A2 In Progress B2
    A3 In Progress B3
    A4 Done B4 02/06/2015 5:17:34 PM

    trying:

    =IF(A1:A10="Done",=(NOW())
    or
    =IF(A1:A10="Done,B1:B10=(NOW()))
    or
    ?

Post a comment



Thanks for your comment! Please note that all comments are pre-moderated, and off-topic ones may be deleted.
For faster help, please keep your question clear and concise. While we can't guarantee a reply to every question, we'll do our best to respond :)