In Part 1 of our Excel IF function tutorial, we started to learn the nuts and bolts of the Excel IF function. As you remember, we discussed a few IF formulas for numbers, dates and text values as well as how to write an IF statement for blank and non-blank cells.

However, for powerful data analysis, you may often need to evaluate multiple conditions at a time, meaning you have to construct more sophisticated logical tests using multiple IF functions in one formula. The formula examples that follow below will show you how to do this correctly. You will also learn how to use Excel IF in array formulas and learn the basics of the IFEFFOR and IFNA functions.

In summary, there can be 2 basic types of multiple conditions - with AND and OR logic. Consequently, your IF function should embed an AND or OR function in the logical test, respectively.

- AND function. If your logical test contains the AND function, Microsoft Excel returns TRUE if
**all the conditions**are met; otherwise it returns FALSE. - OR function. In case you use the OR function in the logical test, Excel returns TRUE if
**any of the conditions**is met; FALSE otherwise.

To better illustrate the point, let's have a look at a few IF examples with multiple conditions.

Suppose, you have a table with the results of two exam scores. The first score, stored in column C, must be equal to or greater than 20. The second score, listed in column D, must be equal to or exceed 30. Only when both of the above conditions are met, a student passes the final exam.

The easiest way to make a proper formula is to write down the condition first, and then incorporate it in the logical_test argument of your IF function:

Condition: AND(B2>=20, C2>=30)

IF/AND formula:

`=IF((AND(C2>=20, D2>=30)), "Pass", "Fail")`

Easy, isn't it? The formula tells Excel to return "Pass" if a value in column C >=20 AND a value in column D >=30. Otherwise, the formula returns "Fail". The screenshot below proves that our Excel IF /AND function is correct:

In practice, a seemingly correct IF / AND formula may result in an error because of this specificity. For example, the below formula will return "Divide by Zero Error" (#DIV/0!) if cell A2 is equal to 0:

`=IF(AND(A2<>0,(1/A2)>0.5),"Good", "Bad")`

The avoid this, you should use a nested IF function:

`=IF(A2<>0, IF((1/A2)>0.5, "Good", "Bad"), "Bad")`

You use the combination of IF & OR functions in a similar way. The difference from the IF / AND formula discussed above is that Excel returns TRUE if **at least one** of the specified conditions is met.

So, if we modify the above formula in the following way:

`=IF((OR(C2>=20, D2>=30)), "Pass", "Fail")`

Column E will have the "Pass" mark if either the first score is equal to or greater than 20 **OR** the second score is equal to or greater than 30.

As you see in the screenshot below, our students have a better chance to pass the final exam with such conditions (Scott being particularly unlucky failing by just 1 point : )

More formula examples can be found in Excel IF OR functon.

In case you have to evaluate your data based on several sets of multiple conditions, you will have to employ both AND & OR functions at a time.

In the above table, suppose you have the following criteria to evaluate the students' success:

- Condition 1: column C>=20 and column D>=25
- Condition 2: column C>=15 and column D>=20

If either of the above conditions is met, the final exam is deemed passed, otherwise - failed.

The formula might seem tricky, but in a moment, you will see that it is not! You just have to express two conditions as AND statements and enclose them in the OR function since you do not require both conditions to be met, either will suffice:

`OR(AND(C2>=20, D2>=25), AND(C2>=15, D2>=20)`

Finally, use the above OR function as the logical test in the IF function and supply value_if_true and value_if_false arguments. As the result, you will get the following IF formula with multiple AND / OR conditions:

`=IF(OR(AND(C2>=20, D2>=25), AND(C2>=15, D2>=20)), "Pass", "Fail")`

The screenshot below indicates that we've got the formula right:

Naturally, you are not limited to using only two AND/OR functions in your Excel IF formulas. You can use as many logical functions as your business logic requires, provided that:

- In Excel 2016, 2013, 2010 and 2007, your formula includes no more than 255 arguments, and the total length of the formula does not exceed 8,192 characters.
- In Excel 2003 and lower, you can use up to 30 arguments and the total length of your formula shall not exceed 1,024 characters.

If you need to create more elaborate logical tests for your data, you can include additional IF statements in the value_if_true and value_if_false arguments of your Excel IF formulas. These multiple IF functions are called **nested IF functions** and they may prove particularly useful if you want your formula to return 3 or more different results.

Here's a typical example: suppose you want not simply to qualify the students' results as Pass/Fail, but define the total score as "*Good*", "*Satisfactory*" and "*Poor*". For instance:

- Good: 60 or more (>=60)
- Satisfactory: between 40 and 60 (>40 and <60)
- Poor: 40 or less (<=40)

To begin with, you can add an additional column (E) with the following formula that sums numbers in columns C and D:

`=C2+D2`

And now, let's write a nested IF function based on the above conditions. It's considered a good practice to start with the most important condition and make your functions as simple as possible. Our Excel nested IF formula is as follows:

`=IF(E2>=60, "Good", IF(E2>40, "Satisfactory", "Poor "))`

As you see, just one nested IF function is sufficient in this case. Naturally, you can nest more IF functions if you want to. For example:

`=IF(E2>=70, "Excellent", IF(E2>=60, "Good", IF(E2>40, "Satisfactory", "Poor ")))`

The above formula adds one more conditions - the total score of 70 points and more is qualified as "Excellent".

For more information about Excel IF with multiple conditions, please see How to use nested IF in Excel.

Like other Excel functions, IF can be used in array formulas. You may need such a formula if you want to evaluate every element of the array when the IF statement is carried out.

For example, the following array SUM/IF formula demonstrates how you can sum cells in the specified range based on a certain condition rather than add up the actual values:

`=SUM(IF(B1:B5<=1,1,2))`

The formula assigns a certain number of "points" to each value in column B - if a value is equal to or less than 1, it equates to 1 point; and 2 points are assigned to each value greater than 1. And then, the SUM function adds up the resulting 1's and 2's, as shown in the screenshot below.

Earlier in this tutorial, we've discussed a few IF formula examples demonstrating how to use the Excel IF function with logical functions AND and OR. Now, let's see what other Excel functions can be used with IF and what benefits this gives to you.

When discussing nested IF functions, we wrote the formula that returns different ranking (Excellent, Good, Satisfactory or Poor) based on the total score of each student. As you remember, we added a new column with the formula that calculates the total of scores in columns C and D.

But what if your table has a predefined structure that does not allow any modifications? In this case, instead of adding a helper column, you could add values directly in your If formula, like this:

`=IF((C2+D2)>=60, "Good", IF((C2+D2)=>40, "Satisfactory", "Poor "))`

Okay, but what if your table contains a lot of individual scores, say 5 different columns or more? Summing so many figures directly in the IF formula would make it enormously big. An alternative is embedding the SUM function in the IF's logical test, like this:

`=IF(SUM(C2:F2)>=120, "Good", IF(SUM(C2:F2)>=90, "Satisfactory", "Poor "))`

In a similar fashion, you can use other Excel functions in the logical test of your IF formulas:

**IF and AVERAGE:**

`=IF(AVERAGE(C2:F2)>=30,"Good",IF(AVERAGE(C2:F2)>=25,"Satisfactory","Poor "))`

The formulas retunes "Good" if the average score in columns C:F is equal to or greater than 30, "Satisfactory" if the average score is between 29 and 25 inclusive, and "Poor" if less than 25.

**IF and MAX/MIN:**

To find the highest and lowest scores, you can use the MAX and MIN functions, respectively. Assuming that column F is the total score column, the below formulas work a treat:

MAX: `=IF(F2=MAX($F$2:$F$10), "Best result", "")`

MIN: `=IF(F2=MIN($F$2:$F$10), "Worst result", "")`

If you'd rather have both the Min and Max results in the same column, you can nest one of the above functions in the other, for example:

`=IF(F2=MAX($F$2:$F$10) ,"Best result", IF(F2=MIN($F$2:$F$10), "Worst result", ""))`

In a similar manner, you can use the IF function with your custom worksheet functions. For example, you can use it with the GetCellColor / GetCellFontColor functions to return different results based on a cell color.

In addition, Excel provides a number of special IF functions to analyze and calculate data based on different conditions.

For example, to count the occurrences of a text or numeric value based on a single or multiple conditions, you can use COUNTIF and COUNTIFS, respectively. To find out a sum of values based on the specified condition(s), use the SUMIF or SUMIFS functions. To calculate the average according to certain criteria, use AVERAGEIF or AVERAGEIFS.

For the detailed step-by-step formula examples, check out the following tutorials:

- How to use the COUNTIF in Excel
- Using Excel COUNTIFS and COUNTIF with multiple conditions
- SUMIF in Excel - formula examples to conditionally sum cells
- How to use Excel SUMIFS and SUMIF with multiple criteria

You already know a way to spot blank and non-blank cells using the ISBLANK function. Microsoft Excel provides analogous functions to identify text and numeric values - ISTEXT and ISNUMBER, respectively.

Here's is example of the nested Excel IF function that returns "Text" if cell B1 contains any text value, "Number" if B1 contains a numeric value, and "Blank" if B1 is empty.

`=IF(ISTEXT(B1), "Text", IF(ISNUMBER(B1), "Number", IF(ISBLANK(B1), "Blank", "")))`

Sometimes, you can achieve the desired result by embedding the IF statement in some other Excel function, rather than using another function in a logical test.

Here's another way how you can use the CONCATINATE and IF functions together:

`=CONCATENATE("You performed ", IF(C1>5,"fantastic!", "well"))`

I believe you hardly need any explanation of what the formula does, especially looking at the screenshot below:

Both of the functions, IFERROR and IFNA, are used to trap errors in Excel formulas and replace them with another calculation, predefined value or text message. In earlier Excel versions, you can use the IF ISERROR and IF ISNA combinations instead.

The difference is that IFERROR and ISERROR handle all possible Excel errors, including #VALUE!, #N/A, #NAME?, #REF!, #NUM!, #DIV/0!, and #NULL!. While IFNA and ISNA specialize solely in #N/A errors.

Here is the simplest example of the IFERROR formula:

`=IFERROR(B2/C2, "Sorry, an error has occurred")`

As you see in the screenshot above, column D displays the quotient of the division of a value in column B by a value in column C. You can also see two error messages in cells D2 and D5 because everyone knows that you cannot divide a number by zero.

In some cases, however, you may not want to trap all errors, but rather test the condition causing a specific error. For example, to replace a divide by zero error with your own message, use the following IF formula:

`=IF(C2=0, "Sorry, an error has occurred", B2/C2)`

And that's all I have to say about using the IF function in Excel. I thank you for reading and hope to see you on our blog next week!

Excel formulas
CSV
Excel functions
Print
Financial functions
Vlookup
Merge data in Excel
SumIf
CountIf
Excel Compare
If statement
Excel Charts
Pivot Table
Conditional formatting
Excel formatting
Excel duplicates
Excel date
Excel tips
Excel macro
Outlook
Google Sheets
Outlook duplicates
Outlook templates

## 2,813 responses to "Excel IF statement with multiple AND/OR conditions, nested IF formulas, and more"

not sure why, but the post is not displaying the entire formula as I am pasting it,

=IF(AND(B25>A15,B25A16,B25A17,B25A18,B25A19,B25A20,B25*C16)

Need help with formula

if D3=x,v4>120,"RED", "YELLOW"),If D4="Active", "BLANK")

