Google Sheets QUERY function: a spreadsheet cure-all you have yet to discover

If you've been following this blog for a while, you may remember QUERY function for Google Sheets. I mentioned it as a possible solution for a couple of cases. But those are far from enough to uncover its full potential. Today, it's high time we get to know this spreadsheets superhero properly. And guess what – one equally noteworthy tool will also be there :)

Did you know that Google Sheets QUERY function is considered to be the most powerful one in spreadsheets? Its peculiar syntax favours tens of different operations. Let's try and break its parts down to learn them once and for all, shall we?

Syntax of Google Sheets QUERY function

At first glance, Google Sheets QUERY is just another function with 1 optional and 2 required arguments:

=QUERY(data, query, [headers])
  • data is the range to process. Required. Everything is crystal clear here.
    Note. Only one small reminder here established by Google: each column should contain one type of data: textual, or numeric, or boolean. If there are different types, QUERY will work with the one that occurs the most. Other types will be considered as empty cells. Strange, but keep that in mind.
  • query is the way to process the data. Required. This is where all the fun begins. Google Sheets QUERY function uses a special language for this argument: Google Visualization API Query Language. It's written in a way similar to SQL. Basically, it's a set of special clauses (commands) used to tell the function what to do: select, group by, limit, etc.
    Note. The entire argument must be enclosed in double-quotes. Values, in their turn, should be wrapped in quotation marks.
  • headers is optional for when you need to indicate the number of header rows in your data. Omit the argument (as I do below), and Google Sheets QUERY will assume it based on the contents of your table.

Now let's dig deeper into the clauses and whatever they do.

Clauses used in Google Sheets QUERY formulas

Query language consists of 10 clauses. They may frighten at first glance, especially if you're not familiar with SQL. But I promise, once you get to know them, you will get a powerful spreadsheet weapon at your disposal.

I'm going to cover each clause and provide formula examples using this list of imaginary students and their paper subjects:
Different types of data for the QUERY function.
Yep, I'm one of those weirdos who think Pluto should be a planet :)

Tip. Several clauses can be used within one Google Sheets QUERY function. If you nest them all, make sure to follow the order of their appearance in this article.

Select (all or specific columns)

The very first clause – select – is used to tell what columns you need to return with Google Sheets QUERY from another sheet or table.

Example 1. Select all columns

To fetch each and every column, use select with an asterisk – select *

=QUERY(Papers!A1:G11,"select *")

Select all columns.

Tip. If you omit the select parameter, Google Sheets QUERY will return all columns by default:

=QUERY(Papers!A1:G11)

Example 2. Select specific columns

To pull only certain columns, list them after the select clause:

=QUERY(Papers!A1:G11, "select A,B,C")

Return specific columns only.

Tip. The columns of interest will be copied in the same order you mention them in the formula:

=QUERY(Papers!A1:G11, "select C,B,A")

Return certain columns in another order.

Google Sheets QUERY – Where clause

Google Sheets QUERY where is used to set the conditions towards the data you want to get. In other words, it acts as a filter.

If you use this clause, QUERY function for Google Sheets will search columns for values that meet your conditions and fetch all matches back to you.

Tip. Where can function without the select clause.

As usual, to specify conditions, there are sets of special operators for you:

  • simple comparison operators (for numeric values): =, <>, >, >=, <, <=
  • complex comparison operators (for strings): contains, starts with, ends with, matches, != (doesn't match / doesn't equal to), like.
  • logical operators to combine several conditions: and, or, not.
  • operators for blank / not empty: is null, is not null.
Tip. If you're upset or worried about having to deal with such a huge number of operators again, we feel you. Our Multiple Vlookup Matches will find all matches and build QUERY formulas in Google Sheets for you if necessary.

Let's see how these operators behave in formulas.

Example 1. Where with numbers

I will add where to my Google Sheets QUERY from above to get the info on those planets that have more than 10 moons:

=QUERY(Papers!A1:G11,"select A,B,C,F where F>=10")

Select columns based on the condition for numbers.

Tip. I also mentioned column F to fetch just to make sure the criterion is met. But it's completely optional. You don't have to include columns with conditions into the result:

