Excel IF statement with multiple AND/OR conditions, nested IF formulas, and more
In Part 1 of our Excel IF function tutorial, we started to learn the nuts and bolts of the Excel IF function. As you remember, we discussed a few IF formulas for numbers, dates and text values as well as how to write an IF statement for blank and non-blank cells.
However, for powerful data analysis, you may often need to evaluate multiple conditions at a time, meaning you have to construct more sophisticated logical tests using multiple IF functions in one formula. The formula examples that follow below will show you how to do this correctly. You will also learn how to use Excel IF in array formulas and learn the basics of the IFEFFOR and IFNA functions.
How to use Excel IF function with multiple conditions
In summary, there can be 2 basic types of multiple conditions - with AND and OR logic. Consequently, your IF function should embed an AND or OR function in the logical test, respectively.
- AND function. If your logical test contains the AND function, Microsoft Excel returns TRUE if all the conditions are met; otherwise it returns FALSE.
- OR function. In case you use the OR function in the logical test, Excel returns TRUE if any of the conditions is met; FALSE otherwise.
To better illustrate the point, let's have a look at a few IF examples with multiple conditions.
Example 1. Using IF & AND function in Excel
Suppose, you have a table with the results of two exam scores. The first score, stored in column C, must be equal to or greater than 20. The second score, listed in column D, must be equal to or exceed 30. Only when both of the above conditions are met, a student passes the final exam.
The easiest way to make a proper formula is to write down the condition first, and then incorporate it in the logical_test argument of your IF function:
Condition: AND(B2>=20, C2>=30)
IF/AND formula:
=IF((AND(C2>=20, D2>=30)), "Pass", "Fail")
Easy, isn't it? The formula tells Excel to return "Pass" if a value in column C >=20 AND a value in column D >=30. Otherwise, the formula returns "Fail". The screenshot below proves that our Excel IF /AND function is correct:
In practice, a seemingly correct IF / AND formula may result in an error because of this specificity. For example, the below formula will return "Divide by Zero Error" (#DIV/0!) if cell A2 is equal to 0:
=IF(AND(A2<>0,(1/A2)>0.5),"Good", "Bad")
The avoid this, you should use a nested IF function:
=IF(A2<>0, IF((1/A2)>0.5, "Good", "Bad"), "Bad")
Example 2. Using IF with OR function in Excel
You use the combination of IF & OR functions in a similar way. The difference from the IF / AND formula discussed above is that Excel returns TRUE if at least one of the specified conditions is met.
So, if we modify the above formula in the following way:
=IF((OR(C2>=20, D2>=30)), "Pass", "Fail")
Column E will have the "Pass" mark if either the first score is equal to or greater than 20 OR the second score is equal to or greater than 30.
As you see in the screenshot below, our students have a better chance to pass the final exam with such conditions (Scott being particularly unlucky failing by just 1 point : )
More formula examples can be found in Excel IF OR functon.
Example 3. Using IF with AND & OR functions
In case you have to evaluate your data based on several sets of multiple conditions, you will have to employ both AND & OR functions at a time.
In the above table, suppose you have the following criteria to evaluate the students' success:
- Condition 1: column C>=20 and column D>=25
- Condition 2: column C>=15 and column D>=20
If either of the above conditions is met, the final exam is deemed passed, otherwise - failed.
The formula might seem tricky, but in a moment, you will see that it is not! You just have to express two conditions as AND statements and enclose them in the OR function since you do not require both conditions to be met, either will suffice:
OR(AND(C2>=20, D2>=25), AND(C2>=15, D2>=20)
Finally, use the above OR function as the logical test in the IF function and supply value_if_true and value_if_false arguments. As the result, you will get the following IF formula with multiple AND / OR conditions:
=IF(OR(AND(C2>=20, D2>=25), AND(C2>=15, D2>=20)), "Pass", "Fail")
The screenshot below indicates that we've got the formula right:
Naturally, you are not limited to using only two AND/OR functions in your Excel IF formulas. You can use as many logical functions as your business logic requires, provided that:
- In Excel 2016, 2013, 2010 and 2007, your formula includes no more than 255 arguments, and the total length of the formula does not exceed 8,192 characters.
- In Excel 2003 and lower, you can use up to 30 arguments and the total length of your formula shall not exceed 1,024 characters.
Using multiple IF statements in Excel (nested IF functions)
If you need to create more elaborate logical tests for your data, you can include additional IF statements in the value_if_true and value_if_false arguments of your Excel IF formulas. These multiple IF functions are called nested IF functions and they may prove particularly useful if you want your formula to return 3 or more different results.
Here's a typical example: suppose you want not simply to qualify the students' results as Pass/Fail, but define the total score as "Good", "Satisfactory" and "Poor". For instance:
- Good: 60 or more (>=60)
- Satisfactory: between 40 and 60 (>40 and <60)
- Poor: 40 or less (<=40)
To begin with, you can add an additional column (E) with the following formula that sums numbers in columns C and D:
=C2+D2
And now, let's write a nested IF function based on the above conditions. It's considered a good practice to start with the most important condition and make your functions as simple as possible. Our Excel nested IF formula is as follows:
=IF(E2>=60, "Good", IF(E2>40, "Satisfactory", "Poor "))
As you see, just one nested IF function is sufficient in this case. Naturally, you can nest more IF functions if you want to. For example:
=IF(E2>=70, "Excellent", IF(E2>=60, "Good", IF(E2>40, "Satisfactory", "Poor ")))
The above formula adds one more conditions - the total score of 70 points and more is qualified as "Excellent".
For more information about Excel IF with multiple conditions, please see How to use nested IF in Excel.
Using Excel IF in array formulas
Like other Excel functions, IF can be used in array formulas. You may need such a formula if you want to evaluate every element of the array when the IF statement is carried out.
For example, the following array SUM/IF formula demonstrates how you can sum cells in the specified range based on a certain condition rather than add up the actual values:
=SUM(IF(B1:B5<=1,1,2))
The formula assigns a certain number of "points" to each value in column B - if a value is equal to or less than 1, it equates to 1 point; and 2 points are assigned to each value greater than 1. And then, the SUM function adds up the resulting 1's and 2's, as shown in the screenshot below.
Using IF function together with other Excel functions
Earlier in this tutorial, we've discussed a few IF formula examples demonstrating how to use the Excel IF function with logical functions AND and OR. Now, let's see what other Excel functions can be used with IF and what benefits this gives to you.
Example 1. Using IF with SUM, AVERAGE, MIN and MAX functions
When discussing nested IF functions, we wrote the formula that returns different ranking (Excellent, Good, Satisfactory or Poor) based on the total score of each student. As you remember, we added a new column with the formula that calculates the total of scores in columns C and D.
But what if your table has a predefined structure that does not allow any modifications? In this case, instead of adding a helper column, you could add values directly in your If formula, like this:
=IF((C2+D2)>=60, "Good", IF((C2+D2)=>40, "Satisfactory", "Poor "))
Okay, but what if your table contains a lot of individual scores, say 5 different columns or more? Summing so many figures directly in the IF formula would make it enormously big. An alternative is embedding the SUM function in the IF's logical test, like this:
=IF(SUM(C2:F2)>=120, "Good", IF(SUM(C2:F2)>=90, "Satisfactory", "Poor "))
In a similar fashion, you can use other Excel functions in the logical test of your IF formulas:
IF and AVERAGE:
=IF(AVERAGE(C2:F2)>=30,"Good",IF(AVERAGE(C2:F2)>=25,"Satisfactory","Poor "))
The formulas retunes "Good" if the average score in columns C:F is equal to or greater than 30, "Satisfactory" if the average score is between 29 and 25 inclusive, and "Poor" if less than 25.
IF and MAX/MIN:
To find the highest and lowest scores, you can use the MAX and MIN functions, respectively. Assuming that column F is the total score column, the below formulas work a treat:
MAX: =IF(F2=MAX($F$2:$F$10), "Best result", "")
MIN: =IF(F2=MIN($F$2:$F$10), "Worst result", "")
If you'd rather have both the Min and Max results in the same column, you can nest one of the above functions in the other, for example:
=IF(F2=MAX($F$2:$F$10) ,"Best result", IF(F2=MIN($F$2:$F$10), "Worst result", ""))
In a similar manner, you can use the IF function with your custom worksheet functions. For example, you can use it with the GetCellColor / GetCellFontColor functions to return different results based on a cell color.
In addition, Excel provides a number of special IF functions to analyze and calculate data based on different conditions.
For example, to count the occurrences of a text or numeric value based on a single or multiple conditions, you can use COUNTIF and COUNTIFS, respectively. To find out a sum of values based on the specified condition(s), use the SUMIF or SUMIFS functions. To calculate the average according to certain criteria, use AVERAGEIF or AVERAGEIFS.
For the detailed step-by-step formula examples, check out the following tutorials:
- How to use the COUNTIF in Excel
- Using Excel COUNTIFS and COUNTIF with multiple conditions
- SUMIF in Excel - formula examples to conditionally sum cells
- How to use Excel SUMIFS and SUMIF with multiple criteria
Example 2. IF with ISNUMBER and ISTEXT functions
You already know a way to spot blank and non-blank cells using the ISBLANK function. Microsoft Excel provides analogous functions to identify text and numeric values - ISTEXT and ISNUMBER, respectively.
Here's is example of the nested Excel IF function that returns "Text" if cell B1 contains any text value, "Number" if B1 contains a numeric value, and "Blank" if B1 is empty.
=IF(ISTEXT(B1), "Text", IF(ISNUMBER(B1), "Number", IF(ISBLANK(B1), "Blank", "")))
Example 3. Using the result returned by IF in another Excel function
Sometimes, you can achieve the desired result by embedding the IF statement in some other Excel function, rather than using another function in a logical test.
Here's another way how you can use the CONCATINATE and IF functions together:
=CONCATENATE("You performed ", IF(C1>5,"fantastic!", "well"))
I believe you hardly need any explanation of what the formula does, especially looking at the screenshot below:
IF function vs. IFERROR and IFNA
Both of the functions, IFERROR and IFNA, are used to trap errors in Excel formulas and replace them with another calculation, predefined value or text message. In earlier Excel versions, you can use the IF ISERROR and IF ISNA combinations instead.
The difference is that IFERROR and ISERROR handle all possible Excel errors, including #VALUE!, #N/A, #NAME?, #REF!, #NUM!, #DIV/0!, and #NULL!. While IFNA and ISNA specialize solely in #N/A errors.
Here is the simplest example of the IFERROR formula:
=IFERROR(B2/C2, "Sorry, an error has occurred")
As you see in the screenshot above, column D displays the quotient of the division of a value in column B by a value in column C. You can also see two error messages in cells D2 and D5 because everyone knows that you cannot divide a number by zero.
In some cases, however, you may not want to trap all errors, but rather test the condition causing a specific error. For example, to replace a divide by zero error with your own message, use the following IF formula:
=IF(C2=0, "Sorry, an error has occurred", B2/C2)
And that's all I have to say about using the IF function in Excel. I thank you for reading and hope to see you on our blog next week!
You may also be interested in
2,813 responses to "Excel IF statement with multiple AND/OR conditions, nested IF formulas, and more"
=IF(A4="big creek",“Karen”,IF(A4="vista AOR","Jim",IF(A4="alhambra","Martin")))
I know I can't use * for remaining characters with IF function. Is there a way to use multiple IF statements with partial texts and not case sensitive? The above did not work.
Really appreciate the help!
Hello!
Instead of the "* big *" condition, you can use the formula to find the value in the text
ISNUMBER(SEARCH("big",A4,1))
I hope my advice will help you solve your task.
=IF(K:K="published","Live-API",IF(K:K="blocked","",IF(K:K="published","Live")))
Can I use the OR condition here?
Live-API or Live
Hello!
There are 2 conditions in your formula
K:K=”published”,”Live-API”
and
K:K=”published”,”Live”
The information you provided is not enough to understand your case and give you any advice, but this is wrong.
Thank you that worked perfectly. The calculating cell contains FALSE until all conditional are met. Is there a way FALSE can be blank until all conditions are me?
Thanks you
Hello!
If I understand your task correctly, You can use something like this formula —
=IF(A1>B1,A1,"")
Use "" instead of FASLE.
I have rows with some data in column A the same and need to combine data in column B whenever the data in column A is the same.
What formula can I use to summarize this data? A pivot table summarized the data, but it’s still shown in separate cells. I need to have one cell per column A answer.
Hello!
The IF function won't help you find the sum of the values.
If I understand your task correctly, you need to use the SUMIF function.
Say A1, A2, A3 and A4 cells with 100 characters
if you make the following formula
=IFS(1=1,CONCATENATE(A1,A2,A3,A4))
it throws a #Value error, I believe because A1...A4 exceeds the 255 text length
If you use
=IF(1=1,(A1 &A2 &A3&A4))
then it works as a charm
Anybody knows why this happens?
I mean by the second formula
=IF(1=1,CONCATENATE(A1,A2,A3,A4))
IF function is working, not IFS
Hello!
To combine long texts, I recommend using the CONCATENATE and CONCAT functions.
In a single CONCATENATE formula, you can concatenate up to 255 strings, a total of 8,192 characters.
Solve the the issue in the equation
=IF(OR(H8>=6,P8>=40%)2000, 2500, IF(OR(H8>=5,P8>=40%), 1500, 2000, IF(OR(H8>=4,P8>=40%), 750, 1500, IF(OR(H8<4,P8<40%),0,0))))
Hello!
I’m sorry but your task is not entirely clear to me. For me to be able to help you better, please describe your task in more detail. Please specify what you were trying to find, what problem or error occurred. Give an example of the source data and the expected result.
It’ll help me understand it better and find a solution for you.
Hi ,
I wondered if you could help me with the following problem!
=IF($I$9=$A$3:$A$40,$C$3:$C$40,if($I$9=$B$3,$C$3:$C$40,0)
Can anyone please assist?
Hello!
Your formula is missing parentheses.
=IF($I$9=$A$3:$A$40,$C$3:$C$40,IF($I$9=$B$3,$C$3:$C$40,0))
Is this the problem?
i have a problem hope you can help me.
I want to construct a if statement such that
A1=10000
B1= 12 or 24 or 36
C1 =??
i want to automatically calculate if B1=12, C1=A1/2, if B1=24, C1=A1 and B1=36, C1=A1*1.5
Can someone help me?
Many thanks
Hello!
Please try the following formula:
=IF(B1=12,A1/2,IF(B1=24,A1,IF(B1=36,A1*1.5,"")))
or
=IFS(B1=12,A1/2,B1=24,A1,B1=36,A1*1.5)
I hope this will help
Any Body can correct this formula
=IF(ISNUMBER(SEARCH("011","012",014","017","061","076",077","078","085","089","092","095","099"
",C2)),"Cellcard") IF(ISNUMBER(SEARCH("010","015","016","069","070","081","086","087","093","096","098",C2)),"Smart")
IF(ISNUMBER(SEARCH( "088","097","071","031","060","066","067","068","090",C2)),"Metfone")
Hello!
Could you please describe your task in more detail? What result do you want to get? Give an example of the source data and the expected result.
It’ll help me understand it better and find a solution for you
Can you help me? I need a formula that will do the following and will also need to meet multiple conditions:
If A1="Contract",B1="Cold" and C1<=1 year from today's date, display 7.5%, but if A1="Contract",B1="Cold" and C1<=2-4 years from today's date, display 3%.
A1 can be: Contract, Casino or Forms
B1 can be: cold or warm
and the percentages for all change based 1-4 years from today's date
I can't figure out how to incorporate all of the conditions within one formula.
Thank you so much!
Hello!
If I got you right, the formula below will help you with your task:
=IF(AND(A1="Contract",B1="Cold",DATEDIF(TODAY(),C1,"y")<=1),7.5%,IF(AND(A1="Contract",B1="Cold",OR(DATEDIF(TODAY(),C1,"y")>=2,DATEDIF(TODAY(),C1,"y")<=4)),3%,))
To find the difference between dates, use the DATEDIF function.
I hope my advice will help you solve your task.
Thank you for your help. I put the formula in and changed the cells and I am receiving a #NUM! error.
Hello!
The formula I sent to you was created based on the description you provided in your first request. You wrote the conditions in the second paragraph.
In order to prevent it from happening, please provide me with the detailed description of your task. Any examples of the source data and expected result would be of great help. It’ll help me avoid further confusions and find the right solution for you.
Hi
Please help me with following
If column A and B both contains apple the answer should be apple
And in the same way if both columns contains banana then also i need to get apple
If in column A is apple and in column B is banana answer should be banana and vise versa
Kindly help me using excel formula for this
Hello!
Example 3 "Using IF with AND & OR functions" above has the answer to your question.
I am working with Excell 2010 and I have a sheet like bellow
Cement, Brick, Sand (50 Item) = these all item will show as "Civil"
Wood, Board, Paint (15 Item) = these all item will show as "Carpentry"
Glass, Aluminium, Lock (10 item) = these all item will show as "Aluminium"
Paint, Polish, PaintWages (5 Item) = these all item will show as "Paint"
and many more.
I put a formula like it.
=IF(OR(A1="Aluminium Work (WIP)",A1="Aluminum & Glass work (HTL - Advance)",A1="Glass Materials ( WIP )"),"Aluminium",IF(OR(A1="Door Frame",A1="False Celling (HTL Febricator Advance)",A1="Flush Door",A1="Miscellaneous (Carpentry)",A1="Plastic Door",A1="Receiption decorational expenses (wip)",A1="Solid Door"),"Carpentry","")))
But After putting more then 25 logic it is not working, please help me.
Hello!
The IF function has a limit on the number of conditions. I recommend using a 2-column table in which each product has a corresponding name. For example, Cement - Civil, Brick - Civil. With the VLOOKUP function, you will insert the name from this table into your main table.
Read how to do a Vlookup in Excel.
I hope my advice will help you solve your task.
Hello,
I'm working on formula..
There is three input strings and based on that i need to find the answer... for i.e.. Box size - 8ft / Application - Chill / Door opening - Limited - for these inputs answer should come as C150e or any one input wrong answer should come as NA.
Hello!
Based on your description, it is hard to completely understand your task. However, I’ll try to guess and offer you the following formula:
=IF(A1*B1*C1=8,"C150e","NA")
What if i want to seperate date column into 5 combinations such as "0-30 days", "31-60 Days", "61-90 Days", "91-120 Days", "120 Days n Above".
Thanks
Hello!
I hope you have studied the recommendations in the tutorial above. It contains answers to your question
Please try the following formula:
=IF((D1-TODAY())<=30,"0-30 days", IF(D1-TODAY()<=60,"31-60 days", IF(D1-TODAY()<=90,"61-90 days", IF(D1-TODAY()<=120,"91-120 days", "120 Days n Above") ) ))
Hi,
i am working with the Excel 2016 and I need a formula that will check if the the name in the first column is consistent with the names in the column alongside.
For instance:
Column B: Fruit, Vegetable; Beef.
Column C: Strawbarry, Apple; Potatoes, Salad greens Spinach, Turnips, Onions, beef, pork, sausage, veal, chicken
Fruit: strawbarry, apple;
Vegetable: Potatoes, Salad greens Spinach, Turnips, Onions,
Meat: beef, pork, sausage, veal, chicken
I need to check with a third column (D) if the column B is Fruit and the column C is Strawbarry, the check is correct --> "Ok"; while if the column B is Fruit and the column C is chicken the check will be negative --> "Non ok".
Please help me with this.
Thanks
Hello!
If I got you right, the formula below will help you with your task:
=IF(A1=(IF(SUM(--(B1={"strawbarry","apple"}))=1,"Fruit", IF(SUM(--(B1={"Potatoes","Salad","greens","Spinach","Turnips","Onions"}))=1,"Vegetable", IF(SUM(--(B1={"beef","pork","sausage","veal","chicken"}))=1,"Meat","" ) ))),"OK","NOT")
The fastest and correct way to determine which species a product belongs to is to use the VLOOKUP function. But your information is not enough to give you advice on its use.
Question No. 2
STELCO
Emp ID Emp Name salary Emp Type HRA TA PF Bonus Total
ST001 Amir Khan 8563 1
ST002 John Abraham 5320 2
ST003 Akshya 6586 3
ST004 Dileep 14521 4
ST005 Santhosh 4500 5
HRA Salary>=6000 20 %of sal 1000
TA Salary>=6000 2000 1500
PF Salary>=8000 14 %of sal 8% of sal
Hello!
For me to be able to help you better, please describe your task in more detail. Please specify what you were trying to find, what formula you used and what problem or error occurred. Give an example of the source data and the expected result.
It’ll help me understand it better and find a solution for you.
Hi,
Amazing work Ablebits.com..
I try the formula here:
=IF(S4,"SUBMITTED","NOT SUBMITTED")
S4 represent the date of actual submission. I need to add another criteria "Ready by QC" in the formula.
If not mistaken, I need to have another date for "Ready by QC", correct?
Example:
Column A: Date Actual submission is: 20-09-2020
If the actual date key in, column C will turn to "Submitted", If empty, it will appear "Not Submitted"
Column B: Date sent for QC: 18-09-2020
Column C will turn to 'Ready by QC". If not key in the date column B, it will turn to submitted.
i am not sure if this the correct explaination.
Hello!
Based on your description, it is hard to completely understand your task. However, I’ll try to guess and offer you the following formula:
=IF(B1<>"","Ready by QC",IF(A1<>"","Submitted",""))
Hope this is what you need.
HI I M REQUIRED FOLLOWING FORMAT COMPLETE: -
I HAVE THREE COLMS
B=CW C=PW D=DIFFERENCE (CW-PW)
I HAVE REQUIRED A FORMULA:
IF D IS MORE THAN B SHOWS CALL, D IS MORE THAN C SHOWS PUT, IF B AND C FIGURES DIFFERENCE NOT DOUBLE THEN SHOWS SIDEWAYS.
Hello!
Your task is not completely clear to me. Give an example of the source data and the expected result.
It’ll help me understand it better and find a solution for you
Dear Sir/ Madam
I m using under mention formula
=IF(OR(B2>C2,C2C2,C2<B2, C2=B2), "put", "call","Sideways")) not works,
I want if C2=B2 difference is not double shows sideways also shows sideways
Hello!
Your formula is wrong. The information you provided is not enough to understand your case and give you any advice. Please provide me with an example of the source data and the expected result.
I am trying to put a formula together that is checking to see if 3 separate criteria's are met, and if they are met, it will populate data from another sheet in the same document. I've tried multiple formulas but they aren't exactly working. Please see below:
=IF(A9="REC 365", 1 * IF(C9="5 Year 4.99%",'REC Data Set'!A3:G25,"")) ---This one works but when i introduce the third criteria, it fails:
=IF(A9="REC 365", 1 * IF(C9="5 Year 4.99%", 1 * IF(E9="3.30",'REC Data Set'!A3:G25,"")))
I got closer with the AND argument but it doesn't work exactly, just gives me a value of false
=AND(A9="REC 365", AND(C9="5 Year 4.99%", AND(E9="3.30", 'REC Data Set'!A3:G25,"")))
Any help would be greatly appreciated. Thank you!
I have also tried this method:
=IF(AND(A9="REC 365", C9="5 Year 4.99%", E9="3.30"), 'REC Data Set'!A3:G25)
I'm getting a result of FALSE because something about this formula isn't true? I don't understand. All criteria is being met, this formula should at the very least evaluate as true.
Hello!
It is very difficult to understand a formula that contains unique references to your workbook worksheets.
I assume that you have a number in cell E9. You are comparing it to the text "3.3". Write down the condition E9 = 3.3
I hope my advice will help you solve your task.
Good Morning! Thank you for your reply!
I understand its difficult to decipher what I have going on here, and I appreciate your assistance.
I do have 3.30 in cell E9. I have also tried 3.3. Is there anyway you could (or be willing to) take a look at my document so you can see what I'm doing wrong? I have a formula that works for everything until it evaluates the last part for cell E9. Please see below:
=IF(A9="REC 365",IF(C9="5 Year 4.99%",IF(E9="3.3",'REC Data Set'!A3:G25,"")))
If I remove the E9 portion the formula works fine. I am out of ideas at this point and I've even gone in and tried referencing different cells and removing formatting from E9 and trying to use different cells instead of E9 to try everything I can think of. Please let me know if you are willing to take a look.
Thanks again either way!
I want to add that it has something to do with E9 being a number. When I change the formula to this:
=IF(A9="REC 365",IF(C9="5 Year 4.99%",IF(L10="G",'REC Data Set'!A3:G25,"")))
It works perfectly. For some reason the formula fails when it involves numbers of any sort.
L10 is just a random cell i used for testing and populated it with the value G. Any ideas on why it would fail with it being a number?
Thanks again!
Hello!
I already wrote to you that you are comparing text with a number. Change the formula
= IF(A9 = "REC 365", IF(C9 = "5 Year 4.99%", IF(E9 = 3.3, 'REC Data Set'! A3: G25, "")))
Thank you for your help!
I was able to do a work around of some sort that I'm okay with using for now. Id still like to know why its failing but I'm okay for now. This is my work around formula below:
=IF(A9="REC 365",IF(C9="5 Year 4.99%",IF(E9="A 3.30",'REC Data Set'!A3:G25,"")))
When the "A" is introduced, it works fine. Very strange.
Thanks for listening to me complain LOL
Hello,
I wonder if you can help? I am trying to get a score in excel. We have to score clients on the amount of outgoing they spend. For example if someone has an outgoing <2000 they get a score of 0, if they have -1000 to -5000 they get a score of 1, if they have -5001 to -10000 they get a score of 2.
Does that make sense? Basically scoring someone on their outgoings but I don't know how to do this with minus figures and when someone has a from to figure.
Any help would be great.
Hello!
Explain your terms. The amount 1500 refers to both a score of 0 and 1.
Please describe your problem in more detail. It’ll help me understand it better and find a solution for you.
Hi
I would want a formula to sum the multiple cells only in case whereever it is mentioned as roll up.
MatchID Status Amount
12345. Roll up HERE I need to have the sum the amount of below two rows
12345. 100
12345. 100
Hello!
I am not sure I fully understand what you mean. Please describe your problem in more detail. Include an example of the source data and the result you want to get. It’ll help me understand your request better and find a solution for you. Thank you.
I'm trying to work our a formula to add times to different delivery methods. for example . if seafreight add 42 days to dispatched date. if Airfreight add 14 days to dispatched date.
any ideas
Hello!
I hope you have studied the recommendations in the tutorial above. If I understand your task correctly, the following formula should work for you:
=IF(B1="seafreight",A1+42,IF(B1="Airfreight",A1+14,""))
Thanks your so much
Hello,
I have a table with multiple columns - Gift, Type, Date, Year Since Gift & Exempted.
Under Type there is a 2 option dropdown menu. - Charity and BPR.
I have got the Year since gift to automatically calculate the years.
What I would like to be able to do is have the Exempt column show "yes" or "no" if the gift is exempt.
If the Type column shows "Charity" it is exempt, so the exempt column would need to show Yes.
If the Type column shows "BPR" and it has been more than 2 years in the years since gift column it would be exempt, so would need to show "Yes". If its not exempt, I would like the column to show "No".
This is the formula that I have used, but it does not work correctly.
=IF(OR(AND(F14="BPR",H14>2),OR(F14="Charity",H14>=0)),"Yes","No")
Please can you advise.
Thank you!
Hello!
If I understand your task correctly, the following formula should work for you:
=IF(OR(AND(F14="BPR",H14>2),AND(F14="Charity",H14>=0)),"Yes","No")
I hope this will help.
Hi,
Thank you for this!
I am however having the same problem. It works correctly for the BPR output but if I change the dropdown to Charity it does not change.
I was wondering if you could help me? I am trying to figure out what is wrong with this formula. I keeping getting the #VALUE! error.
=IF((AND(G2=OR("AF","SA"),(F2="R"))),"5.0%",IF(AND(G2=OR("AF","SA"),(F2=OR("S","F"))),"6.0%",IF((AND(G2=OR("NA","EU","AS","OC"),(F2=OR("R","S","F")))),"6.0%")))
Thanks in advance!
Hello!
Your formula is incorrect. Pay attention to how to write the AND and OR conditions correctly. See above Example 3 - Using IF with AND & OR functions.
G2=OR(“AF”,”SA”) - incorrect
OR(G2=“AF”,G2=”SA”) - correct
I was looking all over on how to code the IF AND OR formula for different shifts base on a time and your example on the grades showed me the way.
=IF(ISBLANK(D1),"",IF(AND(D1>=TIME(6,0,0),D1=TIME(14,0,0),D1<TIME(22,0,0)),"2nd Shift","Night Shift")))
There may be a better way, but this is working
Thanks
guys i've spend 5 hours. I just can't figure this out, so i seek help from you and god himself.
I want to make an IF statement between theese numbers.
7% $1,000.00
8% $10,000.00
9% $50,000.00
9.50% $100,000.00
how do I make if between 1000 and 9999 then show 7% or between 10000 and 49999 then show 8% etc.. etc...
all my love
Hello!
I hope you have studied the recommendations in the tutorial above. It contains answers to your question
=IF(A1>=100000,9.5%,IF(A1>=50000,9%,IF(A1>=10000,8%,7% ) ) )
Hope this is what you need.
Thx for your fast reply. I just figured it out my self.
the "=IF" functions does not work. I ahve to use an "=IF(And(" function.
so the code gonna look like this
=if(and(K14=F12,K14=F13,K14=F14,K14=F15,K14=F16,K14=F17,K14=F18),E18,"Forkert beløb i j14"))))))))
Thx for helping it's much appreciated
Hello!
Explain what exactly does not work. How does this new formula relate to your problem?
I have another great question which is even harder to figure out.
I got this cummulative calculations which starts with
5% of all up to 10,000.00 $
10% of all between 100001 and up to 20,000.00 $
12% of all between 20001 up to 50,000.00 $
etc. etc..
how do I make that calcualtion so it won't keeping make 5% of all after 10k but still SUM the all the differnet percentages?
thx for your time and help. how can I share your knowledge with the community?
Hello!
You have not described all the conditions and the expected result, but I think the following formula will suit you:
=MIN(A1,10000)*5% + MAX(0,A1-MIN(MAX(0,A1-20000),30000) - MAX(0,A1-50000)-10000)*10% + MIN(MAX(0,A1-20000),30000)*12% + MAX(0,A1-50000)*12%
I hope it’ll be helpful.
Is there a way to make this Countif statement work?
=COUNTIF(C11:C112,"Low", AND D11:D112,"Work in Progress")
Hello!
Unfortunately, without seeing your data it is difficult to give you any advice. I am assuming you have not one but several conditions to count. Therefore, I recommend using the COUNTIFS function. Read this detailed instruction.
I hope this will help, otherwise please do not hesitate to contact me anytime.
I want to have solution of the following, if some one can help me:
Cell A1 = Professional
Cell A26 = sum of figures from cell A2 to A25
I want to have results in A30 that if cell A1 is equal to "Professional" and results of A26 is less than or equal to 400 than it should display the results of A26 otherwise 400 should be there,
Hope anyone of you can understand my query
Naeem Sabir
Please can someone help me with an excel formula? I have a cell E6 which has a drop down (Not Applicable, Fully Implemented, Mostly Implemented, Partly Implemented and Not Implemented). I want cell E7 to output 100%, 100%, 75%, 50% and 0% when E6 is Not Applicable, Fully Implemented, Mostly Implemented, Partly Implemented and Not Implemented respectively.
Hello!
Use an IF function with nested conditions. You can find detailed instructions in this article.
If there is anything else I can help you with, please let me know.
Hi, i want determine the latest date for this:
If: a1=complete, c1=complete, e1=complete,g1=complete, i1=complete, if all of these are in "complete status" i want to get the latest date: b1=2/1/2020,d1=3/2/2020,f1=4/2/2020,h1=5/1/2020,j1=6/1/2020,j1=7/1/2020
Hello!
You can find the highest date according to your criteria using the MAXIFS function.
=MAXIFS(A1:D1,A2:D2,"Complete")
Hope this is what you need.
If you write 5 column like this
A.Name
B. Source (broker,ref and direct)
C .product value
D. commission %
E. Commission amount( need formuls this column)
1 ) if any broker(column B) sale 1 product
Get commission (product value* 2%)=
2 ) any existing buyer through his refrence sale 1 product to any customer
Get commission 3 types
* 1 st deal = 10k
* 2 nd deal = 20k
* 3 rd deal = 30k
And
3) if direct sale any product
Get 0 commision
How to codition formula in one cell
Hello!
Your task is not completely clear to me. Explain condition 2 using your table data as an example. Give an example of the source data and the expected result.
It’ll help me understand it better and find a solution for you.
Hi would you be able to help me with the below. I have 2 formulas that work separately however want to merge them into one formula.
=IF(OR(AND(SUM(W3:X3)>=100,Y3>=0), AND(SUM(W3:X3)<=100, Y3<=0)), "Yes", "No")
=IF(W3="","N/A", IF( X3= "", "N/A", IF(Y3="", "N/A")))
I would like to add into the first formula that if W3 or X3 or Y3 are blank, then it should return "N/A"
Hello
i have a list of names, scores, sex and statuses and here's my assignment:
if the "status" of the customer is "Faculty" then give it a value with "Dr. " plus a space plus First Name plus a space plus Last Name.
if the "status" of the customer is "student" and the "sex" is "M" then give it a value with "Mr. " plus space plus first name space plus last name
if the "status" of the customer is "student" and the "sex" is "F" then give it a value with "Ms. " plus a space plus first name plus space plus last name
please help me out with that one i am completely clueless on how to do it..
Hello!
Your question has already been asked here: https://www.ablebits.com/office-addins-blog/2014/12/03/excel-if-function-iferrror-ifna/comment-page-18/#comment-560805
Good morning Svetlana,
I really need some help on this,
How do i write a formula to convert every 0.30 to 1.
Assuming cell a1 contains 100, how do i count very 30 as 1.
I hope this makes sense and I really appreciate the assistance!!
Thank you in advance for the help!!
Kind regards,
Samuel
Hi Friends
Could you please help me to get the excel formula?
c11 = 50% of b11 or 100000, which one is lower
Thanks
Manik
Hello!
I recommend that you use the MIN function as described in this guide.
Hello, I am attempting to forecast employee availability based upon a singular calendar date.
Through conditional formatting I’ve created cells to be filled if they align with the start and end dates based upon a singular employee being able to forecast 10 different start and end dates columns.
I was able to get all 10 to feed into a singular cell based on a IF(OR(AND statement, however I will only get a 1 if true and 0 if false. For the entirety of the formula...
My end-state is that I would like to create a data validation that doesn’t allow any date to overlap any of the other dates.
My thought was if a cell yielded 1, great! If the cell went greater than 1, then the user would get an error message stating the date overlaps with another.
Unless you know a better solution? I am all ears, Grand Master Yoda :)
Please Help
Warm Regards, Michael
Hello!
Unfortunately, without seeing your data it is impossible to give you advice.
I'm sorry, it is not very clear what result you want to get. Could you please describe your task in more detail and send us a small sample workbook with the source data and expected result to support@ablebits.com? Please shorten your tables to 10-20 rows/columns and include the link to your blog comment.
We'll look into your task and try to help.
Hi can anyone spot the error in the following formula? Thanks.
=IF(C$7<=55,"37%", IF(55<C$7<=60,"26%", IF(60<C$765,"12.5%"))))
It gives either 37% (for 55) as outcome.
Hello!
If I got you right, the formula below will help you with your task:
=IF(C$7<=55,"37%",IF(AND(55
Hi
Can any one apply the formula for given 2 conditions please.
Condition-1
Marks 20 to 40
Marks 41 to 60
Marks 61 to 80
Marks 81 to 100
Eligible Marks 30
Score (Marks) 30
% of Marks 100
Award for 1500
Eligible Marks 30
Score (Marks) 35
% of Marks 117
Award for 2500
Condition-2
Marks 20 to 40
Marks 41 to 60
Marks 61 to 80
Marks 81 to 100
Eligible Marks 45
Score (Marks) 45
% of Marks 100
Award for 2000
Eligible Marks 45
Score (Marks) 55
% of Marks 122
Award for 3000
Hello!
Sorry, I do not fully understand the task. ould you please describe it in more detail? What result do you want to get? Thank you!
Condition:1
Marks >=20 & Marks =20 & Marks =41 & Marks =41 & Marks <=60
% Marks 110 & Above
Eligible for Rs.3000/- reward
Hello!
Perhaps you can help me. I am hoping to write a IF + AND statement with multiple results.
A171 is "2" and A1 >53 AND <71 is "0". Thanks!
Hello!
Please reread the article above, it covers your case completely.
What does the condition mean - A171 is “2”?
I wish to write fx where A1>71= hypytension, A153=71, "hypertension, IF(A1<=53, "hypotension, IF(A1=53, "normal"))))
However this does not work for me. Thanks
I wish to write fx where A1>71= hypytension, A153=71, "hypertension, IF(A1<=53, "hypotension, IF(A1=53, "normal"))))
However this does not work for me. Thanks
Sorry meant that I wish the span of normal to be between 53.
My initial thought was fx= IF(A1>=71, "hypertension, IF(A1<=53, "hypotension, IF(A1=53, "normal"))))
I have a condition kindly provide me the formula
upto 10 KM a company charges $20
above it per km a have additional charges is $2 per KM
if a person travel following km what was the formula
A B C D E F
1 18
2 10
3 24
Then what is the formula I put in B1