trying to day if D3 = Active and V4 Greater than 120 then RED otherwise Yellow. But if D3 is not equal to Active then leave it blank.

Thanks

Anna

Hello Anna!

If I understand your task correctly, the following formula should work for you:

=IF(AND(D3="Active",V4 > 120),"RED", IF(D3 <> "Active","","YELLOW"))

I hope it’ll be helpful.

lets says =IF(AND(R4>S4,S4>T4,T4>U4,U4>V4,V4>W4,W4>X4),"UP&DOWN",IF(AND(R4<S4,S4<T4,T4<U4,U4<V4,V4<W4,W4<X4),"PASS","NOT GROWN"))

up&down cannot be used idk why,the circumstance was r4 to w4 just one of them going down its gonna say up&down

please help

Hello!

Please describe your problem in more detail. It’ll help me understand it better and find a solution for you. Thank you.

=IF(OR(AND(AA2="Canada",Z2="Vancouver"),K2=1,k2=9),M2*5,M2=M2)

how do i solve the problem below using the nested OR & AND function

Increment the backers-count by 5 if:

The launched_at_month is January OR September

The city is Vancouver AND the country_trimmed is Canada

If these conditions are not met, the backers-count stays the same.

Hello!

If I understand your task correctly, the following formula should work for you:

=IF(AND(AA2="Canada",Z2="Vancouver", OR(K2=1,K2=9)),M2*5,M2)

I hope it’ll be helpful.

IF(OR(D7="N/A", AND(D7="0", F7="Yes")), "0","1")

I need the value of this formula to be 0 if, either the value of D7 is N/A or if the value of D7=0 AND F7 is Yes.

Am I using the correct formula for this condition?

Hello Sanjay!

The formula is spelled correctly. However, if you do not write numbers as text, then you do not need to use quotation marks.

=IF(OR(D7="N/A", AND(D7=0, F7="Yes")), 0,1)

Thanks Alexander Trifuntov.

It worked. I spent a lot of time on this and finally your suggestion did the trick.

Appreciate the quick turnaround.

Could you help with this data validation custom formula? This formula works:

=OR(D10="X", D10="B") but when I add an additional condition, it doesn't work. My new conditions are:

CONDITION 1: D10="X" OR

CONDITION 2: D10="B" AND E10="55"

I have tried several combinations of OR and AND formula including the sample here on the this website but none works for me. I appreciate your help. Thank you very much.

Hello Montey!

If I understand your task correctly, the following formula should work for you:

=IF(OR(D10="X", AND(D10="B",E10=55) ),TRUE,FALSE)

I hope this will help, otherwise please do not hesitate to contact me anytime.

Hi Alexander,

It works! I just removed the IF function as my condition needs to be always true to allow data entry in another cell. Thank you very much!

If month is 202005 or 202006, and staus is hiring, then vlookup based on business name else 0

if(or('Org moves'!CO2=202005,'Org moves'!CO2202006) And('Org moves'!CP2="Hiring"),vlookup(Walk!B7,'Org moves'!AB:CQ,68,0),"0")

i used this. please help resolving error

Hello!

I could not check your formula on real data. Try this formula

=IF(AND(OR('Org moves'!CO2=202005,'Org moves'!CO2=202006), ('Org moves'!CP2="Hiring")), VLOOKUP(B7,'Org moves'!AB:CQ,68,0),"0")

I hope this will help, otherwise please do not hesitate to contact me anytime.

Need help with a formula !

My cell contains the following value (95% Cotton, 5% Elastane)

I need to set a condition that if my cell has the value "cotton" and the percentage before the string(cotton) is >= 50% it should return true if not it should return false.

Here are a few samples of how the values could be populated.

90% Cotton, 8% Polyamide, 2% Elastane

95% Baumwolle (Bio), 5% Elasthan

90% Cotton, 8% Polyamide, 2% Elastane

In whatever scenario if the cell has value with "cotton" in it and the value before the string is >= 50% , it should return true.

Thank you

Hello Mustafa!

If I understand your task correctly, the following formula should work for you:

=IF(IFERROR(IFERROR(MID(A10,SEARCH("Cotton",A10,1)-4,2), MID(A10,SEARCH("Cotton",A10,1)-3,1)),0) >= 50,TRUE,FALSE)

I hope this will help, otherwise please do not hesitate to contact me anytime.

I'm so stuck!! I'm as blank as the sky !!

if A3 has "New" and B3 has "CT" then put value of H3 in Cell? ... But with the drop down I need

if A3 has "New" and B3 has "SUS" then put value of H4 in Cell?

This Is probably simple but i'm tired but need it :( Thank guys n Girls :)

Hello David!

If I understand your task correctly, the following formula should work for you:

=IF(AND(A3="New",B3="CT"),H3, IF(AND(A3="New",B3="SYS"),H4,0))

I hope this will help, otherwise please do not hesitate to contact me anytime.

Hello devid,

I am trying to calculate a cell is eligible or not .like if a cell contain yes,or date then and then he is eligible otherwise no..how to create formula

Hello,

Looking to use conditional formatting to turn a row Green if the word "TEST" is in any cell in that row twice

Row should turn RED if the word test is only there once

Thank You!

Meaning, two cells in that row contain the word TEST

Hello Mindy!

Use conditional formatting as described in these manuals.

https://www.ablebits.com/office-addins-blog/2014/08/07/relative-absolute-cell-references-excel-conditional-formatting/

https://www.ablebits.com/office-addins-blog/2014/06/10/excel-conditional-formatting-formulas/

Apply the condition formula

=COUNTIF($A50:$Z50,"TEST")>1

I hope this will help

in excel formula if a1 is between 1 to 5 then multiple 2.5 and if A1 is between 6 to 9 then multiply from 2

Hello Sydney!

If I understand your task correctly, the following formula should work for you:

=IF(AND(A1 > 1,A1 < 5),A1*2.5,IF(AND(A1 > 6,A1 < 9),A1*2,A1))

I hope it’ll be helpful.

Dear Alex,

Thank you so much. It answered my question and its perfectly working.

how can i make a formula using grading system (5,4,3,2,1) in date submission

5 for earlier than due date by 2 or more days

4 for earlier than due date by 1 day

3 for due date

2 for later than due date by 1 day

1 for later than due date by 2 or more days

this is my sample formula i made, but seems not to get the grade 2 or somethings wrong i think, pls help

=IF(H17<=F17-2,"5",IF(H17F17,"2",IF(H17>=F17,"1")))))

Hello Melvin!

If I understand your task correctly, the following formula should work for you:

=IF((F17-H17) >=2,5,IF((F17-H17) >=1,4,IF(F17=H17,3, IF((F17-H17)>-2,2,1))))

Hope this is what you need.

My goal is to know when to Water my lawn. I am trying to nest and or in an if function.

So on even days if the week day is Monday, Tuesday Friday or Saturday then I water.

I got the formula to work but on August first - - it switched to odd days.

this is the formula I used in the first cell for June 1st =IF(AND(OR(WEEKDAY(A1,1)=2,WEEKDAY(A1,1)=3,WEEKDAY(A1,1)=6,WEEKDAY(A1,1)=7), AND(MOD(A1,2)=0)), "Water", " ") --- Where did I go wrong?

6/1 Monday

6/2 Tuesday Water

6/3 Wednesday

6/4 Thursday

6/5 Friday

6/6 Saturday Water

6/7 Sunday

6/8 Monday Water

6/9 Tuesday

6/10 Wednesday

6/11 Thursday

6/12 Friday Water

6/13 Saturday

6/14 Sunday

6/15 Monday

6/16 Tuesday Water

6/17 Wednesday

6/18 Thursday

6/19 Friday

6/20 Saturday Water

6/21 Sunday

6/22 Monday Water

6/23 Tuesday

6/24 Wednesday

6/25 Thursday

6/26 Friday Water

6/27 Saturday

6/28 Sunday

6/29 Monday

Hi,

I'm having a problem with writing the formula for the following with 3 conditions:

-if column A says yes , and the value in column B=80 then I need to multiply Value in B by 0.30

if column A says no , then I need to multiply Value in B by 0.45

Your help will be much appreciated

Hello Aneta,

Please try the following formula:

=IF(AND(A1="Yes",B1=80), B1*0.3,IF(A1="No",B1*0.45,B1))

I hope it’ll be helpful.

hi ,

Thank you, that's amazing it works , I have one last question.