=QUERY(Papers!A1:G11,"select A,B,C where F>=10")

Example 2. Where with text strings

  • I want to see all rows where the grade is either F or F+. I will use the contains operator for that:

    =QUERY(Papers!A1:G11,"select A,B,C,G where G contains 'F'")

    Select columns based on text.

    Note. Don't forget to surround your text with quotation marks.
  • To get all rows with F only, just replace contains with an equal sign (=):

    =QUERY(Papers!A1:G11,"select A,B,C,G where G='F'")

  • To check the papers that are yet to be delivered (where the grade is missing), check column G for blanks:

    =QUERY(Papers!A1:G11,"select A,B,C,G where G is null'")

Example 3. Where with dates

Guess what: Google Sheets QUERY has even managed to tame dates!

Since spreadsheets store dates as serial numbers, usually, you have to resort to the help of special functions like DATE or DATEVALUE, YEAR, MONTH, TIME, etc.

But QUERY has found its way around dates. To enter them properly, simply type the word date and then add the date itself formatted as yyyy-mm-dd: date '2020-01-01'

Here's my formula to get all rows with a Speech date before 1 Jan 2020:

=QUERY(Papers!A1:G11,"select A,B,C where B<date '2020-01-01'")

Select columns based on a certain date.

Example 4. Combine several conditions

To use a certain period of time as a criterion, you will need to combine two conditions.

Let's try and retrieve those papers that were delivered in Autumn, 2019. The first criteria should be a date on or after 1 September 2019, the second — on or before 30 November 2019:

=QUERY(Papers!A1:G11,"select A,B,C where B>=date '2019-09-01' and B<=date '2019-11-30'")

Combine several conditions with AND logic.
Or, I can select papers based on these parameters:

  • before 31 December 2019 (B<date '2019-12-31')
  • have either A or A+ as a grade (G contains 'A')
  • or B/B+ (G contains 'B')

=QUERY(Papers!A1:G11,"select A,B,C,G where B<date '2019-12-31' and G contains 'A' or G contains 'B'")

Use AND and OR logic operators in the Google Sheets QUERY When clause.

Tip. If your head is about to explode already, don't give up just yet. There's a tool that is perfectly capable to build all these formulas for you, no matter the number of criteria. Jump right to the end of the article to get to know it.

Google Sheets QUERY – Group By

Google Sheets QUERY group by command is used to concatenate rows. However, you should use some aggregate functions in order to summarize them.

Note. Group by must always follow the select clause.

Unfortunately, there's nothing to group in my table as there are no recurring values. So let me adjust it a bit.

Suppose, all the papers are to be prepared by 3 students only. I can find the highest grade each student got. But since they are letters, it is the MIN function I should apply to column G:

=QUERY(Papers!A1:G11,"select A,min(G) group by A")

Note. If you don't use an aggregate function with any column in the select clause (column A in my example), you must duplicate them all in the group by clause.

Group rows using QUERY function in Google Sheets.

Google Sheets QUERY – Pivot

Google Sheets QUERY pivot clause works the other way around, if I may say so. It transposes data from one column to a row with new columns, grouping other values accordingly.

For those of you dealing with dates, it can be a real discovery. You'll be able to get a quick glance at all the distinct years from that source column.

Note. When it comes to pivot, every column used in the select clause should be covered with an aggregate function. Else, it should be mentioned in the group by command following your pivot.

Remember, my table now mentions only 3 students. I'm going to make the function tell me how many reports each student made:

=QUERY(Papers!A1:G11,"select count(G) pivot A")

Use the pivot clause to produce another table.

Google Sheets QUERY – Order By

This one is pretty easy :) It is used to sort the outcome by the values in certain columns.

Tip. All previous clauses are optional when using order by. I use select to return fewer columns for demonstration purposes.

Let's go back to my original table and sort reports by speech date.

This next Google Sheets QUERY formula will get me columns A, B and C, but at the same time will sort them by date in column B:

=QUERY(Papers!A1:G11,"select A,B,C order by B")

Get the data sorted by a certain column.

Limit