I need to write the formula for the following but the one I did below it does not work:

=IFS(AND(G9="yes",F9=80),F9*0.3),IF(G9="no",F9*0.45)

Here are 3 conditions:

1.IF G9 says yes and F9=80, theN multiply F9*0.30

3.if G9 says no, then multiply F9 * 0.45

Your help would be much appreciated. Thank you Alexander

Hello Aneta!

Why are you asking the same question twice? Just change the cell addresses in the formula above.

Sorry, I'm not sure what happened there, I have one extra condition to enter

IF G9 says yes and F9 I greater or equal to 80 , then I need to multiply F9*0.30, if G9 says yes and F9 is lower than 80 then multiply F9* 0.15, if G9 says yes then multiply F9 by 0.45

I got help with a formula last month and need to add some additional variables to it. typed at end of my comment is the formula i have so far, but need to also add somewhere into the below "if AJ6 = CONUS AND D6 IS NOT 12, AND I6 IS "D", then return 10 and if I6 is "C", then return 12" everything else below remains the same. I'm not sure if this is even possible.

=IF(Aj6="Conus",IF(AND(D6=12, SUM(IF(G6={9820580,159384},1,0))=1),17, IF(OR(D6 < 12,AND(D6=12,G6=6620363)),15,"")), IF(AJ6="Oconus",28,""))

Hello Jessica!

Replace the "" symbol in your formula

=IF(AH1="Conus", IF(AND(D1=12,SUM(IF(G1={9820580,159384},1,0))=1),17, IF(OR(D1 < 12,AND(D1=12,G1=6620363)),15,"")), IF(AH1="Oconus",28,""))

with these conditions:

=IF(AND(AJ6="Conus",D6<>12,I6="D"), 10,IF(I6="C",12,""))

The result is a new formula:

=IF(AH1="Conus", IF(AND(D1=12,SUM(IF(G1={9820580,159384},1,0))=1),17, IF(OR(D1 < 12,AND(D1=12,G1=6620363)),15,"")), IF(AH1="Oconus",28,IF(AND(AJ6="Conus",D6<>12,I6="D"),10, IF(I6="C",12,""))

))

I hope it’ll be helpful.

That didn't work :( "C" and "D" values in column I for CONUS are still returning 15 instead of 12 and 10

what if i concatenate the ranking (ei. A,B,C,D) with Conus or Oconus. Then i would just need a formula that says:

if A1=ACONUS or BCONUS and D1 is anything but 12, return 15

if A1=CCONUS and D1 is anything but 12, return 12

if A1=DCONUS and D1 is anything but 12 return 10

if ACONUS, BCONUS, CCONUS, DCONUS and D1=12, return 17

if A1= AOCONUS or BOCONUS, return 34

if A1 = COCONUS or DOCONUS, return 32

if 1-2 range answer multiplies by 2,500

3-4 multiplies by 3,000

5-6 multiplies by 4,500

what is the formular

Hello Bridget!

If I understand your task correctly, the following formula should work for you:

=IFERROR(CHOOSE(R1,2500,2500,3000,3000,4500,4500)*Q1,Q1)

or

=IF(OR(R1=1,R1=2),Q1*2500,IF(OR(R1=3,R1=4),Q1*3000,IF(OR(R1=5,R1=6),Q1*4500,Q1)))

Hope this is what you need.

Hi i have question regarding multiple condition:How to get system stock May'20 column by applying function IF.please suggest

example:

Customer ; Stock to be consumed; Schedule May'20 ;System stock (May'20)

B 602 560 42

C 545 YTR −

D 1 0 1

E 27 0 27

G 120 150 30

H 36 YTR -

Thanks in advance

Hello!

You have not specified which system stock you want to receive on May 20 - general or by customer. But in any case, I recommend using the SUMIFS function. Read more in this Excel SUMIFS guide.

I hope this will help, otherwise please do not hesitate to contact me anytime.

Hi, I really need some help please.

I need the end result to be Yes or No.

For yes, the criteria should be:

F2 must be greater than 2

G2 must be False

S2 must be False

Q2 must not contain the words Matter Data

=IF((AND(F2>2,G2="False",S2="False",Q2Matter Data)),"Yes","No")

=IF((AND(F2>2,G2="False",S2="False",Q2Matter Data)),"Yes","No")

...Sorry, slight typo but still doesn't work :(

Hello Ami!

If I understand your task correctly, the following formula should work for you:

=IF(AND(F2>2,G2="FALSE",S2="FALSE", NOT(ISNUMBER(FIND("Matter Data",Q2,1)))),"Yes","No")

Read how to use the IF function with text values here.

I hope this will help, otherwise please do not hesitate to contact me anytime.

HI! I'm trying to say if B2=sat or sun AND g2=As Scheduled value should be $5 if not $0 so the conditions to get $5 are it has to be sat or sun AND as scheduled

so far I've tried

=IF(ISTEXT(B9),"Sat",IF(ISTEXT(B9),"Sun",IF(ISTEXT(G9),"As Scheduled","$5")))

=IF(AND(B2="Sun",B2="Sat",G2="As Scheduled"),"$5","$0")

I'm driving my self mad! Hope you can help! Thanks!

Hello Mary!

If I got you right, the formula below will help you with your task:

=IF(AND(OR(B2="Sat",B2="Sun"), G2="As Sheduled"),"$5","$0")

I hope it’ll be helpful.

I am working on an employee schedule. I have start times that I want to turn into Open, Close on another section of the sheet. I have that working with the =IF(ISNUMBER(SEARCH("8a",B4)),"Open","Close")

However, I have OFF on some days and I need it to show OFF on the other Section with the Open,Close

This is the formula I came up with but it gives a Value Error

=IF(ISNUMBER(SEARCH("8a",B4)),"Open","Close") IF(B4:G13 = "OFF", "OFF", "")

Hello David!

If I got you right, the formula below will help you with your task

=IF(ISNUMBER(SEARCH("8a",B4)),"Open", IF(B4="OFF","OFF","Close"))

I hope this will help, otherwise please do not hesitate to contact me anytime.

That fixed my formula. Thank you

Hello All,

I am looking for a formula

if the value is equal or less that one , the it should be calculated the 50%

something like - IF(K13<=1(K13+K13*50/100)

And if the value is greater than 1 but less or equal to 5 , then add 40%

Need both in a single line

Hello!

The formula below will do the trick for you

=IF(K13 <= 1,K13*0.5,IF(AND(K13 <= 5,K13 > 1),K13*1.4,K13))

I hope it’ll be helpful.

Hi, I'm beginner. I have a one query as below posted.

Q- A builders merchant gives 10% discount on certain product lines.

The discount is only given on products which are on Special Offer, when the Order Value is $1000 or above.

[use IF and AND functions]

Product Special Offer Order Value Discount Total

Product 1 Yes 1,500 150 1,350

Product 2 No 1,300 130 1,170

Product 3 Yes 500 - 500

Product 4 Yes 2,800 280 2,520

How formulation i should follow for above case.

Hello Jay!

If I understand your task correctly, the following formula should work for you

=IF(AND(B10="Yes",C10*D10>1000), C10*D10*0.9,C10*D10)

I hope this will help, otherwise please do not hesitate to contact me anytime.

Hi Again, the previous formula didn't return the needed updated results. So i wondered if i concatenate the ranking (ei. A,B,C,D) with Conus or Oconus. Then i would just need a formula that calculates the below requirements, can you please help?:

if A1=ACONUS or BCONUS and D1 is anything but 12, return 15

if A1=CCONUS and D1 is anything but 12, return 12

if A1=DCONUS and D1 is anything but 12 return 10

if ACONUS, BCONUS, CCONUS, DCONUS and D1=12, return 17

if A1= AOCONUS or BOCONUS, return 34

if A1 = COCONUS or DOCONUS, return 32

Hello iam looking for a formula for this, if A1=A2,B1=B2,M1=M2 then it is a "True Duplicate" otherwise "NO" the result "True Duplicate" or "NO" is supposed to show up in both rows

Please help

Hello Penny!

Write this formula in the cells in which you want to see messages

=IF(AND(A1=A2,B1=B2,M1=M2),"True Duplicate","No")

I hope my advice will help you solve your task.

Hello All,

I am trying to get these three conditional "follow up status" from the variables "QA=1 means Followed Up and QA=2 means Not Followed Up" and PZ2=Estimated Follow up Date. But I still can not find the right and correct calculation. So may I get any help for the solution?

=IF(AND(QA=1, PZ2<"5/31/2020"),"Followed up", IF(AND(QA=2, PZ2"6/1/2020"),"Waiting for follow up")))

Hello All,

I am trying to get these three conditional "follow up status" from the variables "QA=1 means Followed Up and QA=2 means Not Followed Up" and PZ2=Estimated Follow up Date. But I still can not find the right and correct calculation. So may I get any help for the solution?

Please ignore the first one.

=IF(AND(QA=1, PZ2<"5/31/2020"),"Followed up", IF(AND(QA=2, PZ2"6/1/2020"),"Waiting for follow up")))

Hello Dev!

To check the condition with the date, use the expression PZ2 < DATE (2020,5,31) instead of PZ2 < "5/31/2020"

In addition, QA cannot be a reference to a cell. Maybe you wanted to write QA1? Or is it a named range?

I hope this will help, otherwise please do not hesitate to contact me anytime.

Dear Alexander,

As you suggested I tried adding "DATE" like this but still I couldn't get the right/correct solution. Could you have any next way and right way to solve this one?

=IF(AND(QA2>0, PZ2<DATE(2020,5,31)),"Followed up", IF(AND(QA2=2, PZ2DATE(2020,6,1)),"Waiting for follow up")))

Thank you very much!

Dear Alexander,

As you suggested I tried adding "DATE" like this but still I couldn't get the right/correct solution. Could you have any next way and right way to solve this one?

=IF(AND(QA2>0, PZ2<DATE(2020,5,31)),"Followed up", IF(AND(QA2=2, PZ2DATE(2020,6,1)),"Waiting for follow up")))

Dear Dev!

Your answer is not entirely clear to me. I will try to find a solution, but more information is needed. What is the mistake in your opinion? Give an example of the source data and the expected result. It’ll help me understand it better and find a solution for you.

I suggest this version of the formula

=IF(AND(QA2 > 0,PZ2 < DATE(2020,5,31)),"Followed up",IF(AND(QA2=2,PZ2 < DATE(2020,6,1)),"Waiting for follow up","0"))

Thank you.

Dear Alexander,

Thank you for your quick responses on my issue. I solved my issue with your reference using the function;

=IF(AND(ISNUMBER(S2)),"Followed up",IF(AND(QA2=2,PZ2<DATEVALUE("5/31/2020")),"Follow up missing","Waiting for follow up"))

Dear Alexander,

This the final I used function. Thank you for good responses.

=IF(AND(QC3=1), "Followed up", IF(AND(QC3=2,QB3<DATEVALUE("5/31/2020")), "Follow up missing", "Waiting for follow up"))

Happy!!!

Hello Alexander,

You give great hacks. Please guide me in one condition.

I want to mark special present (CV) to 2000 employee for 1-17 May 2020. However, in the excel sheet there might be already P (Present), or Y (Half Day) status for employee and remaining cells as blank. I want to ensure that i give maximum 14 CV attendance in blank cells. Rest cells with value "P" and "Y" to remain unchanged. Please guide. I have made the below formula:

=IF(OR(D1="P",D1="Y",D1="R"),D1,"PL")

However, i am not able to stop formula from giving CV beyond 14 times.

Please guide.

Thanks in advance.

Hello Ankur!

I’m sorry but your task is not entirely clear to me.

For me to be able to help you better, please describe your task in more detail. There is no CV in your formula. Do you want to record CV no more than 14 times in the cells for your employees? Then you need to use the COUNTIF function. Please let me know in more detail what you were trying to find, what formula you used and what problem or error occurred. In that case I will try to help you.

My Bad. Let me again explain my question to you:

I want to mark special present (CV) to 2000 employee for 1-17 May 2020. Out of these 2000 employees many might have worked also and might have got the real attendance. However, in the attendance (excel) sheet there might be cells with P (Present), R (Rest) or Y (Half Day) status for employee and remaining cells as blank (Absent). I want to ensure that i give maximum 14 CV attendance in blank cells (from B1 to R1). Rest cells with value "P", "Y" & "R" to remain unchanged. Please guide. I have made the below formula:

=IF(OR(D1="P",D1="Y",D1="R"),D1,"CV")

However, i am not able to stop formula from giving CV beyond 14 times.

Please guide.

For now, when i am using this formula, the result comes as "CV" for all the blank cells till R2 (that is 17th May). SO the condition of stopping CV after 14 days is not fulfilled. I want to ensure that while using this formula, i do not give "CV" attendance more than 14 times.

Thanks in advance.

Regards

Hello!

You can use the data validation tool to limit the number of CV values. Select the range B1: R1 and use the formula = COUNTIF ($ B1: $ R1, "CV") <15 to check the data.

You cannot enter your CV more than 14 times.

Read more about data validation here.

If you use the formula to automatically fill in the values, then in cell B1 you can write the formula

=IF(COUNTIF($A1:A1,"CV") < 15,"CV","")

Then copy it to the right along the line. Not more than 14 CVs will be recorded.

Hello,

I need a formula to calculate incentive on sale.

Creiteria - if sale(D3) is less than 1.51L the incentive is equal to same figure in % (1.51%), if the sale is 1.52L then the incentive is 1.52%, up to 4.99L same percentage (4.99%) and above 5L the incentive is 5% flat.

Please do the needful.

Thank you

Hello!

If you use your conditions, you get a very simple formula.

=IF(D3 < 5,D3*D3/100,D3*0.05)

Hello,

Sorry.I need a formula to calculate incentive on sale.

Creiteria - if sale(D3) is less than 1.51L the incentive is 0. if the sale is above 1.51L the incentive is equal to same figure in % (1.51%), if the sale is 1.52L then the incentive is 1.52%, it continues up to 4.99L same percentage (4.99%) and above 5L the incentive is 5% flat.

Please do the needful.

Thank you

I have a multi-layer problem set, if anyone can help.

This is a data of around 50k Rows. So i have 2 rows. Row A contains item ordered, Row B has timestamps. If i want to calculate the item wise time gaps, how do i go about it? So for example:

Row A: Row B:

Dell Laptop 11:23:04

Mouse 11:39:00

Snickers 12:45:01

Dell Laptop 12:49:08

Dell Laptop 12:51:46

Mouse 12:45:00

I need Row C to show time difference between the next sale of Dell Laptop and first sale, time gap between then third sale of Dell Laptop and second sale.Same goes with Mouse, Snickers, etc

so Row C1 should ideally be (12:49:08-11:23:04) = 01:26:04

C2 (12:45:00-11:39:00) = 01:06:00

and so on. The gaps should calculate only time difference of items sold for only those particular items.

Complicated for me. Would appreciate the help thanks.

Hello!

If in your table the first row is the heading, column A contains the goods, column B contains the time of sale, then in cell C2 write down the formula

=IF(INDEX($B$1:B1, LARGE(IF($A$1:A1=A2,ROW($A$1:A1),1),1))=0,"", B2-INDEX($B$1:B1,LARGE(IF($A$1:A1=A2,ROW($A$1:A1),1),1)))

I hope this will help, otherwise please do not hesitate to contact me anytime.

=IF((AND(I13=,I22=0,I29=0,I30=0),"0.00%",SUM(I13:I35)/SUM(K13:K35)))

is this possible?

Hello!

Perhaps you wanted to write down the formula

=IF(AND(I13=0,I22=0,I29=0,I30=0),"0.00%", SUM(I13:I35)/SUM(K13:K35))

I have product names in multiple columns and marked the customer name and quantity they ordered in rows. Now I want a different sheet with customer name, quantity and name of product customer ordered. is there a formula to bring the name and quantity of the product customer ordered in columns if the quantity is >= to 0.5.

I have used IF formula and it works for just one column. How do I go about giving multiple commands to have the result as in below in one cell?

2 Apples, 1 Orange, 5 mangoes

Hello!

I think the article "How to Vlookup in rows and columns (two-way lookup)" will be useful to you.

Dear All,

I require to find three successive cell data A, WO, A in multiple rows in a single page.Then I have to replace any cell data of my choice based on the condition met.

For eg. the following shows multiple successive cell data present in a sheet.

P A WO A

If successive cells are A WO A respectively, then I Have to replace "WO" with "A"

Please solution

Hello!

If I understand you correctly, some values are written in several cells. You want to change some of them using a formula with the IF function. But an Excel formula can only change the value of the cell in which it is written. In your case, you need to use VBA.

Dear Alexander

please help me with this.

I need a formula that can return the highest value in a group of Data.

let say

A1=D-300 B1=1 C1=1

A2=D-300 B2=1 C2=2

A3=D-300 B3=2 C3=1

I need a formula that can take into consideration the value in column A and B (even if column A has the same value and column B has different value) and return the highest value in column C. Such that the result will read

D-300 FOR 1 = 2

D-300 FOR 2 = 1

I did not quite understand what result you want to get (number, text, or something else). But I think that this formula will be useful.

To find the value in column A that matches the maximum value in column B, use the formula

=INDEX(A1:A37,MATCH(MAX(B1:B37),B1:B37,0))

If Column A has 3 same values i.e 1,1,1 and column B has three different values i.e A,B,C and column C also have three different values P,Q,R so column D should display only Values which are available for A in column C i.e P.

A B C D(Formula)

1 A P P

1 B Q P

1 C R P

2 A L L

2 B M L

2 C N L

Hello Sir,

Need your help to create formula for this.

i am unable to merge two formulas