What if I told you, you don't have to bring each and every row into the result? What if I told you that Google Sheets QUERY can pull only a certain amount of the first matches it finds?

Well, the limit clause is designed to help you with that. It limits the number of rows to return by the given number.

Tip. Feel free to use limit without other previous clauses.

This formula will show the first 5 rows where the column with grades contains a mark (is not empty):

=QUERY(Papers!A1:G11,"select A,B,C,G where G is not null limit 5")

Pull a specific number of rows from the beginning.

Offset

This clause is kind of opposite to the previous one. While limit gets you the number of rows you specify, offset skips them, retrieving the rest.

Tip. Offset also doesn't require any other clauses.

=QUERY(Papers!A1:G11,"select A,B,C,G where G is not null offset 5")

Skip rows at the beginning using <em>offset</em>.
If you try and use both limit and offset, the following will happen:

  1. Offset will skip rows at the beginning.
  2. Limit will return a number of the following rows.

=QUERY(Papers!A1:G11,"select A,B,C,G where G is not null limit 3 offset 3")

Out of 11 rows of data (the first one is a header and QUERY function in Google Sheets does a nice job understanding that), offset skips the first 3 rows. Limit returns 3 next rows (starting from the 4th one):
Use both limit and offset in Google Sheets QUERY.

Google Sheets QUERY – Label

Google Sheets QUERY label command lets you change header names of the columns.

Tip. Other clauses are optional for label as well.

Put the label first, followed by the column ID and a new name. If you rename few columns, separate each new pair of column-label by a comma:

=QUERY(Papers!A1:G11,"select A,B,C label A 'Name', B 'Date'")

Rename columns using Google Sheets QUERY label clause.

Format

The format clause makes it possible to alter the format of all values in a column. For that, you will need a pattern standing behind the desired format.

Tip. The format clause can also play solo in the Google Sheets QUERY.

=QUERY(Papers!A1:G11,"select A,B,C limit 3 format B 'mm-dd, yyyy, ddd'")

Format values right through QUERY function in Google Sheets.

Tip. I mentioned some date formats for Google Sheets QUERY in this blog post. Other formats can be taken directly from spreadsheets: Format > Number > More Formats > Custom number format.

Options

This one is used to set some additional settings for the outcome data.

For example, such command as no_values will return formatted cells only.

The quickest way to build QUERY formulas – Multiple Vlookup Matches

However powerful the QUERY function in Google Sheets is, it may require a learning curve to get ahold of. It's one thing to illustrate each clause separately on a small table, and completely another to try and build everything correctly with a few clauses and a much bigger table.

That's why we decided to dress Google Sheets QUERY up in a user-friendly interface and make it the add-on.

Why Multiple VLOOKUP Matches is better than formulas?

Well, with the add-on there's absolutely no need to:

  • figure out anything about those clauses. It's really easy to create lots of complex conditions in the add-on: as many as you need despite their order to fetch as many matches as you need.
    Note. At the moment, the following clauses were incorporated into the tool: select, where, limit, and offset. If your task requires other clauses as well, please comment below – perhaps, you'll help us improve ;)
  • know how to enter operators: just pick the one from a drop-down list.
  • puzzle over the correct way to enter date and time. The add-on lets you enter them as you used to based on your spreadsheet locale.
    Tip. There's always a hint available in the tool with examples of different data types.

As a bonus, you'll be able to:

  • preview both the result and the formula
  • make quick adjustments to your criteria
  • select a place for the result
  • insert the result as both QUERY formula or as values

I'm not kidding, see for yourself. Though this GIF was sped up, it took me less than a minute to fine-tune all criteria and get the result:
Have Multiple VLOOKUP Matches create Google Sheets QUERY formulas for you.
If you're curious enough, here's a detailed video showing how the add-on works:

Tip. There's also a video transcript available in this blog post.

I hope you will give the add-on a chance and get it from Google Workspace Marketplace. Don't be shy and share your feedback, especially if there's something about it you don't like.

Also, feel free to check out its tutorial page or home page.

You may also be interested in

Table of contents