=IF(F2<=1000,IF(G2=1,2499,IF(F21000,F2<=1800),IF(G2=1,2999,IF(G2=2,1999,"Invalid detail")))

if i write this formula in one column then it only gives result of first formula condition.

Hello!

I’m sorry but your task is not entirely clear to me. For me to be able to help you better, please describe your task in more detail. Please specify what you were trying to find, what problem or error occurred. The formula you wrote is incorrect. This may be a copy error. Give an example of the source data and the expected result.

It’ll help me understand it better and find a solution for you. Thank you.

Hello Sir,

I need you help for below situation:

In column A there are Fruit names, in column B Purchase dates, in column C values are Open or Closed and in Column D Today's date is mentioned. Please help me generate a formula so that it meets below condition:

If Fruit names are either Apple, Mango or Grapes and if Purchase dates is less than Today's date and in column C value is Open, then result should be 1 else 0.

Thanks,

Klywin

Hello Klywin!

If you apply the IF function to many conditions, the formula will be very large and complex. I recommend using this formula:

=SUM(IF(A1={"Apple","Mango","Gapes"},1,0)) * (--(B1<TODAY()) * (--(C1="Open")))

I hope this will help, otherwise please do not hesitate to contact me anytime.

Hi;

I need some advise for this situation :

Any advise how would the formula looks like for multiple conditions

Conditions:

IF number<=5,and size <= 10 return "Small"

IF number<=10,and size <= 10 return "Upsize"

IF number<=10,and size <= 20 return "Upsize"

IF number<=15 and size <= 30 return "Large"

IF number= 30 return "Upsize"

IF number= 30 return "Upsize"

Hello!

The article above details how to use IF nested functions.

You can use something like this

=IF(AND(A1<=5,B1<=10),"Small", IF(AND(A1<=10,B1<=10),"Up", IF(AND(A1<=10,B1<=20),"Up", IF(AND(A1<=15,B1<=30),"large", IF(A1=30,"Up","")))))

1st set of data Input data Result data

1 4 1 4 6 1 9 1

2 6 3 2 3

9 9 4 9

4 6

I have the data in 3 columns,named as "first set of data". If I enter the secondary data called as "input data" How I can design the formula to get the result data according to mentioned in result data? Any body can help me please.

Hello!

I’m sorry but your task is not entirely clear to me. For me to be able to help you better, please describe your task in more detail. Please specify what you were trying to find, what formula you used and what problem or error occurred. Give an example of the source data and the expected result.

It’ll help me understand it better and find a solution for you. Thank you.

=IF(AND(C10="upendra",C11>=70%),"yes",IF(AND(C10=" vivek",C11>=60%),"yes"," no"))

Hello,

I have three different strings(Gender(Male/Female), Score and Productivity.

My task is to tel that if it is Male and score is more than 70% and productivity is more than 0.5 it is a good boy student, otherwise it is a good girl student. How to make that if one of conditions are not met it would leave blank or N/A?

I have tried something like this: If(OR(And(B2="Female", I2>70%, G2>0.5)),"Good girl student", "Good boy student").

Hello Dom!

Specify your conditions. According to you, "if it is Male and score is more than 70% and productivity is more than 0.5 it is a good boy student, otherwise it is a good girl student." What does "otherwise" mean? And if it is Male and score is less than 70 % and productivity is less than 0.5 it is a good girl student? It suits your conditions.

I am sorry for confusing you,

I have four columns: Gender(there it is written Male and Female), than Score(Percent of score written), Productivity(number written) and empty column named(Good boy student/good girl student)

The task is to make formula which checks if it is a male of female, than if the score is more than 70% and if the productivity is more than 0.5. If all conditions is met it should write in column "Good boy student/good girl student" that it is a good boy student if it is Male and a good girl student if it is Female.

Dear Alexander,

Is it also possible that if conditions are not met it would leave blank or write N/A in the cell?

Best regards

Hello!

If I understand your task correctly, the following formula should work for you:

=IF(AND(B1 > 0.7,C1 > 0.5),IF(A1="Male","Good boy student","Good girl student"),"")

Hope this is what you need.

Thank you very much,

It works,

Best regards

Dear Alexander,

I am sorry for confusing you,

I have four columns: Gender(there it is written Male and Female), than Score(Percent of score written), Productivity(number written) and empty column named(Good boy student/good girl student)

The task is to make formula which checks if it is a male of female, than if the score is more than 70% and if the productivity is more than 0.5. If all conditions is met it should write in column "Good boy student/good girl student" that it is a good boy student if it is Male and a good girl student if it is Female.

Is it also possible that if conditions are not met it would leave blank or write N/A in the cell?

Best regards

Is there a way that I can combine an IF with an AND and OR functions?

Here are the two that I need help combining:

IF(AND(A1="fruit",B1="old"),C1*70%,C1*55%)

IF(AND(A1="veggie",B1="old"),C1*50%,C1*40%)

Hello!

These two formulas cannot be combined into one, since they contradict each other. If A1 = ”fruit”, B1 = ”new”. These values mean FALSE in both formulas. What should the formula return - C1 * 55% or C1 * 40%?

That's what I was afraid of... -_-

Thank you for your help!

=IF((AND(H6,H8,H11)="Valid"),"Valid","Invalid")

Can you please identify the problem

I am trying to pass on a text" Valid" when all 3 cells display "Valid" otherwise "Invalid"

Hi,

Can you help for following condition.

If P3 is >0.05 then P3-0.05

If P3 is <-0.05 then P3+0.05

if P3 is in between 0.05 and -0.05 then PASSED

HOW TO WRITE FORMULA

THANKS :)

=IF(P3>0.05,P3-0.05,IF(P3<-0.05,P3+0.05,"Passed"))

Hello Charles!

If I understand your task correctly, the following formula IF should work for you:

=IF(P3 > 0.05,P3-0.05, IF(P3 < -0.05,P3+0.05, "PASSED" ) )

I hope this will help

Hi I am working on a shift schedule where we have different shifts namely as follow:

Shift: 1 - 06h00 - 14h00 = 6hours

Shift: 2 - 14h00 - 20h00 = 6hours

Shift: 3 - 20h00 - 06h00 = 10hours

Shift: 4 - 08h00 - 17h00 = 9hours

Shift: + - 06h00 - 10h00 & 16h00 - 20h00 = 8hours

Shift: N - 18h00 - 06h00 = 12hours

or if employee is off then it will be a Letter O and that should equal to 0

So the idea is that should an employee work a shift on say block C9, whether it is any of the above shifts that it automatically gives the hours on the on say block K9.

So I tried the following formula but it simple does not work.

=IF(C9=1;6;0)OR(IF(C9=2;6;0;)(IF(C9=3;10;0)(IF(C9=4;9;0)(IF(C9=+;8;0)(IF(C9=N;12;0)(IF(C9=O;0;0)

Not to sure if I explained it correctly, but hope you can help with this.

Hello Dwayne!

If I understand your task correctly, the following formula should work for you:

=IF(OR(C9=1,C9=2),6, IF(C9=3,10, IF(C9=4,9, IF(C9=""+"",8, IF(C9=""N"",12, IF(C9=""O"",0,0))))))

Hope this is what you need.

Hi, I want to take a table where column A is a simple numbered list, 1-10, and column B is the value corresponding to the number to it's left in that row, in column A. Then I want to automate my spreadsheet so that when I enter any number, 1-10, in column C, it returns the correct value from the table. I know how If and OR and INDEX work, but I cannot figure out how to create the command, which I am assuming will be a string of 10 nested commands, such as for my 1st entry in C1: "If(OR(A1=1,"B1"),(A1=2,"B2"),(A1=3,"B3"))...etc". Thanks!

Hello Peter!

if you entered a number in cell C1, you can replace it with some other value only using the VBA macro. A cell can contain either a value or a formula. Depending on the value of C1, cell D1 can be changed.

Please help me, to generate IFs formula: given the situation, that I have 3 cases and fall into 80,000, the percentage should be 9% because it is below 100,000. Please help in formulating formula. I tried several times but I can't.

Below are the conditions to be met.

CASES 50000 75000 100,000 150000 200,000 250000

1 2% 5% 10% 15% 21% 27%

2 3% 7% 13% 20% 28% 35%

3 4% 9% 17% 27% 35% 45%

4 4% 9% 17% 27% 35% 45%

5 4% 10% 19% 30% 38% 47%

6 4% 10% 19% 30% 38% 47%

7 5% 12% 22% 32% 40% 50%

Hoping for your usual support on the matter.

Hello Joe!

You need to use the function NDEX MATCH with multiple criteria in rows and columns. Read these instructions in detail.

If you need any further assistance, please don’t hesitate to ask.

Total Taxable amount USD 10,00,000/-Tax free 3,00,000/- reducing balance 7,00,000/- 1st slab amount 1,00,0000/- How will i show in the row by formula 1,00,000/- next row 2,00,000/- next row 4,00,000/- (Auto reducing method not)

I will be grateful if you help me

YASIN

Hello!

I’m sorry but your task is not entirely clear to me. For me to be able to help you better, please describe your task in more detail. Please specify what you were trying to find, what formula you used and what problem or error occurred. Give an example of the source data and the expected result.

It’ll help me understand it better and find a solution for you. Thank you.

Hi, I really need help to add a final condition to this formula below, I have tried a few different things and just keep getting errors so any input would be great if it is possible

=IF(AND(C3=$A$3,I3<1,"Y","N") BUT IF M3="Transfer Debit"=N

Hello Sabina!

I’m sorry but your task is not entirely clear to me. Could you please describe it in more detail?

What does it mean "IF M3="Transfer Debit"=N"??

Thank you!

Hi Alexander, thanks for your quick response so basically I need to add an extra criteria to the formula. The first part is fine but the extra condition is basically but if cell M3 contains the text Transfer Debit change it to N... is this even possible? Or would it be a completely different formula?

(summary of formula - If column C = A and column I < 1 = Y but if M3 = Transfer Debit N and everything else N).. hope this makes sense, sorry I'm not great at excel so might be why i am not very clear.

Hello Sabina!

If I understand your task correctly, the following formula should work for you:

=IF(M3="Transfer Debit","N", IF(AND(C3=$A$3,I3 < 1),"Y","N"))

I hope this will help

Thank you so much, it worked!!!

=IF(E2>=70, "Excellent", IF(E2>=60, "Good", IF(E2>40, "Satisfactory", "Poor ")))

What are the best alternatives for this formula?

I tried = If(AND...), / If(OR...) but couldn't get the expected result.

Little help will be well appreciated.

If column A is 1 then cell X If Column b is 1 then Cell Y otherwise C*D.

Any help?

Hello Sean!

Your conditions contradict each other. What if both column A = 1 and column B = 1? If both conditions are met? Read carefully the IF function with multiple conditions above.

Hello, I am trying to accomplish a formula that is evaluating multiple cells to return a specific answer. I am using if/and but I cannot seem to get a does not contain to work? Here is my formula, the AE2 part is where it is failing. Any ideas?

=IF(AND(K2="Parent",AQ2="Chassis",AE2"*DECOMM*"),"Chassis/Parent","NOT Chassis/Parent")

Supposed to work a.... K2 = Parent and AQ2 = Chassis and AE2 does not contain DECOMM then return the false/positive value.

Hello Josh!

If I understand your task correctly, the following formula should work for you:

=IF(AND(K2="Parent",AQ2="Chassis", ISERROR(FIND("DECOMM",AE2,1))),"Chassis/Parent","NOT Chassis/Parent")

I hope it’ll be helpful.

Alexander, Thank you so much this worked perfectly!

Hello, can you kindly help me with this formula? Been stuck on this for hours.

Total amount: Cell E29

Discount: >3000 -10% >5000 -15% >10000 -20%

Formula written: =IF(E29>=3000,"E29*-0.1", IF(AND(E29>=5000,"E29*-0.15", IF(AND(E29>10000,"E29*-0.2","0")))))

Thankyou for helping! Your help is very much appreciated!

Hello Jerelina!

The formula below will do the trick for you:

=-IF(E29>=10000,E29*0.2, IF(E29>=5000,E29*0.15, IF(E29>=3000,E29*0.1,0)))

I hope this will help

Hi Can someone help me please?

I am trying to put a formula for example if the Price is let's say £100 to be split into three columns like column one will be 0-£50

Column two will be for anything that is above £50 but less or equal to £60

Column three anything that is above £60 but less or equal to £70.

Column four anything about £70.

If any of the conditions don't meet let's say if column two is less than £50 to bring 0.

Any help is much appreciated.

Mita.

Hello Mita!

I’m sorry but your task is not entirely clear to me.

Please describe your problem in more detail. Include an example of the source data and the result you want to get. It’ll help me understand your request better and find a solution for you. Thank you.

I am trying to calculate commission income. If gross commission is >220,000 then the net amount of commission they earn goes up. Here are my conditions:

0-220,000 - .60

220,001-440,000 - .65

440,001-660,000 - .70

660,001-880,000 - .75

880,001+ - .80

This is the formula I'm working with but it keeps coming back as #VALUE! =IF(OR(BR125>220001,BR125440001,BR125<=660000),BR8*BR4,"")

What am I doing wrong?

Thank you so much for your help, I'm ready to pull my hair out.

Megan

Hello Megan!

If I understand your task correctly, the following formula IF should work for you:

=IF(A1>880000,B1*0.8, IF(A1>660000,B1*0.75, IF(A1>440000,B1*0.7, IF(A1>220000,B1*0.65, B1*0.6))))

Hope this is what you need.

You are a life saver! Guess I was making this harder than it needed to be. Thanks for getting me on the right track and thank you for taking the time to help all of us!

Hello Alexander,

I want to decide the candidate is eligible or not, if the cell is contain NA or date ..how to write formula

Hi,

I need your help with the below condition.

If Cell B7=30000 then B9 should be 4(this value is in the cell H10)

If Cell B7=50000 then B9 should be 4(this value is in the cell H11)

If Cell B7=100000 then B8 should be 4(this value is in the cell H12)

If Cell B7=150000 then B8 should be 5(this value is in the cell H13)

If Cell B7=200000 then B8 should be 5(this value is in the cell H14)

If Cell B7=330000 then B8 should be 4(this value is in the cell H15)

If Cell B7=500000 then B8 should be 4(this value is in the cell H16)

Kind regards

Mohsin

Hello!

If I understand your task correctly, the following formula IF should work for you:

=IF(B7=30000,H10, IF(B7=50000,H11,IF(B7=100000,H12,IF(B7=150000,H13,IF(B7=200000,H14, IF(B7=330000,H15, IF(B7=500000,H16,"")))))))

I hope it’ll be helpful.

Hi,

I really need your help, identifying the proble with my formula.

if value range of is as bollow,

For income range 20,000 to 29,999 ratio is 35% for type A, 30% for type B.

and income range 30,000 to 49,999 ratio is 40% for type A, 35% for type B.

Here,

D9 = location of the cell which is a dropdown menue whether to choose A/ B

G22 = location of the cell which is a used for input ranging from 0 - 50000

H127 =

=IF(AND(G22<30000,D9="A"),.35,IF(AND(30000<=G22,G22<50000,D9="A"),.40,IF(AND(G22<30000,D10="B"),.30,IF(AND(30000<=G22,G22<50000,D10="B"),.35,))))

Thanks

Nizam

Hello!

If I understand your task correctly, the following formula IF should work for you:

=IF(AND(G22 > 20000,G22 < 30000),IF(D9="A",0.35,IF(D9="B",0.3,0)),IF(AND(G22 > 30000,G22 < 50000), IF(D9="A",0.4,IF(D9="B",0.35,0)),0))

I hope it’ll be helpful.

Hi I'm having troubles nesting all 4 formulas together. Is it possible? Please help!

1) =IF(AND(BF2>=62,BH2>=5),"ELIGIBLE TO RETIRE", "not eligible to retire")

2) =IF(AND(BF2>=60,BH2>=20),"ELIGIBLE TO RETIRE", "not eligible to retire")

3) =IF(AND(BF2>=55,BH2>=30),"ELIGIBLE TO RETIRE", "not eligible to retire")

4) =IF(AND(BF2>=55,BH2>=10),"ELIGIBLE TO RETIRE", "not eligible to retire")

Example #1 (BF=Age)Age 63 with BH=yrs of svc)15 years of service - should be true for both 1 & 2 arguments

Example #1 (BF=Age)Age 57 with BH=yrs of svc)15 years of service - should be true for argument 4

I figured it out. Just needed to read an earlier post you provided to someone else!! Thank you for all you do! All of you Excel gurus!! Have a great day!

=IF(AND(BF2>=62,BH2>=5),"ELIGIBLE TO RETIRE",IF(AND(BF2>=60,BH2>=20),"ELIGIBLE TO RETIRE",IF(AND(BF2>=55,BH2>=30),"ELIGIBLE TO RETIRE",IF(AND(BF2>=55,BH2>=10),"ELIGIBLE TO RETIRE","not eligible to retire"))))

Hello!

If I understand your task correctly, the following formula should work for you:

=IF(OR(AND(BF2>=62,BH2>=5,AND(BF2>=60,BH2>=20),AND(BF2>=55,BH2>=10))),"ELIGIBLE TO RETIRE", "not eligible to retire")

I hope it’ll be helpful.

I am trying to make a column populate a specific rate based on criteria in the two columns before it.

Column 1 is their name

Column C is their insurance (BLTC or MCLTC)

Column D is the level assigned (Level 1, Level 2, level 3)

Column E is the rate per day we receive based on insurance and level as they are distinct. For example if you have BLTC and are a level 2 it would be $207.31. If you are MCLTC and level 2 is would be $200.07. I would like column 4 to auto populate based on insurance and level as the rates are specific by insurance and level.

Can anyone help me with this? Thanks in advance!

Hi

I am trying to get multiple areas to display based on 2 or 3 chars. Tried this below formula but they are not returning the right Areas.Column F2 has a about 7-8 chars and i want to search the first 2 and 3 chars. Can you please help?

Hope this makes sense. Thank you!

=LOOKUP( LEFT(F2, 3), {"AL,N1,N2,N3,NW,EN","SL9,SL0,WD,HP","SG,LU,CM,CB,RM","GU,TW,KT,SL5,SL4","SL3,HA,UB"}, {"Area 1","Area 2","Area 3","Area 4","Area 5"})

Below is the criteria

GU Area 4

TW Area 4

KT Area 4

SL9 Area 2

SL3 Area 5

SL0 Area 2

SL2 Area 5

SL5 Area 4

SL4 Area 4

SG Area 3

LU Area 3

CM Area 3

CB Area 3

RM Area 3

WD Area 2

HA Area 5

UB Area 5

HP Area 2

EN Area 1

NW Area 1

N1 Area 1

N2 Area 1

N3 Area 1

AL Area 1

Hello!

If I understand your task correctly, the following formula should work for you:

=CHOOSE(MATCH("*"&LEFT(F2, 3)&"*", {"AL ,N1 ,N2 ,N3 ,NW ,EN ","SL9,SL0,WD ,HP ","SG ,LU ,CM ,CB ,RM ","GU ,TW ,KT ,SL5,SL4","SL3,HA ,UB "},0), "Area 1","Area 2","Area 3","Area 4","Area 5")

I hope this will help

This worked. I just had to change the F2,2 and will just have to ignore the 3 chars as this will complicate allot of it more. Thanks you again Alex.

Please be so kind and support me with the formula:

=IF(AND($K13;"";$N13;"";$O13;"");"No Risk";IF(AND($K13;"";$N13;"";O13;"");"Middle Risk"))

Somehow it doesn't work and I get only "No Risk" based on first logical test.

Thank you

Hello Olya!

You used the same formulas for different IF conditions. Maybe you should use something like this formula

=IF(AND($K13="",$N13="",$O13=""),"No Risk", IF(AND($K13<>"",$N13<>"",O13<>""),"Middle Risk",""))

I hope this will help, otherwise please do not hesitate to contact me anytime.

1 2 3 = =IF(A2,NUMBERVALUE(A2),B2) = Pass

2 3 = =IF(A3,NUMBERVALUE(A3),B3) = Pass

3 = =IF(A4,NUMBERVALUE(A4),B4)*(IF(B4,NUMBERVALUE(B4),C4)) - Fail

Can you please let me know why 3rd formula is not working.

Hello!

I’m sorry but your task is not entirely clear to me. Could you please describe it in more detail? In your data, B4 = 0? C4 = 0? Formula 3 returns 0. What value should formula 3 return? What result would you like to get with these formulas?

I have a nominal concentration with +- 15% acceptance criteria.

Some data generated (at least 500), in which some are within acceptance criteria and some are out of acceptance criteria.

I need to calculate, mean, SD, CV and nominal after including and excluding out of acceptance criteria values.

I have multiple products in column b. What I want to do is in Column A - I need to be able to have only 3 product labels namely Alpha, beta and charlie.So for example all products in column b having the word alpha in their product name will be labeled as alpha. Then for all products with beta labeled as beta and for the rest which does not meet the criterias will be labeled as charlie..checking for your asssistance and thanks in advance.

Hello!

I’m sorry but your task is not entirely clear to me.

Please describe your problem in more detail. Include an example of the source data and the result you want to get. It’ll help me understand your request better and find a solution for you. Thank you.

Greetings,

i seeking you kindly support and assistance on below table range, how can i use the IF Function on below.

if a transaction value 40000, the first 2999 to be rewarded @ 0.50@ and 3,000 -9,999 @ 1% and so on as on below table.

Spend Range Domestic Cashback % International Cashback %

0-2,999 0.50% 1.00%

3,000 -9,999 1.00% 1.50%

10,000-19,999 1.25% 2.00%

20,000-39,999 1.50% 2.50%

>=40,000 3.00% 5.00%

See here the solution to the same problem

for every full R100 due(amount after discount),the manager gives R12 to a charity fund .

form an if statement ..

I need help

Hello!

If I understand your task correctly, to calculate the amount of contributions to a charity fund, use the formula

=INT(Q100/R100)*R12

Q100 - Sales Amount

Hope this is what you need.

D71521151 22/05/2020 0.02

D71519430 20/05/2020 0.27

D71520950 22/05/2020 0.15

D71520985 22/05/2020 0.40

D71522327 28/05/2020 0.32

Third coloumn value is weight and if i want to get result in 4th coloumn with conditions that if weight is <.1 then 50, If it is between .1 to .25 then 100 and if it is .25 to .5 then 150.

How we can do this???

Please suggest.

Hello!

To select the third value from a cell, use the formula

=--TRIM(RIGHT(SUBSTITUTE(A1," ",REPT(" ",20)),20))

Then use the recommendations from this article to create the IF formula

I want a function that work like this

I have this options (Invoice, Payment, Credit note, Expense) as a drop-down-list in Cell A1

entering an Amount on Cell B1 and expect the change in Cell C1 where the balance will change when an option is selected at cell A1

1. Invoice, the amount in cell B1 will add up to the balance Amount in cell C1

2. if other options are selected the Amount in B1 will reduce the value in Cell C1

Hello Gabriel!

If I understand your task correctly, the following formula should work for you:

=IF(A1="Invoice",B1+C1,C1-B1)

The formula can be written in D1

I have two columns. If there are duplicates in column A of a certain namex, column B MUST be the same for each duplicate with a true/false as the output. Example

A1 B1

123 t2

123 t2

I have over 6000 rows and have tried to use two if statements but this entails searching for the duplicates of each name which is tedious as there could be human errors and I could miss one. There is not an equal amount of duplicates for each input in column A either. I also don't know what column B should be. All i know is that they should be equal for the each duplicate of that type in column A. Let me know if you have questions

Hello Blanca!

Your explanation is not very clear. Manually working with so much data is very difficult. Therefore, I recommend using the ready-made solution Ablebits Data - Duplicate Remover.

This tool is available as a part of our Ultimate Suite for Excel that you can install in a trial mode and use for free: https://www.ablebits.com/files/get.php?addin=xl-suite&f=free-trial

If cell A value >50000,1% rebate is obtained. If cell A value >100,000,2% rebate , >200,000,2.5% Rebate , >300,000 3% rebate is obtained

Hello!

See here the solution to the same problem

I need to create a formula that will determine the % Error based on a low and high range for the % of error. In my spreadsheet, I have a table (shown below) that has the % of Error and ranges assigned as follows. If I want to determine the % of error on a cell value that is 29, I need to create a formula that will check all of the potential ranges in the table to find that the right answer is 20%. I have tried to create a formula using IF and AND, but can't quite get it to work. Any help is appreciated!

% Error Low High

10% 36 45

20% 27 35

40% 18 26

60% 9 17

80% 5 8

5. Brittany wants to identify employees who are eligible to take a CPR course at the clubs' expense. Employees who can work as camp counselors are eligible for the course. In cell M3, enter a formula using a nested IF function as follows to determine first if an employee has already been trained in CPR, and if not, whether that employee meets the qualifications to take the course:

a. If the value in the CPR Trained column is equal to the text "Yes", the formula should display Trained as the text.

b. Otherwise, the formula should determine if the value in the Camp Counselor column is equal to the text "Yes" and return the text Yes if true and No if false.

Hello!

Read the article above carefully. It has all the necessary information on using the IF function. You will be able to complete your task.

Hello, I am trying to combine some if statements with index match (Exact Formula Below) and have a mostly working formula except I would like to return a value if there is no value in the returning cell. Basically I am getting "1/0/1900" or "0" when the formula finds an empty cell. I am not sure if the if(len( can be added to the below? If so I am not sure where to place it :)

=IFERROR(IF($A2="","ADD SERIAL",INDEX('RACS 06-15-2020'!CS:CS,MATCH($A2,'RACS 06-15-2020'!$M:$M,0))),"NOT IN RACS")

Hello Josh!

Unfortunately, without seeing your data it hard to give you advice.

Perhaps this IF formula will replace 0 with another value.

=IF(IFERROR(IF($A2=””,”ADD SERIAL”,INDEX(‘RACS 06-15-2020′!CS:CS, MATCH($A2,’RACS 06-15-2020’!$M:$M,0))),”NOT IN RACS”)<> 0,IFERROR(IF($A2=””,”ADD SERIAL”,INDEX(‘RACS 06-15-2020′!CS:CS, MATCH($A2,’RACS 06-15-2020’!$M:$M,0))),”NOT IN RACS”),"Value")

I hope it’ll be helpful.

Hello, thank you and Please help:

=IF(R3219="Shopify Payments",(N3219*0.965-0.3), OR(R3219="Stripe Connects",(N3219*0.971-0.3)))

If shopify payment on Cell R3219, multiple N3219 by 0.965 minus 0.3 cents, but if R3219 is stripe connects, multiple N3219 by 0.971 and minus 0.3 instead.

Thank you

Hello Philip!

If I understand your task correctly, the following formula should work for you:

=IF(R3219="Shopify Payments",N3219*0.965-0.3, IF(R3219="Stripe Connects",N3219*0.971-0.3,0))

I hope this will help

=IF(AND([@[PO Number]]"",[@[Fob Date.]]"",[@[Invoice No.]]"",[@[Onboard Date]]="",[@[BL NO.]]="",[@[Doc''s Sub HSBC]]=""),"NEED GSP SUBMIT",IF(AND([@[PO Number]]"",[@[Fob Date.]]"",[@[Invoice No.]]"",[@[Onboard Date]]"",[@[BL NO.]]"",[@[Doc''s Sub HSBC]]=""),"BANK DOCS PENDING",IF(AND([@[PO Number]]"",[@[Fob Date.]]"",[@[Invoice No.]]"",[@[Onboard Date]]"",[@[BL NO.]]"",[@[Doc''s Sub HSBC]]""),"PROCESS OK","WARNING")))

Please clarify above formula logic I do not understand

Hello!

Unfortunately, without seeing your data it hard to give you advice.

The formula uses named ranges and references to an Excel spreadsheet.

In many cases, it’s easier to write your own formula than to try to understand someone else’s formula.

I want to calculate a Reorder Level for Inventory.

The Formula in text is:

[Opening Inventory + Material Received - Material Sold = Closing Inventory]

Closing Inventory cannot be negative and a particular material should be ordered only if

the Closing Inventory falls below a particular level, say below 5kg.

Hello!

If I understand your task correctly, the following formula should work for you:

=IF(Closing Inventory<5,"Reorder",Closing Inventory)

Hi,

I am trying to put in a formula that will have 6 awnsers depending on a drop down which has 3 choices and another drop down which is a yes/No drop down. But i cant get it to work im using the IF And fuctions. I you can help it would be much appreciated.

=IF(AND($P$4="YES",H4="STANDARD"),'Support Item Name'!C2:C8,IF(AND($P$4="YES",H4="INTENSITY 2"),'Support Item Name'!C9:C15,IF(AND($P$4="YES",H4="INTENSITY 3"),'Support Item Name'!C16:C22,IF(AND($P$4="NO",H4="STANDARD"),'Support Item Name'!C23:C29,IF(AND($P$4="NO",H4="INTENSITY 2"),'Support Item Name'!C30:C36,IF(AND($P$4="NO",H4="INTENSITY 3"),'Support Item Name'!C37:C43))))))

Hello Donald!

I’m sorry but your task is not entirely clear to me. For me to be able to help you better, please describe your task in more detail. Describe in detail all the conditions that you use. What result corresponds to each of the conditions? It’ll help me understand it better and find a solution for you. Thank you.

How can I use this condition in an if statement. For example. If CA is between 20 and 25

I Want to put condition like if value of E1 is less than 100 multiply E1 with X1 and if value of E1 is between 101 to 300 multiply E1 with X2. Please help.

+if(E1<100,100<E1<301),"E1*X1","E1*X2")

Hello Safal!

If I understand your task correctly, the following formula should work for you:

=IF(E1<100,E1*X1,IF(E1<301,E1*X2,""))

I hope it’ll be helpful.

please coach me on the Nested functions on between and reduction % of the following:

Between 5,001 and 7,500 - reduction 2.5%

Between 7,501 and 10,000 - reduction 5%

Between 10,001 and 20,000 - reduction 10%

Between 20,001 and 30,000 - reduction 20%

More than 30,000 - reduction 30%

Good day, I am trying to write a formula that calculates the accumulation of days for every certain amount of days worked, for example. for every 16 days worked, 1.25 accumulates in the next column.

Hi, I'm trying to do an "if" or change an "if" statement. Right now it says

=IF(W5=5000,W5-5000))

When figures are put in column Z if there is nothing over 5000 then it puts (5000) in column AG and I want it to read 0. I've tried everything to make it work even reducing the formula to:

=IF(W5>5000,W5-5000,"0") but it still puts (5000).

So not sure how to fix this issue just want column AG to read 0 if there is any figure or a zero in column Z.

Thanks Kathi

the first formula is =IF(W5=5000,W5-5000))

cut and paste is removing some of the formula: =if (W5=5000, W5-5000))

Hope this works

Hello Kathi!

I’m sorry but your task is not entirely clear to me. For me to be able to help you better, please describe your task in more detail.

You put numbers in column Z, and the formula refers to column W. Is that correct? What does the AG column have to do with this?

Give an example of the source data and the expected result.

It’ll help me understand it better and find a solution for you. Thank you.

Hi,

Column W = Taxable Amount

Column Z = Non-Taxable Amount

Column AG = Results

Example: if Column W has taxable amount less than or equal to 5000 then the result in Column AG reads zero which is correct; however, if Column Z (non-taxable) has an amount and Column W (taxable) has no amount or zero then Column AG (results) puts -5000 and the result should be zero. The only time Column AG would have an actual amount would be if Column W (taxable) is more than 5000 and then any amount over 5000 would be what shows in Column AG (results). It's where I track sales tax for revenue and to get what I report to the state. We have a DOS based accounting system that is very antiquated. I hope this helps with the explanation.

Kathi

Hello Kathi!

If I understand your task correctly, the following formula should work for you:

=IF(W1<=5000,0,IF(AND(Z1>0,W1=0),0, W1-5000 ))

Hi,

I need to apply two condition in my excel column which IFERROR function (since if divided by 0 the value will return to "-") and second one is IF function (when the divided value become -1 and the value will return to "-").

very appreciate if you can help me.

thanks

Hello Saleh!

Unfortunately, without seeing your data it hard to give you advice.

I hope you have studied the recommendations in the above tutorial.

I recommend that you study this article on using the IFERROR function.

Scenario No. 1

Col.1 Col.2 Col.3

100 0 x

Scenario No. 2

Col.1 Col.2 Col.3

0 100 x

Col.3 (x) is to find the percentage diff. between Col.1 and Col.2

Scenario 1. ((Col.2-Col.1)/Col.1)=-1

Scenario 2, ((Col.2-Col.1)/Col.1)=Div/0

so for both scenario i need to return as "-"

Scenario. 1 Scenario 2

+IFS(IFERROR((Col.2-Col.1)/Col.1,"-"),"-",(G84-$D84)/$D84=-1,"-")

Can you advise.

Thanks

Saleh

Hello Saleh!

If I understand your task correctly, the following formula should work for you:

=IFS(ISERROR((B1-A31)/A1),"-", ISERROR((F1-E1)/E1),"-")

I hope this will help, otherwise please do not hesitate to contact me anytime.

I'm trying to use the following formula but it's not giving the correct results.

=IF(OR(AND(J137="ASSEMBLY",K137"N"), OR(J137="ASSEMBLY",K137"Y")),G137,C136)

What I'm looking for is if J137 = Assembly and K137 is not N or Y display G137, else display C136. I'm not sure what I'm missing here.

Formula should have read

=IF(OR(AND(J137="ASSEMBLY",K137"N"), OR(J137="ASSEMBLY",K137"Y")),G137,C136)

Hello Bill!

If I understand your task correctly, the following formula should work for you:

=IF(AND(J137="ASSEMBLY",OR(K137<>"N",K137<>"Y")),G137,C136)

I hope it’ll be helpful.

Hi I'm trying to figure out a if statement for my "total add-on price" column. I want my formula to be if the customer purchased three or more add-on options,(which prices are listed under the different add on options) they receive a 15% discount on all add on options?

Hello Courtney!

I hope you have studied the recommendations in the above tutorial. Please specify what what formula you used and what problem or error occurred. Include an example of the source data and the result you want to get. It’ll help me understand the problem you faced better and help you.

What is the formula

If below 1,000, the rate is 2.00

If 1,000 and above, the rate is 2.20

Hello Marvin!

I hope you have studied the recommendations in the above tutorial.

=IF(A1<1000, 2 , 2.2)

Hello,

Can you please help me how to how to get exact formula of binary computation in excel. if C5 is less than to D5 or D5 is less than C5 and multiply to 20%. Thank you

Hello Johnzin!

Your conditions "if C5 is less than to D5 or D5 is less than C5" contradict each other. One of them will always be executed. Therefore, your formula does not make sense.

9873424761 6700670610

9873424761

9873424761 9873424761

6700670610

If first and second column is different then print both

if first column is blank and second column is number then print number

if first and second column are same then print any one

if first column number and second is bland then print first column

Hi question is there is Incentive which I have to pay to my employees according to their collection please refer below and I would like to calculate their incentive " % " based on their collection. please send me formula for the same.

Amount Percentage

25000-30000 10%

30001-40000 20%

40001-50000 30%

Name of the employees Amount collected Incentive

John 25000

Paul 32000

Peter 32500

Isaac 48010

Lemuel 32180

Hello!

See the answer to the question above.

Hi, I'm trying to figure out how to create a certain formula and am hoping someone can help. Here's what I want to do:

Ex. If cells F7, F8, and F9 are NOT blank, return a value of "YES" to cell G7.

Basically, the criteria in F7, F8, and F9 has to be checked off before G7 can be marked off as complete. I can do a "normal" If/then function referencing 1 cell, but am having trouble figuring out how to set a "True" value when referencing multiple cells.

Thank you!!

Hello Joanne!

I hope you have studied the recommendations in the above tutorial.

If I understand your task correctly, the following formula should work for you:

=IF(AND(F7<>"",F8<>"",F9<>""),"Complete","")

Hi, please I can't make the mega formula for the followings, please help me out:-

Section Chapters

I 1 to 5

II 6 to 14

III 15

IV 16 to 24

V 25 to 27

VI 28 to 38

VII 39 to 40

VIII 41 to 43

IX 44 to 46

X 47 to 49

XI 50 to 63

XII 64 to 67

XIII 68 to 70

XIV 71

XV 72 to 83

XVI 84 to 85

XVII 86 to 89

XVIII 90 to 92

XIX 93

XX 94 to 96

XXI 97

For above infomation, how can a cell returns 'Section' in roman letters if fall in the right chapter number?

Anubody can help to solve this?:

I have following conditions

Cell A1 = value $1000

Cell B1 = text A

Cell C1 = text B

Cell D1 = cell condition TRUE or FALSE (always on condition is set)

Now I want to do following in cell E1

1.) IF B1=C1 AND D1=TRUE => calculate A1*0.1

2.) IF B1=C1 AND D1=FALSE => calculate A1*0.2

3.) IF B1C1 => 0

1.) IF B1=C1 AND D1=TRUE => calculate A1*0.1

2.) IF B1=C1 AND D1=FALSE => calculate A1*0.2

3.) IF B1C1 => 0

Hello!

Explain what it means "3.) IF B1C1 => 0"

I was confused in formula can you please help me out

1840 P

1841 A

1842 P

1843 P

1844 P

1845

I need to mark "P"(present) and "A"(absent) all numbers but i have only list of numbers which are "P" (present)

I need to mark both P and A

will be very thankful if you reply :)

Hello Jamin!

I’m sorry but your task is not entirely clear to me. For me to be able to help you better, please describe your task in more detail. Please specify what you were trying to find, what formula you used and what problem or error occurred. Give an example of the source data and the expected result.

It’ll help me understand it better and find a solution for you. Thank you.

How do i do an IF formula similar to below that actually works

=IF(A5>1=(B5*120,IF(A5<1=B5*40)))

Please help!

Hello William!

Please use the following formula

=IF(A5>1,B5*120,B5*40)

I hope this will help

I am trying to use excel to add or subtract a value if it falls into a certain ranges otherwise just place the number in the correct box.

the ranges are:

145.1-145.5, 146.6-146.999999,147.6-148.0 subtract .6