54 responses to "Google Sheets QUERY function: a spreadsheet cure-all you have yet to discover"

  1. Alton says:

    Hello,
    Is there anyway to show row number in a query?

    Thanks.

  2. Noe says:

    Hi,

    I woul like to learn about query more where X column has a exactly value, I see some examples when you use more than or less than but I don´t know how to use with exactly value,

    Thanks a lot !

  3. Anusha says:

    Can I split one row with 10 columns data of marks into 5 rows and 3 columns, while importing data using IMPORTRANGE function.

  4. Abbie says:

    Hi 👋, I'm trying to search rows rather than columns using the Query function. I want to return the headers every time a I receive a 'No' answer in my data. This needs to be done for each individual row.

    Range A1:B10, select row A where B contains 'No'

    Or should I be using an array or index?

    Thanks!

  5. James says:

    Hi,

    On the Query function, is it possible to search under a specific column where instead of using the A,B or C column you will be using the Header name itself like County, Building,

    Because from my understanding if data from the columns A.B and C were to be moved to another column, then the queried data will also be changes as specific to what the column has.

    So instead I would like to have a specific column identifier?

    Thanks!

  6. Nick says:

    How do you select data from the row being grabbed in the query to populate another portion of the table. If I run =QUERY(J:J, "where J=true") how do I get it to reproduce the data from those queried rows for columns B, C, and D? I haven't had the best luck with testing so far.

  7. Eric says:

    Can you use Select where A begins with (A-Com) - or any range of letters. Trying to sort data to different tabs based on last names ranges.

    • Hello Eric,

      If 'A-Com' is literally a string used at the beginning of some cells, you can get such cells using the 'where' label:
      =QUERY(A1:A50, "select * where A starts with 'A-Com'

      But if you mean it's a range of letters, you will have to list each letter separately, like this:
      =QUERY(A1:A50, "select * where (A starts with 'A') or (A starts with 'B') or A starts with 'C'")
      Note that all cases but the last one are put into brackets.

  8. Vinesh Jain says:

    How to extract parts of data from one cell and display in different columns at the destination sheet using QUERY()?

  9. Marina G says:

    Hello, I'm trying to use lowercase trimmed values in my select query, but am getting an error
    =QUERY({Original!A2:Q18909}, "select lower(trim(Col1)), count(lower(trim(Col1))) where Col1 is not null Group BY Col1 PIVOT Col2 ",0)

    The error reads #VALUE Unable to parse query

    Could you please point where I go wrong? Thanks!

    • Hello Marina,

      There's no need to wrap the range in curly brackets unless you combine multiple datasets. Also, you refer to Col1 with the 'select' clause twice, this can be the problem.

      The best way for us to help you is for you to share an editable copy of the spreadsheet with us – support@apps4gs.com – we'll look into it. Make sure it contains the formula that causes problems. If you have confidential information there, you can replace it with some irrelevant data, just keep the format.

      Note. We keep that Google account for file sharing only, please do not email there. Once you share the file, just confirm by replying to this comment.

  10. Jesper F. says:

    Hello Natalia and the rest of the Ablebits Team.

    I'm trying to make a join query, where I combine data in the same cell.

    So let's say I have the same author talking about different subjects and his name is listed 3-4 times in column A, but with different subjects in column B. Then I want an overview where the query joins the subjects by the name of the author.
    So something like =join(", ",query(A:B,"Select A,B by A")) or something like that.

    And even further, also sums the profits by the authors subjects would be an awesome addition!

    Could you help me out? Thanks!

  11. Ray says:

    Hi

    Great article, but I'm stuck and wondered if you can help, I'm Trying to get a (Where) query to return columns from sheet1 into sheet2 where the criteria to meet is in col1 in sheet2!

    An example from your article is 1 below, but I'm trying to achieve 2?
    1) =QUERY(Sheet1!A1:G11,"select A,B,C,F where F>=10")

    2) =QUERY(Sheet1!A1:G11,"select A,B,C,F where A = Sheet2!A2:A")

    Its a text based field, so if it were countries for example, I have a column of countries and I want to filter every row from sheet1 that corresponds with col1 in sheet2, every row line being unique.

    Any help is much appriciated.

    Thanks

    Sheet1!A2:A being the filter data that is in Col1 of both my sheets?

  12. Hassan Maateeq says:

    is there a way to return the query results with bordered cells. I mean make cells that have results with borderes

  13. Saumittra says:

    Hi Natalia, How can i find rows in a column(that has sentences as values) that dont contain a particular word?

  14. Cassie says:

    Hi Natalia,

    I was hoping you can assist!

    Column H I J is where my datas are and I need to return the data if what I type in Column G matches column H — what is the best way to go about this?

  15. Nick says:

    Hello, thanks for taking the time to write great blogs and helping us all so much.

    My issue is I am using query to select figures from a couple of columns (that are created each day and so generally differ in length) which relate to volumes of sales of different products. I can exclude the top row from being sorted alphabetically but the 'Totals' row at the bottom is swept up and included.
    If I call it 'zz Total' obviously it stays down where I want it to be but that's horrible - is there a way to exclude the final line from being included in the query search?

    • Hello Nick,

      Thank you for the feedback! :)

      You can make the formula ignore the first and the last rows using the ArrayFormula and OFFSET functions respectively for the 'limit' command. Here's an example:
      =QUERY({Sheet10!A1:E}, "select * limit " &ArrayFormula(max(if(len(Sheet10!A1:E), ROW(Sheet10!A1:E), )))-2 & " OFFSET 1", 0)

      If you're not sure how to incorporate that into your own QUERY, please provide your exact formula here.

  16. Sam says:

    Hello, I am wanting to pull columns from a named range based on a cell value in the sheet I'm pulling the info into but I can't seem to figure out how to do it.
    I want columns D, O and P from the named range All2021Regos where C = my current spreadsheets C2.

    =Query(All2021Regos,"select D,O,P Where C=C2")

    =Query(All2021Regos,"select D,O,P Where C='Attendance Sheet auto'!C2",)

    I was hoping for something like this, but with a named range, and with having a cell determine the value rather than having it in the formula.
    =QUERY(IMPORTRANGE("insert_url","Range"),"Select Col1, Col2 Where Col4='Value'")

    Any help would defs be appreciated.

    • Hello Sam,

      You can try this one:
      =QUERY(All2021Regos,"select D,O,P where C='Value'")

      Or, if you'd like to reference a cell, you need to let QUERY know that it's a reference, not a column name (I add 1 at the end, so it sees the header row):
      =QUERY(All2021Regos,"select D,O,P where C='"&C2&"'", 1)

  17. Angelique says:

    Hi, i have an issue and need help please :)
    When both query have numbers it's working but when one doesn't find a result i have N/A error, i can't find a way to solve that even with a "ifna"

    =IF(isblank(B9),,{QUERY(Dividendes_TFSA!$B$8:$F$55,"select F where B='"&B9&"' and C like '%March%'")+QUERY(Dividendes_RRSP!$B$9:$H$55,"select G where B='"&B9&"' and C like '%March%'")})

    Thank you very much.

  18. James says:

    I would like to type a date into one cell... and have a query pull a column from another page that has dates in the top row (i'd like to search for the date here). Is this possible, and if so, what would the formula look like?

    • Hi James,

      For me to be able to help you better, please share a small sample spreadsheet with us (support@apps4gs.com) with 2 sheets: (1) a sample of your data (2) the result you expect to get. I kindly ask you to shorten the tables to 10-20 rows. If you have confidential information there, you can replace it with some irrelevant data, just keep the format. I'll look into it.

      Note. We keep that Google account for file sharing only and don't monitor its Inbox. Please do not email there. Once you share the file, just confirm by replying to this comment.

  19. Jacob says:

    I would like to figure out how to search by numbers. I have =QUERY(' Install PO Log'!B2:P,"SELECT * WHERE P = '72'",1) and I basically have jobs that are all assigned their specific numbers and I want to group the jobs by the numbers rather than by their name in order to simplify some other things for me. Is that possible? I can't figure it out, It only seems to work when I search by letters.

    For Example:
    This is my job list:

    Mcdonalds 1
    Arbys 2
    Wendys 3
    Arbys 2
    Arbys 2
    Mcdonalds 1

    I want to group them by searching by "2" instead of "Arbys" is that possible?

    • Hello Jacob,

      When searching for numbers, do no put them into single quotes:
      =QUERY('Install PO Log'!B2:P,"SELECT * WHERE P=72",1)

      Only text strings should be wrapped in quotes in Google Sheets formulas.

      • Jacob says:

        You just solved an issue I had been trying to solve for 6+ hours thank you so much!

        My next question is how I select certain columns. I have Columns A-P but I only need columns B,C,D,F,G,H,I,J,M,N,P. Right now, I have to hide the columns I don't need but that's very time-consuming when I have hundreds of these formulas to do. Is there any way to throw those specific columns into the formula so only they show? Below is the formula I am using now and I would just like to only use specific columns.

        =QUERY(' Install PO Log'!B2:P,"SELECT * WHERE P = 53",1)

  20. Neal says:

    How can I add an order function to this query where it will sort both sets of data together in one list? Basically I want to pull two sets of data then have both sets ordered together in one long list.

    ={query('Reg Data'!A:AA,"Select F, E, H, K, U, R, V, X, G, Y, AA WHERE S='US History A'",0); query('Reg Data'!A:AA,"Select F, E, H, K, U, R, V, X, G, Z, AA WHERE T='US History A'",0)}

    I want to sort the entire list using this: Order by R, F, E

    Thank you for your help.

    • Hello Neal,

      By adding the 'order by' clause to each QUERY, you will sort each range individually.

      To sort the entire result, you need to wrap QUERY in the SORT function:
      =SORT({QUERY('Reg Data'!A:AA,"select F,E,H,K,U,R,V,X,G,Y,AA where S='US History A'",0); QUERY('Reg Data'!A:AA,"select F,E,H,K,U,R,V,X,G,Z,AA where T='US History A'",0)},5,TRUE,6,TRUE,18,TRUE)

  21. Madhusmita Roy says:

    I am using Query in a google sheet , but all the results are coming together in the 1st row only and from the 2nd row it is coming properly .

    For example : Data should be like..
    Col 1 Col 2 Col 3
    A B. C
    D. E. F

    But the Data is coming like after using Query function :

    Col 1. Col 2. Col 3
    A D. B E C F
    D. E. F

  22. Pierre G. says:

    Hello,
    I have 15 columns with Group tag as header and containing lists of names.
    Some names appears in different columns / Group tags.
    How can I display in a single cell the different columns headers / Group tags where a specific name is appearing?
    Thank you in advance,

    • Hello Pierre,

      For me to be able to help you, please share a small sample spreadsheet with us (support@apps4gs.com) with 2 sheets: (1) an example of your source data (if you have confidential information there, you can replace it with some irrelevant data, just keep the format) (2) the result you expect to get (the result sheet is of great importance and often gives us a better understanding than any text description). I kindly ask you to shorten the tables to 10-20 rows.

      Note. We keep that Google account for file sharing only and don't monitor its Inbox. Please do not email there. Once you share the file, just confirm by replying to this comment.

      I'll look into it.

  23. Lola says:

    Hello, I have a query where I have the top 10, but am trying to find the next 10 now
    =query(A:BA), "SELECT Col10, sum(Col51)/1000 WHERE Col9='XXX' Group by Col10 Order by sum(Col51)/1000 desc limit 10 LABEL Col10 '', sum(Col51)/1000 ' '",-1)
    Offset only removes the first 10 rows from the original data set, not from the grouping, so was hoping to group desc next 10 if that's possible?
    Thanks!

    • Hello Lola,

      Offset is exactly the clause that you'd use to find 'the next 10'. Can you please share an editable copy of your file with us (support@apps4gs.com) where you used the formula and it didn't work? Also, please include the example of the result you'd like to get, it will give us the exact picture of your task. Thank you.

Post a comment



Thank you for your comment! When posting a question, please be very clear and concise. This will help us provide a quick and relevant solution to your query. We cannot guarantee that we will answer every question, but we'll do our best :)