146.0-146.4, 147.0-147.4 add.6

All other just move the entered number the cell.

I can get it to do it to one set of ranges, but it fails when I try and use multiple ranges.

Any help would be greatly appreciated.

Thank you

This is the formula that I am currently trying to use, but numbers outside the ranges are subtracted.

=IF(OR(B2>=145.09999,B2=146.599999,B2=147.5999999,B2<=148.00001),B2-0.6,B2)

Example. If I enter 144.100 I still get the answer of 143.500

Hello!

The formula below will do the trick for you:

=IF(OR(AND(A1>145.1,A1<145.5),AND(A1>146.6,A1<146.9999),AND(A1>147.6,A1<148)),A1-0.6,IF(OR(AND(A1>146,A1<146.4),AND(A1>147,A1<147.4)),A1+0.6,A1))

Hope this is what you need.

Hi there

I need assistance with the following formula please:

=IF(AND(K11=0),(OR(ISNUMBER(SEARCH("8000000",C11)),ISNUMBER(SEARCH("9000000",C11)),ISNUMBER(SEARCH("9100000",C11)),ISNUMBER(SEARCH("9500000",C11)))),"NO","YES")

I need 2 criteria to be met.

If colomn K's value is = 0

AND the text in column C contains 8000000 or 9000000 or 9100000 or 9500000

Result should be NO

Otherwise YES

Thanks for your help

Hello Elouise!

If I understand your task correctly, the following formula should work for you:

=IF(AND(K11=0,OR(ISNUMBER(SEARCH("8000000",C11)), ISNUMBER(SEARCH("9000000",C11,1)),ISNUMBER(SEARCH("9100000",C11,1)), ISNUMBER(SEARCH("9500000",C11,1)))),"NO","YES")

I hope this will help

Hello, I am trying to figure out a formula by which if a cell contains yes it will add a specific amount to 4 totals in different cells.

If yes add 1 million to running Total in 2 different cells, 750k to another and 500k to the last cell.

What kind of formula would I be looking for?

Thank you for any help!

Hello Josh!

The Ecxel formula can only change the value of the cell in which it is written.

For distance calculation Compare two cell and third must automatic enter .

If A & B - 2

If A& C = 3

If A&D = 4

If B&C = 5 et., to compare 20 possibilities

Hello!I’m sorry but your task is not entirely clear to me. For me to be able to help you better, please describe your task in more detail. Please specify what you were trying to find, what formula you used and what problem or error occurred. Give an example of the source data and the expected result.

It’ll help me understand it better and find a solution for you. Thank you.